Télécharger la plaquette Cast3M


fr en

Télécharger lignecourant.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  lignecourant.dgibi
  2.  
  3. GRAPH = faux ;
  4.  
  5. ***********************************************************************
  6. * CALCUL DES LIGNES DE COURANT : ON TESTE LES OPERATEURS LAPN ET FIMP *
  7. * ON VERIFIE QUE L'ERREUR ENTRE PSI_NUM ET PSI_EXACT EVOLUE DE FACON  *
  8. * QUADRATIQUE                                                         *
  9. * H. PAILLERE/TTMF/JUILLET 1997                                       *
  10. * ON CONSIDERE LE DOMAINE [0,1]x[0,1] ET LA FONCTION DE COURANT       *
  11. * PSI_EXACT = x(x-1)y^2(y-1)                                          *
  12. * ASSOCIEE AU CHAMP DE VITESSE (u,v) DONNE PAR :                      *
  13. *   u_ex = dPSI/dy et v_ex = -dPSI/dx                                 *
  14. * ON RESOUD L'EQUATION DE POISSON :                                   *
  15. *              d2PSI/dx2 + d2PSI/dy2 = du_ex/dy - dv_ex/dx            *       
  16. * AVEC COMME C.L PSI=0 SUR LES BORDS DU DOMAINE                       *
  17. ***********************************************************************
  18.  
  20. OPTI ELEM QUA4 ;
  21. OPTI ISOV SULI ;
  22.  
  23. REPETER BLOC2 6 ;
  24.  
  25. n = (&BLOC2) ;
  26. NX = 5*n  ;
  27. NY = 5*n ;
  28.  
  29. A1 = 0.0 0.0 ;
  30. A2 = 1.0 0.0 ;
  31. A3 = 1.0 1.0 ;
  32. A4 = 0.0 1.0 ;
  33.  
  34. DOMTOT = 'DALLER' (A1 'DROI' NX A2) (A2 'DROI' NY A3)
  35.                   (A3 'DROI' NX A4) (A4 'DROI' NX A1) 'PLAN' ;
  36.  
  37. MDOMTOT = CHAN DOMTOT QUAF ;
  38. $DOMTOT = 'MODE' MDOMTOT 'NAVIER_STOKES' LINE;
  39. DOMA $DOMTOT 'IMPR' ;
  40. CNT = CONT DOMTOT ;
  41.  
  42. XX YY = 'COOR' DOMTOT ;
  43.  
  44. ******************************************************************
  45. * EVALUATION DE LA FONCTION DE COURANT EXACTE + CHAMP DE VITESSE *
  46. ******************************************************************
  47.  
  48. PSIEX = KOPS XX '*' ((XX-1.0)) ;
  49. PSIEX = KOPS PSIEX '*' (KOPS YY '*' YY) ;
  50. PSIEX = KOPS PSIEX '*' ((YY-1.0)) ;
  51. PSIEX = KCHT $DOMTOT SCAL SOMMET PSIEX ;
  52.  
  53. SI ( GRAPH ) ;
  54. TRACE PSIEX DOMTOT 14 'TITR'
  55.         'FONCTION DE COURANT EXACTE' ;
  56. FINSI ;
  57.  
  58. U = KOPS XX '*' ((XX-1.0)) ;
  59. U = KOPS U '*' YY ;
  60. G = KOPS (YY*3.0) '-' 2.0 ;
  61. U = KOPS U '*' G ;
  62. G = KOPS (XX*2.0) '-' 1.0 ;
  63. V = KOPS G '*' ((YY-1.0)) ;
  64. V = KOPS V '*' YY ;
  65. V = KOPS V '*' YY ;
  66. V = KOPS V '*' (-1.0) ;
  67.  
  68. U = NOMC 'UX' U 'NATU' 'DISCRET' ;
  69. V = NOMC 'UY' V 'NATU' 'DISCRET' ;
  70. UU = KCHT $DOMTOT VECT SOMMET (U ET V) ;
  71. UNCH = VECT UU 1.0 UX UY VERT ;
  72.  
  73. SI ( GRAPH ) ;
  74. TRACE UNCH DOMTOT 'TITR' 'CHAMP DE VITESSE' ;
  75. FINSI ;
  76.  
  77. ******************************************************************
  78. * ON CALCULE LA FONCTION DE COURANT NUMERIQUEMENT A PARTIR DE LA *
  79. * DONNEE DU CHAMP DE VITESSE                                     *
  80. ******************************************************************
  81.  
  82. SW = KOPS UU 'ROT' $DOMTOT ;
  83.  
  84. RK = EQEX $DOMTOT 'OPTI' 'EF' 'IMPL'
  85. ZONE $DOMTOT OPER LAPN 1.0   INCO 'PSI'
  86. ZONE $DOMTOT OPER FIMP sw   INCO 'PSI'
  87. 'CLIM' 'PSI' 'TIMP' CNT 0. ;
  88.  
  89. RK.'INCO' = TABLE INCO ;
  90. RK.'INCO'.'PSI' = KCHT $DOMTOT SCAL SOMMET 0. ;
  91. EXEC RK ;
  92.  
  93. PSI = RK.'INCO'.'PSI' ;
  94.  
  95. SI ( GRAPH ) ;
  96. TRACE PSI DOMTOT CNT 14 'TITR' 
  97.         'FONCTION DE COURANT CALCULEE' ;
  98. FINSI ;
  99.  
  100. ************************************************************
  101. * CALCUL DE L'ERREUR ENTRE FONCTION DE COURANT CALCULEE ET *
  102. * FONCTION DE COURANT ANALYTIQUE                           *
  103. ************************************************************
  104.  
  105. ER0 = KOPS PSI '-' PSIEX ;
  106. ER2 = KOPS ER0 '*' ER0 ;
  107. ERR = 0. ;
  108. NPTD=NBNO DOMTOT ;
  109. REPETER BLOC1 NPTD ;
  110. P1 = (DOMA $DOMTOT SOMMET) POIN &BLOC1 ;
  111. ERR = ERR + ('EXTR' ER2 'SCAL' P1) ;
  112. FIN BLOC1 ;
  113. ERR = ERR/NPTD ;
  114. ERR = ERR ** 0.5 ;
  115.  
  116. MESSAGE '======================================================' ;
  117. MESSAGE 'ERREUR EN NORME L2   = ' ERR ;
  118. MESSAGE '======================================================' ;
  119.  
  120. SI ( (n 'NEG' 1) ) ;
  121.         LISTE n ;
  122.         PERR = PROG (LOG ERR) ;
  123.         ERRPSI = ERRPSI ET PERR ;
  124.         PXXX = PROG (LOG (1./NX)) ;
  125.         ERRXXX = ERRXXX ET PXXX ;
  126. SINON ;
  127.         ERRPSI = PROG (LOG ERR) ;
  128.         ERRXXX = PROG (LOG (1./NX)) ;
  129. FINSI ;
  130.  
  131. FIN BLOC2 ;
  132.  
  133. SI ( GRAPH ) ;
  134. EVOL1 = EVOL 'MANU' 'LOG(DX)' ERRXXX 'LOG(ERR(PSI))' ERRPSI ;
  135. TAB1 = TABLE ;
  136. TAB1.1 = 'MARQ CROI ' ;
  137. TAB1.'TITRE' = TABLE ;
  138. TAB1.'TITRE'. 1 = MOT 'MAILLAGE QUA4' ;
  139. DESS EVOL1 LEGE TAB1 'XBOR' -4. 0. 'YBOR' -11.0 -7.0 'GRIL' ;
  140. FINSI ;
  141.  
  142. SI ( (MINI ERRPSI) > -10.9 ) ;
  143.         ERREUR 5 ;
  144. FINSI ;
  145.  
  146. FIN ;
  147.  
  148.  
  149.  
  150.  
  151.  
  152.  
  153.  
  154.  
  155.  
  156.  
  157.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales