Exemples de jeux de données Cast3M

* fichier :  mma_02.dgibi
************************************************************************
************************************************************************
 
************************************************************************
*      Test de l'opérateur MMA : Méthode des Asymptotes Mobiles        *
*                       Globalement Convergente                        *
*            Application à un problème simple (pour jouer)             *
*                                                                      *
* Le problème s'écrit :                                                *
*    Minimiser :  f0(x) = x1² + x2² + x3²                              *
*      sur x                                                           *
*         avec :  f1(x) = (x1-5)² + (x2-2)² + (x3-1)² - 9 <= 0         *
*                 f2(x) = (x1-3)² + (x2-4)² + (x3-3)² - 9 <= 0         *
*                 0 <= xi <= 5   pour i=1,2,3                          *
*                                                                      *
* La solution est : x1 = 2.0175   x2 = 1.7800   x3 = 1.2375            *
************************************************************************
 
* Options d'affichage
OPTI 'ECHO' 0 ;
itrac = FAUX ;
 
* Procédure pour calculer f0, f1, f2 ainsi que les dérivées partielles
*                         df0/dxi, df1/dxi, df2/dxi pour i=1,2,3
DEBP FONC a*'LISTREEL' ;
  f = SOMM (a ** 2) ;
  df = 2. * a ;
  b1 = PROG 5. 2. 1. ;
  b2 = PROG 3. 4. 3. ;
  g = PROG ((SOMM ((a - b1) ** 2)) - 9.)
           ((SOMM ((a - b2) ** 2)) - 9.) ;
  dgda = TABL ;
  dgda . 1 = 2. * (a - b1) ;
  dgda . 2 = 2. * (a - b2) ;
FINP f df g dgda ;
 
* Solution de référence
x1ref = 2.0175 ;
x2ref = 1.7800 ;
x3ref = 1.2375 ;
xref  = PROG x1ref x2ref x3ref ;
f0ref df0dxref fval0 dfdxref = FONC xref ;
MESS ;
MESS 'Solution de reference' ;
MESS '       x1          x2          x3          f0' ;
MESS (CHAI 'FORMAT' '(F12.8)' x1ref /7 x2ref >1 x3ref >1 f0ref >1) ;
 
* Choix d'un point initial pour les inconnues
x0 = PROG 4. 3. 2. ;
 
* Calcul de f0(x0), df0dx(x0), fval(x0), dfdx(x0)
f0 df0dx fval dfdx = FONC x0 ;
 
* Initialisation de la table pour la MMA
t = TABL ;
t . 'X'     = x0 ;
t . 'XMIN'  = 0. ;
t . 'XMAX'  = 5. ;
t . 'F0VAL' = f0 ;
t . 'DF0DX' = df0dx ;
t . 'FVAL'  = fval ;
t . 'DFDX'  = dfdx ;
t . 'C'     = 1000. ;
t . 'GC'    = VRAI ;
 
* Itérations de la MMA
x01 = EXTR x0 1 ;
x02 = EXTR x0 2 ;
x03 = EXTR x0 3 ;
lx1 = PROG x01 ;
lx2 = PROG x02 ;
lx3 = PROG x03 ;
lit = PROG 0. ;
lf0 = PROG f0 ;
f1  = EXTR fval 1 ;
f2  = EXTR fval 2 ;
li  = PROG (MAXI 0. f1 f2) ;
MESS ;
MESS 'Optimisation par GC-MMA' ;
MESS 'It sIt x1          x2          x3          f0           kktnorm' ;
MESS (CHAI 'FORMAT' '(F12.8)' 0 0 /6 x01 >1 x02 >1 x03 >1 f0 >1) ;
* Boucle d'optimisation
REPE loop 10 ;
* Appel à MMA
  lit = lit ET &loop ;
* Boucle des sous itérations de la GCMMA
  REPE sloop 15 ;
    MMA t ;
*   Si le sous problème est conservatif
*   mise à jour des valeurs des fonctions et arret des sous itérations
    SI (t . 'CONSERV') ;
      xmma = t . 'X' ;
      f0 df0dx fval dfdx = FONC xmma ;
      t . 'F0VAL'  = f0 ;
      t . 'DF0DX'  = df0dx ;
      t . 'FVAL'   = fval ;
      t . 'DFDX'   = dfdx ;
      QUIT sloop ;
*   Sinon, mise à jour des valeurs des fonctions (pas besoin des gradients)
*   dans WTABLE et nouvelle sous itération
    SINON ;
      xmma = t . 'WTABLE' . 'X' ;
      f0 df0dx fval dfdx = FONC xmma ;
      t . 'WTABLE' . 'F0VALNEW'  = f0 ;
      t . 'WTABLE' . 'FVALNEW'   = fval ;
    FINSI ;
  FIN sloop ;
* Calcul du résidu pour les conditions KKT
  res kkt2 kktinf = KKT_MMA t ;
* Bilan de l'itération
  sit = t . 'WTABLE' . 'ITER' ;
  x1 = EXTR xmma 1 ;
  x2 = EXTR xmma 2 ;
  x3 = EXTR xmma 3 ;
  lx1 = lx1 ET x1 ;
  lx2 = lx2 ET x2 ;
  lx3 = lx3 ET x3 ;
  lf0  = lf0 ET f0 ;
  f1   = EXTR fval 1 ;
  f2   = EXTR fval 2 ;
  li   = li ET (MAXI 0. f1 f2) ;
  MESS (CHAI 'FORMAT' '(F12.8)' &loop sit /6 x1 >1 x2 >1 x3 >1 f0 >1 kkt2 >1) ;
FIN loop ;
nit = (DIME lf0) - 1 ;
MESS ;
 
* Vérification du résultat
errmax = MAXI 'ABS' ((xmma - xref) / xref) ;
MESS 'Erreur relative max (sur x)' ;
MESS errmax ;
MESS ;
 
* Évolutions temporelles de f, de l'infaisabilité et des variables
* en fonction des itérations d'optimisation
SI itrac ;
  lit   = PROG 0. 'PAS' 1. nit ;
  evf0  = EVOL 'ROUG' 'MANU' 'Iteration' lit 'F0'  lf0 ;
  evfr  = EVOL 'ROUG' 'MANU' 'Iteration' (PROG 0. nit) 'F0' (PROG f0ref f0ref) ;
  tl    = TABL ;
  tl . 2 = 'TIRR' ;
  tl . 'TITRE' = TABL ;
  tl . 'TITRE' . 1  = 'F0 calculee' ;
  tl . 'TITRE' . 2  = 'F0 ref.' ;
  DESS (evf0 ET evfr) 'TITR' 'Fonction objectif F0(x) VS Iterations' 'LEGE' tl ;
  evi   = EVOL 'VERT' 'MANU' 'Iteration' lit 'Inf' li ;
  tl . 'TITRE' . 1  = 'Infaisabilite' ;
  DESS evi 'TITR' 'Infaisabilite VS Iterations' 'LEGE' tl ;
  evx1  = EVOL 'ROUG' 'MANU' 'Iteration' lit 'x' lx1 ;
  evx1r = EVOL 'ROUG' 'MANU' 'Iteration' (PROG 0. nit) 'x' (PROG x1ref x1ref) ;
  evx2  = EVOL 'ORAN' 'MANU' 'Iteration' lit 'x' lx2 ;
  evx2r = EVOL 'ORAN' 'MANU' 'Iteration' (PROG 0. nit) 'x' (PROG x2ref x2ref) ;
  evx3  = EVOL 'JAUN' 'MANU' 'Iteration' lit 'x' lx3 ;
  evx3r = EVOL 'JAUN' 'MANU' 'Iteration' (PROG 0. nit) 'x' (PROG x3ref x3ref) ;
  tl . 4  = 'TIRR' ;
  tl . 6  = 'TIRR' ;
  tl . 'TITRE' . 1  = 'x1 calcule' ;
  tl . 'TITRE' . 2  = 'x1 ref.' ;
  tl . 'TITRE' . 3  = 'x2 calcule' ;
  tl . 'TITRE' . 4  = 'x2 ref.' ;
  tl . 'TITRE' . 5  = 'x3 calcule' ;
  tl . 'TITRE' . 6  = 'x3 ref.' ;
  DESS (evx1 ET evx1r ET evx2 ET evx2r ET evx3 ET evx3r) 'TITR' 'Valeurs x VS Iterations' 'LEGE' tl ;
FINSI ;
 
* Sortie en erreur si l'écart aux valeurs de références est trop important
SI (errmax > 1.E-5) ;
  ERRE 'Erreur dans le calcul d''optimisation' ;
SINON ;
  MESS 'Cas test passe avec succes !' ;
FINSI ;
 
 
FIN ;