Télécharger la plaquette Cast3M


fr en

Télécharger motrtracdp.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : motrtracdp.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. *         MODELE HYPERELASTIQUE MOONEY RIVLIN  QUASI-COMPRESSIBLE      *
  6. *           EN GRANDES TRANSFORMATIONS - DEFORMATIONS PLANES           *
  7. *                                                                      *
  8. *   TEST DE VALIDATION DU MODELE : TRACTION  SELON LA DIRECTION Y      *
  9. *    DEFORMATIONS PLANES COMPARAISON AVEC LA SOLUTION ANALYTIQUE       *
  10. *                                                                      *
  11. *   Contribution de Laurent Gornet - Ecole Centrale de Nantes (2008)   *
  12. *======================================================================*
  13. *  Pour plus d'informations, voir la presentation de L. Gornet lors    *
  14. *  du Club Cast3m 2006, disponible sur le site Web de Cast3m.          *
  15. *======================================================================*
  16. *  Exemple d'utilisation d'un modele UMAT en grandes transformations   *
  17. *                                                                      *
  18. *  Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. *         ne peut contenir que des modeles de type UMAT. On ne peut    *
  20. *         pas melanger les derivees objectives et les modeles de C3m.  *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'DEFO' 'ECHO' 0 ;
  24. * Mettre VRAI si l'on souhaite divers traces.
  25. *GRAPH = VRAI ;
  26. GRAPH = FAUX ;
  27. title = 'CHAINE' 'MOONEY-RIVLIN -' 'TRACTION UNIAXIALE Y' ;
  28.  
  29. *======================================================================*
  30. *             Geometrie - Maillage                                     *
  31. *======================================================================*
  32. * Longueur (direction x) de la plaque/membrane :
  33. Lg_x = 1. ;
  34. * Largeur (direction y) de la plaque/membrane :
  35. Lg_y = 1. ;
  36. * Nombre d'elements selon les directions x et y :
  37. Nel_x = 2;
  38. Nel_y = 2;
  39. * 'TRI6' 'TRI3'   'QUA8'
  40. 'OPTION' 'ELEM' 'QUA4' ;
  41. *
  42. P1 =  0.    0. ;
  43. P2 = Lg_x   0. ;
  44. P3 = Lg_x Lg_y ;
  45. P4 =  0.  Lg_y ;
  46. *
  47. L1 = 'DROITE' Nel_x P1 P2 ;
  48. L2 = 'DROITE' Nel_y P2 P3 ;
  49. L3 = 'DROITE' Nel_x P3 P4 ;
  50. L4 = 'DROITE' Nel_y P4 P1 ;
  51. *
  52. SU = 'DALLER' L1 L2 L3 L4 ;
  53. 'SI' GRAPH ;
  54.   'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  55. 'FINSI' ;
  56.  
  57. *======================================================================*
  58. *             Modele - Materiau - Caracteristiques (en Pa)             *
  59. *======================================================================*
  60. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'ET'
  61.       ('NEG' ('VALEUR' 'MODE') 'PLANCONT')) ;
  62.   'MESS' 'Ce modele ne fonctionne qu en 2D CONTRAINTES PLANES' ;
  63.   'ERREUR' 5 ;
  64. 'FINSI' ;
  65. * Calcul du Module d'Young
  66. * Ne pas oublier de definir les parametres lies a l'elasticite.
  67. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  68. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  69. *
  70. LCMAT = 'MOTS' 'YOUN' 'NU  '  'C1  ' 'C2  '  'D' ;
  71. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'  
  72.                     'NON_LINEAIRE' 'UTILISATEUR'
  73.                     'NUME_LOI' 31  'C_MATERIAU' LCMAT ;
  74. *
  75. * Pour calculer le module d'Young, on utilise les
  76. * Coefficients du modele de Mooney-Rivlin (en  MPa) :
  77. * 
  78. C1 = 0.183  ;     C2 = 0.0034   ;
  79. * 
  80. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  81. * du fait de l'incompressibilite inherente au modele.
  82. * Le module de Young YOU est alors connu, car, pour ce modele, le
  83. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  84. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  85. * de la traction. En fonction du niveau de deformation atteinte en 
  86. * traction, il faut augmenter cette valeur afin de pouvoir faire 
  87. * converger les calculs (module tangent en fin de calculs).
  88. * Prendre des valeurs superieures n'entraine pas de modification des
  89. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  90. *
  91. XNU = 0.499 ;
  92. YOUini = 3.*(2.*(C1+C2)) ;   YOU = 100. * YOUini ;
  93. *
  94. * Coef quasi-incompressible
  95. CoeD  =   1.E-4 ;
  96. *
  97. MA = MATE MO 'YOUN' YOU 'NU  ' XNU 'C1  ' C1 'C2  ' C2 'D' CoeD ;
  98. *
  99. *======================================================================*
  100. *             Conditions aux limites - Traction suivant UY             *
  101. *======================================================================*
  102. BL1 = 'BLOQUER' 'UY  ' L1 ;
  103. BL2 = 'BLOQUER' 'UY  ' L3 ;
  104. BL4 = 'BLOQUER' 'UX  ' P1 ;
  105. BLTOT = BL1 'ET' BL2 'ET' BL4 ;
  106. *
  107. * Definition des instants du chargement :
  108. t_deb = 0. ;   t_fin = 10. ;
  109. L_tps = 'PROG' t_deb t_fin ;
  110. * Deplacement suivant Y :
  111. L_UY = 'PROG' 0. ( 3. * Lg_y) ;
  112. FF_y = 'DEPIMP' BL2 1. ;
  113. EV_y = 'EVOL' 'MANU' 'TEMPS' L_tps  'LAMY' L_UY ;
  114.  
  115. CHARTOT = 'CHARGEMENT' 'DIMP' FF_y EV_y ;
  116.  
  117. *======================================================================*
  118. *             Initialisation de la table pour appel a PASAPAS          *
  119. *======================================================================*
  120. TAB1 = 'TABLE' ;
  121. TAB1.'MODELE' = MO ;
  122. TAB1.'CARACTERISTIQUES' = MA ;
  123. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  124. TAB1.'CHARGEMENT' = CHARTOT ;
  125. ***** LG
  126. *TAB1 . 'DELTAITER' = 150;
  127. *TAB1.'PRECISION' = 1.E-5 ;
  128. *TAB1.'FTOL' = 1.E-5 ;
  129. *TAB1.'MTOL' = 1.E-5 ;
  130. *****
  131. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  132. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  133. TAB1.'HYPOTHESE_DEFORMATIONS' = MOT 'UTILISATEUR' ;
  134. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  135. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  136. *
  137. L_abs = TAB1.'TEMPS_SAUVES' ;
  138. n_abs = 'DIMENSION' L_abs ;
  139. *
  140. PASAPAS TAB1 ;
  141. *
  142. * Quelques traces de controle apres calculs
  143. 'SI' GRAPH ;
  144.   Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  145.   Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  146.   'TRACER' (Defo_0 'ET' Defo_1)
  147.            'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  148.   'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  149.            'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  150. 'FINSI' ;
  151. *
  152. *======================================================================*
  153. *             Construction de la solution analytique                   *
  154. *======================================================================*
  155. * Definitions :
  156. * - Allongement selon direction y : Lamy = 1 + (UY/Lg_y)
  157. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  158. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  159. * Dans le cas du modele de MOONEY RIVLIN :
  160. * dW/dI1 = C1 et dW/dI2 = C2
  161. *
  162. * Les contraintes de Cauchy sont calculables analytiquement :
  163. * - SCxx = 0.
  164. * - SCyy = 2.(Lamy**2 - 1./Lamy**2).(dW/dI1 + dW/dI2)
  165. * - SCxy = 0  (pas de cisaillement)
  166. * - SCzz = 0  (hypothese des contraintes planes)
  167. *
  168. L_Un  = 'PROG' n_abs '*' 1. ;
  169. Lamy  = L_Un + (('IPOL' L_abs L_tps L_UY) / Lg_Y) ;
  170. *
  171. L_z1 = Lamy * Lamy ;  L_z2 = L_Un / (Lamy * Lamy);
  172. * LG modif hartsmith !! averifier
  173. L_tr = L_Un * 3.;
  174. I1 = L_z1 +   L_z2 + L_Un ;
  175. I2 = I1 ;
  176. *
  177. dWI1 = C1;
  178. dwI2 = C2;
  179. *
  180. SCxx_th = 0. * L_Un ;
  181. SCyy_th =(L_z1 - L_z2) * ((2.*dWI1*L_Un) + (2.*dWI2*L_Un)) ;
  182. SCxy_th = 0. * L_Un ;
  183. 'SI' GRAPH ;
  184. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' Lamy 'SCYY' SCyy_th ;
  185. dess  Evyy_th ;
  186. 'FINSI' ;
  187. *======================================================================*
  188. *             Comparaison des resultats avec la solution analytique    *
  189. *======================================================================*
  190. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  191. * calculees et les solutions analytiques correspondantes.
  192. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  193. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  194. *
  195. TabD = TAB1.'DEPLACEMENTS' ;
  196. TabS = TAB1.'CONTRAINTES' ;
  197. Confini = 'FORM' ;
  198. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  199. *
  200. SCxx = 'PROG' 0. ;
  201. SCyy = 'PROG' 0. ;
  202. SCxy = 'PROG' 0. ;
  203. 'REPETER' Boucle (n_abs - 1) ;
  204.   'FORM' (TabD.&Boucle) ;
  205.   VolSU = 'INTG' MO ChmUn ;
  206.   SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  207.   SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  208.   SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  209.   'FORM' Confini ;
  210. 'FIN' Boucle ;
  211. *  LG lamb
  212. L_abs = Lamy;
  213. *
  214. 'SI' GRAPH ;
  215.   tlege = 'TABLE' ;
  216.   tlege. 1 = 'MARQ CROI' ;
  217.   tlege.'TITRE' = 'TABLE' ;
  218.   tlege.'TITRE'. 1 = 'Numerique' ;
  219.   tlege.'TITRE'. 2 = 'Analytique' ;
  220.   Evxx    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  221.   Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  222.   'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  223.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (MPa)') ;
  224.   Evyy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  225.   Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  226.   'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  227.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (MPa)') ;
  228.   Evxy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  229.   Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  230.   'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  231.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (MPa)');
  232. 'FINSI' ;
  233. *
  234. * Tests de bon fonctionnement :
  235. r_z = 'MAXIMUM' ('ABS' SCyy_th) ;
  236. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) / r_z ;
  237. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) / r_z ;
  238. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) / r_z ;
  239. *
  240. MESS ' RESULTATS : ' title ;
  241. MESS ' ------------------------------------------------- ';
  242. 'SAUTER' 1 'LIGNE' ;
  243. 'MESS' '  Tests de bon fonctionnement :' ;
  244. 'MESS' ' -------------------------------' ;
  245. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  246. 'MESS' ' Ecart relatif maximal entre la valeur moyenne '
  247.        'calculee' ;
  248. 'MESS' '                          et la '
  249.        'solution analytique associee' ;
  250. 'MESS' ' Composante XX : ' r_xx ;
  251. 'MESS' ' Composante YY : ' r_yy ;
  252. 'MESS' ' Composante XY : ' r_xy ;
  253. 'SAUTER' 1 'LIGNE' ;
  254. * Ecart relatif maximal tolere
  255. Sigref = 1.E-3 ;
  256. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  257.   'MESS' ' ---------------------' ;
  258.   'MESS' '  ECHEC DU CAS-TEST !' ;
  259.   'MESS' ' ---------------------' ;
  260.   'ERREUR' 5 ;
  261. 'SINON' ;
  262.   'MESS' ' ----------------------' ;
  263.   'MESS' '  SUCCES DU CAS-TEST !' ;
  264.   'MESS' ' ----------------------' ;
  265. 'FINSI' ;
  266. 'SAUTER' 1 'LIGNE' ;
  267.  
  268. 'FIN' ;
  269.  
  270.  
  271.  
  272.  
  273.  
  274.  
  275.  
  276.  
  277.  
  278.  
  279.  
  280.  
  281.  
  282.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales