Télécharger la plaquette Cast3M


fr en

Télécharger mooneydp.dgibi

Retour à la liste

Numérotation des lignes : 

  1. *ù fichier : mooneydp.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. *         MODELE HYPERELASTIQUE MOONEY RIVLIN  QUASI-COMPRESSIBLE      *
  6. *           EN GRANDES TRANSFORMATIONS - DEFORMATIONS PLANES           *
  7. *                                                                      *
  8. *   TEST DE VALIDATION DU MODELE : TRACTION  SELON LA DIRECTION Y      *
  9. *    DEFORMATIONS PLANES COMPARAISON AVEC LA SOLUTION ANALYTIQUE       *
  10. *                                                                      *
  11. *   Contribution de Laurent Gornet - Ecole Centrale de Nantes (2008)   *
  12. *======================================================================*
  13. *  Pour plus d'informations, voir la presentation de L. Gornet lors    *
  14. *  du Club Cast3m 2006, disponible sur le site Web de Cast3m.          *
  15. *======================================================================*
  16. *  Exemple d'utilisation d'un modele UMAT en grandes transformations   *
  17. *                                                                      *
  18. *  Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. *         ne peut contenir que des modeles de type UMAT. On ne peut    *
  20. *         pas melanger les derivees objectives et les modeles de C3m.  *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'DEFO' 'ECHO' 0 ;
  24.  
  25. * Mettre VRAI si l'on souhaite divers traces.
  26. *GRAPH = VRAI ;
  27. GRAPH = FAUX ;
  28. title = 'CHAINE' 'MOONEY-RIVLIN -' 'TRACTION UNIAXIALE Y' ;
  29.  
  30. *======================================================================*
  31. *             Geometrie - Maillage                                     *
  32. *======================================================================*
  33. * Longueur (direction x) de la plaque/membrane :
  34. Lg_x = 1. ;
  35. * Largeur (direction y) de la plaque/membrane :
  36. Lg_y = 1. ;
  37. * Nombre d'elements selon les directions x et y :
  38. Nel_x = 2;
  39. Nel_y = 2;
  40. * 'TRI6' 'TRI3'   'QUA8'
  41. 'OPTION' 'ELEM' 'QUA4' ;
  42. *
  43. P1 =  0.    0. ;
  44. P2 = Lg_x   0. ;
  45. P3 = Lg_x Lg_y ;
  46. P4 =  0.  Lg_y ;
  47. *
  48. L1 = 'DROITE' Nel_x P1 P2 ;
  49. L2 = 'DROITE' Nel_y P2 P3 ;
  50. L3 = 'DROITE' Nel_x P3 P4 ;
  51. L4 = 'DROITE' Nel_y P4 P1 ;
  52. *
  53. SU = 'DALLER' L1 L2 L3 L4 ;
  54. 'SI' GRAPH ;
  55.   'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  56. 'FINSI' ;
  57.  
  58. *======================================================================*
  59. *             Modele - Materiau - Caracteristiques (en Pa)             *
  60. *======================================================================*
  61. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'ET'
  62.       ('NEG' ('VALEUR' 'MODE') 'PLANCONT')) ;
  63.   'MESS' 'Ce modele ne fonctionne qu en 2D CONTRAINTES PLANES' ;
  64.   'ERREUR' 5 ;
  65. 'FINSI' ;
  66. * Calcul du Module d'Young
  67. * Ne pas oublier de definir les parametres lies a l'elasticite.
  68. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  69. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  70. *
  71. LCMAT = 'MOTS' 'YOUN' 'NU  '  'C1  ' 'C2  '  'D' ;
  72. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'  
  73.                     'NON_LINEAIRE' 'UTILISATEUR'
  74.                     'NUME_LOI' 31  'C_MATERIAU' LCMAT ;
  75. *
  76. * Pour calculer le module d'Young, on utilise les
  77. * Coefficients du modele de Mooney-Rivlin (en  MPa) :
  78. * 
  79. C1 = 0.183  ;     C2 = 0.0034   ;
  80. * 
  81. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  82. * du fait de l'incompressibilite inherente au modele.
  83. * Le module de Young YOU est alors connu, car, pour ce modele, le
  84. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  85. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  86. * de la traction. En fonction du niveau de deformation atteinte en 
  87. * traction, il faut augmenter cette valeur afin de pouvoir faire 
  88. * converger les calculs (module tangent en fin de calculs).
  89. * Prendre des valeurs superieures n'entraine pas de modification des
  90. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  91. *
  92. XNU = 0.499 ;
  93. YOUini = 3.*(2.*(C1+C2)) ;   YOU = 100. * YOUini ;
  94. *
  95. * Coef quasi-incompressible
  96. CoeD  =   1.E-4 ;
  97. *
  98. MA = MATE MO 'YOUN' YOU 'NU  ' XNU 'C1  ' C1 'C2  ' C2 'D' CoeD ;
  99. *
  100. *======================================================================*
  101. *             Conditions aux limites - Traction suivant UY             *
  102. *======================================================================*
  103. BL1 = 'BLOQUER' 'UY  ' L1 ;
  104. BL2 = 'BLOQUER' 'UY  ' L3 ;
  105. BL4 = 'BLOQUER' 'UX  ' P1 ;
  106. BLTOT = BL1 'ET' BL2 'ET' BL4 ;
  107. *
  108. * Definition des instants du chargement :
  109. t_deb = 0. ;   t_fin = 10. ;
  110. L_tps = 'PROG' t_deb t_fin ;
  111. * Deplacement suivant Y :
  112. L_UY = 'PROG' 0. ( 3. * Lg_y) ;
  113. FF_y = 'DEPIMP' BL2 1. ;
  114. EV_y = 'EVOL' 'MANU' 'TEMPS' L_tps  'LAMY' L_UY ;
  115.  
  116. CHARTOT = 'CHARGEMENT' 'DIMP' FF_y EV_y ;
  117.  
  118. *======================================================================*
  119. *             Initialisation de la table pour appel a PASAPAS          *
  120. *======================================================================*
  121. TAB1 = 'TABLE' ;
  122. TAB1.'MODELE' = MO ;
  123. TAB1.'CARACTERISTIQUES' = MA ;
  124. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  125. TAB1.'CHARGEMENT' = CHARTOT ;
  126. ***** LG
  127. *TAB1 . 'DELTAITER' = 150;
  128. *TAB1.'PRECISION' = 1.E-5 ;
  129. *TAB1.'FTOL' = 1.E-5 ;
  130. *TAB1.'MTOL' = 1.E-5 ;
  131. *****
  132. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  133. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  134. TAB1.'HYPOTHESE_DEFORMATIONS' = MOT 'UTILISATEUR' ;
  135. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  136. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  137. *
  138. L_abs = TAB1.'TEMPS_SAUVES' ;
  139. n_abs = 'DIMENSION' L_abs ;
  140. *
  141. PASAPAS TAB1 ;
  142. *
  143. * Quelques traces de controle apres calculs
  144. 'SI' GRAPH ;
  145.   Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  146.   Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  147.   'TRACER' (Defo_0 'ET' Defo_1)
  148.            'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  149.   'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  150.            'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  151. 'FINSI' ;
  152. *
  153. *======================================================================*
  154. *             Construction de la solution analytique                   *
  155. *======================================================================*
  156. * Definitions :
  157. * - Allongement selon direction y : Lamy = 1 + (UY/Lg_y)
  158. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  159. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  160. * Dans le cas du modele de MOONEY RIVLIN :
  161. * dW/dI1 = C1 et dW/dI2 = C2
  162. *
  163. * Les contraintes de Cauchy sont calculables analytiquement :
  164. * - SCxx = 0.
  165. * - SCyy = 2.(Lamy**2 - 1./Lamy**2).(dW/dI1 + dW/dI2)
  166. * - SCxy = 0  (pas de cisaillement)
  167. * - SCzz = 0  (hypothese des contraintes planes)
  168. *
  169. L_Un  = 'PROG' n_abs '*' 1. ;
  170. Lamy  = L_Un + (('IPOL' L_abs L_tps L_UY) / Lg_Y) ;
  171. *
  172. L_z1 = Lamy * Lamy ;  L_z2 = L_Un / (Lamy * Lamy);
  173. * LG modif hartsmith !! averifier
  174. L_tr = L_Un * 3.;
  175. I1 = L_z1 +   L_z2 + L_Un ;
  176. I2 = I1 ;
  177. *
  178. dWI1 = C1;
  179. dwI2 = C2;
  180. *
  181. SCxx_th = 0. * L_Un ;
  182. SCyy_th =(L_z1 - L_z2) * ((2.*dWI1*L_Un) + (2.*dWI2*L_Un)) ;
  183. SCxy_th = 0. * L_Un ;
  184. 'SI' GRAPH ;
  185. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' Lamy 'SCYY' SCyy_th ;
  186. dess  Evyy_th ;
  187. 'FINSI' ;
  188. *======================================================================*
  189. *             Comparaison des resultats avec la solution analytique    *
  190. *======================================================================*
  191. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  192. * calculees et les solutions analytiques correspondantes.
  193. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  194. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  195. *
  196. TabD = TAB1.'DEPLACEMENTS' ;
  197. TabS = TAB1.'CONTRAINTES' ;
  198. Confini = 'FORM' ;
  199. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  200. *
  201. SCxx = 'PROG' 0. ;
  202. SCyy = 'PROG' 0. ;
  203. SCxy = 'PROG' 0. ;
  204. 'REPETER' Boucle (n_abs - 1) ;
  205.   'FORM' (TabD.&Boucle) ;
  206.   VolSU = 'INTG' MO ChmUn ;
  207.   SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  208.   SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  209.   SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  210.   'FORM' Confini ;
  211. 'FIN' Boucle ;
  212. *  LG lamb
  213. L_abs = Lamy;
  214. *
  215. 'SI' GRAPH ;
  216.   tlege = 'TABLE' ;
  217.   tlege. 1 = 'MARQ CROI' ;
  218.   tlege.'TITRE' = 'TABLE' ;
  219.   tlege.'TITRE'. 1 = 'Numerique' ;
  220.   tlege.'TITRE'. 2 = 'Analytique' ;
  221.   Evxx    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  222.   Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  223.   'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  224.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (MPa)') ;
  225.   Evyy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  226.   Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  227.   'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  228.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (MPa)') ;
  229.   Evxy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  230.   Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  231.   'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  232.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (MPa)');
  233. 'FINSI' ;
  234. *
  235. * Tests de bon fonctionnement :
  236. r_z = 'MAXIMUM' ('ABS' SCyy_th) ;
  237. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) / r_z ;
  238. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) / r_z ;
  239. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) / r_z ;
  240. *
  241. MESS ' RESULTATS : ' title ;
  242. MESS ' ------------------------------------------------- ';
  243. 'SAUTER' 1 'LIGNE' ;
  244. 'MESS' '  Tests de bon fonctionnement :' ;
  245. 'MESS' ' -------------------------------' ;
  246. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  247. 'MESS' ' Ecart relatif maximal entre la valeur moyenne '
  248.        'calculee' ;
  249. 'MESS' '                          et la '
  250.        'solution analytique associee' ;
  251. 'MESS' ' Composante XX : ' r_xx ;
  252. 'MESS' ' Composante YY : ' r_yy ;
  253. 'MESS' ' Composante XY : ' r_xy ;
  254. 'SAUTER' 1 'LIGNE' ;
  255. * Ecart relatif maximal tolere
  256. Sigref = 1.E-3 ;
  257. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  258.   'MESS' ' ---------------------' ;
  259.   'MESS' '  ECHEC DU CAS-TEST !' ;
  260.   'MESS' ' ---------------------' ;
  261.   'ERREUR' 5 ;
  262. 'SINON' ;
  263.   'MESS' ' ----------------------' ;
  264.   'MESS' '  SUCCES DU CAS-TEST !' ;
  265.   'MESS' ' ----------------------' ;
  266. 'FINSI' ;
  267. 'SAUTER' 1 'LIGNE' ;
  268.  
  269. 'FIN' ;
  270.  
  271.  
  272.  
  273.  
  274.  
  275.  
  276.  
  277.  
  278.  
  279.  
  280.  
  281.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales