Télécharger la plaquette Cast3M


fr en

Télécharger gridturb_expl.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  gridturb_expl.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. **********************************************************
  5. * GRID TURBULENCE : convection of homogeneous turbulence *
  6. * Analysis of the K-Epsilon TURBULENCE MODEL             *
  7. * Mohammadi/Pironneau p. 74     (Wiley)                  *
  8. * H. PAILLERE/TTMF/AVRIL 1997                            *
  9. **********************************************************
  10.  
  11. COMPLET = FAUX ;
  12. GRAPH = FAUX ;
  13.  
  14. SI ( COMPLET ) ;
  15.         D = 4 ;
  16.         NITER = 1000 ;
  17. SINON ;
  18.         D = 1 ;
  19.         NITER = 150 ;
  20. FINSI ;
  21.  
  22. NX = D*10 ;
  23. NY = D ;
  24.  
  26. opti elem qua8 ;
  27. opti isov suli ;
  28.  
  29. ******************************************************************
  30. * PROCEDURE POUR ESTIMER LA CONVERGENCE VERS L'ETAT STATIONNAIRE *
  31. ******************************************************************
  32.  
  33. DEBPROC CALCUL ;
  34. ARGU RVX*'TABLE' ;
  35.  
  36. RV = RVX.'EQEX' ;
  37.  
  38. DD = RV.PASDETPS.'NUPASDT' ;
  39. NN = DD/10 ;
  40. LO = (DD-(10*NN)) EGA 0 ;
  41. SI ( LO ) ;
  42.  
  43. EN   = RV.INCO.'EN' ;
  44. ENM1 = RV.INCO.'ENM1' ;
  45. KN   = RV.INCO.'KN' ;
  46. KNM1 = RV.INCO.'KNM1' ;
  47.  
  48. ERRE = KOPS EN '-' ENM1 ;
  49. ELIE = MAXI ERRE 'ABS' ;
  50. ELIE = (LOG (ELIE + 1.0E-20))/(LOG 20.) ;
  51. ERRK = KOPS KN '-' KNM1 ;
  52. ELIK = MAXI ERRK 'ABS' ;
  53. ELIK = (LOG (ELIK + 1.0E-20))/(LOG 20.) ;
  54. MESSAGE 'ITER ' RV.PASDETPS.'NUPASDT' '   ERREUR LINF ' ELIK ELIE ;
  55. RV.INCO.'ENM1' = KCHT $DOMTOT 'SCAL' 'SOMMET' (RV.INCO.'EN') ;
  56. RV.INCO.'KNM1' = KCHT $DOMTOT 'SCAL' 'SOMMET' (RV.INCO.'KN') ;
  57. IT = PROG RV.PASDETPS.'NUPASDT' ;
  58. ERK = PROG ELIK ;
  59. ERE = PROG ELIE ;
  60. RV.INCO.'IT' = (RV.INCO.'IT') ET IT ;
  61. RV.INCO.'ERK' = (RV.INCO.'ERK') ET ERK ;
  62. RV.INCO.'ERE' = (RV.INCO.'ERE') ET ERE ;
  63. FINSI ;
  64.  as2 ama1  = 'KOPS' 'MATRIK' ;
  65.  FINPROC as2 ama1 ;
  66.  
  67. ***********************
  68. * GEOMETRY OF PROBLEM *
  69. ***********************
  70.  
  71. A1 = 0.0 0.0 ;
  72. A2 = 1.0 0.0 ;
  73. A3 = 1.0 0.1 ;
  74. A4 = 0.0 0.1 ;
  75.  
  76. A1A2 = A1 'DROI' NX A2 ;
  77. A2A3 = A2 'DROI' NY A3 ;
  78. A3A4 = A3 'DROI' NX A4 ;
  79. A4A1 = A4 'DROI' NY A1 ;
  80.  
  81. DOMTOT = 'DALLER' A1A2 A2A3 A3A4 A4A1 'PLAN' ;
  82. DOMTOT = CHAN DOMTOT QUAF ;
  83. A4A1   = CHAN A4A1   QUAF ;
  84. A2A3   = CHAN A2A3   QUAF ;
  85. ELIM (DOMTOT et A4A1 et A2A3) 1.E-3 ;
  86.  
  87. $DOMTOT = 'MODE' DOMTOT 'NAVIER_STOKES' 'MACRO' ;
  88. DOMA $DOMTOT IMPR ;
  89. $INLET  = 'MODE' A4A1 'NAVIER_STOKES' 'MACRO' ;
  90.  INLET  = 'DOMA' $INLET 'MAILLAGE' ;
  91. $OUTLET = 'MODE' A2A3 'NAVIER_STOKES' 'MACRO' ;
  92.  
  93. DOMTOT = DOMA $DOMTOT MAILLAGE ;
  94. CNT = CONT DOMTOT ;
  95.  
  96. *****************
  97. * PHYSICAL DATA *
  98. *****************
  99.  
  100. Uinlet = 1.0 ;
  101. Kinlet = 0.01 ;
  102. Einlet = 0.01 ;
  103.  
  104. Nu = 1.E-10 ;
  105. tos = 0. 0. ;
  106.  
  107. *****************************************
  108. * ANALYTICAL SOLUTION FOR K(x) AND E(x) *
  109. *****************************************
  110.  
  111. C2 = 1.92 ;
  112. X1 = COOR 1 (DOMA $DOMTOT SOMMET) ;
  113. ZZZ = KOPS X1 '*' (EINLET/KINLET*(C2-1.0)) ;
  114. ZZZ = KOPS ZZZ '+' 1.0 ;
  115. KAN = KOPS ZZZ '**' (1./(1.-C2)) ;
  116. KAN = KOPS KAN '*' KINLET ;
  117.  
  118. EAN = KOPS ZZZ '**' (C2/(1.-C2)) ;
  119. EAN = KOPS EAN '*' EINLET ;
  120.  
  121. ********************
  122. * SET OF EQUATIONS *
  123. ********************
  124.  
  125. RV = EQEX $DOMTOT 'ITMA' NITER 'ALFA' 0.8
  126.         'ZONE' $DOMTOT 'OPER' CALCUL
  127.         'OPTI' 'SUPGDC'
  128.         'ZONE' $DOMTOT 'OPER' 'NSKE' NU 'NUT' 'INCO' 'UN' 'KN' 'EN' 
  129.         'OPTI' 'CENTREE'
  130.         'ZONE' $OUTLET 'OPER' 'TOIM' tos 'INCO' 'UN'
  131.         'ZONE' $DOMTOT 'OPER' 'DFDT' 1. 'UN' 'DELTAT' 'INCO' 'UN'
  132.         'ZONE' $DOMTOT 'OPER' 'DFDT' 1. 'KN' 'DELTAT' 'INCO' 'KN'
  133.         'ZONE' $DOMTOT 'OPER' 'DFDT' 1. 'EN' 'DELTAT' 'INCO' 'EN';
  134.  
  135. RV = EQEX RV
  136.         'CLIM' 'UN' 'UIMP' INLET Uinlet
  137.                'UN' 'VIMP' INLET 0.
  138.                'KN' 'TIMP' INLET Kinlet
  139.                'EN' 'TIMP' INLET Einlet ;
  140.  
  141. RVP = EQPR $DOMTOT KTYPI 1
  142.         ZONE $DOMTOT 'OPER' 'PRESSION' 0. ;
  143.  
  144. RV.INCO = TABLE INCO ;
  145. RV.INCO.'UN' = KCHT $DOMTOT VECT SOMMET (1. 0.) ;
  146. RV.INCO.'KN' = KCHT $DOMTOT SCAL SOMMET Kinlet ;
  147. RV.INCO.'EN' = KCHT $DOMTOT SCAL SOMMET Einlet ;
  148. RV.INCO.'ENM1' = KCHT $DOMTOT SCAL SOMMET Einlet ;
  149. RV.INCO.'KNM1' = KCHT $DOMTOT SCAL SOMMET Kinlet ;
  150. RV.INCO.'NUT' = KCHT $DOMTOT SCAL CENTRE 1.E-10 ;
  151. RV.INCO.'IT' = PROG 1 ;
  152. RV.INCO.'ERK' = PROG 0.;
  153. RV.INCO.'ERE' = PROG 0.;
  154. RV.PRESSION = RVP ;
  155.  
  156. EXEC RV ;
  157.  
  158. SI ( GRAPH ) ;
  159. TRACE DOMTOT ;
  160. EVOLK = EVOL 'MANU' 'ITERATIONS' (RV.INCO.'IT') 'LOG|E|inf'
  161.            (RV.INCO.'ERK') ;
  162. EVOLE = EVOL 'MANU' 'ITERATIONS' (RV.INCO.'IT') 'LOG|E|inf'
  163.            (RV.INCO.'ERE') ;
  164. TAB1 = TABLE ;
  165. TAB1.1 = 'MARQ CROI ' ;
  166. TAB1.2 = 'MARQ TRIA ' ;
  167. TAB1.'TITRE' = TABLE ;
  168. TAB1.'TITRE'. 1 = MOT 'CONVERGENCE_K' ;
  169. TAB1.'TITRE'. 2 = MOT 'CONVERGENCE_E' ;
  170. DESS (EVOLK ET EVOLE) 'XBOR' 0. (2.*NITER) 'YBOR' -15.0 0.0 
  171.                 LEGE TAB1 ;
  172.  
  173. TRACE RV.INCO.'KN' DOMTOT CNT 'TITR' 'KN' 20 ;
  174. TRACE RV.INCO.'EN' DOMTOT CNT 'TITR' 'EN' 20 ;
  175.  
  176. EVOLKN = EVOL (ROUG) 'CHPO' RV.INCO.'KN' 'SCAL' A1A2 ;
  177. EVOLKA = EVOL (BLEU) 'CHPO' KAN 'SCAL' A1A2 ;
  178. EVOLEN = EVOL (ROUG) 'CHPO' RV.INCO.'EN' 'SCAL' A1A2 ;
  179. EVOLEA = EVOL (BLEU) 'CHPO' EAN 'SCAL' A1A2 ;
  180.  
  181. TAB1 = TABLE ;
  182. TAB1.1 = 'MARQ CROI ' ;
  183. TAB1.2 = ' ' ;
  184. TAB1.'TITRE' = TABLE ;
  185. TAB1.'TITRE'. 1 = MOT 'NUMERIQUE' ;
  186. TAB1.'TITRE'. 2 = 'MOT' 'ANALYTIQUE' ;
  187.  
  188. DESS (EVOLKN ET EVOLKA) LEGE TAB1 'TITR' 'Grid Turbulence K' ;
  189. DESS (EVOLEN ET EVOLEA) LEGE TAB1 'TITR' 'Grid Turbulence E' ;
  190. FINSI ;
  191.  
  192. ERRK = KOPS RV.INCO.'KN' '-' KAN ;
  193. ERRK = KOPS ERRK '*' ERRK ;
  194. ERR2 = 0. ;
  195. REPETER BLOC1 (NBNO (DOMA $DOMTOT MAILLAGE)) ;
  196. P1 = (doma $DOMTOT SOMMET) POIN &BLOC1 ;
  197. ERR1 = 'EXTR' ERRK 'SCAL' P1 ;
  198. ERR2 = ERR2 + ERR1 ;
  199. FIN BLOC1 ;
  200. ERR2 = ERR2/(nbno (doma $DOMTOT MAILLAGE)) ;
  201. ERR2 = ERR2 ** 0.5 ;
  202. ERR2K = ERR2/Kinlet ;
  203. MESSAGE 'ERREUR SUR K EN NORME L2 = ' ERR2K ;
  204.  
  205. ERRE = KOPS RV.INCO.'EN' '-' EAN ;
  206. ERRE = KOPS ERRE '*' ERRE ;
  207. ERR2 = 0. ;
  208. REPETER BLOC1 (NBNO (DOMA $DOMTOT MAILLAGE))  ;
  209. P1 = (DOMA $DOMTOT SOMMET) POIN &BLOC1 ;
  210. ERR1 = 'EXTR' ERRE 'SCAL' P1 ;
  211. ERR2 = ERR2 + ERR1 ;
  212. FIN BLOC1 ;
  213. ERR2 = ERR2/(NBNO (DOMA $DOMTOT MAILLAGE)) ;
  214. ERR2 = ERR2 ** 0.5 ;
  215. ERR2E = ERR2/Einlet ;
  216. MESSAGE 'ERREUR SUR E EN NORME L2 = ' ERR2E ;
  217.  
  218. * TESTS D'ERREUR *
  219.  
  220. SI ( (MINI RV.INCO.'ERE') > -5.0 ) ;
  221.         ERREUR 5 ;
  222. FINSI ;
  223. SI ( (MINI RV.INCO.'ERK') > -5.0 ) ;
  224.         ERREUR 5 ;
  225. FINSI ;
  226.  
  227. SI ( ERR2K > 1.5D-2 ) ;
  228.         ERREUR 5 ;
  229. FINSI ;
  230.  
  231. SI ( ERR2E > 3.0D-2 ) ;
  232.         ERREUR 5 ;
  233. FINSI ;
  234.  
  235. FIN ;
  236.  
  237.  
  238.  
  239.  
  240.  
  241.  
  242.  
  243.  
  244.  
  245.  
  246.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales