Télécharger la plaquette Cast3M


fr en

Télécharger hartcis.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : hartcis.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. *         MODELE HYPERELASTIQUE HART-SMITH INCOMPRESSIBLE              *
  6. *           EN GRANDES TRANSFORMATIONS - CONTRAINTES PLANES            *
  7. *                                                                      *
  8. *   TEST DE VALIDATION DU MODELE : CISAILLEMENT DANS LA DIRECTION X    *
  9. *   COMPARAISON AVEC LA SOLUTION ANALYTIQUE                            *
  10. *                                                                      *
  11. *   Contribution de Laurent Gornet - Ecole Centrale de Nantes (2010)   *
  12. *======================================================================*
  13. *  Pour plus d'informations, voir la presentation de L. Gornet lors    *
  14. *  du Club Cast3m 2009, disponible sur le site Web de Cast3m.          *
  15. *======================================================================*
  16. *  Exemple d'utilisation d'un modele UMAT en grandes transformations   *
  17. *                                                                      *
  18. *  Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. *         ne peut contenir que des modeles de type UMAT. On ne peut    *
  20. *         pas melanger les derivees objectives et les modeles de C3m.  *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ECHO' 0 ;
  24. *
  25. * Mettre VRAI si l'on souhaite divers traces.
  26. GRAPH = FAUX ;
  27. *GRAPH = VRAI ;
  28. title = 'CHAINE' 'HART-SMITH - ' 'CISAILLEMENT SIMPLE XY' ;
  29.  
  30. *======================================================================*
  31. *             Geometrie - Maillage                                     *
  32. *======================================================================*
  33. * Longueur (direction x) de la plaque/membrane :
  34. Lg_x = 1.8 ;
  35. * Largeur (direction y) de la plaque/membrane :
  36. Lg_y = 1. ;
  37. * Nombre d'elements selon les directions x et y :
  38. Nel_x = 5 ;
  39. Nel_y = 2 ;
  40. *
  41. 'OPTION' 'ELEM' 'QUA4' ;
  42. *
  43. P1 =  0.    0. ;
  44. P2 = Lg_x   0. ;
  45. P3 = Lg_x Lg_y ;
  46. P4 =  0.  Lg_y ;
  47. *
  48. L1 = 'DROITE' Nel_x P1 P2 ;
  49. L2 = 'DROITE' Nel_y P2 P3 ;
  50. L3 = 'DROITE' Nel_x P3 P4 ;
  51. L4 = 'DROITE' Nel_y P4 P1 ;
  52. *
  53. SU = 'DALLER' L1 L2 L3 L4 ;
  54. 'SI' GRAPH ;
  55.   'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  56. 'FINSI' ;
  57.  
  58. *======================================================================*
  59. *             Modele - Materiau - Caracteristiques (en Pa)             *
  60. *======================================================================*
  61. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'OU'
  62.       ('NEG' ('VALEUR' 'MODE') 'PLANCONT')) ;
  63.   'MESS' 'Ce modele ne fonctionne qu en 2D CONTRAINTES PLANES' ;
  64.   'ERREUR' 5 ;
  65. 'FINSI' ;
  66. *
  67. * Ne pas oublier de definir les parametres lies a l'elasticite.
  68. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  69. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  70. *
  71. LCMAT = MOTS 'YOUN' 'NU  ' 'G'  'K1'  'K2'  ;
  72. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'  
  73.                     'NON_LINEAIRE' 'UTILISATEUR'
  74.                     'NUME_LOI' 34  'C_MATERIAU' LCMAT ;
  75. * Calcul du Module d'Young
  76. * Coefficients du modele de Mooney-Rivlin (en MPa) :
  77. C1 = 0.183  ;     C2 = 0.0034   ;
  78. *
  79. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  80. * du fait de l'incompressibilite inherente au modele.
  81. * Le module de Young YOU est alors connu, car, pour ce modele, le
  82. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  83. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  84. * de la traction. En fonction du niveau de deformation atteinte en 
  85. * traction, il faut augmenter cette valeur afin de pouvoir faire 
  86. * converger les calculs (module tangent en fin de calculs).
  87. * Prendre des valeurs superieures n'entraine pas de modification des
  88. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  89. *
  90. XNU = 0.499 ;
  91. YOUini = 3.*(2.*(C1+C2)) ;   YOU = 1000. * YOUini ;
  92. *
  93. *Parametres du modèle HS : essais Treloar/Kawabata MPa
  94. G = 0.175  ;
  95. K1 = 2.86E-4   ;
  96. K2 = 0.311   ;
  97. * 
  98. MA = MATE MO 'YOUN' YOU 'NU  ' XNU 'G' G 'K1' K1 'K2' K2 ;
  99.  
  100. *======================================================================*
  101. *             Conditions aux limites - Traction suivant UY             *
  102. *======================================================================*
  103. CTOT = 'CONTOUR' SU ;
  104. BL1 = 'BLOQUER' 'UX  ' CTOT ;
  105. BL2 = 'BLOQUER' 'UY  ' CTOT ;
  106. BLTOT = BL1 'ET' BL2 ;
  107. *
  108. * Definition des instants du chargement :
  109. t_deb = 0. ;   t_fin = 10. ;
  110. L_tps = 'PROG' t_deb t_fin ;
  111. * Cisaillement suivant X :
  112. UX_deb = 0. ;  UX_fin = 7. * Lg_y ;
  113. L_UX = 'PROG' UX_deb UX_fin ;
  114. EV_xy = 'EVOL' 'MANU' 'TEMPS' L_tps  'LAMX' L_UX ;
  115. chp_y = 'NOMC' 'UX  ' ('COORD' 2 CTOT) ;
  116. FF_xy = 'DEPIMP' BL1 chp_y ;
  117. CHARTOT = 'CHARGEMENT' 'DIMP' FF_xy EV_xy ;
  118.  
  119. *======================================================================*
  120. *             Initialisation de la table pour appel a PASAPAS          *
  121. *======================================================================*
  122. TAB1 = 'TABLE' ;
  123. TAB1.'MODELE' = MO ;
  124. TAB1.'CARACTERISTIQUES' = MA ;
  125. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  126. TAB1.'CHARGEMENT' = CHARTOT ;
  127. *TAB1.'PRECISION' = 1.E-6 ;
  128. *TAB1.'FTOL' = 1.E-5 ;
  129. *TAB1.'MTOL' = 1.E-5 ;
  130. *TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  131. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  132. TAB1.'HYPOTHESE_DEFORMATIONS' = MOT 'UTILISATEUR' ;
  133. TAB1.'MAXDEFOR' = 1E2;
  134. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  135. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  136. *
  137. L_abs = TAB1.'TEMPS_SAUVES' ;
  138. n_abs = 'DIMENSION' L_abs ;
  139. *
  140. PASAPAS TAB1 ;
  141. *
  142. * Quelques traces de controle apres calculs
  143. 'SI' GRAPH ;
  144.   Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  145.   Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  146.   'TRACER' (Defo_0 'ET' Defo_1)
  147.            'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  148.   'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  149.            'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  150. 'FINSI' ;
  151. *
  152. *======================================================================*
  153. *             Construction de la solution analytique                   *
  154. *======================================================================*
  155. * Definitions :
  156. * - Cisaillement selon xy : Cisx = UX/Lg_y
  157. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  158. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  159. * Dans le cas du modele de HART-SMITH :
  160. * dW/dI1 = G * exp (k1 * (I1 - 3)**2) et dW/dI2 = G * k2 * 1 / I2 
  161. *
  162. * Les contraintes de Cauchy sont calculables analytiquement :
  163. * - SCxx =  2.(Cisx**2).dW/dI1
  164. * - SCyy = -2.(Cisx**2).dW/dI2
  165. * - SCxy =  2.Cisx.(dW/dI1 + dW/dI2)
  166. * - SCzz = 0  (hypothese des contraintes planes)
  167. *
  168. Cisx  = ('IPOL' L_abs L_tps L_UX) / Lg_y ;
  169. L_z1 = Cisx * Cisx ;
  170. *LG
  171. L_Un  = 'PROG' n_abs '*' 1. ;
  172. L_tr = L_Un * 3.;
  173. I1 =  L_z1 + L_tr ;
  174. I2 = I1;
  175. **********************************************************************
  176. dWI1= G * (exp (k1 *((I1 - L_tr)**2)));
  177. dWI2= G * k2 * L_Un / I2;
  178. **********************************************************************
  179. SCxx_th =  2.*dWI1*L_z1 ;
  180. SCyy_th = -2.*dWI2*L_z1 ;
  181. SCxy_th =  2.*(dWI1+dWI2)*Cisx ;
  182. *======================================================================*
  183. *             Comparaison des resultats avec la solution analytique    *
  184. *======================================================================*
  185. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  186. * calculees et les solutions analytiques correspondantes.
  187. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  188. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  189. *
  190. TabD = TAB1.'DEPLACEMENTS' ;
  191. TabS = TAB1.'CONTRAINTES' ;
  192. Confini = 'FORM' ;
  193. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  194. *
  195. SCxx = 'PROG' 0. ;
  196. SCyy = 'PROG' 0. ;
  197. SCxy = 'PROG' 0. ;
  198. 'REPETER' Boucle (n_abs - 1) ;
  199.   'FORM' (TabD.&Boucle) ;
  200.   VolSU = 'INTG' MO ChmUn ;
  201.   SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  202.   SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  203.   SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  204.   'FORM' Confini ;
  205. 'FIN' Boucle ;
  206. *
  207. *  LG gam  Cisx
  208. L_abs = Cisx;
  209. *
  210. 'SI' GRAPH ;
  211.   tlege = 'TABLE' ;
  212.   tlege. 1 = 'MARQ CROI' ;
  213.   tlege.'TITRE' = 'TABLE' ;
  214.   tlege.'TITRE'. 1 = 'Numerique' ;
  215.   tlege.'TITRE'. 2 = 'Analytique' ;
  216.   Evxx    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  217.   Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  218.   'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  219.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (MPa)') ;
  220.   Evyy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  221.   Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  222.   'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  223.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (MPa)') ;
  224.   Evxy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  225.   Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  226.   'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  227.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (MPa)');
  228.  
  229.  
  230. 'FINSI' ;
  231. *
  232. * Tests de bon fonctionnement :
  233. *
  234. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th))  ;
  235. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) ;
  236. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) ;
  237. *
  238. MESS ' RESULTATS : ' title ;
  239. MESS ' ------------------------------------------------- ';
  240. 'SAUTER' 1 'LIGNE' ;
  241. 'MESS' '  Tests de bon fonctionnement :' ;
  242. 'MESS' ' -------------------------------' ;
  243. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  244. 'MESS' ' Ecart maximal absolu entre la valeur moyenne calculee' ;
  245. 'MESS' '                         et la '
  246.        'solution analytique associee' ;
  247. 'MESS' ' Composante XX : ' r_xx   ' MPa' ;
  248. 'MESS' ' Composante YY : ' r_yy   ' MPa' ;
  249. 'MESS' ' Composante XY : ' r_xy   ' MPa' ;
  250. 'SAUTER' 1 'LIGNE' ;
  251. * Ecart relatif maximal tolere
  252. Sigref = 1.E-3 ;
  253. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  254.   'MESS' ' ---------------------' ;
  255.   'MESS' '  ECHEC DU CAS-TEST !' ;
  256.   'MESS' ' ---------------------' ;
  257.   'ERREUR' 5 ;
  258. 'SINON' ;
  259.   'MESS' ' ----------------------' ;
  260.   'MESS' '  SUCCES DU CAS-TEST !' ;
  261.   'MESS' ' ----------------------' ;
  262. 'FINSI' ;
  263. 'SAUTER' 1 'LIGNE' ;
  264.  
  265. 'FIN' ;
  266.  
  267.  
  268.  
  269.  
  270.  
  271.  
  272.  
  273.  
  274.  
  275.  
  276.  
  277.  
  278.  
  279.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales