Télécharger la plaquette Cast3M


fr en

Télécharger gdep4.dgibi

Retour à la liste

Numérotation des lignes : 

  1. *----------------------------------------------------------------------*
  2. ************************************************************************
  3. ************************************************************************
  4. * fichier gdep4.dgibi                                                  *
  5. *                                                                      *
  6. * Exemple de la donnée d'un état mécanique initial avec :              *
  7. *   - Comportement mécanique non linéaire (élasto-plastique) ;         *
  8. *   - Grands déplacements.                                             *
  9. *                                                                      *
  10. * On simule 2 fois un essai de traction simple :                       *
  11. *   - 1ere simulation sert de reference.                               *
  12. *   - 2nd simulation permet de tester la donnee de l'état initial,     *
  13. *     puis de comparer la solution a la 1ere.                          *
  14. *                                                                      *
  15. *----------------------------------------------------------------------*
  16. * IG1 = VRAI : traces ;                                                *
  17. IG1      = FAUX ;
  18. *                                                                      *
  19. 'OPTI' 'DIME' 2 'ELEM' 'QUA8' 'MODE' 'PLAN' 'CONT' ;
  20. *                                                                      *
  21. S1       = ((0 0) 'DROI' 1 (1 0)) 'TRAN' 1 (0 1) ;
  22. L1       = S1 'COTE' 1 ;
  23. L2       = S1 'COTE' 2 ;
  24. L3       = S1 'COTE' 3 ;
  25. L4       = S1 'COTE' 4 ;
  26. 'SI' IG1 ;
  27.   'TRAC' 'QUAL' S1 'TITR'
  28. ' Cas-test de la donnee du deplacement initial en grands deplacements' ;
  29. 'FINS' ;
  30. *                                                                      *
  31. *---------------------- MODELE / CARACTERISTIQUES ---------------------*
  32. *                                                                      *
  33. MOD1     = 'MODE' S1 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'CINEMATIQUE' ;
  34. MAT1     = 'MATE' MOD1 'YOUN' 200.E9 'NU' 0.3 'SIGY' 150.E6 'H' 200.E6 ;
  35. *                                                                      *
  36. *-------------------------- BLOCAGES / C.L. ---------------------------*
  37. *                                                                      *
  38. * Blocages traction simple suivant (O,y) ;                             *
  39. CL1      = 'BLOQ' L1 'UY' ;
  40. CL3      = 'BLOQ' L3 'UY' ;
  41. CL4      = 'BLOQ' L4 'UX' ;
  42. CL0      = CL1 'ET' CL3 'ET' CL4 ;
  43. 'SI' IG1 ;
  44.   'TRAC' 'QUAL' (S1 'ET' ((L1 'ET' L4) 'COUL' 'ROUG')) 'TITR'
  45.     ' On bloque L1 en (O,y) et L4 en (O,x) ' ;
  46. 'FINS' ;
  47. *                                                                      *
  48. * Deplacement impose :                                                 *
  49. EPYY1    = 1.E-3 ;
  50. DCL3     = 'DEPI' CL3 EPYY1 ;
  51. 'SI' IG1 ;
  52.   'TRAC' 'QUAL' (S1 'ET' (L3 'COUL' 'ROUG')) 'TITR' 
  53.     ' On impose un deplacement sur L3 suivant (O,y) ' ;
  54. 'FINS' ;
  55. *                                                                      *
  56. * Chargement associe :                                                 *
  57. LTPS1    = 'PROG' 0. 1. ;
  58. EV1      = 'EVOL' 'MANU' 'TEMP' LTPS1 'AMPL' LTPS1 ;
  59. CG1      = 'CHAR' 'DIMP' DCL3 EV1 ;
  60. *                                                                      *
  61. *------------------------------ PASAPAS -------------------------------*
  62. *                                                                      *
  63. XPREC1   = 1.E-10 ;
  64. *                                                                      *
  65. TAB1                         = 'TABL' ;
  66. TAB1 . 'MODELE'              = MOD1 ;
  67. TAB1 . 'CARACTERISTIQUES'    = MAT1 ;
  68. TAB1 . 'BLOCAGES_MECANIQUES' = CL0 ;
  69. TAB1 . 'CHARGEMENT'          = CG1 ;
  70. TAB1 . 'TEMPS_CALCULES'      = 'PROG' 0. 'PAS' 0.1 1. ;
  71. TAB1 . 'GRANDS_DEPLACEMENTS' = VRAI ;
  72. TAB1 . 'PRECISION'           = XPREC1 ;
  73. *                                                                      *
  74. PASAPAS TAB1 ;
  75. *                                                                      *
  76. TAB2                         = 'TABL' ;
  77. TAB2 . 'MODELE'              = MOD1 ;
  78. TAB2 . 'CARACTERISTIQUES'    = MAT1 ;
  79. TAB2 . 'BLOCAGES_MECANIQUES' = CL0 ;
  80. TAB2 . 'CHARGEMENT'          = CG1 ;
  81. TAB2 . 'TEMPS_CALCULES'      = 'PROG' 0.9 1. ;
  82. TAB2 . 'GRANDS_DEPLACEMENTS' = VRAI ;
  83. TAB2 . 'PRECISION'           = XPREC1 ;
  84. TAB2 . 'TEMPS'               = 'TABL' ;
  85. TAB2 . 'TEMPS'        . 0    = 0.9 ;
  86. TAB2 . 'DEPLACEMENTS'        = 'TABL' ;
  87. TAB2 . 'DEPLACEMENTS' . 0    = TAB1 . 'DEPLACEMENTS' . 9 ;
  88. TAB2 . 'CONTRAINTES'         = 'TABL' ;
  89. TAB2 . 'CONTRAINTES'  . 0    = TAB1 . 'CONTRAINTES'  . 9 ;
  90. TAB2 . 'VARIABLES_INTERNES'  = 'TABL' ;
  91. TAB2 . 'VARIABLES_INTERNES' . 0 = TAB1 . 'VARIABLES_INTERNES' . 9 ;
  92. TAB2 . 'DEFORMATIONS_INELASTIQUES' = 'TABL' ;
  93. TAB2 . 'DEFORMATIONS_INELASTIQUES'  . 0 =
  94.   TAB1 . 'CONTINUATION' . 'DEFORMATIONS_INELASTIQUES' ;
  95. *                                                                      *
  96. PASAPAS TAB2 ;
  97. *                                                                      *
  98. *-------------------------------- TEST --------------------------------*
  99. *                                                                      *
  100. DDEP10   = (TAB1 . 'DEPLACEMENTS' . 10) - (TAB2 . 'DEPLACEMENTS' . 1) ;
  101. DSIG10   = (TAB1 . 'CONTRAINTES'  . 10) - (TAB2 . 'CONTRAINTES'  . 1) ;
  102. NDEP10   = 'MAXI' 'ABS' (TAB1 . 'DEPLACEMENTS' . 10 'ENLE' 'LX') ;
  103. NSIG10   = 'MAXI' 'ABS' (TAB1 . 'CONTRAINTES'  . 10) ;
  104. DDEP10   = DDEP10 'ENLE' 'LX' ;
  105. ERRDEP10 = 'MAXI' 'ABS' (DDEP10 / NDEP10) ;
  106. ERRSIG10 = 'MAXI' 'ABS' (DSIG10 / NSIG10) ;
  107. 'SI' IG1 ;
  108.   'TRAC' ('CHAN' 'CHAM' (DDEP10 / NDEP10) MOD1) MOD1 'TITR' ('CHAI' 
  109. ' Erreur relative sur les deplacements =' 'FORMAT' '(E8.1)' ERRDEP10) ;
  110.   'TRAC' (DSIG10 / NSIG10) MOD1 'TITR' ('CHAI' 
  111.     ' Erreur relative sur la contrainte =' 'FORMAT' '(E8.1)' ERRSIG10) ;
  112. 'FINS' ;
  113. ERR0     = 'MAXI' ('PROG' ERRDEP10 ERRSIG10) ;
  114. *                                                                      *
  115. 'SI' (ERR0 > XPREC1) ;
  116.   'ERRE' 5 ;
  117. 'FINS' ;
  118. *                                                                      *
  119. 'FIN' ;
  120.  
  121.  
  122.  
  123.  
  124.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales