Exemples de jeux de données Cast3M

* fichier : meric3.dgibi
* section : Mecanique Viscoplastique
*----------------------------------------------------------------------*
*                        M E R I C 3 . D G I B I                       *
*----------------------------------------------------------------------*
*
* Objet :
* -------
*
* Exemple d'utilisation et test de validation de la loi de comportement
* MERIC_CAILLETAUD.
*
* Exemple derivé de meric2.dgibi.
*
*
* Description :
* -------------
* Essai de traction-compression.
*
* Type de calcul : Mecanique, grands deplacements
* Mode de calcul : 3D
* Type d'element : CUB8 BBAR
* Chargement     : Deplacement impose
* Reference      : sans objet
* Objectif       : verification bon fonctionnement
*
*----------------------------------------------------------------------*
 
* Pour afficher les traces, mettre IGRAPH a vrai :
IGRAPH = faux ;
 
*opti trac psc ;
 
*------------------------ Maillage (1 element) ------------------------*
 
opti dime 3 elem CUB8 ;
 
ne1 = 1 ;
l1  = (0 0 0) droi ne1 (1 0 0) ;
S1  = l1 tran ne1 (0 1 0) ; 
V1  = S1 volu tran ne1 (0 0 1) ;
 
S2  = V1 face 2 ;
p1  = V1 poin proc (0 0 1) ;
px0 = (V1 coor 1) poin mini ;
py0 = (V1 coor 2) poin mini ;
 
si IGRAPH ;
  trac qual V1 titr ' Maillage ' ;
fins ;
*
*---------------------- Modele & Carateristiques ----------------------*
*
* Parametres issus du modele de chaboce (voir Lemaitre & Chaboche) ;
SIGY1 = 82.e6 ;
TAU0  = 0.5 * SIGY1 ;
N1    = 24. ;
K1    = 151.e6 ;
CLM   = 162400.e6 ;
Gam   = 2800. ;
A1    = CLM / Gam ;
C1    = Gam   ;
Q1    = 142.e6 - SIGY1 ;
B1    = 8. ;
* Valeurs parametres modele Meric_Cailletaud :
K0    = 0.5 * K1 / (3. ** (1. / N1)) ;
C0    = 0.5 * C1 ;
Q0    = 0.5 * Q1 ;
 
* Module d'Young et coeff. de Poisson :
YM1   = 200.e9 ;
NU1   = 0.3 ;
 
* Modeles & Caracteristiques :
mo1 = 'MODE' V1  'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 'VISCOPLASTIQUE'  'MERIC_CAILLETAUD' 'BBAR' ;
ma1 = 'MATE' mo1 'YOUN' YM1 'NU' NU1 'TAU0' TAU0 'NX' 1 'NY' 0 'NZ' 1 'BX' -1 'BY' 0 'BZ' 1 
                 'K'    K0  'N'  N1  'A'    A1   'C'    C0 'B' B1 'Q' Q0 ;
 
*-------------------------- CL & Chargement ---------------------------*
*
cl1 = bloq uz S1 ;
cl2 = bloq ux px0 ;
cl3 = bloq uy py0 ;
cl4 = bloq uz s2 ;
 
u1  = 0.002 ;
f1  = depi cl4 u1 ;
 
xt1  = 100. ;
yt1  =  1. ;
ev1  = evol manu temp (xt1 * (prog 0. 1. 2.  3. 4. 6.))
                      (yt1 * (prog 0. 1. 0. -1. 0. 2.)) ;
cgu1 = char dimp f1 ev1 ;
 
si IGRAPH ;
  trac qual (V1 et (S1 coul roug) et (S2 coul vert) et ((px0 et py0) coul bleu))
    titr ' CL : Uz=0 en S1 (rouge), Ux=0 en x=y=0 (bleu) et Uz impose sur S2 (vert)' ;
  dess (u1*ev1) titre ' Evolution temporelle du deplacement impose ';
fins ;
 
*------------------------- Resolution PASAPAS -------------------------*
*
* Modele de Chaboche :
ta1 = tabl ;
ta1.modele = mo1 ;
ta1.caracteristiques = ma1 ;
ta1.blocages_mecaniques = cl1 et cl2 et cl3 et cl4 ;
ta1.chargement = cgu1 ;
ta1.temps_calcules = (prog 0. pas 0.1 6.) * xt1 ;
 
ta1.grands_deplacements = vrai ;
ta1.lagrangien          = mot 'REACTUALISE' ;
ta1.predicteur          = mot 'HPP' ;
 
ta1.mes_sauvegardes = tabl ;
ta1.mes_sauvegardes.defto = vrai ;
ta1.mes_sauvegardes.defin = vrai ;
 
pasapas ta1 ;
 
*-------------------- Postraitement des resultats ---------------------*
 
* Courbe force-deplacement, puis contrainte-deformation :
evuz1    = evol temp ta1 deplacements p1 uz ;
evfz1    = evol temp ta1 reactions p1 fz ;
evfu1    = evol roug manu lege 'Meric' 'MARQ' 'ROND' 'TAIL' 'S' '\e' (extr evuz1 ordo) '\s (MPa)' (extr evfz1 ordo) ;
evfu1    = evfu1 * 1.e-6 ; comm 'force => contrainte (MPa)' ;
 
* Comparaison modeles Meric-Chaboche
si IGRAPH ;
  dess evfu1 titr 'Reponse contrainte-deformation' lege gril poin gris posy exce ;
fins ;
 
fin ;