Télécharger la plaquette Cast3M


fr en

Télécharger gatt_dpg.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  gatt_dpg.dgibi
  2. *
  3. *     Test gatt_dpg.dgibi: Jeux de données            
  4. *     ---------------------------------------         
  5. * 
  6. 'OPTI' 'DIME' 2 'MODE' 'PLAN' 'GENE' ;
  7. 'OPTI' 'ELEM' 'QUA8'                 ;
  8. 'OPTI' 'TRAC' 'PSC'                  ;
  9. 'TEMPS' 'ZERO'                       ;
  10. L = 'MOT' LIST ; F = 'MOT' FIN       ;
  11. *                                                                               
  12. ***********************************************************          
  13. *                TEST DE VALIDATION                       *
  14. *                ------------------                       *
  15. *               MODELE GATT_MONERIE                       *
  16. *  AFA3GLAA INCOMPRESSIBLE AVEC COUPLAGE DYNAMIQUE        *
  17. *                                                         *
  18. *  MAILLAGE:                                              *
  19. *     EPROUVETTE CARRE                                    *
  20. *                                                         *
  21. *  CHARGEMENT:                                            *
  22. *     CONTRAINTE DE COMPRESSION IMPOSEE (ESSAI DE FLUAGE) *
  23. *     TEMPERATURE CONSTANTE                               *
  24. *     DENSITE DE FISSIONS CONSTANTE                       *
  25. *     PRIMAIRE - MECANISMES 1 ET 2 - IRRADIATION          *
  26. *     DENSIFICATION - GONFLEMENT                          *
  27. ***********************************************************          
  28. *
  29. * repertoire des fichiers "divers"
  30. DIVERS = VENV 'CASTEM_DIVERS';
  31. *
  32. GRAPH    = FAUX ;
  33. LISTCOUR = VRAI ;
  34. *
  35. NE   = 1  ;
  36. H    = 1. ;
  37. *
  38. OO   = 0.              0.            ;
  39. A1   = H               0.            ;
  40. A2   = H               H             ;
  41. A3   = 0.              H             ;
  42. *
  43. LB   = 'DROIT' NE  OO A1             ;
  44. LD   = 'DROIT' NE  A1 A2             ;
  45. LH   = 'DROIT' NE  A2 A3             ;
  46. LG   = 'DROIT' NE  A3 OO             ;
  47. *
  48. SU1  = 'DALL' LB  LD  LH  LG  'PLAN' ;
  49. *
  50. MODL1= MODE SU1 MECANIQUE ELASTIQUE
  51.   VISCOPLASTIQUE GATT_MONERIE 'DPGE' OO      ;
  52. *
  53. * ----------------------*
  54. * Materiau GATT_MONERIE *
  55. * ----------------------*
  56. TE1  = 1300. + 273.  ;
  57. PO   = 4.9E-2        ;
  58. DF1  = 1.E18         ;
  59. *
  60. TA = @GATTPAR ('CHAINE' DIVERS '/fichier_gatt') ;
  61. *
  62. TA.'BP'   = 0.      ;
  63. TA.'POR0' = PO      ;
  64. TA.'CR'   = 0.16E-2 ;
  65. *
  66. MATREE = MATE MODL1 'YOUN' (TA.'YOUN') ; 
  67. PP = 'MANU' 'CHML' MODL1 'T' TE1 'PORO' PO RIGIDITE ; 
  68. EE = 'VARI' 'NUAG' MODL1 MATREE PP ;
  69. *
  70. MATR11 = 'MATE' MODL1  'YOUN' EE  'NU' 0.  'RHO' 10950.  'ALPH' 0. 'TALP' 0. 'TREF' 1. ;
  71. *
  72. MATR12 = 'MATE' MODL1 
  73.  'R'    (TA.'R')    'DG0' (TA.'DG0') 'DG'  (TA.'DGCR')
  74.  'K1'   (TA.'K1')   'M1'  (TA.'M1')  'Q1'  (TA.'Q1')  'N1'   (TA.'N1') 
  75.  'K2'   (TA.'K2')   'M2'  (TA.'M2')  'Q2'  (TA.'Q2')  'N2'   (TA.'N2') 
  76.  'OMEG' (TA.'OMEG') 'H'   (TA.'H')   'Q'   (TA.'Q')   'BETA' (TA.'BETA')
  77.  'K'    (TA.'K')    'A'   (TA.'A')   'Q3'  (TA.'Q3')  'N3'   (TA.'N3')
  78.  'CR'   (TA.'CR')   'CR1' (TA.'CR1') 'CR2' (TA.'CR2') 'CR3'  (TA.'CR3');
  79. *
  80. MATR13 = 'MATE' MODL1 
  81.  'KP'   (TA.'KPAF')   'AP' (TA.'AP')  'BP'  (TA.'BP')  'QP'  (TA.'QP') ;
  82. * 
  83. MATR14 = 'MATE' MODL1 
  84.  'ADEN' TA.'ADEN' 'KGON' TA.'KGON'. 
  85.  'POR0' (TA.'POR0') 'BUMI' (TA.'BUMI')  'EFIS' (TA.'EFIS') ;
  86. *
  87. * TYPE = 0. combustible UO2            sinon combustible AFA3GLAA
  88. * COMP = 0. combustible incompressible sinon compressible
  89. * DYN  = 0. couplage dynamique         sinon statique
  90. *
  91. MATR15 = 'MATE' MODL1 'TYPE' 1.   'COMP' 1.   'DYN' 1. ;
  92. *
  93. MATR16 = 'MATE' MODL1
  94.          'DYN1' (TA.'DYN1')   'DYN2' (TA.'DYN2')   'DYN3' (TA.'DYN3') ;
  95. *
  96. MATR1 = MATR11 'ET' MATR12 'ET' MATR13 'ET' MATR14 'ET'
  97.         MATR15 'ET' MATR16 ;
  98. *
  99. * -----------------------*
  100. * Conditions aux limites *
  101. * -----------------------*
  102. CLYB = 'BLOQ' 'UY' LB                  ;
  103. CLXG = 'BLOQ' 'UX' LG                  ;
  104. CLT  = CLYB 'ET' CLXG                  ;
  105. *
  106. TMIL = 1.E6 ;
  107. TFIN = 2.E6 ;
  108. *
  109. RHO0 = 1. - TA.'POR0' ;
  110. AKBU = TA.'EFIS'*270./238./10950./RHO0*DF1 ;
  111. * CE QUI SUIT EST VRAI CAR LE FLUX DE FISSIONS EST CONSTANT 
  112. TBU = (TA.'BUMI' / AKBU) - 1. ;
  113. TTBU = ('ENTI' (TBU/10000.)) * 10000. ;
  114. *-------------------*
  115. * Instants calcules *
  116. *-------------------*
  117. 'SI' LISTCOUR ;
  118. *--------------
  119. LIST1 = 'PROG' 0  'PAS' 0.1 1 'PAS' 1 10 'PAS' 10 100 'PAS' 100 1000 
  120.                   'PAS' 500  15000 ;
  121. 'SINON' ;
  122. *--------
  123. LIST1 = 'PROG' 0  'PAS' 0.1 1 'PAS' 1 10 'PAS' 10 100 'PAS' 100 1000 
  124.                   'PAS' 500  30000 ;
  125. 'FINSI' ;
  126. *--------
  127. * ------------------------------*
  128. * Chargement cte en temperature *
  129. * ------------------------------*
  130. CHTEMP   = 'MANU' 'CHPO' SU1 1 'T' 1.           ;
  131. EVT      = 'EVOL' 'MANU' ('PROG' 0.  (2.*TFIN)) 
  132.                          ('PROG' TE1 TE1)       ;
  133. CHARTEMP = 'CHAR' 'T' CHTEMP EVT                ;
  134. * -------------------------------------*
  135. * Chargement cte en densite de fission *
  136. * -------------------------------------*
  137. CHFISS   = 'MANU' 'CHPO' SU1 1 'DFIS' 1.        ;
  138. EVF      = 'EVOL' 'MANU' ('PROG' 0.  (2.*TFIN)) 
  139.                          ('PROG' DF1 DF1)       ;
  140. CHARFISS = 'CHAR' 'DFIS' CHFISS EVF             ;
  141. * -----------------------*
  142. * Chargement en pression *
  143. * -----------------------*
  144. valpres  = 60E6                                    ;
  145. compr    = 'PRES' 'MASS' MODL1 valpres LH          ;
  146. EVP      = 'EVOL' 'MANU' ('PROG' 0.  1. (2.*TFIN)) 
  147.                          ('PROG' 0.  1.        1.) ;
  148. CHARMECA = 'CHAR' 'MECA' compr EVP                 ;
  149. *
  150. CHARTOT  = CHARMECA 'ET' CHARTEMP 'ET' CHARFISS ;
  151. * ---------------------------------------*
  152. * Variables internes initiales 'PORO'=PO *
  153. * ---------------------------------------*
  154. VAR00 = 'ZERO' MODL1 'VARINTER'                                    ;
  155. VAR01 = 'MANU' 'CHML' MODL1 'PORO' PO 
  156.                             'TYPE' 'VARIABLES INTERNES' 'STRESSES' ;
  157. VAR0  = VAR00 + VAR01                                              ;
  158. *
  159. *
  160. TAB1 = TABLE                           ;
  161. TAB1.'TEMPERATURES' = TABLE            ;
  162. TAB1.'VARIABLES_INTERNES'= TABLE       ;
  163. TAB1.'BLOCAGES_MECANIQUES' = CLT       ;
  164. TAB1.'MODELE' = MODL1                  ;
  165. TAB1.'CHARGEMENT' = CHARTOT            ;
  166. TAB1.'TEMPERATURES' . 0 = CHTEMP       ;
  167. TAB1.'VARIABLES_INTERNES' . 0 = VAR0   ; 
  168. TAB1.'CARACTERISTIQUES' = MATR1        ;
  169. TAB1.'TEMPS_CALCULES' = LIST1          ;
  170. TAB1.'TEMPS_SAUVES' = LIST1            ;
  171. *
  172. TMASAU                   = TABLE       ;
  173. tab1 . 'MES_SAUVEGARDES' = TMASAU      ;
  174. TMASAU .'DEFTO' = VRAI                 ;
  175. TMASAU .'DEFIN' = VRAI                 ;
  176. *
  177. PASAPAS TAB1                           ;
  178. *
  179. *
  180. *
  181. *****************************************
  182. *        CONTROLE DES RESULTATS         *
  183. *****************************************
  184. *
  185. *
  186. AP      = TA.'AP'        ;
  187. BP      = TA.'BP'        ;
  188. N1      = TA.'N1'        ;
  189. N2      = TA.'N2'        ;
  190. DG      = TA.'DGCR'      ;
  191. *
  192. * Facteurs multiplicatifs dus au dopage par le Chrome
  193. WC1 = 'TANH' ( (TA.'CR' - TA.'CR2') / TA.'CR3' ) ;
  194. WC1 = 1. + ( 0.5 * TA.'CR1' * (1. + WC1) )       ;
  195. CV  = 180. / PI                                  ;
  196. WC2 = 1. - ( 'COS' (CV * DG / TA.'DG0') )        ;
  197. WC2 = 2. * (TA.'DG0'**TA.'M2') * WC2             ;
  198. *
  199. * Calcul de TO pour la fonction de couplage dynamique
  200. TO = 'TANH' ( (TA.'DYN2' - TE1) / TA.'DYN3' ) ;
  201. TO = TA.'DYN1' * (1. + TO)                    ;
  202. TO = TO + 1.                                  ;
  203. *
  204. BUMI = TA.'BUMI' ;
  205. AKEVD = AKBU*TA.'KGON' ;
  206. ADEN = TA.'ADEN' ; 
  207. KGON = TA.'KGON' ;
  208. * -------------------------------------------------------------------*
  209. * Calcul de la cte AAAA intervenant ds le calcul de la def. de dens. *
  210. * -------------------------------------------------------------------*
  211. BUMAX0=60.D0*BUMI ;
  212. CRIT=1.D-10 ;
  213. 'REPE' BLOC 100 ;         
  214.   BUMAX = BUMI* ('EXP' (1. - (ADEN/(KGON*BUMAX0)))) ;
  215.   BUMAX = (0.2*BUMAX) + (0.8*BUMAX0) ;
  216.   TEST='ABS' ((BUMAX-BUMAX0)/BUMAX0) ;
  217.   'SI' ('<' TEST CRIT) ; 
  218.     'QUIT' BLOC ; 
  219.   'FINS' ;
  220.   BUMAX0=BUMAX ;
  221. 'FIN' BLOC ;
  222. AAAA = (-1.D0*RHO0*(ADEN-(KGON*BUMAX))) /
  223.                 ((1.D0+ADEN)*(LOG(BUMAX/BUMI)))  ;
  224. *
  225. * -----------------------*
  226. * Controle des resultats *
  227. * -----------------------*
  228. SS = TAB1 . 'CONTRAINTES'                   ;
  229. VV = TAB1 . 'VARIABLES_INTERNES'            ;
  230. IN = TAB1 . 'DEFORMATIONS_INELASTIQUES'     ;
  231. NCONT = ('DIME' (TAB1 . 'CONTRAINTES')) - 1 ; 
  232. *
  233. ERMAX1 = 0.        ;
  234. ERMAX2 = 0.        ;
  235. *
  236. Lzeit   = 'PROG' ;
  237. Lteta   = 'PROG' ;
  238. Lteta_c = 'PROG' ;
  239. Lepsv   = 'PROG' ;
  240. Lepsv_c = 'PROG' ;
  241. *
  242. ind0  = 9  ;
  243. zeit0 = 1. ;
  244. *
  245. epsv0 = 'MAXI' ('EXCO' IN.(ind0 + 1) 'EIYY') ; 
  246. *
  247. 'REPE' BLOC (NCONT - ind0) ;
  248. *
  249.   ind = ind0 + &BLOC ;
  250. *
  251. * ----------------------------------------------------
  252. * SMYY = valpres ET LES AUTRES COMPOSANTES SONT NULLES
  253. * ----------------------------------------------------
  254.   SMYY = -1. * valpres ;
  255.   SSM  = SMYY / 3.     ;
  256.   SSEQ = 'ABS' SMYY    ;
  257. * Deviateur des contraintes
  258.   SSPRIM2 = SMYY - SSM ;
  259. * Contrainte YY calculee
  260.   sy_c = 'MAXI' ('EXCO' SS.ind 'SMYY') ;
  261. * --------------------------------------------------------------
  262. * VITESSE DE DEFORMATION VISCO-PLASTIQUE EVP D"ORIGINE THERMIQUE
  263. * --------------------------------------------------------------
  264. *-- fluage primaire
  265. *
  266.   EVP02 = -1.5 * TA.'KPAF' * 
  267.    ('EXP' (-1.*TA.'QP'/(TA.'R'*TE1))) * (SSEQ**AP) ;
  268. *
  269. *-- fluage secondaire (2 mecanismes)
  270. *
  271. * on teste la porosite :
  272.   PP = 'MAXI' ('EXCO' VV . &BLOC 'PORO')   ;
  273.   ECART1 = 'ABS' ((PP - PO) / PO)          ;
  274.   ERMAX1 = 'MAXI' ('PROG' ECART1 ERMAX1)   ;
  275. *
  276.   A1 = (N1* (PP**(-1./N1) - 1.)**(-2.*N1/(N1+1.)))      ;
  277.   B1 = (1. + (2.*PP/3.))/ ((1. - PP) **(2.*N1/(N1+1.))) ;
  278.   B1 = B1 + (A1/4.)                                     ;
  279.   A1 = 0.                                               ;
  280. *
  281.   A2 = (N2* (PP**(-1./N2) - 1.)**(-2.*N2/(N2+1.)))      ;
  282.   B2 = (1. + (2.*PP/3.))/ ((1. - PP) **(2.*N2/(N2+1.))) ;
  283.   B2 = B2 + (A2/4.)                                     ;
  284.   A2 = 0.                                               ;
  285. *
  286.   EVP12 = 0.5 * (TA.'K1' * (DG**TA.'M1') * WC1 *
  287.   ('EXP' (-1.*TA.'Q1'/(TA.'R'*TE1))) * 
  288.   (((A1*((1.5*SSM)**2)) + (B1*(SSEQ ** 2)))**((N1-1.)/2.)) *
  289.   ((A1*1.5*SSM) + (3.*B1*SSPRIM2))) ;
  290. *
  291.   EVP22 = 0.5 * (TA.'K2' * WC2 * ('EXP' (-1.*TA.'Q2'/(TA.'R'*TE1))) * 
  292.   (((A2*((1.5*SSM)**2)) + (B2*(SSEQ ** 2)))**((N2-1.)/2.)) *
  293.   ((A2*1.5*SSM) + (3.*B2*SSPRIM2))) ;
  294. * -----------------------------
  295. * FONCTION DE COUPLAGE STATIQUE
  296. * -----------------------------
  297.   TETA0 = 0.5 * TA.'BETA' *
  298.       (1. + 
  299.       ('TANH' ((TE1 - (TA.'OMEG' * (SSEQ**(-1.*TA.'Q')))) / TA.'H'))) ;
  300. * ------------------------------
  301. * FONCTION DE COUPLAGE DYNAMIQUE
  302. * ------------------------------
  303.   zeit  = TAB1.'TEMPS'.ind        ;
  304.   duree = zeit - zeit0            ; 
  305.   TETA = ( 1. + (zeit/TO) ) ** -1 ;
  306.   TETA = TETA0 * (1. - TETA)      ;
  307. * Fonction de couplage dynamique calculee
  308.   teta_c = 'MAXI' ('EXCO' VV.ind 'TETA') ;
  309. * ----------------------------------
  310. * VITESSE DE DEFORMATION IRRADIATION
  311. * ----------------------------------
  312.   EVIR2 = 1.5 * TA.'A' * DF1 * (SSEQ **(TA.'N3' - 1.)) * 
  313.        ('EXP' (-1.*TA.'Q3'/(TA.'R'*TE1))) * SSPRIM2 ;
  314. * ------------------------------------
  315. * DEFORMATION VISCO-PLASTIQUE SELON YY
  316. * ------------------------------------
  317.  KFI      = 1.+(TA.'K'*DF1)                      ;
  318.  EPSVa    = EVIR2 + ( KFI * (EVP02+EVP12) )      ;
  319.  EPSVb    = KFI * (EVP22 - EVP12)                ;
  320.  INTGTETA = 'LOG' ( 1. + (duree/TO) )            ;
  321.  INTGTETA = TO * INTGTETA                        ;
  322.  INTGTETA = TETA0 * (duree - INTGTETA)           ;
  323.  epsv     = (EPSVa * duree) + (EPSVb * INTGTETA) ;
  324.  epsv     = epsv0 + epsv                         ;
  325. * Deformation viscoplastique calculee
  326.  epsv_c = 'MAXI' ('EXCO' IN.ind 'EIYY') ;
  327. * On teste la deformation viscoplastique :
  328.      ECART2 = 'ABS' ((epsv_c - epsv) / epsv)  ;
  329.      ERMAX2 = 'MAXI' ('PROG' ECART2 ERMAX2)   ;
  330. *
  331.   Lzeit   = Lzeit   'ET' ('PROG' zeit)   ;
  332.   Lteta   = Lteta   'ET' ('PROG' TETA)   ;
  333.   Lteta_c = Lteta_c 'ET' ('PROG' teta_c) ;
  334.   Lepsv   = Lepsv   'ET' ('PROG' epsv)   ;
  335.   Lepsv_c = Lepsv_c 'ET' ('PROG' epsv_c) ;
  336. *
  337. 'FIN' BLOC ;
  338. *
  339.   'SI' (ERMAX1 '&lt;EG' 1E-5)               ;
  340.      'ERRE' 0                            ;
  341.   'SINO'                                 ;
  342.      'MESS' 'POROSITE NON CONSTANTE'     ;
  343.      'MESS' 'ERREUR MAXIMALE POROSITE :' 
  344.              ERMAX1 '> 1E-5 '            ; 
  345.      'ERRE' 5                            ;
  346.   'FINS'                                 ;
  347. *
  348. 'SI' ( ERMAX2 '&lt;EG' 0.05)                                ;
  349.    'ERRE' 0                                              ;
  350. 'SINO'                                                   ;
  351.    'MESS' 'ERREUR MAXIMALE DEFORMATION VISCOPLASTIQUE :' 
  352.            ERMAX2 '> 0.05 '                              ; 
  353.    'ERRE' 5                                              ;
  354. 'FINS'                                                   ;
  355. *
  356. *
  357. 'SI' GRAPH ;
  358.  'TITR' 'Deformations planes general. : Fonction de couplage dynamique';
  359.  EVTETA    = 'EVOL' 'MANU' 'Temps' Lzeit 'TETA' Lteta   ;
  360.  EVTETA_C  = 'EVOL' 'MANU' 'Temps' Lzeit 'TETA' Lteta_c ;
  361.  TAD     = TABLE                                        ;
  362.  TAD . 1 = 'TIRC'                                       ;
  363.  TAD . 2 = 'TIRR'                                       ; 
  364.  TAD . 'TITRE' = TABLE                                  ;
  365.  TAD . 'TITRE' . 1 = 'TETA THEORIQUE'                   ;
  366.  TAD . 'TITRE' . 2 = 'TETA CALCULEE'                    ;
  367.  'DESS' (EVTETA 'ET' EVTETA_C) TAD 'LEGE'               ;
  368. *
  369.   'TITR' 'Deformations planes general. : Deformation viscoplastique' ;
  370.   EVEPSV    = 'EVOL' 'MANU' 'Temps' Lzeit 'EPSV' Lepsv               ;
  371.   EVEPSV_C  = 'EVOL' 'MANU' 'Temps' Lzeit 'EPSV' Lepsv_c             ;
  372.   TAD     = TABLE                                                    ;
  373.   TAD . 1 = 'TIRC'                                                   ;
  374.   TAD . 2 = 'TIRR'                                                   ; 
  375.   TAD . 'TITRE' = TABLE                                              ;
  376.   TAD . 'TITRE' . 1 = 'EPSV THEORIQUE'                               ;
  377.   TAD . 'TITRE' . 2 = 'EPSV CALCULEE'                                ;
  378.   'DESS' (EVEPSV 'ET' EVEPSV_C) TAD 'LEGE'                           ;
  379. 'FINS' ;
  380. *
  381. 'FIN';
  382.  
  383.  
  384.  
  385.  
  386.  
  387.  
  388.  
  389.  
  390.  
  391.  
  392.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales