Télécharger la plaquette Cast3M


fr en

Télécharger gdep1.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  gdep1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. complet = faux;
  5. *
  6. *************************************************
  7. *  pour calcul complet mettre complet à : vrai;
  8. *************************************************
  9. GRAPH='N';                                                                      
  10. SAUT PAGE ;                                                                     
  11. ****************************************************************
  12. *  GRAND ROTATION D' UNE POUTRE
  13. *****************************************************************
  14. *
  15. *  DESCRIPTION DU PROBLEME
  16. *  -----------------------
  17. * IL S'AGIT DE TROUVER LA POSITION POST FLAMBAGE D 'UN POTEAU
  18. * CHARGE AXIALEMENT A UNE EXTREMITE ET ENCASTRE A L'AUTRE
  19. * EXTREMITE .
  20. *
  21. * REFERENCE :
  22. * ----------
  23. * STEPHEN P. TIMOSHENKO AND JAMES M. GERE,THEORY OF ELASTIC STABILITY
  24. * ,(NEW YORK :MCGRAW-HILL BOOK COMPANY,1961),P.48 
  25. ******************************************************************
  26. OPTION  ECHO 1 ;
  27. OPTIO DIME 3 ELEM SEG2 ;
  28. *
  29. *-----------------------------------------------------------------
  30. * le pilotage est fait sur l'amplitude du deplacement du point P2
  31. * auquel on attribut le signe du deplacement transversal (UY)
  32. 'DEBPROC' AUTOPILO DELT*'CHPOINT' DELA*'CHPOINT' ZMOD*'MMODEL'
  33.  ZMAT*'MCHAML' TTT*TABLE;
  34.    Ux = ( EXTR DELT P2 'UX' ) ;
  35.    Uy = ( EXTR DELT P2 'UY' ) ;
  36.    U = (ux*ux + (uy*uy))**0.5 ;
  37.    NORM1 = U * uy / (abs uy) ;
  38. FINPROC   NORM1;
  39. *---------------------------------------------------------------
  40. * MAILLAGE 
  41. * 
  42. P1 = 0. 0. 0.  ; P2 = 12. 0. 0. ;
  43. L1 = D 12 P1 P2  ;
  44. *
  45. *   MODELE 
  46. *  
  47.  MOD1 = MODEL L1 MECANIQUE ELASTIQUE POUT;
  48. *
  49. *   CARACTERISTIQUES MATERIELLES ET GEOMETRIQUES
  50. *
  51.  MAT1 = MATER MOD1 YOUN 2.E7 NU 0.0  ;
  52.  CAR1 = CARA MOD1 'SECT' 0.15 'INRY' 2.8125E-4 'INRZ' 2.8125E-4 
  53.  'TORS' 0.00001 ;
  54. *
  55. * MATRICE DE RIGIDITE 
  56. *
  57.  RIG1 = RIGI MOD1 (MAT1 ET CAR1) ;
  58. *
  59. *  FORCES ET CONDITIONS AUX LIMITES 
  60. *
  61.  CL1 = BLOQ P1 'DEPL' 'ROTA' ;
  62.  F1  = FORCE (-1. 0. 0. ) P2 ;
  63. *
  64. *  RESOLUTION 
  65. *
  66.  DEP1 = RESO (RIG1 ET CL1) F1 ;
  67.  SIG1 = SIGM MOD1 (MAT1 ET CAR1) DEP1 ;
  68. *
  69. *   MATRICE DE RAIDEUR GEOMETRIQUE
  70. *
  71.  KS1 = KSIGM MOD1 SIG1 (CAR1) 'FLAM' ;
  72. *
  73. * CALCUL DE MODES DE FLAMBAGE
  74. *
  75.  TAB1 = TABLE ;
  76.  TAB1.OBJM = MOD1 ;
  77.  TAB1.LAM1 = 0. ;
  78.  TAB1.LAM2 = 1000. ;
  79.  TAB1.NMOD = 1 ;
  80.  TAB1.CLIM = (CL1  ) ;
  81.  TAB1.RIGI = RIG1 ;
  82.  TAB1.KSIG = KS1 ;
  83.  TAB2 = FLAMBAGE TAB1 ;
  84.  LAMB1 = (TAB2.1).LAMB ;
  85. *
  86. *  CALCUL NON-LINEAIRE  GEOMETRIQUE
  87. * 
  88.  F11 = F1 *  LAMB1 ;
  89.  F3 = FORCE   (0. 1. 0.) P2  ; 
  90. * 
  91. *---- PREPARATION DE LA TABLE POUR NONLIN
  92. *
  93. *  OBJET CHARGEMENT 
  94. *
  95. LI1 = PROG 0. 2. ;
  96. LI2 = PROG 0. 2. ;
  97. EV = EVOL MANU T LI1 F(T) LI2 ;
  98. CHA1 = CHAR  'MECA' ( F11 ET F3)  EV ;
  99. *
  100. LIS1A = prog 0. 0.65;
  101. TAB3 = TABLE;
  102. TAB3.'GRANDS_DEPLACEMENTS' = VRAI ;
  103. TAB3.'AUTOMATIQUE' = VRAI ;
  104. TAB3.'AUTOCRIT' = 0.05  ;
  105. TAB3.'MAXITERATION'= 100 ;
  106. TAB3.'AUTOPAS' =1000 ;
  107. TAB3.'BLOCAGES_MECANIQUES' = CL1;
  108. TAB3.'MODELE' = MOD1;
  109. TAB3.'CARACTERISTIQUES' = (MAT1 ET CAR1);
  110. TAB3.'CHARGEMENT' = CHA1;
  111. TAB3.'TEMPS_CALCULES' = LIS1A;
  112. TAB3.'K_SIGMA'=FAUX;
  113. TAB3.'REAC_GRANDS'=10.E-2 ;
  114. TAB3.'HYPOTHESE_DEFORMATIONS'='LINEAIRE' ;
  115. PASAPAS TAB3 ;
  116. *
  117. TAB3.'AUTOCRIT' = 0.1  ;
  118. TAB3.'AUTOPAS' =1000 ;
  119. LIS1B = prog 0.65 0.9;
  120. TAB3.'TEMPS_CALCULES' = LIS1B;
  121. PASAPAS TAB3 ;
  122. *
  123. si complet;
  124. LIS1C = prog 0.9 1.;
  125. TAB3.'AUTOCRIT' = 0.2  ;
  126. TAB3.'TEMPS_CALCULES' = LIS1C;
  127. PASAPAS TAB3 ;
  128. *
  129. LIS1D = prog 1. 1.152;
  130. TAB3.'AUTOCRIT' = 0.5  ;
  131. TAB3.'TEMPS_CALCULES' = LIS1D;
  132. PASAPAS TAB3 ;
  133. finsi;
  134. **************************************************************
  135. *   COMPARAISON AVEC LES RESULTATS ANALYTIQUES
  136. *
  137. * 1) CHARGEMENT = 1.152 * PCR 
  138.  DEP1 = PECHE TAB3 'DEPLACEMENTS'  ;
  139.  PP1 = POINT L1 12   ;
  140.  XX1 = (EXTR DEP1 PP1  UX) +  (COOR 1 PP1) ;
  141.  YY1 = (EXTR DEP1 PP1  UY) +  (COOR 2 PP1) ;
  142.  XX2 = (EXTR DEP1 P2  UX) +  (COOR 1 P2) ;
  143.  YY2 = (EXTR DEP1 P2  UY) +  (COOR 2 P2) ;
  144.  TN = ((YY2 - YY1)/(XX2 - XX1)) ;
  145.  ALPHA = ATG TN ;
  146. si complet;
  147. ALPHATH = 60.  ;
  148. sinon;
  149. ALPHATH= 6.5710;
  150. finsi;
  151.  ER1 =((ABS (ALPHA - ALPHATH )) / (ABS ALPHATH )) * 100. ;
  152. MESS    'ANGLE DE ROTATION  P = 1.152  * PCR     ' ;
  153. MESS 'THEORIE ' ALPHATH 'CASTEM ' ALPHA '%ERREUR ' ER1 ;
  154. *
  155. SI (ER1 < 6);
  156. ERRE 0;
  157. SINON;
  158. ERRE 5;
  159. FINSI;
  160. FIN ;
  161.  
  162.  
  163.  
  164.  
  165.  
  166.  
  167.  
  168.  
  169.  
  170.  
  171.  
  172.  
  173.  
  174.  
  175.  
  176.  
  177.  
  178.  
  179.  
  180.  
  181.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales