Télécharger la plaquette Cast3M


fr en

Télécharger metallurgie_07.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  metallurgie_07.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *__________________________________________________________________*
  5. *   TEST METALLURGIE_07                                            *
  6. *                                                                  *
  7. *   CALCUL DES PROPORTIONS DE PHASE METALLURGIQUE                  *
  8. *   CALCUL DE LA DEFORMATION THERMIQUE METALLURGIQUE               *
  9. *   TEMPERATURE IMPOSEE DURANT TOUT LE CALCUL                      *
  10. *                                                                  *
  11. *   Un modele THERMO-METALLURGIQUE + MECANIQUE est cree            *
  12. *   en 2D Axisymetrique                                            *
  13. *                                                                  *
  14. *   Utilisation de PASAPAS et de procedures utilisateur :          *
  15. *      - Procedure PARATHER : + Mise a jour du materiaux THERMIQUE *
  16. *                               avec la proportion de phase.       *
  17. *                                                                  *
  18. *      - Procedure REEV_THE : Mise a jour des proportions de phase *
  19. *                             pour le modele de MELANGE            *
  20. *                                                                  *
  21. *   Le modele metallurgique contient 5 phases ayant des cinetiques *
  22. *   de transformation differentes                                  *
  23. *      - Metal de Base (MB)                                        *
  24. *      - Austenite                                                 *
  25. *      - Martensite                                                *
  26. *      - Bainite                                                   *
  27. *      - Ferrite                                                   *
  28. *__________________________________________________________________*
  29. *   MAILLAGE :                                                     *
  30. *    - Eprouvette cylindrique de hauteur 100mm et de rayon 12,5mm  *
  31. *      P4 _____ P3                                                 *
  32. *        |     |    ^                                              *
  33. *        |     |    |                                              *
  34. *        |     |    |                                              *
  35. *        |     |    | h0      Y                                    *
  36. *        |     |    |         ^                                    *
  37. *        |     |    |         |                                    *
  38. *      P1 _____ P2  v         o --> X                              *
  39. *                                                                  *
  40. *        <-----> r0                                                *
  41. *      Origine du repere : P1                                      *
  42. *                                                                  *
  43. *   CHARGEMENT :                                                   *
  44. *    - Rampe de temperature lineaire de 20°C  a 900°C a 5°C/s      *
  45. *    - Maintient a 900°C durant 60s                                *
  46. *    - Rampe de temperature lineaire de 900°C a 20°C  a -10°C/s    *
  47. *                                                                  *
  48. *   CL :                                                           *
  49. *    - Blocage de la temperature (imposee partout)                 *
  50. *    - Blocage 'UZ' de la ligne reliant P1 et P2                   *
  51. *    - Blocage 'UR' de la ligne reliant P1 et P4                   *
  52. *__________________________________________________________________*
  53.  
  54. 'OPTI' 'DIME' 2   'MODE' 'AXIS' 'ELEM' 'QUA4' ;
  55. 'OPTI' 'TRAC' PSC 'EPTR'  10 ;
  56.  
  57. ************************************************************************
  58. *  Parametrage du Jeu de Donnees
  59. ************************************************************************
  60. * Parametrage MAILLAGE
  61. h0      = 100.; 'COMM' 'hauteur du cylindre'              ;
  62. r0      = 12.5; 'COMM' 'rayon du cylindre'                ;
  63.  
  64. * Parametrage THERMIQUE
  65. TMIN    =  20.; 'COMM' 'Temperature ambiante'             ;
  66. TMAX    = 900.; 'COMM' 'Temperature du palier isotherme'  ;
  67. VCHAUFF =   5.; 'COMM' 'vitesse de chauffage'             ;
  68. VCHAUFF =   5.; 'COMM' 'Vitesse de chauffage       [°C/s]';
  69. VREFROI = -10.; 'COMM' 'Vitesse de refroidissement [°C/s]';
  70. PALLIER =  60.; 'COMM' 'Duree du palier isotherme  [s]'   ;
  71.  
  72. * Parametrage METALLURGIE (Proportions initiales de phases)
  73. MB_ini  = 0.1 ;
  74. MART_ini= 0.2 ;
  75. BAIN_ini= 0.3 ;
  76. FERR_ini= 0.4 ;
  77. AUST_ini= 0.0 ;
  78.  
  79. * Parametrage DISCRETISATION
  80. dens0   = 10.0 ; 'COMM' 'densite du maillage'        ;
  81. DT      = 0.25  ; 'COMM' 'pas de temps pour le calcul';
  82.  
  83. ************************************************************************
  84. *  Pour faire des beaux DESSINS
  85. ************************************************************************
  86. * LISTMOTS contenant les couleurs
  87.   LESCOUL = 'MOTS' 'VIOL' 'VERT' 'CYAN' 'BRIQ' 'BOUT' 'JAUN' 'OLIV'
  88.                    'ORAN' 'ROUG' 'BLEU' 'BRUN' 'CARA' 'GRIS' 'NOIR' ;
  89.   NBCOUL  = 'DIME'  LESCOUL ;
  90.  
  91. * LISTMOTS contenant les marques dans DESS
  92.   LESMARQ = 'MOTS' 'CROI' 'PLUS' 'MOIN' 'BARR' 'ETOI' 'CARR'
  93.                    'LOSA' 'ROND' 'TRID' 'TRIU' 'TRIL' 'TRIR';
  94.   NBMARQ  = 'DIME'  LESMARQ ;
  95. ************************************************************************
  96.  
  97. ************************************************************************
  98. * Debut de la procedure PARATHER
  99. ************************************************************************
  100. 'DEBP' PARATHER  PRECED*'TABLE' TPS1*'FLOTTANT';
  101. ************************************************************************
  102. * PROCEDURE PARATHER :
  103. *   DESCRIPTION :
  104. *   -------------
  105. *   Cette procedure permet de modifier le materiaux avant l'appel a
  106. *   VARI 'NUAG' dans TRANSNON.
  107. *     - Les composantes K, C et RHO sont une moyenne arithmethique
  108. *       ponderee par la fraction de phase des Ki, Ci et RHOi
  109. *   L'indice ETAB.'MAT_TOT' est remplace
  110. *   L'indice ETAB . 'CHARGEMENT' est remplace
  111. *
  112. *   ENTREES :
  113. *   ---------
  114. *   - PRECED : TABLE complete de PASAPAS
  115. *   - TPS1   : Temps courant
  116. *
  117. *   SORTIES :
  118. *   ---------
  119. *   - Aucune
  120. *
  121. ************************************************************************
  122.  
  123. *I - Mise a jour du materiau Thermique avec les proportions de phases
  124.    ETAB    = PRECED.'WTABLE';
  125.    MOD1    = ETAB.'MOD_TOT' ;
  126.    T1      = ETAB.'THER_COURANT' ;
  127.    T1      ='CHAN' 'CHAM' T1 MOD1 'RIGIDITE' 'CARACTERISTIQUES';
  128.  
  129.    MAT_ORIG= ETAB.'MAT_TOT';
  130.    COMPORIG='EXTR' MAT_ORIG 'COMP';
  131.    NBCOMP  ='DIME' COMPORIG;
  132.  
  133.    MAT0 ='VIDE' 'MCHAML';
  134.    REPE SURCOM NBCOMP;
  135.      II     = &SURCOM;
  136.      LACOMP ='EXTR' COMPORIG II;
  137.      SI(('NEG' LACOMP 'K') 'ET' ('NEG' LACOMP 'RHO') 'ET' ('NEG' LACOMP 'C'));
  138.         MAT0 = MAT0 'ET' ('EXCO' MAT_ORIG LACOMP LACOMP);
  139.      FINS;
  140.    FIN SURCOM;
  141.  
  142. *  Instanciation du materiaux de chaque phase
  143.    MATPHAS ='REDU'  MOD1 MATPHAS ;
  144.    MAT2    ='VARI' 'NUAG' MOD1 MATPHAS T1 'RIGIDITE';
  145.  
  146. *  On fait ensuite la moyenne qui nous interesse (Ponderation par la proportion de phase)
  147.    MCHPHA  = PRECED.'ESTIMATION'.'PROPORTIONS_PHASES';
  148.  
  149.    MCHPHA  ='CHAN' 'CONS' MCHPHA 'THE1'              ;
  150.    MCHPHA  ='REDU'  MCHPHA ETAB.'MOD_COND'           ;
  151.    MCHPHA  ='CHAN' 'RIGIDITE' MCHPHA MOD1            ;
  152.    MCHPHA  ='CHAN' 'TYPE' MCHPHA 'CARACTERISTIQUES'  ;
  153.  
  154.    MOPROP1 ='EXTR'  MCHPHA 'COMP'                    ;
  155.    MOMAT2  ='EXTR'  MAT2   'COMP'                    ;
  156.  
  157.    MCHK    ='CHAN' 'TYPE' ('VIDE' 'MCHAML') 'CARACTERISTIQUES' ;
  158.    MCHR    ='CHAN' 'TYPE' ('VIDE' 'MCHAML') 'CARACTERISTIQUES' ;
  159.    MCHC    ='CHAN' 'TYPE' ('VIDE' 'MCHAML') 'CARACTERISTIQUES' ;
  160.  
  161. * Boucle sur les phases
  162.    NBPHA   ='DIME' MOPROP1;
  163.    REPE SURP NBPHA;
  164.      IP    = &SURP ;
  165.      PROPIP='EXCO' MCHPHA ('EXTR' MOPROP1 IP) 'SCAL' ; 'COMM' 'Prop de la phase numero IP' ;
  166.  
  167. *    Moyenne sur les K
  168.      IB    = IP;
  169.      RATIO ='EXCO' MAT2 ('EXTR' MOMAT2 IB) 'SCAL';
  170.      MCHK  =(PROPIP * RATIO) + MCHK ;
  171.  
  172. *    Moyenne sur les RHO
  173.      IB    = IB + NBPHA;
  174.      RATIO2='EXCO' MAT2 ('EXTR' MOMAT2 IB) 'SCAL';
  175.      MCHR  =(PROPIP * RATIO2) + MCHR ;
  176.  
  177. *    Moyenne sur les CP
  178.      IB    = IB + NBPHA;
  179.      RATIO3='EXCO' MAT2 ('EXTR' MOMAT2 IB) 'SCAL';
  180.      MCHC  =(PROPIP * RATIO3) + MCHC ;
  181.    FIN SURP;
  182.  
  183.    MCHK    ='CHAN' 'COMP' 'K'   MCHK ;
  184.    MCHR    ='CHAN' 'COMP' 'RHO' MCHR ;
  185.    MCHC    ='CHAN' 'COMP' 'C'   MCHC ;
  186.  
  187. *  REMPLACEMENT DU MATERIAUX
  188.    ETAB.'MAT_TOT'= MCHK 'ET' MCHR 'ET' MCHC 'ET' MAT0 ;
  189.  
  190.  
  191. 'FINP';
  192. ************************************************************************
  193. * Fin de la procedure PARATHER
  194. ************************************************************************
  195.  
  196.  
  197. ************************************************************************
  198. * Debut de la procedure PARATHER
  199. ************************************************************************
  200. 'DEBP' REEV_THE  PRECED*'TABLE' N1*'ENTIER';
  201. ************************************************************************
  202. * PROCEDURE REEV_THE :
  203. *   DESCRIPTION :
  204. *   -------------
  205. *   Cette procedure met a jour le materiau pour le modele de MELANGE
  206. *    - Passage des proportions de phases de la METALLURGIE a la MECANIQUE
  207. *    - AMELIORATION POSSIBLE : Que ce soit fait automatiquement...
  208. *        + Changement du CONSTITUANT automatiquement
  209. *        + Projection si demandé (TAB1.'PROJECTION' = VRAI ;)
  210. *
  211. *   ENTREES :
  212. *   ---------
  213. *   - PRECED : TABLE complete de PASAPAS
  214. *   - N1     : Numero d'appel (initialisation ou apres THERMIQUE)
  215. *
  216. *   SORTIES :
  217. *   ---------
  218. *   - Aucune
  219. *
  220. ************************************************************************
  221.    WTAB    = PRECED.'WTABLE';
  222.    MODAUTR ='ENLE' WTAB.'MODELE' 'FORM' 'MELANGE';
  223.    MATAUTR ='REDU' WTAB.'CARACTERISTIQUES' MODAUTR;
  224.  
  225.    MCHPHA  = PRECED.'ESTIMATION'.'PROPORTIONS_PHASES';
  226.  
  227. *  Passage des PROPORTIONS_PHASES sur le modele de MELANGE (Sans PROJECTION)
  228.    MCHPMEL  ='CHAN' 'CONS' MCHPHA 'MEL1';
  229.    MCHPMEL  ='CHAN' MCHPMEL 'TYPE' 'CARACTERISTIQUES';
  230.  
  231. *  REMPLACEMENT DU MATERIAUX DANS WTAB
  232.    WTAB.'CARACTERISTIQUES'=MCHPMEL 'ET' MATAUTR ;
  233. 'FINP';
  234. ************************************************************************
  235. * Fin de la procedure REEV_THE
  236. ************************************************************************
  237.  
  238.  
  239. ************************************************************************
  240. *MAILLAGE
  241. ************************************************************************
  242. axes    = @repere (0. 0.) ('PROG' 25. 25.) 'ROUG' ;
  243. P1      ='POIN' 0. 0. ;
  244. P2      ='POIN' r0 0. ;
  245. P3      ='POIN' r0 h0 ;
  246. P4      ='POIN' 0. h0 ;
  247.  
  248. L1      ='DROI' P1 P2 'DINI' dens0 'DFIN' dens0 ;
  249. L2      ='DROI' P2 P3 'DINI' dens0 'DFIN' dens0 ;
  250. L3      ='DROI' P3 P4 'DINI' dens0 'DFIN' dens0 ;
  251. L4      ='DROI' P4 P1 'DINI' dens0 'DFIN' dens0 ;
  252.  
  253. MAILT   ='DALL' L1 L2 L3 L4 ;
  254. 'TRAC' 'QUAL' MAILT;
  255.  
  256. ************************************************************************
  257. * Definition des MODELES
  258. ************************************************************************
  259. MODTHE  ='MODE' MAILT   'THERMIQUE' 'CONDUCTION' 'QUA4' 'CONS' 'THE1' ;
  260.  
  261. TPHASE  = TABL;
  262. * LISTMOTS utiles pour la metallurgie
  263. *  1- Metal de base 100% initialement
  264. *  2- Martensite
  265. *  3- Bainite
  266. *  4- Ferrite
  267. *  5- Austenite
  268. TPHASE.'PHASES'  ='MOTS' 'MB  ' 'MART' 'BAIN' 'FERR' 'AUST'               ;
  269. TPHASE.'REACTIFS'='MOTS' 'MB  ' 'MART' 'BAIN' 'FERR' 'AUST' 'AUST' 'AUST' ;
  270. TPHASE.'PRODUITS'='MOTS' 'AUST' 'AUST' 'AUST' 'AUST' 'MART' 'BAIN' 'FERR' ;
  271. TPHASE.'TYPE'    ='MOTS' 'LEBL' 'LEBL' 'LEBL' 'LEBL' 'KOIS' 'LEBL' 'LEBL' ;
  272.  
  273. NBCOMP  ='DIME' TPHASE.'PHASES';
  274.  
  275. MODCP1  ='MODE' MAILT 'METALLURGIE' 'PHASES'   TPHASE.'PHASES'
  276.                                     'REACTIFS' TPHASE.'REACTIFS'
  277.                                     'PRODUITS' TPHASE.'PRODUITS'
  278.                                     'TYPE'     TPHASE.'TYPE'
  279.                                     'CONS'    'MET1';
  280.  
  281. MOMMB   ='MODE' MAILT  'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'PARFAIT' 'CONS' 'MEC1' 'PHASE' 'MB'  ;
  282. MOMMART ='MODE' MAILT  'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'PARFAIT' 'CONS' 'MEC2' 'PHASE' 'MART';
  283. MOMBAIN ='MODE' MAILT  'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'PARFAIT' 'CONS' 'MEC3' 'PHASE' 'BAIN';
  284. MOMFERR ='MODE' MAILT  'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'PARFAIT' 'CONS' 'MEC4' 'PHASE' 'FERR';
  285. MOMAUST ='MODE' MAILT  'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'PARFAIT' 'CONS' 'MEC5' 'PHASE' 'AUST';
  286.  
  287. MODMEC  = MOMMB  'ET' MOMMART 'ET' MOMBAIN 'ET' MOMFERR 'ET' MOMAUST ;
  288. MOMELMEC='MODE' MAILT  'MELANGE' 'PARALLELE' MODMEC 'CONS' 'MEL1' ;
  289.  
  290. MODTOT  = MODTHE 'ET' MODCP1 'ET'  MODMEC 'ET' MOMELMEC ;
  291.  
  292. *******************************************************************************
  293. * Definition des materiaux des phases pures (THERMIQUE & MECANIQUE)
  294. *******************************************************************************
  295. MCHK   ='VIDE' 'MCHAML'          ; 'COMM' 'Conductivite thermique'             ;
  296. MCHRHO ='VIDE' 'MCHAML'          ; 'COMM' 'Masse volumique'                    ;
  297. MCHC   ='VIDE' 'MCHAML'          ; 'COMM' 'Capacite calorifique'               ;
  298. CTYP   ='MOT'  'CARACTERISTIQUES';
  299.  
  300. ********************
  301. * 1- Metal de base *
  302. ********************
  303. IPAHS  = 1;
  304. ICOUL  = @MOD  IPAHS NBCOUL;
  305. COUL1  ='EXTR' LESCOUL ICOUL;
  306. CPHAS  ='CHAI' 'K' IPAHS;
  307. LTKP1  ='PROG' 0 55 113 162 191 243 293 392
  308.                457 507 605 655 756 795 840 856
  309.                900 950 1000 1101 1202 1303 1400 1500
  310.                1502 1600   ;
  311. LKP1   ='PROG' 0.0376 0.0389 0.0401 0.0407 0.0407 0.0404 0.0398 0.038
  312.                0.0364 0.0352 0.0329 0.0317 0.0291 0.0273 0.0252 0.0248
  313.                0.0253 0.0261 0.027 0.0283 0.0299 0.0314 0.0328 0.0343
  314.                0.05 0.05;
  315. EVKP1  ='EVOL' COUL1 'MANU' 'T' LTKP1 CPHAS LKP1;
  316. MCHK   = MCHK  'ET' ('MANU' 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  317.  
  318. CPHAS  ='CHAI' 'R' IPAHS;
  319. LTRHOP1='PROG' 0 20 100 200 300 400
  320.                500 600 700 800 900 1440
  321.                2500 ;
  322. LRHOP1 ='PROG' 7852.D-9 7852.D-9 7815.D-9 7778.D-9 7741.D-9 7705.D-9
  323.                7668.D-9 7633.D-9 7595.D-9 7562.D-9 7527.D-9 7345.D-9
  324.                7011.D-9 ;
  325. EVRHOP1='EVOL' COUL1 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  326. MCHRHO = MCHRHO'ET' ('MANU' 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  327.  
  328. CPHAS  ='CHAI' 'C' IPAHS;
  329. LTCP1  ='PROG' 21 50 150 200 250 300 350 450 550
  330.                650 700 750 850 1000 1200 1300 1400 1440
  331.                1465 1490 1540 1590 1615 1640 2500 ;
  332. LCP1   ='PROG' 460.5 485.6 519.1 531.6 556.7 573.5 598.6 661.4 749.3
  333.                845.6 1431.6 950.2 900 845.6 800 815 840 850
  334.                1210 1840 2470 1840 1210 840 707 ;
  335. EVCP1  ='EVOL' COUL1 'MANU' 'T' LTCP1 CPHAS LCP1;
  336. MCHC   = MCHC  'ET' ('MANU' 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  337.  
  338. CPHAS  ='CHAI' 'ALP' IPAHS;
  339. LTALP1 ='PROG' 20. 'PAS' 1. 700. ;
  340. LALP1  = 16.1D-6 * (LTALP1 ** 0) ;
  341. EVALP1 ='EVOL' COUL1 'MANU' 'T' LTALP1 'ALPH' LALP1;
  342.  
  343. *****************
  344. * 2- Martensite *
  345. *****************
  346. IPAHS  = 2;
  347. ICOUL  = @MOD  IPAHS NBCOUL;
  348. COUL1  ='EXTR' LESCOUL ICOUL;
  349. CPHAS  ='CHAI' 'K' IPAHS;
  350. EVKP1  ='EVOL' COUL1 'MANU' 'T' LTKP1 CPHAS LKP1;
  351. MCHK   = MCHK  'ET' ('MANU' 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  352.  
  353. CPHAS  ='CHAI' 'R' IPAHS;
  354. EVRHOP1='EVOL' COUL1 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  355. MCHRHO = MCHRHO'ET' ('MANU' 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  356.  
  357. CPHAS  ='CHAI' 'C' IPAHS;
  358. EVCP1  ='EVOL' COUL1 'MANU' 'T' LTCP1 CPHAS LCP1;
  359. MCHC   = MCHC  'ET' ('MANU' 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  360.  
  361. CPHAS  ='CHAI' 'ALP' IPAHS;
  362. LALP2  = LALP1 ;
  363. EVALP2 ='EVOL' COUL1 'MANU' 'T' LTALP1 'ALPH' LALP1;
  364.  
  365. **************
  366. * 3- Bainite *
  367. **************
  368. IPAHS  = 3;
  369. ICOUL  = @MOD  IPAHS NBCOUL;
  370. COUL1  ='EXTR' LESCOUL ICOUL;
  371. CPHAS  ='CHAI' 'K' IPAHS;
  372. EVKP1  ='EVOL' COUL1  'MANU' 'T' LTKP1 CPHAS LKP1;
  373. MCHK   = MCHK  'ET' ('MANU' 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  374.  
  375. CPHAS  ='CHAI' 'R' IPAHS;
  376. EVRHOP1='EVOL' COUL1  'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  377. MCHRHO = MCHRHO'ET' ('MANU' 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  378.  
  379. CPHAS  ='CHAI' 'C' IPAHS;
  380. EVCP1  ='EVOL' COUL1  'MANU' 'T' LTCP1 CPHAS LCP1;
  381. MCHC   = MCHC  'ET' ('MANU' 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  382.  
  383. CPHAS  ='CHAI' 'ALP' IPAHS;
  384. EVALP3 ='EVOL' COUL1  'MANU' 'T' LTALP1 'ALPH' LALP1;
  385.  
  386. **************
  387. * 4- Ferrite *
  388. **************
  389. IPAHS  = 4;
  390. ICOUL  = @MOD  IPAHS NBCOUL;
  391. COUL1  ='EXTR' LESCOUL ICOUL;
  392. CPHAS  ='CHAI' 'K' IPAHS;
  393. EVKP1  ='EVOL' COUL1  'MANU' 'T' LTKP1 CPHAS LKP1;
  394. MCHK   = MCHK  'ET' ('MANU' 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  395.  
  396. CPHAS  ='CHAI' 'R' IPAHS;
  397. EVRHOP1='EVOL' COUL1  'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  398. MCHRHO = MCHRHO'ET' ('MANU' 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  399.  
  400. CPHAS  ='CHAI' 'C' IPAHS;
  401. EVCP1  ='EVOL' COUL1  'MANU' 'T' LTCP1 CPHAS LCP1;
  402. MCHC   = MCHC  'ET' ('MANU' 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  403.  
  404. CPHAS  ='CHAI' 'ALP' IPAHS;
  405. EVALP4 ='EVOL' COUL1  'MANU' 'T' LTALP1 'ALPH' LALP1;
  406.  
  407. ****************
  408. * 5- Austenite *
  409. ****************
  410. IPAHS  = 5;
  411. ICOUL  = @MOD  IPAHS NBCOUL;
  412. COUL1  ='EXTR' LESCOUL ICOUL;
  413. CPHAS  ='CHAI' 'K' IPAHS;
  414. LTKP5  ='PROG' 0    20 100 200 400 600 800 856
  415.                900 1000 1200 1500 1502 1600   ;
  416. LKP5   ='PROG' 0.0121 0.0124 0.0136 0.015 0.018 0.021 0.0239 0.0248
  417.                0.0254 0.0269 0.0298 0.0343 0.05 0.05;
  418. EVKP5  ='EVOL' COUL1  'MANU' 'T' LTKP5 CPHAS LKP5;
  419. MCHK         = MCHK  'ET' ('MANU' 'CHML' MODTHE CPHAS EVKP5 'TYPE' CTYP) ;
  420.  
  421. CPHAS  ='CHAI' 'R' IPAHS;
  422. LTRHOP5='PROG' 0 20 100 200 300 400
  423.                500 600 700 800 900 1440
  424.                2500 ;
  425. LRHOP5 ='PROG' 7852.D-9 7841.D-9 7794.D-9 7736.D-9 7680.D-9 7624.D-9
  426.                7569.D-9 7514.D-9 7458.D-9 7408.D-9 7356.D-9 7087.D-9
  427.                6613.D-9 ;
  428. EVRHOP5='EVOL' COUL1  'MANU' 'T' LTRHOP5 CPHAS LRHOP5;
  429. MCHRHO       = MCHRHO'ET' ('MANU' 'CHML' MODTHE CPHAS EVRHOP5 'TYPE' CTYP);
  430.  
  431.  
  432. CPHAS  ='CHAI' 'C' IPAHS;
  433. LTCP5  ='PROG' 21   50   150  200  250  300  350  475  575  675  800
  434.                950  1000 1100 1200 1300 1400 1440 1465 1490 1540 1590
  435.                1615 1640 2500 ;
  436. LCP5   ='PROG' 460.5 485.6 519.1 531.6 556.7 573.5 598.6 652 671 685 715
  437.                742 750 774 795 815 840 850 1210 1840 2470 1840
  438.                1210 840 707 ;
  439. EVCP5  ='EVOL' COUL1  'MANU' 'T' LTCP5 CPHAS LCP5;
  440. MCHC         = MCHC  'ET' ('MANU' 'CHML' MODTHE CPHAS EVCP5 'TYPE' CTYP) ;
  441.  
  442.  
  443. CPHAS  ='CHAI' 'ALP' IPAHS;
  444. LTALP5 ='PROG' 600. 'PAS' 1. 1000. ;
  445. LALP5  = 22.6D-6 * (LTALP5 ** 0.)  ;
  446. EVALP5 ='EVOL' COUL1  'MANU' 'T' LTALP5 'ALPH' LALP5;
  447.  
  448.  
  449. TDESS1           ='TABL' ;
  450. TDESS1 . 'TITRE' ='TABL' ;
  451. 'REPE' SURPHA NBCOMP;
  452.    NOMP ='EXTR' TPHASE.'PHASES' &SURPHA;
  453. *  TDESS1 . &SURPHA           ='CHAI' 'MARQ ' LAMAR ' REGU';
  454.    TDESS1 . 'TITRE' . &SURPHA = NOMP;
  455. 'FIN'  SURPHA;
  456. EVALP  = EVALP1 'ET' EVALP2 'ET' EVALP3 'ET' EVALP4 'ET' EVALP5 ;
  457. 'DESS' EVALP 'LEGE' TDESS1 'TITR' 'Evolution des APLHA de chaque phase en fonction de la temperature';
  458.  
  459. *******************************************************************************
  460. * Proprietes pour la metallurgie : DEBUT
  461. *******************************************************************************
  462. PROG_T   ='PROG'  716.  802. ;
  463. PROG_TPO ='PROG' -1.D-6 0.   ;
  464. PROG_PEQ ='PROG'  0.    1.   ;
  465. PROG_F   ='PROG'  0.    1.   ;
  466. PROG_TAU ='PROG' 12.    0.5  ;
  467.  
  468. *1ere transformation : 'MB'   --> 'AUST'
  469.   PEQ1 ='EVOL' 'MANU' 'T'   PROG_T   'PEQ1' PROG_PEQ ;
  470.   F1   ='EVOL' 'MANU' 'TPOI'PROG_TPO 'F1'   PROG_F   ;
  471.   TAU1 ='EVOL' 'MANU' 'T'   PROG_T   'TAU1' PROG_TAU ;
  472.  
  473. *2eme transformation : 'MART' --> 'AUST' parametres identiques a la premiere
  474.   PEQ2 ='EVOL' 'MANU' 'T'   PROG_T   'PEQ2' PROG_PEQ ;
  475.   F2   ='EVOL' 'MANU' 'TPOI'PROG_TPO 'F2'   PROG_F   ;
  476.   TAU2 ='EVOL' 'MANU' 'T'   PROG_T   'TAU2' PROG_TAU ;
  477.  
  478. *3eme transformation : 'BAIN' --> 'AUST' parametres identiques a la premiere
  479.   PEQ3 ='EVOL' 'MANU' 'T'   PROG_T   'PEQ3' PROG_PEQ ;
  480.   F3   ='EVOL' 'MANU' 'TPOI'PROG_TPO 'F3'   PROG_F   ;
  481.   TAU3 ='EVOL' 'MANU' 'T'   PROG_T   'TAU3' PROG_TAU ;
  482.  
  483. *4eme transformation : 'FERR' --> 'AUST' parametres identiques a la premiere
  484.   PEQ4 ='EVOL' 'MANU' 'T'   PROG_T   'PEQ4' PROG_PEQ ;
  485.   F4   ='EVOL' 'MANU' 'TPOI'PROG_TPO 'F4'   PROG_F   ;
  486.   TAU4 ='EVOL' 'MANU' 'T'   PROG_T   'TAU4' PROG_TAU ;
  487.  
  488. *5eme transformation : 'AUST' --> 'MART'
  489.   MS5  = 380.   ;
  490.   KM5  = 0.0247 ;
  491.  
  492. *6eme transformation : 'AUST' --> 'BAIN'
  493.   PEQ6 ='EVOL' 'MANU' 'T'    ('PROG' 375 380 405 600)
  494.                       'PEQ6' ('PROG' 0.  1.  1.  0.  );
  495.   F6   ='EVOL' 'MANU' 'TPOI' ('PROG' -100. -80.  -60.  -50.  -40.  -30.  -25.  -20. -18.  -15.  -12.  -10. -9.   -5.  -1.   -0.05    0.D0    1.D-6)
  496.                       'F6'   ('PROG'  0.005 1.573 2.857 3.417 3.982 4.583 4.833 5.26 5.472 6.033 7.675 11.4 18.45 17.1 0.328 0.00238 0.00238 0.   ) ;
  497.   TAU6 ='EVOL' 'MANU' 'T'    ('PROG' 375  380)
  498.                       'TAU6' ('PROG' 1.D6 20 );
  499.  
  500. *7eme transformation : 'AUST' --> 'FERR'
  501.   PEQ7 ='EVOL' 'MANU' 'T'    ('PROG' 625 630 730 735 )
  502.                       'PEQ7' ('PROG' 0   1   1   0   );
  503.   F7   ='EVOL' 'MANU' 'TPOI' ('PROG' -8.5  -6.2 -4.7  0.  1.D-6)
  504.                       'F7'   ('PROG'  0.001 0.13 1.5  1.5 0.   );
  505.   TAU7 ='EVOL' 'MANU' 'T'    ('PROG' 625  630 )
  506.                       'TAU7' ('PROG' 1.D6 5   );
  507. ************************************************************************
  508. * Definition de la metallurgie : FIN
  509. ************************************************************************
  510.  
  511. ************************************************************************
  512. * GRANDEURS initiales
  513. ************************************************************************
  514. *TEMPERATURE
  515.  CHPTINI = MANU 'CHPO' MAILT 1 'T' TMIN 'NATU' 'DIFFUS' ;
  516.  
  517.  CTYP    ='CHAI' 'VARIABLES_INTERNES';
  518.  CHPINI  ='MANU' 'CHML' MODCP1 'MB  ' MB_ini 'MART' MART_ini 'BAIN' BAIN_ini 'FERR' FERR_ini 'AUST' AUST_ini 'TYPE' CTYP 'NOEUD' ;
  519.  
  520. ************************************************************************
  521. * CARACTERISTIQUES MATERIAUX
  522. ************************************************************************
  523.  MATPHAS = MCHK 'ET' MCHRHO 'ET' MCHC                                      ;
  524.  MATTHE  ='MATE' MODTHE 'K'    0.D0   'RHO' 0.D0 'C' 0.D0                  ;
  525.  
  526.  MAMMB   ='MATE' MOMMB   'YOUN' 180.E9 'NU'  0.28 'SIGY' 280.E6 'ALPH' EVALP1 'TREF' 20.  'TALP' 20. ;
  527.  MAMMART ='MATE' MOMMART 'YOUN' 190.E9 'NU'  0.29 'SIGY' 290.E6 'ALPH' EVALP2 'TREF' 20.  'TALP' 20. ;
  528.  MAMBAIN ='MATE' MOMBAIN 'YOUN' 200.E9 'NU'  0.30 'SIGY' 200.E6 'ALPH' EVALP3 'TREF' 20.  'TALP' 20. ;
  529.  MAMFERR ='MATE' MOMFERR 'YOUN' 210.E9 'NU'  0.31 'SIGY' 210.E6 'ALPH' EVALP4 'TREF' 20.  'TALP' 20. ;
  530.  MAMAUST ='MATE' MOMAUST 'YOUN' 220.E9 'NU'  0.32 'SIGY' 220.E6 'ALPH' EVALP5 'TREF' 450. 'TALP' 20. ;
  531.  
  532.  MATMEC  = MAMMB 'ET' MAMMART 'ET' MAMBAIN 'ET' MAMFERR 'ET' MAMAUST ;
  533.  
  534.  MATCP1  ='MATE' MODCP1 'PEQ1' PEQ1 'TAU1' TAU1 'F1' F1
  535.                         'PEQ2' PEQ2 'TAU2' TAU2 'F2' F2
  536.                         'PEQ3' PEQ3 'TAU3' TAU3 'F3' F3
  537.                         'PEQ4' PEQ4 'TAU4' TAU4 'F4' F4
  538.                         'MS5'  MS5  'KM5'  KM5
  539.                         'PEQ6' PEQ6 'TAU6' TAU6 'F6' F6
  540.                         'PEQ7' PEQ7 'TAU7' TAU7 'F7' F7 ;
  541.  
  542. * Definition du materiau pour le modele de melange mecanique (les proportions de phase)
  543.  MAMELMEC  ='CHAN' 'CONS' CHPINI 'MEL1';
  544.  MAMELMEC  ='CHAN'  MAMELMEC 'TYPE' 'CARACTERISTIQUES';
  545.  MATTOT  = MATTHE 'ET' MATCP1 'ET' MAMELMEC 'ET' MATMEC ;
  546.  
  547. ************************************************************************
  548. * CONDITIONS aux LIMITES
  549. ************************************************************************
  550. * TEMPERATURE IMPOSE PARTOUT
  551.  CLTHE   = BLOQ 'T' MAILT ;
  552.  TIMPO   = DEPI 1.  CLTHE ;
  553.  
  554. * CHARGEMENT THERMIQUE 'T'
  555.  TPS0    = 0.D0;
  556.  TPS1    = TPS0 + ((TMAX-TMIN) / VCHAUFF);
  557.  TPS2    = TPS1 +   PALLIER ;
  558.  TPS3    = TPS2 + ((TMIN-TMAX) / VREFROI);
  559.  
  560.  LTPSCHA ='PROG'  TPS0 TPS1 TPS2 TPS3 ;
  561.  LTCHA   ='PROG'  TMIN TMIN TMAX TMIN ;
  562.  EVT     ='EVOL' 'MANU' LTPSCHA LTCHA ;
  563.  CHAR1   ='CHAR' 'TIMP' TIMPO EVT     ;
  564. 'DESS' EVT 'TITR' 'Chargement en temperature imposee au cours du temps';
  565.  
  566. * BLOCAGE MECANIQUE
  567.  CLMEC1  = BLOQ 'UZ' L1      ;
  568.  CLMEC2  = BLOQ 'UR' L4      ;
  569.  CLMEC   = CLMEC1 'ET' CLMEC2;
  570.  
  571. *CHARGEMENT Total
  572.  CHARTOT = CHAR1 ;
  573.  
  574. ************************************************************************
  575. * DEFINITION DE LA TABLE PASAPAS
  576. ************************************************************************
  577.  LTCAL1  ='PROG' TPS0 'PAS' DT TPS2 ;
  578.  
  579.  TPASAP                                  ='TABL'                 ;
  580.  TPASAP.'MODELE'                         = MODTOT                ;
  581.  TPASAP.'CARACTERISTIQUES'               = MATTOT                ;
  582.  TPASAP.'BLOCAGES_THERMIQUES'            = CLTHE                 ;
  583.  TPASAP.'BLOCAGES_MECANIQUES'            = CLMEC                 ;
  584.  TPASAP.'CHARGEMENT'                     = CHARTOT               ;
  585.  TPASAP.'TEMPS_CALCULES'                 = LTCAL1                ;
  586.  
  587.  TPASAP.'TEMPS'                          ='TABL'                 ;
  588.  TPASAP.'TEMPS'                      . 0 ='EXTR' LTCAL1 1        ;
  589.  TPASAP.'TEMPERATURES'                   ='TABL'                 ;
  590.  TPASAP.'TEMPERATURES'               . 0 = CHPTINI               ;
  591.  TPASAP.'PROPORTIONS_PHASES'             ='TABL'                 ;
  592.  TPASAP.'PROPORTIONS_PHASES'         . 0 = CHPINI                ;
  593.  
  594. * Indices divers
  595.  TPASAP.'PROCESSEURS'                    ='MOT' 'MONO_PROCESSEUR';
  596. *TPASAP.'FTOL'                           = 1.D-5                 ;
  597.  
  598. * PROCEDURES Utilisateurs
  599.  TPASAP.'PROCEDURE_PARATHER'             = VRAI                  ; 'COMM' 'MELANGE THERMIQUE a la MANO' ;
  600.  TPASAP.'PROCEDURE_REEV_THE'             = VRAI                  ; 'COMM' 'Mise a jour des props de phases pour le MELANGE en MECANIQUE'  ;
  601.  
  602.  PASAPAS TPASAP ;
  603.  
  604. * Reprise de calcul pour verifier la dilatation THERMIQUE
  605.  LTCAL1  ='PROG' TPS2 'PAS' DT TPS3 ;
  606.  TPASAP.'TEMPS_CALCULES'                 = LTCAL1                ;
  607.  PASAPAS TPASAP ;
  608.  
  609. ************************************************************************
  610. * POST-TRAITEMENT
  611. ************************************************************************
  612.  fic_sauv ='CHAI' 'COUPLAGE_THERO-METALLURGIQUE-MECANIQUE.sauv' ;
  613. 'OPTI' 'SAUV' fic_sauv ;
  614. 'SAUV' ;
  615.  
  616. * Initialisations pour le POST-TRAITEMENT
  617.  LISCOM ='EXTR' CHPINI 'COMP';
  618.  NBCOMP ='DIME' LISCOM       ;
  619.  TABPHA ='TABL';
  620. 'REPE' SURPHA NBCOMP;
  621.    TABPHA . &SURPHA ='VIDE' 'LISTREEL';
  622. 'FIN' SURPHA;
  623.  
  624.  LTPS ='VIDE' 'LISTREEL';
  625.  LVMI ='VIDE' 'LISTREEL';
  626.  LUZ1 ='VIDE' 'LISTREEL';
  627.  LT1  ='VIDE' 'LISTREEL';
  628. 'REPE' BLOC0 ('DIME' TPASAP.'TEMPS')                ;
  629.    I    = &BLOC0  - 1                            ;
  630.    CHT  = TPASAP.'TEMPERATURES'               . I;
  631.    CHPHA= TPASAP.'PROPORTIONS_PHASES'         . I;
  632.    CHSIG= TPASAP.'CONTRAINTES'                . I;
  633.    DEP1 = TPASAP.'DEPLACEMENTS'               . I;
  634.  
  635.    LTPS = LTPS 'ET' (TPASAP.'TEMPS'  . I)        ;
  636.    VMI1 ='VMIS' MODTOT CHSIG                     ;
  637.    LVMI = LVMI 'ET' ('EXTR' VMI1 'SCAL' 1 1 1)   ;
  638.    LUZ1 = LUZ1 'ET' ('EXTR' DEP1 'UZ'   P3   )   ;
  639.    LT1  = LT1  'ET' ('EXTR' CHT  'T'    P3   )   ;
  640.  
  641. * Extraction pour chaque phase de la valeur courante
  642.   'REPE' SURPHA NBCOMP;
  643.      NOMP       ='EXTR' TPHASE.'PHASES' &SURPHA;
  644.      TABPHA. &SURPHA = TABPHA. &SURPHA 'ET' ('EXTR' CHPHA NOMP 1 1 1);
  645.   'FIN' SURPHA;
  646. 'FIN' BLOC0 ;
  647.  
  648. *Reconstitution des EVOL
  649.  EVTOTa ='VIDE' 'EVOLUTIO';
  650.  EVOPHAS='VIDE' 'EVOLUTIO';
  651.  CPPHAS ='CHAN' 'CHPO' CHPHA MODTOT;
  652.  
  653. 'REPE' SURPHA NBCOMP;
  654.    NOMP             ='EXTR' TPHASE.'PHASES' &SURPHA;
  655.    ICOUL            = @MOD  &SURPHA NBCOUL;
  656.    COUL1            ='EXTR' LESCOUL ICOUL;
  657.    Lpi              = TABPHA. &SURPHA ;
  658.    TABPHA . &SURPHA ='EVOL' COUL1 'MANU' 'TEMP' LTPS NOMP Lpi;
  659.    EVTOTa           = EVTOTa 'ET' TABPHA . &SURPHA ;
  660.    IMARQ            = @MOD   &SURPHA NBMARQ;
  661.    LAMAR            ='EXTR'  IMARQ LESMARQ;
  662.    EVOPHAS          = EVOPHAS 'ET' ('EVOL' COUL1 'CHPO' CPPHAS NOMP L2);
  663. 'FIN'  SURPHA;
  664.  
  665.  EVTOTa  = 'CHAN' 'NOMORD' EVTOTa 'PROP';
  666. 'DESS' EVTOTa  'LEGE' TDESS1 'TITR' ('CHAI' 'Evolution des Props en fonction du temps' ) 'YBOR' 0. 1. ;
  667.  
  668.  EVOPHAS = 'CHAN' 'NOMORD' EVOPHAS 'PROP';
  669. 'DESS' EVOPHAS 'LEGE' TDESS1 'TITR' ('CHAI' 'Props a Temps final' ) 'YBOR' 0. 1. ;
  670.  
  671.  ICOUL   = ICOUL + 1          ;
  672.  ICOUL   = @MOD  ICOUL NBCOUL ;
  673.  COUL1   ='EXTR' LESCOUL ICOUL;
  674.  EVOVMI  ='EVOL' COUL1 'MANU' 'TEMP' LTPS 'VMIS' LVMI;
  675. 'DESS' EVOVMI 'TITR' ('CHAI' 'Evolution de VMIS en fonction du temps' ) ;
  676.  
  677.  ICOUL   = ICOUL + 1          ;
  678.  ICOUL   = @MOD  ICOUL NBCOUL ;
  679.  COUL1   ='EXTR' LESCOUL ICOUL;
  680.  EVOUZ1  ='EVOL' COUL1 'MANU' 'TEMP' LTPS 'UZP3' LUZ1;
  681. 'DESS' EVOUZ1 'TITR' ('CHAI' 'Evolution de UZ au point P3 en fonction du temps' ) 'AXES' ;
  682.  
  683.  ICOUL   = ICOUL + 1          ;
  684.  ICOUL   = @MOD  ICOUL NBCOUL ;
  685.  COUL1   ='EXTR' LESCOUL ICOUL;
  686.  EVOUZ2  ='EVOL' COUL1 'MANU' 'T' LT1 'EPZ' (LUZ1 / h0 * 100);
  687. 'DESS' EVOUZ2 'TITR' ('CHAI' 'Evolution de EPZ (%) au point P3 en fonction de la temperature' ) 'XBOR' 0. 1000. 'AXES';
  688.  
  689. 'TEMP' 'IMPR' 'PROC';
  690. 'TEMP' 'IMPR' 'BOUC';
  691.  
  692. FIN ;
  693.  
  694.  
  695.  
  696.  
  697.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales