Télécharger la plaquette Cast3M


fr en

Télécharger gdtract.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : gdtract.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. *         MODELE HYPERELASTIQUE GORNET-DESMORAT INCOMPRESSIBLE         *
  6. *           EN GRANDES TRANSFORMATIONS - CONTRAINTES PLANES            *
  7. *                                                                      *
  8. *   TEST DE VALIDATION DU MODELE : TRACTION SELON LA DIRECTION Y       *
  9. *   COMPARAISON AVEC LA SOLUTION ANALYTIQUE                            *
  10. *                                                                      *
  11. *   Contribution de Laurent Gornet - Ecole Centrale de Nantes (2010)   *
  12. *======================================================================*
  13. *  Pour plus d'informations, voir la presentation de L. Gornet lors    *
  14. *  du Club Cast3m 2009, disponible sur le site Web de Cast3m.          *
  15. *======================================================================*
  16. *  Exemple d'utilisation d'un modele UMAT en grandes transformations   *
  17. *                                                                      *
  18. *  Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. *         ne peut contenir que des modeles de type UMAT. On ne peut    *
  20. *         pas melanger les derivees objectives et les modeles de C3m.  *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ECHO' 0 ;
  24.  
  25.  
  26. * Mettre VRAI si l'on souhaite divers traces.
  27. GRAPH = VRAI ;
  28. GRAPH = FAUX ;
  29. title = 'CHAINE' 'GORNET - DESMORAT - ' 'TRACTION UNIAXIALE Y' ;
  30.  
  31. *======================================================================*
  32. *             Geometrie - Maillage                                     *
  33. *======================================================================*
  34. * Longueur (direction x) de la plaque/membrane :
  35. Lg_x = 1. ;
  36. * Largeur (direction y) de la plaque/membrane :
  37. Lg_y = 1. ;
  38. * Nombre d'elements selon les directions x et y :
  39. Nel_x = 3;
  40. Nel_y = 4;
  41. * 'TRI6' 'TRI3'   'QUA8' 'QUA4'
  42. 'OPTION' 'ELEM' 'QUA4' ;
  43. *
  44. P1 =  0.    0. ;
  45. P2 = Lg_x   0. ;
  46. P3 = Lg_x Lg_y ;
  47. P4 =  0.  Lg_y ;
  48. *
  49. L1 = 'DROITE' Nel_x P1 P2 ;
  50. L2 = 'DROITE' Nel_y P2 P3 ;
  51. L3 = 'DROITE' Nel_x P3 P4 ;
  52. L4 = 'DROITE' Nel_y P4 P1 ;
  53. *
  54. SU = 'DALLER' L1 L2 L3 L4 ;
  55. 'SI' GRAPH ;
  56.   'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  57. 'FINSI' ;
  58.  
  59. *======================================================================*
  60. *             Modele - Materiau - Caracteristiques (en MPa)             *
  61. *======================================================================*
  62. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'OU'
  63.       ('NEG' ('VALEUR' 'MODE') 'PLANCONT')) ;
  64.   'MESS' 'Ce modele ne fonctionne qu en 2D CONTRAINTES PLANES' ;
  65.   'ERREUR' 5 ;
  66. 'FINSI' ;
  67. * Calcul du Module d'Young
  68. * Ne pas oublier de definir les parametres lies a l'elasticite.
  69. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  70. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  71. *
  72. LCMAT = MOTS 'YOUN' 'NU  '    'H1'  'H2'  'H3'  ;
  73. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'  
  74.                     'NON_LINEAIRE' 'UTILISATEUR'
  75.                 'NUME_LOI' 33  'C_MATERIAU' LCMAT ;
  76. *  'Q8RI'  
  77. * Pour calculer le module d'Young, on utilise les
  78. * Coefficients du modele de Mooney-Rivlin (en  MPa) :
  79. * 
  80. C1 = 0.183  ;     C2 = 0.0034   ;
  81. * 
  82. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  83. * du fait de l'incompressibilite inherente au modele.
  84. * Le module de Young YOU est alors connu, car, pour ce modele, le
  85. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  86. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  87. * de la traction. En fonction du niveau de deformation atteinte en 
  88. * traction, il faut augmenter cette valeur afin de pouvoir faire 
  89. * converger les calculs (module tangent en fin de calculs).
  90. * Prendre des valeurs superieures n'entraine pas de modification des
  91. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  92. *
  93. XNU = 0.497 ; 
  94. YOUini = 3.*(2.*(C1+C2)) ;   YOU = 20000. * YOUini ;
  95. *
  96. *Parametres du modèle GD : essais Treloar/Kawabata MPa
  97. *CoeD  = 1.E-4   ;
  98. H1 = 0.142236  ;
  99. H2 = 1.5854659E-2   ;
  100. H3 = 3.4946541E-4   ;
  101. * 
  102. MA = MATE MO 'YOUN' YOU 'NU  ' XNU  'H1' H1 'H2' H2 'H3' H3 ;
  103. *
  104. *
  105. *======================================================================*
  106. *             Conditions aux limites - Traction suivant UY             *
  107. *======================================================================*
  108. BL1 = 'BLOQUER' 'UY  ' L1 ;
  109. BL2 = 'BLOQUER' 'UY  ' L3 ;
  110. BL4 = 'BLOQUER' 'UX  ' P1 ;
  111. BLTOT = BL1 'ET' BL2 'ET' BL4 ;
  112. *
  113. * Definition des instants du chargement :
  114. t_deb = 0. ;   t_fin = 10. ;
  115. L_tps = 'PROG' t_deb t_fin ;
  116. * Deplacement suivant Y :
  117. L_UY = 'PROG' 0. ( 3. * Lg_y) ;
  118. L_UY = 'PROG' 0. (5. * Lg_y) ; 
  119. L_UY = 'PROG' 0. (8. * Lg_y) ; 
  120. L_UY = 'PROG' 0. (9. * Lg_y) ; 
  121. FF_y = 'DEPIMP' BL2 1. ;
  122. EV_y = 'EVOL' 'MANU' 'TEMPS' L_tps  'LAMY' L_UY ;
  123. *
  124. CHARTOT = 'CHARGEMENT' 'DIMP' FF_y EV_y ;
  125. *
  126. *======================================================================*
  127. *             Initialisation de la table pour appel a PASAPAS          *
  128. *======================================================================*
  129. TAB1 = 'TABLE' ;
  130. TAB1.'MODELE' = MO ;
  131. TAB1.'CARACTERISTIQUES' = MA ;
  132. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  133. TAB1.'CHARGEMENT' = CHARTOT ;
  134. ***** LG
  135. *TAB1.'K_TANGENT'=VRAI;
  136. TAB1.'MAXITERATION'= 150;
  137. *TAB1 . 'DELTAITER' = 150;
  138. *TAB1.'PRECISION' = 1.E-8;
  139. *TAB1.'FTOL' = 1.E-5 ;
  140. *TAB1.'MTOL' = 1.E-5 ;
  141. *****
  142. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  143. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  144. TAB1.'HYPOTHESE_DEFORMATIONS' = MOT 'UTILISATEUR' ;
  145. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  146. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  147. tab1.'REAC_GRANDS'=500.;
  148. *
  149. L_abs = TAB1.'TEMPS_SAUVES' ;
  150. n_abs = 'DIMENSION' L_abs ;
  151. *
  152. PASAPAS TAB1 ;
  153. *
  154. * Quelques traces de controle apres calculs
  155. 'SI' GRAPH ;
  156.   Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  157.   Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  158.   'TRACER' (Defo_0 'ET' Defo_1)
  159.            'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  160.   'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  161.            'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  162. 'FINSI' ;
  163. *
  164. *======================================================================*
  165. *             Construction de la solution analytique                   *
  166. *======================================================================*
  167. * Definitions :
  168. * - Allongement selon direction y : Lamy = 1 + (UY/Lg_y)
  169. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  170. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  171. * Dans le cas du modele GD  : Incompressible
  172. * Les contraintes de Cauchy sont calculables analytiquement :
  173. * - SCxx = 0.
  174. * - SCyy = 2.(Lamy**2 - 1./Lamy).(dW/dI1 + 1./Lamy.dW/dI2)
  175. * - SCxy = 0  (pas de cisaillement)
  176. * - SCzz = 0  (hypothese des contraintes planes)
  177. *
  178. L_Un  = 'PROG' n_abs '*' 1. ;
  179. Lamy  = L_Un + (('IPOL' L_abs L_tps L_UY) / Lg_Y) ;
  180. *
  181. L_z1 = Lamy * Lamy ;  L_z2 = L_Un / Lamy ;
  182. * 
  183. L_tr = L_Un * 3.;
  184. I1 = L_z1 + (2. * L_z2);
  185. I2 = (2. * Lamy) + ( L_Un /  L_z1 );
  186. ************************************************************************   
  187. dWI1= H1 * (exp (H3 *((I1 - L_tr)**2)));
  188. dWI2= 3. * H2 * L_Un / (I2**0.5);
  189. ************************************************************************
  190. SCxx_th = 0. * L_Un ;
  191. SCyy_th =(L_z1 - L_z2) * ((2.*dWI1*L_Un) + (2.*dWI2*L_z2)) ;
  192. SCxy_th = 0. * L_Un ;
  193. *
  194. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' Lamy 'SCYY' SCyy_th ;
  195. *dess  Evyy_th ;
  196. *@EXCEL1 Evyy_th 'GD.txt' ;
  197. *======================================================================*
  198. *             Comparaison des resultats avec la solution analytique    *
  199. *======================================================================*
  200. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  201. * calculees et les solutions analytiques correspondantes.
  202. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  203. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  204. *
  205. TabD = TAB1.'DEPLACEMENTS' ;
  206. TabS = TAB1.'CONTRAINTES' ;
  207. Confini = 'FORM' ;
  208. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  209. *
  210. SCxx = 'PROG' 0. ;
  211. SCyy = 'PROG' 0. ;
  212. SCxy = 'PROG' 0. ;
  213. 'REPETER' Boucle (n_abs - 1) ;
  214.   'FORM' (TabD.&Boucle) ;
  215.   VolSU = 'INTG' MO ChmUn ;
  216.   SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  217.   SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  218.   SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  219.   'FORM' Confini ;
  220. 'FIN' Boucle ;
  221. *  LG lamb
  222. L_abs = Lamy;
  223. *
  224. 'SI' GRAPH ;
  225.   tlege = 'TABLE' ;
  226.   tlege. 1 = 'MARQ CROI' ;
  227.   tlege.'TITRE' = 'TABLE' ;
  228.   tlege.'TITRE'. 1 = 'Numerique' ;
  229.   tlege.'TITRE'. 2 = 'Analytique' ;
  230.   Evxx    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  231.   Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  232.   'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  233.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (MPa)') ;
  234.   Evyy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  235.   Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  236.   'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  237.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (MPa)') ;
  238.   Evxy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  239.   Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  240.   'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  241.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (MPa)');
  242. 'FINSI' ;
  243. *
  244. * Tests de bon fonctionnement :
  245. r_z = 'MAXIMUM' ('ABS' SCyy_th) ;
  246. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) / r_z ;
  247. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) / r_z ;
  248. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) / r_z ;
  249. *
  250. MESS ' RESULTATS : ' title ;
  251. MESS ' ------------------------------------------------- ';
  252. 'SAUTER' 1 'LIGNE' ;
  253. 'MESS' '  Tests de bon fonctionnement :' ;
  254. 'MESS' ' -------------------------------' ;
  255. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  256. 'MESS' ' Ecart relatif maximal entre la valeur moyenne '
  257.        'calculee' ;
  258. 'MESS' '                          et la '
  259.        'solution analytique associee' ;
  260. 'MESS' ' Composante XX : ' r_xx ;
  261. 'MESS' ' Composante YY : ' r_yy ;
  262. 'MESS' ' Composante XY : ' r_xy ;
  263. 'SAUTER' 1 'LIGNE' ;
  264. * Ecart relatif maximal tolere
  265. Sigref = 1.E-3 ;
  266. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  267.   'MESS' ' ---------------------' ;
  268.   'MESS' '  ECHEC DU CAS-TEST !' ;
  269.   'MESS' ' ---------------------' ;
  270.   'ERREUR' 5 ;
  271. 'SINON' ;
  272.   'MESS' ' ----------------------' ;
  273.   'MESS' '  SUCCES DU CAS-TEST !' ;
  274.   'MESS' ' ----------------------' ;
  275. 'FINSI' ;
  276. 'SAUTER' 1 'LIGNE' ;
  277. 'FIN' ;
  278.  
  279.  
  280.  
  281.  
  282.  
  283.  
  284.  
  285.  
  286.  
  287.  
  288.  
  289.  
  290.  
  291.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales