Télécharger la plaquette Cast3M


fr en

Télécharger lire_med_02.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  lire_med_02.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. * Presentation : Ce cas-test permet de :
  6. *                SORTIR des MAILLAGES, CHPOINT, MCHAML et TABLE PASAPAS
  7. *                       au format MED
  8. *                LIRE   les fichiers MED generes
  9. *                VERIFIE et VALIDE les echanges au format MED
  10. *                  - Les valeurs lues sont identiques aux valeurs
  11. *                    attendues (Champs de coordonnees facile a comparer)
  12. *
  13. * Ameliorations a prevoir :
  14. *                - Sortir et lire les MCHAML en d'autres points supports
  15. *                - Sortir et lire les CONSTITUANTS dans les MCHAML
  16. *                - Sortir et lire les NATURES      dans les CHPOINT
  17. *
  18. * Creation : 17/02/2017
  19. * Createur : C. BERTHINIER
  20. *
  21. * Modifications :
  22. *  CB215821 01/02/2018 : Sortie, Relecture & Validation des MAILLAGES
  23. *                      : Sortie, Relecture & Validation des CHPOINTS
  24. *                      : Sortie, Relecture & Validation des MCHAML
  25. *                             - Aux GRAVITE
  26. *                             - Aux NOEUDS
  27. *  CB215821 13/03/2019 : Sortie, Relecture & Validation des TABLES PASAPAS
  28. ************************************************************************
  29.  
  30. * repertoire des fichiers "divers"
  31. DIVERS = VENV 'CASTEM_DIVERS';
  32. * Test si 64 bits. Sortie sinon
  33. 'SI' (2**31 < 0) ; 'MESS' 'MED 32 bits non disponible'; 'FIN'; 'FINSI';
  34. *
  35. 'OPTI' 'TRAC' 'PSC';
  36.  
  37. ************************************************************************
  38. * PROCEDURE POUR VERIFIER UN MAILLAGE
  39. ************************************************************************
  40. 'DEBP' VERMAI M_CAS*'MAILLAGE' M_MED*'MAILLAGE' NOM_MAI*'MOT';
  41. *  TRACE des MAILLAGES
  42.    CHAI1 ='CHAI' 'MAILLAGE' ' ' NOM_MAI ' ' 'CAST3M';
  43.    CHAI2 ='CHAI' 'MAILLAGE' ' ' NOM_MAI ' ' 'LU MED';
  44.   'TRAC' 'QUAL' M_CAS 'TITR' CHAI1;
  45.   'TRAC' 'QUAL' M_MED 'TITR' CHAI2;
  46.  
  47. *  Nombre d''elements
  48.    NE_CAS ='NBEL' M_CAS;
  49.    NE_MED ='NBEL' M_MED;
  50.   'ELIM' M_MED M_CAS 1.D-6;
  51.    NE_DIF ='NBEL' ('DIFF' M_CAS M_MED);
  52.  
  53. *  Nombre de noeuds
  54.    NN_CAS ='NBNO' M_CAS;
  55.    NN_MED ='NBNO' M_MED;
  56.  
  57. *  Verification Nombre d''elements
  58.   'SI' (NE_CAS 'NEG' NE_MED);
  59.     'OPTI' 'ECHO' 0;
  60.     'MESS' '############################################################';
  61.     'MESS' '#        LE MAILLAGES MED  RELUS N EST PAS CONFORME        #';
  62.     'MESS' '#                  ERREUR NOMBRE ELEMENTS                  #';
  63.     'MESS' '############################################################';
  64.     'OPTI' 'ECHO' 1;
  65.     'ERRE' 5;
  66.   'FINS';
  67. *  Verification Nombre de Noeuds
  68.   'SI' (NN_CAS 'NEG' NN_MED);
  69.     'OPTI' 'ECHO' 0;
  70.     'MESS' '############################################################';
  71.     'MESS' '#        LE MAILLAGES MED  RELUS N EST PAS CONFORME        #';
  72.     'MESS' '#                  ERREUR NOMBRE DE NOEUDS                 #';
  73.     'MESS' '############################################################';
  74.     'OPTI' 'ECHO' 1;
  75.     'ERRE' 5;
  76.   'FINS';
  77. *  Verification coordonnees identiques
  78.   'SI' (NE_DIF 'NEG' 0);
  79.     'OPTI' 'ECHO' 0;
  80.     'MESS'  CHAI2;
  81.     'MESS' '############################################################';
  82.     'MESS' '#        LE MAILLAGES MED  RELUS N EST PAS CONFORME        #';
  83.     'MESS' '#                   ERREUR CONNECTIVITE                    #';
  84.     'MESS' '############################################################';
  85.     'OPTI' 'ECHO' 1;
  86.     'ERRE' 5;
  87.   'FINS';
  88. 'FINP';
  89. ************************************************************************
  90. * PROCEDURE POUR VERIFIER UN CHPOINT
  91. ************************************************************************
  92. 'DEBP' VERCHP CHP_CAS*'CHPOINT' CHP_MED*'CHPOINT' NOM_CHP*'MOT';
  93. * A FAIRE !!!
  94. 'FINP';
  95. ************************************************************************
  96. * PROCEDURE POUR VERIFIER UN MCHAML
  97. ************************************************************************
  98. 'DEBP' VERCHM CHM_CAS*'MCHAML' CHM_MED*'MCHAML' LIEU*'MOT' NOM_CHM*'MOT' LENT1*'LISTENTI' LMOT1*'LISTMOTS' XTEMPS*'FLOTTANT';
  99.    MOD_CAS ='MODE' ('EXTR' CHM_CAS 'MAILLAGE') 'MECANIQUE' 'CONS' 'MED';
  100.    MOD_MED ='MODE' ('EXTR' CHM_MED 'MAILLAGE') 'MECANIQUE' 'CONS' 'MED';
  101.    CHM_CAS ='CHAN' 'CONS' CHM_CAS 'MED';
  102.  
  103.    CHAI1 ='CHAI' 'MCHAML' ' ' LIEU ' ' NOM_CHM ' ' 'CAST3M';
  104.    CHAI2 ='CHAI' 'MCHAML' ' ' LIEU ' ' NOM_CHM ' ' 'LU MED';
  105.   'TRAC' MOD_CAS CHM_CAS 'TITR' CHAI1;
  106.   'TRAC' MOD_MED CHM_MED 'TITR' CHAI2;
  107.  
  108. *  Verification : Le champ lu est un champ de coordonnees, on le recree
  109.    CHM_TMP='MANU' 'CHML' MOD_MED 'SCAL' 1.0 'TYPE' 'SCALAIRE' LIEU ;
  110.    CHM_VER='VIDE' 'MCHAML';
  111.   'REPE' SURI (DIME LMOT1);
  112.      ID  ='EXTR' LENT1 &SURI;
  113.      IMO ='EXTR' LMOT1 &SURI;
  114.      CHM_VER=('NOMC' (('COOR' ID CHM_TMP) * (1.D0 + XTEMPS)) IMO) 'ET' CHM_VER ;
  115.   'FIN' SURI;
  116.    XDIFF  ='MAXI' 'ABS' (CHM_MED - CHM_VER) ;
  117.  
  118.   'SI' (XDIFF 'NEG' 0.D0);
  119.     'OPTI' 'ECHO' 0;
  120.     'MESS'  CHAI2;
  121.     'MESS' '############################################################';
  122.     'MESS' '#          LE MCHAML MED RELUS N EST PAS CONFORME          #';
  123.     'MESS' '#                    ERREUR  DE VALEURS                    #';
  124.     'MESS' '############################################################';
  125.     'ERRE' 5;
  126.   'FINS';
  127. 'FINP';
  128.  
  129. ***********************************************************************
  130. * Lecture d'un MAILLAGE 'NASTRAN' avec plusieurs types d'elements
  131. ***********************************************************************
  132.  TAB2  ='LIRE' 'NAS' ('CHAINE' DIVERS '/nastran_long.nas') ;
  133.  TAB21 ='INDE' (TAB2.'MAILLAGES');
  134.  
  135. ***********************************************************************
  136. * Fabrication des MAILLAGES avant d'exporter au format MED            *
  137. ***********************************************************************
  138.  MAILTOT ='VIDE' 'MAILLAGE';
  139. 'REPE' SURI ('DIME' TAB21);
  140.    MAILTOT = MAILTOT 'ET' (TAB2.'MAILLAGES' . (TAB21 . &SURI));
  141. 'FIN' SURI;
  142.  
  143. * Le MAILLAGE MAILTOT contient 11 types d'elements :
  144. *  - 29  element(S) de type SEG2
  145. *  - 93  element(S) de type TRI3
  146. *  - 164 element(S) de type QUA4
  147. *  - 271 element(S) de type TET4
  148. *  - 36  element(S) de type PRI6
  149. *  - 84  element(S) de type CUB8
  150. *
  151. *  - 29  element(S) de type TRI6
  152. *  - 27  element(S) de type QUA8
  153. *  - 271 element(S) de type TE10
  154. *  - 24  element(S) de type PR15
  155. *  - 12  element(S) de type CU20
  156.  
  157.  P1     = 'NOEU' 1   ;
  158.  P2     = 'NOEU' 10  ;
  159.  P3     = 'NOEU' 100 ;
  160.  
  161.  MSEG2  ='ELEM' MAILTOT 'SEG2';
  162.  MTRI3  ='ELEM' MAILTOT 'TRI3';
  163.  MQUA4  ='ELEM' MAILTOT 'QUA4';
  164.  MTET4  ='ELEM' MAILTOT 'TET4';
  165.  MPRI6  ='ELEM' MAILTOT 'PRI6';
  166.  MCUB8  ='ELEM' MAILTOT 'CUB8';
  167.  MTRI6  ='ELEM' MAILTOT 'TRI6';
  168.  MQUA8  ='ELEM' MAILTOT 'QUA8';
  169.  MTE10  ='ELEM' MAILTOT 'TE10';
  170.  MPR15  ='ELEM' MAILTOT 'PR15';
  171.  MCU20  ='ELEM' MAILTOT 'CU20';
  172.  
  173. ***********************************************************************
  174. * Sortie MED des MAILLAGES (SIMPLES & COMPLEXES)
  175. ***********************************************************************
  176. 'OPTI' 'SORT' 'MED_MAILLAGE_simple.med';
  177. 'SORT' 'MED' MTRI3 ;
  178.  
  179. 'OPTI' 'SORT' 'MED_MAILLAGE_complexe.med';
  180. 'SORT' 'MED' MAILTOT ;
  181.  
  182. ***********************************************************************
  183. * Sortie MED des CHPOINTS
  184. ***********************************************************************
  185.  CHPX1 ='CHAN' 'COMP' ('COOR' 1 MTRI3  ) 'UX';
  186.  CHPY1 ='CHAN' 'COMP' ('COOR' 2 MAILTOT) 'UY';
  187.  
  188.  CHPTOT= CHPX1 'ET' CHPY1 ;
  189. 'OPTI' 'SORT' 'MED_CHPOIN_simple.med';
  190. 'SORT' 'MED' CHPX1;
  191.  
  192. 'OPTI' 'SORT' 'MED_CHPOIN_complexe.med';
  193. 'SORT' 'MED' CHPTOT;
  194.  
  195. 'OPTI' 'SORT' 'MED_CHPOIN_melange.med';
  196. 'SORT' 'MED' CHPX1 CHPY1 CHPTOT;
  197.  
  198. ***********************************************************************
  199. * Sortie MED des MCHAML
  200. ***********************************************************************
  201. * MCHAML au GRAVITE (1 SOUS-ZONE et 11 SOUS-ZONES)
  202.  MOD1a ='MODE' MTRI3   'MECANIQUE' ;
  203.  MOD1b ='MODE' MAILTOT 'MECANIQUE' ;
  204.  CHA1a ='MANU' 'CHML' MOD1a 'SCAL' 1.0 'GRAVITE';
  205.  CHA1b ='MANU' 'CHML' MOD1b 'SCAL' 1.0 'GRAVITE';
  206.  
  207.  CHAX1 ='NOMC' ('COOR' 1 CHA1a) 'UX';
  208.  CHAY1 ='NOMC' ('COOR' 2 CHA1b) 'UY';
  209.  
  210. 'OPTI' 'SORT' 'MED_MCHAML_GRAVITE_SZ1.med';
  211. 'SORT' 'MED' CHAX1 ;
  212.  
  213. 'OPTI' 'SORT' 'MED_MCHAML_GRAVITE_SZ11.med';
  214. 'SORT' 'MED' CHAY1 ;
  215.  
  216. * MCHAML au NOEUD (1 SOUS-ZONE et 11 SOUS-ZONES)
  217.  CHA2a ='MANU' 'CHML' MOD1a 'SCAL' 1.0 'NOEUD';
  218.  CHA2b ='MANU' 'CHML' MOD1b 'SCAL' 1.0 'NOEUD';
  219.  CHAZ1 ='NOMC' ('COOR' 3 CHA2a) 'UZ';
  220.  CHAZ2 ='NOMC' ('COOR' 3 CHA2b) 'UZ';
  221.  
  222. 'OPTI' 'SORT' 'MED_MCHAML_NOEUD_SZ1.med';
  223. 'SORT' 'MED' CHAZ1 ;
  224.  
  225. 'OPTI' 'SORT' 'MED_MCHAML_NOEUD_SZ11.med';
  226. 'SORT' 'MED' CHAZ2;
  227.  
  228. * MCHAML melange (NOEUD & GRAVITE, 1 SOUS-ZONE et 11 SOUS-ZONES)
  229. 'OPTI' 'SORT' 'MED_MCHAML_melange.med';
  230. 'SORT' 'MED' CHAX1 CHAY1 CHAZ1 CHAZ2;
  231.  
  232.  
  233.  
  234. ***********************************************************************
  235. * Sortie MED d'une TABLE de SOUS-TYPE PASAPAS
  236. ***********************************************************************
  237. COO1 COO2 COO3 ='COOR' MAILTOT;
  238. COO1           ='NOMC' COO1 'CX';
  239. COO2           ='NOMC' COO2 'CY';
  240. COO3           ='NOMC' COO3 'CZ';
  241. COOCHP         = COO1 'ET' COO2 'ET' COO3 ;
  242.  
  243. COO1 COO2 COO3 ='COOR' CHA1b ;
  244. COO1           ='NOMC' COO1 'MX';
  245. COO2           ='NOMC' COO2 'MY';
  246. COO3           ='NOMC' COO3 'MZ';
  247. COOCHMG        = COO1 'ET' COO2 'ET' COO3 ;
  248.  
  249. COO1 COO2 COO3 ='COOR' CHA2b ;
  250. COO1           ='NOMC' COO1 'NX';
  251. COO2           ='NOMC' COO2 'NY';
  252. COO3           ='NOMC' COO3 'NZ';
  253. COOCHMN        = COO1 'ET' COO2 'ET' COO3 ;
  254.  
  255. LTPS1 ='PROG' 0.D0 'PAS' 0.5D0 1.5D0 ;
  256. NBTPS ='DIME' LTPS1;
  257.  
  258. TPASAP ='TABL';
  259. TPASAP.'SOUSTYPE'='MOT' 'PASAPAS' ;
  260. TPASAP.'MODELE'  = MOD1b ;
  261.  
  262. TPASAP.'TEMPS'               ='TABL' ;
  263. TPASAP.'COORDONNEES_CHPOINT1'='TABL' ;'COMM' 'Un seul   MSOUPO    dans le CHPOINT';
  264. TPASAP.'MCHAML_GRAVI1'       ='TABL' ;'COMM' 'Un seul constituant dans le MCHAML aux GRAVITE';
  265. TPASAP.'MCHAML_NOEUD1'       ='TABL' ;'COMM' 'Un seul constituant dans le MCHAML aux NOEUDS' ;
  266. 'REPE' SURI NBTPS;
  267.    II     =&SURI;
  268.    Xtps   ='EXTR' LTPS1 II ;
  269.  
  270.    TPASAP.'TEMPS'               . (II - 1) = Xtps ;
  271.    TPASAP.'COORDONNEES_CHPOINT1'. (II - 1) =(COOCHP  + 1.D0) * ( 1.D0 + Xtps) ;
  272.    TPASAP.'MCHAML_GRAVI1'       . (II - 1) =(COOCHMG + 1.D0) * ( 1.D0 + Xtps) ;
  273.    TPASAP.'MCHAML_NOEUD1'       . (II - 1) =(COOCHMN + 1.D0) * ( 1.D0 + Xtps) ;
  274. 'FIN' SURI;
  275.  
  276. * TABLE de SOUSTYPE 'PASAPAS' avec CHPOINT, MCHAML (GRAVITE & NOEUDS)
  277. 'OPTI' 'SORT' 'MED_PASAPAS.med';
  278. 'SORT' 'MED' TPASAP ;
  279.  
  280.  
  281. *#####################################################################*
  282. * Verification relecture des MAILLAGES
  283. *#####################################################################*
  284.  TAB1 ='LIRE' 'MED' 'MED_MAILLAGE_simple.med'  ;
  285.  TAB2 ='LIRE' 'MED' 'MED_MAILLAGE_complexe.med';
  286.  
  287. *#####################################################################*
  288. * Validation relecture des MAILLAGES
  289. *#####################################################################*
  290. 'LIST' TAB1;
  291.  MTRI3a = TAB1.'MTRI3' ;
  292.  VERMAI MTRI3 MTRI3a 'MTRI3';
  293.  
  294. 'LIST' TAB2;
  295.  MAILTOTa= TAB2.'MAILTOT';
  296.  MSEG2a  = TAB2.'MSEG2'  ;
  297.  MCU20a  = TAB2.'MCU20'  ;
  298.  MPR15a  = TAB2.'MPR15'  ;
  299.  MTE10a  = TAB2.'MTE10'  ;
  300.  MQUA8a  = TAB2.'MQUA8'  ;
  301.  MTRI6a  = TAB2.'MTRI6'  ;
  302.  MCUB8a  = TAB2.'MCUB8'  ;
  303.  MPRI6a  = TAB2.'MPRI6'  ;
  304.  MTET4a  = TAB2.'MTET4'  ;
  305.  MQUA4a  = TAB2.'MQUA4'  ;
  306.  MTRI3a  = TAB2.'MTRI3'  ;
  307.  
  308.  VERMAI MAILTOT MAILTOTa 'MAILTOT';
  309.  VERMAI MSEG2   MSEG2a   'MSEG2'  ;
  310.  VERMAI MCU20   MCU20a   'MCU20'  ;
  311.  VERMAI MPR15   MPR15a   'MPR15'  ;
  312.  VERMAI MTE10   MTE10a   'MTE10'  ;
  313.  VERMAI MQUA8   MQUA8a   'MQUA8'  ;
  314.  VERMAI MTRI6   MTRI6a   'MTRI6'  ;
  315.  VERMAI MCUB8   MCUB8a   'MCUB8'  ;
  316.  VERMAI MPRI6   MPRI6a   'MPRI6'  ;
  317.  VERMAI MTET4   MTET4a   'MTET4'  ;
  318.  VERMAI MQUA4   MQUA4a   'MQUA4'  ;
  319.  VERMAI MTRI3   MTRI3a   'MTRI3'  ;
  320.  
  321. *#####################################################################*
  322. * Verification relecture des CHPOINT
  323. *#####################################################################*
  324.  TAB3 ='LIRE' 'MED' 'MED_CHPOIN_simple.med'  ;
  325.  TAB4 ='LIRE' 'MED' 'MED_CHPOIN_complexe.med';
  326.  TAB5 ='LIRE' 'MED' 'MED_CHPOIN_melange.med' ;
  327.  
  328. *#####################################################################*
  329. * Validation relecture des CHPOINT
  330. *#####################################################################*
  331. * CONTROLE VISUEL POUR LE MOMENT, COMPARER LES VALEURS !!! A FAIRE !!!
  332. 'LIST' TAB3;
  333.  CHPX2 = TAB3.'CHPX1';
  334. 'TRAC' CHPX1 MTRI3        'TITR' 'CHPOINT_SIMPLE CAST3M';
  335. 'TRAC' CHPX2 TAB3.'MTRI3' 'TITR' 'CHPOINT_SIMPLE LU MED';
  336.  
  337. *Verification : Le champ lu est un champ de coordonnees, on le recree
  338.  MMED  ='EXTR' CHPX2 'MAILLAGE' ;
  339.  MORI  ='EXTR' CHPX1 'MAILLAGE' ;
  340.  NBMED ='NBEL' MMED;
  341.  NBORI ='NBEL' MORI;
  342. 'SI' ('NEG' NBMED NBORI);
  343.   'OPTI' 'ECHO' 0;
  344.   'MESS' '############################################################';
  345.   'MESS' '#     LE CHPOINT MED CHPX1 RELUS EST NON CONFORMES AU      #';
  346.   'MESS' '#       CHPOINT EXPORTE : NOMBRE ELEMENTS INCORRECT        #';
  347.    CHA1 ='CHAI' '#      :' NBORI ':' NBMED ':';
  348.   'MESS' CHA1 ;
  349.   'MESS' '############################################################';
  350.   'OPTI' 'ECHO' 1;
  351.   'ERRE' 5;
  352. 'FINS';
  353.  
  354.  CHPX2v ='CHAN' 'COMP' ('COOR' 1 MMED  ) 'UX';
  355.  ValX2  ='MAXI' 'ABS' (CHPX2 - CHPX2v) ;
  356. 'SI' ('NEG' ValX2 0.D0);
  357.   'OPTI' 'ECHO' 0;
  358.   'MESS' '############################################################';
  359.   'MESS' '#     LE CHPOINT MED CHPX1 RELUS EST NON CONFORMES AU      #';
  360.   'MESS' '#       CHPOINT EXPORTE : VALEURS INCORRECTES              #';
  361.   'MESS' '############################################################';
  362.   'OPTI' 'ECHO' 1;
  363.   'ERRE' 5;
  364. 'FINS';
  365.  
  366. 'LIST' TAB4;
  367.  CHPTO2 = TAB4.'CHPTOT_1' 'ET' TAB4.'CHPTOT_2';
  368.  CHPX2  ='CHAN' 'COMP' ('COOR' 1 TAB4.'MTRI3'  ) 'UX';
  369.  CHPY2  ='CHAN' 'COMP' ('COOR' 2 TAB4.'MAILTOT') 'UY';
  370. 'TRAC' CHPX1 MTRI3          'TITR' 'CHPOINT_COMPLEXE CAST3M, UX';
  371. 'TRAC' CHPX2 TAB4.'MTRI3'   'TITR' 'CHPOINT_COMPLEXE LU MED, UX';
  372. 'TRAC' CHPY1 MAILTOT        'TITR' 'CHPOINT_COMPLEXE CAST3M, UY';
  373. 'TRAC' CHPY2 TAB4.'MAILTOT' 'TITR' 'CHPOINT_COMPLEXE LU MED, UY';
  374.  
  375. *Verification : Le champ lu est un champ de coordonnees, on le recree
  376.  CHPX2v ='CHAN' 'COMP' ('COOR' 1 ('EXTR' CHPX2 'MAILLAGE')) 'UX';
  377.  CHPY2v ='CHAN' 'COMP' ('COOR' 2 ('EXTR' CHPY2 'MAILLAGE')) 'UY';
  378.  ValX2  ='MAXI' 'ABS' (CHPX2 - CHPX2v);
  379.  ValY2  ='MAXI' 'ABS' (CHPY2 - CHPY2v);
  380.  
  381. 'SI' ('NEG' ValX2 0.D0);
  382.   'OPTI' 'ECHO' 0;
  383.   'MESS' '############################################################';
  384.   'MESS' '#     LE CHPOINT MED CHPX1 RELUS EST NON CONFORMES AU      #';
  385.   'MESS' '#       CHPOINT EXPORTE : VALEURS INCORRECTES              #';
  386.   'MESS' '############################################################';
  387.   'OPTI' 'ECHO' 1;
  388.   'ERRE' 5;
  389. 'FINS';
  390. 'SI' ('NEG' ValY2 0.D0);
  391.   'OPTI' 'ECHO' 0;
  392.   'MESS' '############################################################';
  393.   'MESS' '#     LE CHPOINT MED CHPY1 RELUS EST NON CONFORMES AU      #';
  394.   'MESS' '#       CHPOINT EXPORTE : VALEURS INCORRECTES              #';
  395.   'MESS' '############################################################';
  396.   'OPTI' 'ECHO' 1;
  397.   'ERRE' 5;
  398.  FINS ;
  399.  
  400. 'LIST' TAB5;
  401.  CHPX2  = TAB5.'CHPX1';
  402.  CHPY2  = TAB5.'CHPY1';
  403.  CHPTOX ='EXCO' (TAB5.'CHPTOT_1' 'ET' TAB5.'CHPTOT_2') 'UX' 'UX';
  404.  CHPTOY ='EXCO' (TAB5.'CHPTOT_1' 'ET' TAB5.'CHPTOT_2') 'UY' 'UY';
  405. 'TRAC' CHPX1  MTRI3          'TITR' 'MED CHPOIN MELANGE : CHPX1  CAST3M'    ;
  406. 'TRAC' CHPX2  TAB5.'MTRI3'   'TITR' 'MED CHPOIN MELANGE : CHPX1  LU MED'    ;
  407. 'TRAC' CHPY1  MAILTOT        'TITR' 'MED CHPOIN MELANGE : CHPY1  CAST3M'    ;
  408. 'TRAC' CHPY2  TAB5.'MAILTOT' 'TITR' 'MED CHPOIN MELANGE : CHPY1  LU MED'    ;
  409. 'TRAC' CHPX1  MTRI3          'TITR' 'MED CHPOIN MELANGE : CHPTOT CAST3M, UX';
  410. 'TRAC' CHPTOX TAB5.'MTRI3'   'TITR' 'MED CHPOIN MELANGE : CHPTOT LU MED, UX';
  411. 'TRAC' CHPY1  MAILTOT        'TITR' 'MED CHPOIN MELANGE : CHPTOT CAST3M, UY';
  412. 'TRAC' CHPTOY TAB5.'MAILTOT' 'TITR' 'MED CHPOIN MELANGE : CHPTOT LU MED, UY';
  413.  
  414. *#####################################################################*
  415. * Verification relecture des MCHAML
  416. *#####################################################################*
  417. TAB6 ='LIRE' 'MED' 'MED_MCHAML_GRAVITE_SZ1.med' ;
  418. TAB7 ='LIRE' 'MED' 'MED_MCHAML_GRAVITE_SZ11.med';
  419. TAB8 ='LIRE' 'MED' 'MED_MCHAML_NOEUD_SZ1.med'   ;
  420. TAB9 ='LIRE' 'MED' 'MED_MCHAML_NOEUD_SZ11.med'  ;
  421. TAB10='LIRE' 'MED' 'MED_MCHAML_melange.med'     ;
  422.  
  423. *#####################################################################*
  424. * Validation relecture des MCHAML
  425. *#####################################################################*
  426. 'LIST' TAB6;
  427.  CHAX1a = TAB6.'CHAX1';
  428.  VERCHM CHAX1 CHAX1a 'GRAVITE' 'CHAX1' (LECT 1) (MOTS 'UX') 0.D0;
  429.  
  430. 'LIST' TAB7;
  431.  CHAY1a = TAB7.'CHAY1';
  432.  VERCHM CHAY1 CHAY1a 'GRAVITE' 'CHAY1' (LECT 2) (MOTS 'UY') 0.D0;
  433.  
  434. 'LIST' TAB8;
  435.  CHAZ1a = TAB8.'CHAZ1';
  436.  VERCHM CHAZ1 CHAZ1a 'NOEUD'   'CHAZ1' (LECT 3) (MOTS 'UZ') 0.D0;
  437.  
  438. 'LIST' TAB9;
  439.  CHAZ2a = TAB9.'CHAZ2';
  440.  VERCHM CHAZ2 CHAZ2a 'NOEUD'   'CHAZ2' (LECT 3) (MOTS 'UZ') 0.D0;
  441.  
  442. 'LIST' TAB10;
  443.  CHAX1a = TAB10.'CHAX1';
  444.  CHAY1a = TAB10.'CHAY1';
  445.  CHAZ1a = TAB10.'CHAZ1';
  446.  CHAZ2a = TAB10.'CHAZ2';
  447.  
  448.  VERCHM CHAX1 CHAX1a 'GRAVITE' 'CHAX1' (LECT 1) (MOTS 'UX') 0.D0;
  449.  VERCHM CHAY1 CHAY1a 'GRAVITE' 'CHAY1' (LECT 2) (MOTS 'UY') 0.D0;
  450.  VERCHM CHAZ1 CHAZ1a 'NOEUD'   'CHAZ1' (LECT 3) (MOTS 'UZ') 0.D0;
  451.  VERCHM CHAZ2 CHAZ2a 'NOEUD'   'CHAZ2' (LECT 3) (MOTS 'UZ') 0.D0;
  452.  
  453. *#####################################################################*
  454. * Verification relecture des TABLES de SOUSTYPE 'PASAPAS'
  455. *#####################################################################*
  456.  TAB11='LIRE' 'MED' 'MED_PASAPAS.med';
  457. 'LIST' TAB11;
  458.  
  459. *#####################################################################*
  460. * Validation relecture des TABLES de SOUSTYPE 'PASAPAS'
  461. *#####################################################################*
  462.  
  463. FIN;
  464.  
  465.  
  466.  
  467.  
  468.  
  469.  
  470.  
  471.  
  472.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales