Télécharger la plaquette Cast3M


fr en

Télécharger huit2cis.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : huit2cis.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. *         MODELE HYPERELASTIQUE 8 Chaines  INCOMPRESSIBLE              *
  6. *           EN GRANDES TRANSFORMATIONS - CONTRAINTES PLANES            *
  7. *                                                                      *
  8. *   TEST DE VALIDATION DU MODELE : CISAILLEMENT DANS LA DIRECTION X    *
  9. *   COMPARAISON AVEC LA SOLUTION ANALYTIQUE                            *
  10. *                                                                      *
  11. *   Contribution de Laurent Gornet - Ecole Centrale de Nantes (2010)   *
  12. *======================================================================*
  13. *  Pour plus d'informations, voir la presentation de L. Gornet lors    *
  14. *  du Club Cast3m 2009, disponible sur le site Web de Cast3m.          *
  15. *======================================================================*
  16. *  Exemple d'utilisation d'un modele UMAT en grandes transformations   *
  17. *                                                                      *
  18. *  Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. *         ne peut contenir que des modeles de type UMAT. On ne peut    *
  20. *         pas melanger les derivees objectives et les modeles de C3m.  *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ECHO' 0 ;
  24. *
  25. * Mettre VRAI si l'on souhaite divers traces.
  26. GRAPH = FAUX ;
  27. *GRAPH = VRAI ;
  28. title = 'CHAINE' '8 Chaines - ' 'CISAILLEMENT SIMPLE XY' ;
  29.  
  30. *======================================================================*
  31. *             Geometrie - Maillage                                     *
  32. *======================================================================*
  33. * Longueur (direction x) de la plaque/membrane :
  34. Lg_x = 1.8 ;
  35. * Largeur (direction y) de la plaque/membrane :
  36. Lg_y = 1. ;
  37. * Nombre d'elements selon les directions x et y :
  38. Nel_x = 5 ;
  39. Nel_y = 2 ;
  40. *
  41. 'OPTION' 'ELEM' 'QUA4' ;
  42. *
  43. P1 =  0.    0. ;
  44. P2 = Lg_x   0. ;
  45. P3 = Lg_x Lg_y ;
  46. P4 =  0.  Lg_y ;
  47. *
  48. L1 = 'DROITE' Nel_x P1 P2 ;
  49. L2 = 'DROITE' Nel_y P2 P3 ;
  50. L3 = 'DROITE' Nel_x P3 P4 ;
  51. L4 = 'DROITE' Nel_y P4 P1 ;
  52. *
  53. SU = 'DALLER' L1 L2 L3 L4 ;
  54. 'SI' GRAPH ;
  55.   'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  56. 'FINSI' ;
  57.  
  58. *======================================================================*
  59. *             Modele - Materiau - Caracteristiques (en Pa)             *
  60. *======================================================================*
  61. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'OU'
  62.       ('NEG' ('VALEUR' 'MODE') 'PLANCONT')) ;
  63.   'MESS' 'Ce modele ne fonctionne qu en 2D CONTRAINTES PLANES' ;
  64.   'ERREUR' 5 ;
  65. 'FINSI' ;
  66. * Calcul du Module d'Young
  67. * Ne pas oublier de definir les parametres lies a l'elasticite.
  68. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  69. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  70. *
  71. LCMAT = MOTS 'YOUN' 'NU  ' 'NKT'  'VN  '  ;
  72. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'  
  73.                     'NON_LINEAIRE' 'UTILISATEUR'
  74.                     'NUME_LOI' 36  'C_MATERIAU' LCMAT  ;
  75. *
  76. * Pour calculer le module d'Young, on utilise les
  77. * Coefficients du modele de Mooney-Rivlin (en  MPa) : Pourquoi Pas !
  78. * 
  79. C1 = 0.183  ;     C2 = 0.0034   ;
  80. * 
  81. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  82. * du fait de l'incompressibilite inherente au modele.
  83. * Le module de Young YOU est alors connu, car, pour ce modele, le
  84. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  85. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  86. * de la traction. En fonction du niveau de deformation atteinte en 
  87. * traction, il faut augmenter cette valeur afin de pouvoir faire 
  88. * converger les calculs (module tangent en fin de calculs).
  89. * Prendre des valeurs superieures n'entraine pas de modification des
  90. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  91. *
  92. XNU = 0.499 ;
  93. YOUini = 3.*(2.*(C1+C2)) ;   YOU = 1000. * YOUini ;
  94. *Parametres du modèle 8chaines : essais Treloar/Kawabata MPa
  95. xnkt = 0.28;
  96. xvn = 25.4;
  97. * 'DIM3' 1.
  98. MA = MATE MO 'YOUN' YOU 'NU  ' XNU 'NKT' xnkt 'VN' xvn ;
  99. *
  100. *
  101.  
  102. *======================================================================*
  103. *             Conditions aux limites - Traction suivant UY             *
  104. *======================================================================*
  105. CTOT = 'CONTOUR' SU ;
  106. BL1 = 'BLOQUER' 'UX  ' CTOT ;
  107. BL2 = 'BLOQUER' 'UY  ' CTOT ;
  108. BLTOT = BL1 'ET' BL2 ;
  109. *
  110. * Definition des instants du chargement :
  111. t_deb = 0. ;   t_fin = 10. ;
  112. L_tps = 'PROG' t_deb t_fin ;
  113. * Cisaillement suivant X :
  114. UX_deb = 0. ;  UX_fin = 7. * Lg_y ;
  115. L_UX = 'PROG' UX_deb UX_fin ;
  116. EV_xy = 'EVOL' 'MANU' 'TEMPS' L_tps  'LAMX' L_UX ;
  117. chp_y = 'NOMC' 'UX  ' ('COORD' 2 CTOT) ;
  118. FF_xy = 'DEPIMP' BL1 chp_y ;
  119. CHARTOT = 'CHARGEMENT' 'DIMP' FF_xy EV_xy ;
  120.  
  121. *======================================================================*
  122. *             Initialisation de la table pour appel a PASAPAS          *
  123. *======================================================================*
  124. TAB1 = 'TABLE' ;
  125. TAB1.'MODELE' = MO ;
  126. TAB1.'CARACTERISTIQUES' = MA ;
  127. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  128. TAB1.'CHARGEMENT' = CHARTOT ;
  129. *TAB1.'PRECISION' = 1.E-6 ;
  130. *TAB1.'FTOL' = 1.E-5 ;
  131. *TAB1.'MTOL' = 1.E-5 ;
  132. **TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  133. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  134. TAB1.'HYPOTHESE_DEFORMATIONS' = MOT 'UTILISATEUR' ;
  135. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  136. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  137. *
  138. L_abs = TAB1.'TEMPS_SAUVES' ;
  139. n_abs = 'DIMENSION' L_abs ;
  140. *
  141. PASAPAS TAB1 ;
  142. *
  143. * Quelques traces de controle apres calculs
  144. 'SI' GRAPH ;
  145.   Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  146.   Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  147.   'TRACER' (Defo_0 'ET' Defo_1)
  148.            'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  149.   'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  150.            'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  151. 'FINSI' ;
  152. *
  153. *======================================================================*
  154. *             Construction de la solution analytique                   *
  155. *======================================================================*
  156. * Definitions :
  157. * - Cisaillement selon xy : Cisx = UX/Lg_y
  158. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  159. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  160. * Dans le cas du modele de 8 Chaines :
  161. *   W =   , soit dW/dI1 =   et dW/dI2 =  0
  162. *
  163. * Les contraintes de Cauchy sont calculables analytiquement :
  164. * - SCxx =  2.(Cisx**2).dW/dI1
  165. * - SCyy = -2.(Cisx**2).dW/dI2
  166. * - SCxy =  2.Cisx.(dW/dI1 + dW/dI2)
  167. * - SCzz = 0  (hypothese des contraintes planes)
  168. *
  169. Cisx  = ('IPOL' L_abs L_tps L_UX) / Lg_y ;
  170. L_z1 = Cisx * Cisx ;
  171. *LG
  172. L_Un  = 'PROG' n_abs '*' 1. ;
  173. L_tr = L_Un * 3.;
  174. I1 =  L_z1 + L_tr ;
  175. I2 = I1;
  176. *
  177. ****************** modele 8 Chaines *************************************
  178.       ufj = L_Un*xnkt*0.5;
  179.       alp = xnkt*(0.1/xvn)*(L_Un * I1 );
  180.       xop = xnkt*((33./(1050.*(xvn**2)))*((L_Un * (I1 **2))));
  181.       lmp = xnkt*((19.*4./(7000.*(xvn**3)))*((L_Un * (I1 **3))));
  182.       mpo = xnkt*((519.*5./(673750.*(xvn**4)))*((L_Un * (I1 **4))));
  183. *
  184. dWI1= ufj+alp+xop+lmp+mpo;
  185. dWI2= L_Un*0.;
  186. ************************************************************************
  187. SCxx_th =  2.*dWI1*L_z1 ;
  188. SCyy_th = -2.*dWI2*L_z1 ;
  189. SCxy_th =  2.*(dWI1+dWI2)*Cisx ;
  190.  
  191. *======================================================================*
  192. *             Comparaison des resultats avec la solution analytique    *
  193. *======================================================================*
  194. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  195. * calculees et les solutions analytiques correspondantes.
  196. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  197. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  198. *
  199. TabD = TAB1.'DEPLACEMENTS' ;
  200. TabS = TAB1.'CONTRAINTES' ;
  201. Confini = 'FORM' ;
  202. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  203. *
  204. SCxx = 'PROG' 0. ;
  205. SCyy = 'PROG' 0. ;
  206. SCxy = 'PROG' 0. ;
  207. 'REPETER' Boucle (n_abs - 1) ;
  208.   'FORM' (TabD.&Boucle) ;
  209.   VolSU = 'INTG' MO ChmUn ;
  210.   SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  211.   SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  212.   SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  213.   'FORM' Confini ;
  214. 'FIN' Boucle ;
  215. *
  216. *  LG gam  Cisx
  217. L_abs = Cisx;
  218. *
  219. 'SI' GRAPH ;
  220.   tlege = 'TABLE' ;
  221.   tlege. 1 = 'MARQ CROI' ;
  222.   tlege.'TITRE' = 'TABLE' ;
  223.   tlege.'TITRE'. 1 = 'Numerique' ;
  224.   tlege.'TITRE'. 2 = 'Analytique' ;
  225.   Evxx    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  226.   Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  227.   'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  228.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (MPa)') ;
  229.   Evyy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  230.   Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  231.   'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  232.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (MPa)') ;
  233.   Evxy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  234.   Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  235.   'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  236.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (MPa)');
  237. 'FINSI' ;
  238. *
  239. * Tests de bon fonctionnement :
  240. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) ;
  241. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) ;
  242. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) ;
  243. *
  244. MESS ' RESULTATS : ' title ;
  245. MESS ' ------------------------------------------------- ';
  246. 'SAUTER' 1 'LIGNE' ;
  247. 'MESS' '  Tests de bon fonctionnement :' ;
  248. 'MESS' ' -------------------------------' ;
  249. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  250. 'MESS' ' Ecart maximal absolu entre la valeur moyenne calculee' ;
  251. 'MESS' '                         et la '
  252.        'solution analytique associee' ;
  253. 'MESS' ' Composante XX : ' r_xx ' MPa' ;
  254. 'MESS' ' Composante YY : ' r_yy ' MPa' ;
  255. 'MESS' ' Composante XY : ' r_xy ' MPa' ;
  256. 'SAUTER' 1 'LIGNE' ;
  257. * Ecart relatif maximal tolere
  258. Sigref = 1.E-3 ;
  259. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  260.   'MESS' ' ---------------------' ;
  261.   'MESS' '  ECHEC DU CAS-TEST !' ;
  262.   'MESS' ' ---------------------' ;
  263.   'ERREUR' 5 ;
  264. 'SINON' ;
  265.   'MESS' ' ----------------------' ;
  266.   'MESS' '  SUCCES DU CAS-TEST !' ;
  267.   'MESS' ' ----------------------' ;
  268. 'FINSI' ;
  269. 'SAUTER' 1 'LIGNE' ;
  270.  
  271. 'FIN' ;
  272.  
  273.  
  274.  
  275.  
  276.  
  277.  
  278.  
  279.  
  280.  
  281.  
  282.  
  283.  
  284.  
  285.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales