Exemples de jeux de données Cast3M

* fichier :  patch_test_contact.dgibi
************************************************************************
************************************************************************
*
* Modelisation du patch test en 2D et 3D
* Utilsation d'elements lineaires et quadratiques
* Comparaison de la resultante des reactions de contact a la valeur
* imposee.
*
************************************************************************
ITRAC = FAUX ;
 
* Logique indiquant si il y a eu une erreur
berr = FAUX ;
xerr = 1.E-3 ;
 
** Nombre d'element par arete
*  solide 1 (en bas)
*  solide 2 (en haut)
ne1 = 2 ;
ne2 = 3 ;
 
* Valeur de pression imposee
VPRES = 25.E6  ;
 
* Type d'elements
LELEM = 'MOTS' 'QUA4' 'QUA8' 'CUB8' 'CU20';
'REPE' B1 ('DIME' LELEM) ;
*
  ELMZ = 'EXTR' LELEM &B1 ;
*
** Maillages et C.L.
  'SI' ('&lt;EG' &B1 2) ;
    'OPTI' 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ELEM' ELMZ ;
*
    p1   = 0. 0. ;
    p2   = 1. 0. ;
    p3   = 0. 1. ;
    p4   = 1. 1. ;
*
    sur1 = 'DROI' ne1 p1 p2 ;
    sur3 = 'DROI' ne2 p3 p4 ;
*
    vol1 = sur1 'TRAN' ne1 (0. 1.) ;
    vol2 = sur3 'TRAN' ne2 (0. 1.) ;
    vol  = vol1 'ET' vol2 ;
*
    sur2 = vol1 'COTE' 3 ;
    sur4 = vol2 'COTE' 3 ;
*
    are1 = 'CONT' vol1 ;
    are2 = 'CONT' vol2 ;
    are  = are1 ET are2 ;
*
    x y  = 'COOR' are ;
    ptx0 = x 'POIN' 'EGAL' 0. ;
    bl1  = ('BLOQ' 'UX' ptx0 ) ET ('BLOQ' 'UY' sur1) ;
*
    MOSIG = 'SMYY' ;
    MOFOR = 'FY' ;
  'SINON' ;
    'OPTI' 'DIME' 3 'MODE' 'TRID' 'ELEM' ELMZ ;
*
    p1    = 0. 0. 0. ;
    p2    = 1. 0. 0. ;
    p3    = 0. 0. 1. ;
    p4    = 1. 0. 1. ;
*
    lig12 = 'DROI' ne1 p1 p2 ;
    lig43 = 'DROI' ne2 p4 p3 ;
*
    sur1  = lig12 'TRAN' ne1 (0. 1. 0.) ;
    sur3  = lig43 'TRAN' ne2 (0. 1. 0.) ;
*
    vol1  = sur1 'VOLU' ne1 'TRAN' (0. 0. 1.) ;
    vol2  = sur3 'VOLU' ne2 'TRAN' (0. 0. 1.) ;
    vol   = vol1 'ET' vol2 ;
*
    sur2  = vol1 'FACE' 2 ;
    sur4  = vol2 'FACE' 2 ;
*
    env1  = 'ENVE' vol1 ;
    env2  = 'ENVE' vol2 ;
    env   = env1 'ET' env2 ;
*
    are1  = 'ARET' env1 ;
    are2  = 'ARET' env2 ;
    are   = are1 'ET' are2 ;
*
    x y z = 'COOR' env ;
    ptx0  = x 'POIN' 'EGAL' 0. ;
    pty0  = y 'POIN' 'EGAL' 0. ;
    bl1   = ('BLOQ' 'UX' ptx0) 'ET' ('BLOQ' 'UY' pty0) 'ET' ('BLOQ' 'UZ' sur1) ;
*
    MOSIG = 'SMZZ' ;
    MOFOR = 'FZ' ;
  'FINSI' ;
*
  'SI' ITRAC ;
    vec1     = @VISOR sur2 'ROUG' ;
    vec2     = @VISOR sur3 'ROUG' ;
    TRAC vec1 (are ET sur2) 'TITR' 'Orientation surface en contact du solide bas' ;
    TRAC vec2 (are ET sur3) 'TITR' 'Orientation surface en contact du solide haut' ;
    TRAC (are 'ET' (ptx0 'COUL' 'CYAN')) 'TITR' 'Blocage UX = 0' ;
    'SI' ('EGA' ('VALE' 'DIME') 2) ;
      TRAC (are 'ET' (sur1 'COUL' 'CYAN')) 'TITR' 'Blocage UY = 0' ;
    'SINON' ;
      TRAC (are 'ET' (pty0 'COUL' 'CYAN')) 'TITR' 'Blocage UY = 0' ;
      TRAC (are 'ET' (sur1 'COUL' 'CYAN')) 'TITR' 'Blocage UZ = 0' ;
    'FINSI' ;
  'FINSI' ;
*
  VALSU2 = 'MESU' sur2 ;
  VALSU3 = 'MESU' sur3 ;
  VALSUR = 'MINI' VALSU2 VALSU3 ;
*
** Modeles elastique et caracteristiques
  mo = 'MODE' vol 'MECANIQUE' ;
  ma = 'MATE' mo 'YOUN' 200.E9 'NU' 0.3 ;
*
* Modele de contact
  moc = 'MODE' sur2 sur3 'CONTACT' 'SYME' ;
 
** Modele de pression
  mop = 'MODE' sur4 'CHARGEMENT' 'PRESSION' ;
 
** Chargement de pression
  f1   = 'PRES' mop 'PRES' VPRES ;
  ev1  = 'EVOL' 'MANU' ('PROG' 0. 1.) ('PROG' 0. 1.) ;
  cha1 = 'CHAR' 'PRES' f1 ev1 ;
 
** Resolution
  t1                       = TABL ;
  t1.'MODELE'              = mo 'ET' moc 'ET' mop ;
  t1.'CARACTERISTIQUES'    = ma ;
  t1.'BLOCAGES_MECANIQUES' = bl1 ;
  t1.'CHARGEMENT'          = cha1 ;
  t1.'TEMPS_CALCULES'      = 'PROG' 0.1 'PAS' 0.1 1. ;
  t1.'PRECISION'           = 1.E-8 ;
  PASAPAS t1 ;
 
** Post-traitements
  tps = t1.'TEMPS' ;
  dep = t1.'DEPLACEMENTS' ;
  rea = t1.'REACTIONS' ;
  sig = t1.'CONTRAINTES' ;
  nbp = 'DIME' dep ;
  'REPE' b2 nbp ;
    fc2 = 'REDU' (rea . (&b2 - 1)) sur2 ;
    fc3 = 'REDU' (rea . (&b2 - 1)) sur3 ;
    'SI' ITRAC ;
      tps2 = tps. (&b2 - 1) ;
      u2   = dep. (&b2 - 1) ;
      sig2 = sig. (&b2 - 1) ;
      vfc2 = 'VECT' fc2 'FORC' 'ROSE' 1.E-7 ;
      vfc3 = 'VECT' fc3 'FORC' 'TURQ' 1.E-7 ;
      def2 = 'DEFO' vol u2 1. (vfc2 ET vfc3) (EXCO MOSIG sig2) mo ;
      TRAC def2 'TITR' (CHAI 'Contrainte ' ' ' MOSIG ' + reactions du contact au temps' ' ' tps2) ;
    'FINSI' ;
  'FIN' b2 ;
  err2 = ('MAXI' 'ABS' ('EXCO' ('RESU' fc2) MOFOR MOFOR)) '/' VALSUR ;
  err3 = ('MAXI' 'ABS' ('EXCO' ('RESU' fc3) MOFOR MOFOR)) '/' VALSUR ;
  lerr = ('ABS' (('PROG' err2 err3) '-' VPRES)) '/' VPRES ;
  list lerr ; 
  berr = berr 'OU' (lerr '>EG' xerr) ;
'FIN' b1 ;
*
'SI' berr ;
  'ERRE' 5 ;
'FINSI' ;
*
FIN ;