Télécharger mazars_triaxial.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : mazars_triaxial.dgibi
  2. ************************************************************************
  3. * Cas test elementaire pour la loi d'endommagement de Mazars *
  4. * Essai de compression sous confinement (triaxial) *
  5. * *
  6. * Les donnees experimentales servant de reference sont issues de : *
  7. * "Study of the Behavior of Concrete under Triaxial Compression" *
  8. * Domingo Sfer, Ignacio Carol, Ravindra Gettu, Guillermo Etse *
  9. * Journal of Engineering Mechanics, 2002, 128(2): 156-163 *
  10. * doi : 10.1061/(ASCE)0733-9399(2002)128:2(156) *
  11. * *
  12. * Le test est realise avec plusieurs modes de calcul : *
  13. * 1) 3D volumique *
  14. * 2) 2D axisymetrique *
  15. * *
  16. * ITRAC1 : VRAI => affichage resultats *
  17. * IPSC1 : VRAI => affichage resultats dans un PostScript Couleur *
  18. ************************************************************************
  19.  
  20. DIVERS = 'VENV' 'CASTEM_DIVERS' ;
  21. FIC1 = 'CHAI' DIVERS '/mazars_triaxial_0MPa_courbe0.csv';
  22. FIC2 = 'CHAI' DIVERS '/mazars_triaxial_1.5MPa_courbe0.csv';
  23. FIC3 = 'CHAI' DIVERS '/mazars_triaxial_4.5MPa_courbe0.csv';
  24. FIC4 = 'CHAI' DIVERS '/mazars_triaxial_9MPa_courbe0.csv';
  25.  
  26. ** Options pour les traces
  27. ITRAC1 = FAUX ;
  28. IPSC1 = VRAI ;
  29. SI IPSC1 ;
  30. OPTI 'TRAC' 'PSC' ;
  31. FINSI ;
  32.  
  33. ** Liste des modes de calcul a traiter
  34. lcas = LECT 1 2 ;
  35. *nh145313
  36. *lcas = LECT 1 ; COMM '3D volumique' ;
  37. *lcas = LECT 2 ; COMM '2D axisymetrique' ;
  38.  
  39. ** Parametres geometriques
  40. rayo = 75.E-3 ;
  41. long = rayo * (pi ** 0.5) ;
  42. haut = 300.E-3 ;
  43.  
  44. ** Parametres materiau
  45. you = 27.3E9 ;
  46. nu = 0.2 ;
  47. epd0 = 1.E-5 ;
  48. at = 1. ;
  49. ac = 1.1 ;
  50. bt = 10000. ;
  51. bc = 1200. ;
  52. beta = 1. ;
  53.  
  54. ** Parametres chargement
  55. lpres = PROG 0. 1.5E6 4.5E6 9.E6 ;
  56. umax = 0.015 * haut ;
  57.  
  58. ** Legende courbes
  59. tleg = TABL ;
  60. tleg . 'TITRE' = TABL ;
  61.  
  62. *nh145313 .csv recuperes => resext = vrai
  63. resexp = vrai ;
  64.  
  65.  
  66.  
  67.  
  68. **************** C A S #1 : 3 D V O L U M I Q U E ****************
  69. SI (EXIS lcas 1) ;
  70.  
  71. ** Options generales
  72. OPTI 'DIME' 3 'MODE' 'TRID' 'ELEM' 'CUB8' ;
  73.  
  74. ** Maillage
  75. p1 = 0. 0. 0. ;
  76. p2 = 0. long 0. ;
  77. l12 = DROI 1 p1 p2 ;
  78. sgauche = l12 TRAN 1 (0. 0. haut) ;
  79. mail = sgauche VOLU 'TRAN' 1 (long 0. 0.) ;
  80. sdroite = mail FACE 2 ;
  81. env1 = ENVE mail ;
  82. sbas = env1 ELEM 5 ;
  83. shaut = env1 ELEM 2 ;
  84. sdevant = env1 ELEM 4 ;
  85. sderrie = env1 ELEM 3 ;
  86. p3 = mail POIN 'PROC' (0. 0. haut) ;
  87. mes1 = MESU mail ;
  88. *nh145313
  89. cadr1 = COUL ((0. (long + 5.E-3) (haut + 5.E-3)) ET (long (long + 5.E-3) (haut + 5.E-3))) 'BLAN' ;
  90. rep1 = @REPERE (-0.16 -0.16 0.) (PROG 0.3 0.3 0.3) 'TURQ' ;
  91. SI ITRAC1 ;
  92. TRAC 'QUAL' (cadr1 ET rep1 ET mail ET (sgauche COUL 'VERT') ET (sdroite COUL 'ROUG')) 'TITR' '[3D V] Maillage - sgauche, sdroite' ;
  93. TRAC 'QUAL' (cadr1 ET rep1 ET mail ET (sbas COUL 'VERT') ET (shaut COUL 'ROUG')) 'TITR' '[3D V] Maillage - sbas, shaut' ;
  94. TRAC 'QUAL' (cadr1 ET rep1 ET mail ET (sdevant COUL 'VERT') ET (sderrie COUL 'ROUG')) 'TITR' '[3D V] Maillage - sdevant, sderrie' ;
  95. TRAC 'QUAL' (cadr1 ET rep1 ET mail ET ((sgauche ET sbas ET sdevant) COUL 'VERT') ET ((sdroite ET shaut ET sderrie) COUL 'ROUG')) 'TITR' '[3D V] Maillage' ;
  96. FINSI ;
  97.  
  98. ** Modele et caracteristiques materiau
  99. mo = MODE mail 'MECANIQUE' 'ELASTIQUE' 'ENDOMMAGEMENT' 'MAZARS' ;
  100. ma = MATE mo 'YOUN' you 'NU' nu 'KTR0' epd0 'ACOM' ac 'BCOM' bc 'ATRA' at 'BTRA' bt 'BETA' beta ;
  101.  
  102. ** Blocages
  103. blhaut = BLOQ 'UZ' shaut ;
  104. blrig = (BLOQ 'UX' sgauche) ET (BLOQ 'UY' sdevant) ET (BLOQ 'UZ' sbas) ;
  105. bl = blhaut ET blrig ;
  106.  
  107. ** Chargements (plusieurs pressions imposees, deplacement impose)
  108. evc1 = EVOL 'MANU' (PROG 0. 0.5 1.) (PROG 0. 1. 1.) ;
  109. lcoul = MOTS 'BLEU' 'ORAN' 'VERT' 'ROUG' ;
  110. evtot0 = VIDE 'EVOLUTIO' ;
  111. evtot1 = VIDE 'EVOLUTIO' ;
  112. evtot2 = VIDE 'EVOLUTIO' ;
  113. npres = DIME lpres ;
  114. REPE b0 npres ;
  115. * On fait un premier calcul avec seulement la pression imposee
  116. pre1 = EXTR lpres &b0 ;
  117. *nh145313
  118. * fpr = PRES 'MASS' mo (sdroite ET sderrie ET shaut) pre1 ;
  119. fprx = PRES 'MASS' mo sdroite pre1 ;
  120. fpry = PRES 'MASS' mo sderrie pre1 ;
  121. fprz = PRES 'MASS' mo shaut pre1 ;
  122. fpr = fprx ET fpry ET fprz ;
  123. chap = CHAR 'MECA' fpr evc1 ;
  124. * Resolution 1 : mise en pression seulement
  125. t = TABL ;
  126. t . 'MODELE' = mo ;
  127. t . 'CARACTERISTIQUES' = ma ;
  128. t . 'BLOCAGES_MECANIQUES' = blrig ;
  129. t . 'CHARGEMENT' = chap ;
  130. t . 'TEMPS_CALCULES' = PROG 0. 'PAS' 0.1 0.5 ;
  131. t . 'MOVA' = MOT 'D' ;
  132. t . 'MES_SAUVEGARDES' = TABL ;
  133. t . 'MES_SAUVEGARDES' . 'DEFTO' = VRAI ;
  134. PASAPAS t ;
  135. * Resolution 2 : pression + ajout du deplacement impose
  136. dihaut = DEPI blhaut -1. ;
  137. uz0 = ABS (EXTR (t . 'DEPLACEMENTS' . 5) 'UZ' p3) ;
  138. evc2 = EVOL 'MANU' (PROG 0.5 1.) (PROG uz0 (umax - uz0)) ;
  139. chadi = CHAR 'DIMP' dihaut evc2 ;
  140. *nh145313
  141. ** Trace des blocages et du chargement
  142. re0 = @REPERE (-0.16 -0.16 0.) (PROG 0.3 0.3 0.3) ;
  143. mor = MODE re0 'MECANIQUE' 'BARR' ;
  144. mar = MATE mor 'YOUN' 1. 'NU' 1. 'SECT' 1. ;
  145. rir = RIGI mor mar ;
  146. vprx = VECT fprx 'FORC' 'VERT' 1.2E-6 ;
  147. vpry = VECT fpry 'FORC' 'VERT' 1.2E-6 ;
  148. vprz = VECT fprz 'FORC' 'VERT' 1.2E-6 ;
  149. vdiz = VECT dihaut ' ' ' ' 'FLX' 'ROUG' 3.E-2 ;
  150. tit0 = CHAI '[3D V] Blocages et chargement Uimp et Pres.imp =' pre1 ' Pa' ;
  151. SI ITRAC1 ;
  152. TRAC ((RIGI mo ma) ET bl ET rir) (vprx ET vpry ET vprz ET vdiz) 'NOLE' 'TITR' tit0 ;
  153. FINSI ;
  154. t . 'BLOCAGES_MECANIQUES' = bl ;
  155. t . 'CHARGEMENT' = chap ET chadi ;
  156. t . 'TEMPS_CALCULES' = PROG 0.505 'PAS' 0.005 1. ;
  157. PASAPAS t ;
  158. * SI ITRAC1 ;
  159. * tit1 = CHAI '[3D V] UZ vs Temps - P =' ' ' pre1 ;
  160. * DESS (EVOL 'TEMPE' t 'DEPLACEMENTS' 'UZ' p3) 'TITR' tit1 ;
  161. * tit1 = CHAI '[3D V] SMZZ vs Temps - P =' ' ' pre1 ;
  162. * DESS (EVOL 'TEMP' t 'CONTRAINTES' 'SMZZ' 1 1 1) 'TITR' tit1 ;
  163. * FINSI ;
  164.  
  165. ** Post traitement :
  166. * courbes : endommagement moyen vs temps
  167. * contrainte moyenne vs deformation moyenne
  168. * force de reaction vs deplacement impose
  169. tt = t . 'TEMPS' ;
  170. tc = t . 'CONTRAINTES' ;
  171. te = t . 'DEFORMATIONS' ;
  172. tv = t . 'VARIABLES_INTERNES' ;
  173. tu = t . 'DEPLACEMENTS' ;
  174. tr = t . 'REACTIONS' ;
  175. def0 = DEFO (cadr1 ET rep1 ET mail) (tu . 0) 0. ;
  176. ltps = PROG ;
  177. lend = PROG ;
  178. lsig = PROG ;
  179. leps = PROG ;
  180. ldep = PROG ;
  181. lrea = PROG ;
  182. REPE b1 (DIME tt) ;
  183. tps1 = tt . (&b1 - 1) ;
  184. end1 = (INTG mo (tv . (&b1 - 1)) 'D') / mes1 ;
  185. sig1 = (INTG mo (tc . (&b1 - 1)) 'SMZZ') / mes1 ;
  186. eps1 = (INTG mo (te . (&b1 - 1)) 'EPZZ') / mes1 ;
  187. u1 = EXTR (tu . (&b1 - 1)) 'UZ' p3 ;
  188. rea1 = 0. ;
  189. SI ((NBEL (EXTR (tr . (&b1 - 1)) 'MAIL')) > 0) ;
  190. rea1 = @TOTAL (tr . (&b1 - 1)) sbas 'FZ' ;
  191. FINSI ;
  192. ltps = ltps ET tps1 ;
  193. lend = lend ET end1 ;
  194. lsig = lsig ET sig1 ;
  195. leps = leps ET eps1 ;
  196. ldep = ldep ET u1 ;
  197. lrea = lrea ET rea1 ;
  198. FIN b1 ;
  199. evtot0 = evtot0 ET (EVOL (EXTR lcoul &b0) 'MANU' 'Temps' ltps 'D' lend) ;
  200. evtot1 = evtot1 ET (EVOL (EXTR lcoul &b0) 'MANU' 'EPZZ' leps 'SMZZ' lsig) ;
  201. evtot2 = evtot2 ET (EVOL (EXTR lcoul &b0) 'MANU' 'UZ' ldep 'FZ' lrea) ;
  202. tleg . 'TITRE' . &b0 = CHAI 'FORMAT' '(F3.1)' 'Calcul_P=' (pre1*1.E-6) '_MPa' ;
  203. * deformee
  204. REPE b2 (DIME t . 'TEMPS') ;
  205. tps1 = t . 'TEMPS' . (&b2 - 1) ;
  206. * trace de la deformee (pour controle visuel)
  207. def1 = DEFO mail (tu . (&b2 - 1)) 10. 'ROUG' ;
  208. tit1 = CHAI '[3D V] Deformee au temps' ' ' tps1 ;
  209. SI ITRAC1 ;
  210. * TRAC (def0 ET def1) 'TITR' tit1 ;
  211. FINSI ;
  212. FIN b2 ;
  213. SI ITRAC1 ;
  214. TRAC (def0 ET def1) 'TITR' tit1 ;
  215. FINSI ;
  216. FIN b0 ;
  217.  
  218. ** Donnees experimentales de reference (FdP)
  219. si (resexp);
  220. evxp0 = VIDE 'EVOLUTIO' ;
  221. tleg . (npres + 1) = MOT 'MARQ CROI NOLI' ;
  222. tleg . 'TITRE' . (npres + 1) = 'Ref_Exp_P=0.0_MPa' ;
  223. tleg . (npres + 2) = MOT 'MARQ CROI NOLI' ;
  224. tleg . 'TITRE' . (npres + 2) = 'Ref_Exp_P=1.5_MPa' ;
  225. tleg . (npres + 3) = MOT 'MARQ CROI NOLI' ;
  226. tleg . 'TITRE' . (npres + 3) = 'Ref_Exp_P=4.5_MPa' ;
  227. tleg . (npres + 4) = MOT 'MARQ CROI NOLI' ;
  228. tleg . 'TITRE' . (npres + 4) = 'Ref_Exp_P=9.0_MPa' ;
  229. * Courbes Contrainte vs Deformation
  230. txp = LIRE 'CSV' FIC1 'DEBU' 2 'SEPA' ',' ;
  231. evxp0 = evxp0 ET (EVOL 'BLEU' 'MANU' 'EPZZ' (txp . 1) 'SMZZ' (txp . 2)) ;
  232. txp = LIRE 'CSV' FIC2 'DEBU' 2 'SEPA' ',' ;
  233. evxp0 = evxp0 ET (EVOL 'ORAN' 'MANU' 'EPZZ' (txp . 1) 'SMZZ' (txp . 2)) ;
  234. txp = LIRE 'CSV' FIC3 'DEBU' 2 'SEPA' ',' ;
  235. evxp0 = evxp0 ET (EVOL 'VERT' 'MANU' 'EPZZ' (txp . 1) 'SMZZ' (txp . 2)) ;
  236. txp = LIRE 'CSV' FIC4 'DEBU' 2 'SEPA' ',' ;
  237. evxp0 = evxp0 ET (EVOL 'ROUG' 'MANU' 'EPZZ' (txp . 1) 'SMZZ' (txp . 2)) ;
  238. fins;
  239. ** Trace des courbes pour les differents niveaux de pression
  240. SI ITRAC1 ;
  241. DESS evtot0 'TITR' '[3D V] Endommagement vs Temps' 'LEGE' tleg ;
  242. SI RESEXP ;
  243. DESS (evtot1 ET evxp0) 'TITR' '[3D V] Contrainte vs Deformation' 'LEGE' tleg ;
  244. SINON ;
  245. DESS evtot1 'TITR' '[3D V] Contrainte vs Deformation' 'LEGE' tleg ;
  246. FINSI ;
  247. DESS evtot2 'TITR' '[3D V] Reaction vs Deplacement' 'LEGE' tleg ;
  248. FINSI ;
  249. *nh145313
  250. ** Comparaison Calcul / Reference sur l'aire sous la courbe Contrainte vs Deformation
  251. si (resexp);
  252. OPTI ECHO 0 ;
  253. SAUT 1 LIGN ;
  254. MESS ' **************** C A S #1 : 3 D V O L U M I Q U E ****************';
  255. SAUT 1 LIGN ;
  256. tbid = TABL ;
  257. tbid . 'TITRE' = TABL ;
  258. tbid . 1 = 'MARQ PLUS' ;
  259. tbid . 'TITRE' . 1 = 'Cal.init.' ;
  260. tbid . 2 = 'MARQ ETOI' ;
  261. tbid . 'TITRE' . 2 = 'Ref.exp.' ;
  262. tbid . 3 = 'MARQ CROI' ;
  263. tbid . 'TITRE' . 3 = 'Cal.lim.' ;
  264. REPE b2 (DIME evxp0) ;
  265. evexp = EXTR evxp0 'COUR' &b2 ;
  266. xmexp = EXTR (EXTR evexp 'ABSC') (DIME (EXTR evexp 'ABSC')) ;
  267. evcal = EXTR evtot1 'COUR' &b2 ;
  268. ymcal = IPOL xmexp evcal ;
  269. xcal2 = PROG ;
  270. ycal2 = PROG ;
  271. REPE b3 (DIME (EXTR evcal 'ABSC')) ;
  272. xx = EXTR (EXTR evcal 'ABSC') &b3 ;
  273. yy = EXTR (EXTR evcal 'ORDO') &b3 ;
  274. SI (< xx xmexp) ;
  275. QUIT b3 ;
  276. FINSI ;
  277. xcal2 = xcal2 ET (PROG xx) ;
  278. ycal2 = ycal2 ET (PROG yy) ;
  279. FIN b3 ;
  280. xcal2 = xcal2 ET (PROG xmexp) ;
  281. ycal2 = ycal2 ET (PROG ymcal) ;
  282. evcal2 = EVOL MANU 'EPZZ' xcal2 'SMZZ' ycal2 ;
  283. ivexp = INTG evexp ;
  284. ivcal = INTG evcal2 ;
  285. ec1 = ivcal - ivexp ;
  286. er1 = ec1 / ivexp ;
  287. * tit0 = CHAI (tleg . 'TITRE' . &b2) ' Defo.max' xmexp ' -> Contr.cal' ymcal ;
  288. tit0 = CHAI (tleg . 'TITRE' . &b2) ' Aire courb.exp' ivexp ' Aire courb.cal' ivcal ' Ec.Rel.' er1;
  289. SI ITRAC1 ;
  290. DESS (evcal et evexp et evcal2) 'TITR' tit0 'LEGE' tbid ;
  291. FINSI ;
  292. MESS ' Pres.hydrostat :' (tleg . 'TITRE' . &b2) ', Ecart relatif entre Calcul et Reference :' er1 ;
  293. SAUT 1 LIGN ;
  294. FIN b2 ;
  295. OPTI ECHO 1 ;
  296. fins;
  297. FINSI ;
  298.  
  299.  
  300.  
  301.  
  302. **************** C A S #2 : 2 D A X I S Y M E T R I Q U E ****************
  303. SI (EXIS lcas 2) ;
  304. ** Options generales
  305. OPTI 'DIME' 2 'MODE' 'AXIS' 'ELEM' 'QUA4' ;
  306.  
  307. ** Maillage
  308. p1 = 0. 0. ;
  309. p2 = rayo 0. ;
  310. sbas = DROI 1 p1 p2 ;
  311. mail = sbas TRAN 1 (0. haut) ;
  312. shaut = mail COTE 3 ;
  313. p3 = shaut POIN 'PROC' (0. haut) ;
  314. sdroite = mail COTE 2 ;
  315. *nh145313
  316. cadr1 = COUL ((0. (haut + 5.E-3)) ET (long (haut + 5.E-3))) 'BLAN' ;
  317. rep1 = @REPERE (-0.1 -0.06) (PROG 0.15 0.15) 'TURQ' ;
  318. SI ITRAC1 ;
  319. TRAC 'QUAL' (cadr1 ET rep1 ET mail ET (sbas COUL 'VERT') ET ((sdroite ET shaut) COUL 'ROUG')) 'TITR' '[2D Axi.] Maillage' ;
  320. FINSI ;
  321.  
  322. ** Modele et caracteristiques materiau
  323. mo = MODE mail 'MECANIQUE' 'ELASTIQUE' 'ENDOMMAGEMENT' 'MAZARS' ;
  324. ma = MATE mo 'YOUN' you 'NU' nu 'KTR0' epd0 'ACOM' ac 'BCOM' bc 'ATRA' at 'BTRA' bt 'BETA' beta ;
  325. zer = ZERO mo 'NOEUD' ;
  326. un = zer + 1. ;
  327. mes1 = INTG mo un 'SCAL' ;
  328.  
  329. ** Blocages
  330. blhaut = BLOQ 'UZ' shaut ;
  331. blrig = BLOQ 'UZ' sbas ;
  332. bl = blhaut ET blrig ;
  333.  
  334. ** Chargements (plusieurs pressions imposees, deplacement impose)
  335. evc1 = EVOL 'MANU' (PROG 0. 0.5 1.) (PROG 0. 1. 1.) ;
  336. lcoul = MOTS 'BLEU' 'ORAN' 'VERT' 'ROUG' ;
  337. evtot0 = VIDE 'EVOLUTIO' ;
  338. evtot1 = VIDE 'EVOLUTIO' ;
  339. evtot2 = VIDE 'EVOLUTIO' ;
  340. npres = DIME lpres ;
  341. REPE b0 npres ;
  342. * On fait un premier calcul avec seulement la pression imposee
  343. pre1 = EXTR lpres &b0 ;
  344. *nh145313
  345. * fpr = PRES 'MASS' mo (sdroite ET shaut) pre1 ;
  346. fprr = PRES 'MASS' mo sdroite pre1 ;
  347. fprz = PRES 'MASS' mo shaut pre1 ;
  348. fpr = fprr ET fprz ;
  349. chap = CHAR 'MECA' fpr evc1 ;
  350. * Resolution 1 : mise en pression seulement
  351. t = TABL ;
  352. t . 'MODELE' = mo ;
  353. t . 'CARACTERISTIQUES' = ma ;
  354. t . 'BLOCAGES_MECANIQUES' = blrig ;
  355. t . 'CHARGEMENT' = chap ;
  356. t . 'TEMPS_CALCULES' = PROG 0. 'PAS' 0.1 0.5 ;
  357. t . 'MOVA' = MOT 'D' ;
  358. t . 'MES_SAUVEGARDES' = TABL ;
  359. t . 'MES_SAUVEGARDES' . 'DEFTO' = VRAI ;
  360. PASAPAS t ;
  361. * Resolution 2 : pression + ajout du deplacement impose
  362. dihaut = DEPI blhaut -1. ;
  363. uz0 = ABS (EXTR (t . 'DEPLACEMENTS' . 5) 'UZ' p3) ;
  364. evc2 = EVOL 'MANU' (PROG 0.5 1.) (PROG uz0 (umax - uz0)) ;
  365. chadi = CHAR 'DIMP' dihaut evc2 ;
  366. *nh145313
  367. ** Trace des blocages et du chargement
  368. re0 = @REPERE (-0.1 -0.06) (PROG 0.15 0.15) ;
  369.  
  370. mor = MODE re0 'MECANIQUE' 'BARR' ;
  371. mar = MATE mor 'YOUN' 1. 'NU' 1. 'SECT' 1. ;
  372. rir = RIGI mor mar ;
  373. vprr = VECT fprr 'FORC' 'VERT' 1.E-7 ;
  374. vprz = VECT fprz 'FORC' 'VERT' 1.E-7 ;
  375. vdiz = VECT dihaut ' ' 'FLX' 'ROUG' 3.E-2 ;
  376. tit0 = CHAI '[2D Axi.] Blocages et chargement Uimp et Pres.imp =' pre1 ' Pa' ;
  377. SI ITRAC1 ;
  378. TRAC ((RIGI mo ma) ET bl ET rir) (vprr ET vprz ET vdiz) 'NOLE' 'TITR' tit0 ;
  379. FINSI ;
  380. t . 'BLOCAGES_MECANIQUES' = bl ;
  381. t . 'CHARGEMENT' = chap ET chadi ;
  382. t . 'TEMPS_CALCULES' = PROG 0.505 'PAS' 0.005 1. ;
  383. PASAPAS t ;
  384. * SI ITRAC1 ;
  385. * tit1 = CHAI '[2D Axi.] UZ vs Temps - P =' ' ' pre1 ;
  386. * DESS (EVOL 'TEMPE' t 'DEPLACEMENTS' 'UZ' p3) 'TITR' tit1 ;
  387. * tit1 = CHAI '[2D Axi.] SMZZ vs Temps - P =' ' ' pre1 ;
  388. * DESS (EVOL 'TEMP' t 'CONTRAINTES' 'SMZZ' 1 1 1) 'TITR' tit1 ;
  389. * FINSI ;
  390.  
  391. ** Post traitement :
  392. * courbes : endommagement moyen vs temps
  393. * contrainte moyenne vs deformation moyenne
  394. * force de reaction vs deplacement impose
  395. tt = t . 'TEMPS' ;
  396. tc = t . 'CONTRAINTES' ;
  397. te = t . 'DEFORMATIONS' ;
  398. tv = t . 'VARIABLES_INTERNES' ;
  399. tu = t . 'DEPLACEMENTS' ;
  400. tr = t . 'REACTIONS' ;
  401. def0 = DEFO (cadr1 ET rep1 ET mail) (tu . 0) 0. ;
  402. ltps = PROG ;
  403. lend = PROG ;
  404. lsig = PROG ;
  405. leps = PROG ;
  406. ldep = PROG ;
  407. lrea = PROG ;
  408. REPE b1 (DIME tt) ;
  409. tps1 = tt . (&b1 - 1) ;
  410. end1 = (INTG mo (tv . (&b1 - 1)) 'D') / mes1 ;
  411. sig1 = (INTG mo (tc . (&b1 - 1)) 'SMZZ') / mes1 ;
  412. eps1 = (INTG mo (te . (&b1 - 1)) 'EPZZ') / mes1 ;
  413. u1 = EXTR (tu . (&b1 - 1)) 'UZ' p3 ;
  414. rea1 = 0. ;
  415. SI ((NBEL (EXTR (tr . (&b1 - 1)) 'MAIL')) > 0) ;
  416. rea1 = @TOTAL (tr . (&b1 - 1)) sbas 'FZ' ;
  417. FINSI ;
  418. ltps = ltps ET tps1 ;
  419. lend = lend ET end1 ;
  420. lsig = lsig ET sig1 ;
  421. leps = leps ET eps1 ;
  422. ldep = ldep ET u1 ;
  423. lrea = lrea ET rea1 ;
  424. FIN b1 ;
  425. evtot0 = evtot0 ET (EVOL (EXTR lcoul &b0) 'MANU' 'Temps' ltps 'D' lend) ;
  426. evtot1 = evtot1 ET (EVOL (EXTR lcoul &b0) 'MANU' 'EPZZ' leps 'SMZZ' lsig) ;
  427. evtot2 = evtot2 ET (EVOL (EXTR lcoul &b0) 'MANU' 'UZ' ldep 'FZ' lrea) ;
  428. tleg . 'TITRE' . &b0 = CHAI 'FORMAT' '(F3.1)' 'Calcul_P=' (pre1*1.E-6) '_MPa' ;
  429. * deformee
  430. REPE b2 (DIME t . 'TEMPS') ;
  431. tps1 = t . 'TEMPS' . (&b2 - 1) ;
  432. * trace de la deformee (pour controle visuel)
  433. def1 = DEFO mail (tu . (&b2 - 1)) 10. 'ROUG' ;
  434. tit1 = CHAI '[2D Axi.] Deformee au temps' ' ' tps1 ;
  435. SI ITRAC1 ;
  436. * TRAC (def0 ET def1) 'TITR' tit1 ;
  437. FINSI ;
  438. FIN b2 ;
  439. SI ITRAC1 ;
  440. TRAC (def0 ET def1) 'TITR' tit1 ;
  441. FINSI ;
  442. FIN b0 ;
  443.  
  444. ** Donnees experimentales de reference (FdP)
  445. si (resexp);
  446. evxp0 = VIDE 'EVOLUTIO' ;
  447. tleg . (npres + 1) = MOT 'MARQ CROI NOLI' ;
  448. tleg . 'TITRE' . (npres + 1) = 'Ref_Exp_P=0.0_MPa' ;
  449. tleg . (npres + 2) = MOT 'MARQ CROI NOLI' ;
  450. tleg . 'TITRE' . (npres + 2) = 'Ref_Exp_P=1.5_MPa' ;
  451. tleg . (npres + 3) = MOT 'MARQ CROI NOLI' ;
  452. tleg . 'TITRE' . (npres + 3) = 'Ref_Exp_P=4.5_MPa' ;
  453. tleg . (npres + 4) = MOT 'MARQ CROI NOLI' ;
  454. tleg . 'TITRE' . (npres + 4) = 'Ref_Exp_P=9.0_MPa' ;
  455. * Courbes Contrainte vs Deformation
  456. txp = LIRE 'CSV' FIC1 'DEBU' 2 'SEPA' ',' ;
  457. evxp0 = evxp0 ET (EVOL 'BLEU' 'MANU' 'EPZZ' (txp . 1) 'SMZZ' (txp . 2)) ;
  458. txp = LIRE 'CSV' FIC2 'DEBU' 2 'SEPA' ',' ;
  459. evxp0 = evxp0 ET (EVOL 'ORAN' 'MANU' 'EPZZ' (txp . 1) 'SMZZ' (txp . 2)) ;
  460. txp = LIRE 'CSV' FIC3 'DEBU' 2 'SEPA' ',' ;
  461. evxp0 = evxp0 ET (EVOL 'VERT' 'MANU' 'EPZZ' (txp . 1) 'SMZZ' (txp . 2)) ;
  462. txp = LIRE 'CSV' FIC4 'DEBU' 2 'SEPA' ',' ;
  463. evxp0 = evxp0 ET (EVOL 'ROUG' 'MANU' 'EPZZ' (txp . 1) 'SMZZ' (txp . 2)) ;
  464. fins;
  465. ** Trace des courbes pour les differents niveaux de pression
  466. SI ITRAC1 ;
  467. DESS evtot0 'TITR' '[2D Axi.] Endommagement vs Temps' 'LEGE' tleg ;
  468. SI RESEXP ;
  469. DESS (evtot1 ET evxp0) 'TITR' '[2D Axi.] Contrainte vs Deformation' 'LEGE' tleg ;
  470. SINON ;
  471. DESS evtot1 'TITR' '[2D Axi.] Contrainte vs Deformation' 'LEGE' tleg ;
  472. FINSI ;
  473. DESS evtot2 'TITR' '[2D Axi.] Reaction vs Deplacement' 'LEGE' tleg ;
  474. FINSI ;
  475. *nh145313
  476. ** Comparaison Calcul / Reference sur l'aire sous la courbe Contrainte vs Deformation
  477. si (resexp);
  478. OPTI ECHO 0 ;
  479. SAUT 1 LIGN ;
  480. MESS ' **************** C A S #2 : 2 D A X I S Y M E T R I Q U E ****************';
  481. SAUT 1 LIGN ;
  482. tbid = TABL ;
  483. tbid . 'TITRE' = TABL ;
  484. tbid . 1 = 'MARQ PLUS' ;
  485. tbid . 'TITRE' . 1 = 'Cal.init.' ;
  486. tbid . 2 = 'MARQ ETOI' ;
  487. tbid . 'TITRE' . 2 = 'Ref.exp.' ;
  488. tbid . 3 = 'MARQ CROI' ;
  489. tbid . 'TITRE' . 3 = 'Cal.lim.' ;
  490. REPE b2 (DIME evxp0) ;
  491. evexp = EXTR evxp0 'COUR' &b2 ;
  492. xmexp = EXTR (EXTR evexp 'ABSC') (DIME (EXTR evexp 'ABSC')) ;
  493. evcal = EXTR evtot1 'COUR' &b2 ;
  494. ymcal = IPOL xmexp evcal ;
  495. xcal2 = PROG ;
  496. ycal2 = PROG ;
  497. REPE b3 (DIME (EXTR evcal 'ABSC')) ;
  498. xx = EXTR (EXTR evcal 'ABSC') &b3 ;
  499. yy = EXTR (EXTR evcal 'ORDO') &b3 ;
  500. SI (< xx xmexp) ;
  501. QUIT b3 ;
  502. FINSI ;
  503. xcal2 = xcal2 ET (PROG xx) ;
  504. ycal2 = ycal2 ET (PROG yy) ;
  505. FIN b3 ;
  506. xcal2 = xcal2 ET (PROG xmexp) ;
  507. ycal2 = ycal2 ET (PROG ymcal) ;
  508. evcal2 = EVOL MANU 'EPZZ' xcal2 'SMZZ' ycal2 ;
  509. ivexp = INTG evexp ;
  510. ivcal = INTG evcal2 ;
  511. ec1 = ivcal - ivexp ;
  512. er1 = ec1 / ivexp ;
  513. * tit0 = CHAI (tleg . 'TITRE' . &b2) ' Defo.max' xmexp ' -> Contr.cal' ymcal ;
  514. tit0 = CHAI (tleg . 'TITRE' . &b2) ' Aire courb.exp' ivexp ' Aire courb.cal' ivcal ' Ec.Rel.' er1;
  515. SI ITRAC1 ;
  516. DESS (evcal et evexp et evcal2) 'TITR' tit0 'LEGE' tbid ;
  517. FINSI ;
  518. MESS ' Pres.hydrostat :' (tleg . 'TITRE' . &b2) ', Ecart relatif entre Calcul et Reference :' er1 ;
  519. SAUT 1 LIGN ;
  520. FIN b2 ;
  521. OPTI ECHO 1 ;
  522. fins;
  523. FINSI ;
  524.  
  525.  
  526.  
  527.  
  528. FIN ;
  529.  
  530.  
  531.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales