Télécharger la plaquette Cast3M


fr en

Télécharger gatt_3d.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  gatt_3d.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. *     Test gatt_3d.dgibi: Jeux de données            
  6. *     ---------------------------------------         
  7. * 
  8. 'OPTI' 'DIME' 3 'MODE' 'TRID'        ;
  9. 'OPTI' 'ELEM' 'CU20'                 ;
  10. 'OPTI' 'TRAC' 'PSC'                  ;
  11. 'TEMPS' 'ZERO'                       ;
  12. L = 'MOT' LIST ; F = 'MOT' FIN       ;
  13. *                                                                               
  14. *******************************************************          
  15. *                TEST DE VALIDATION                   *
  16. *                ------------------                   *
  17. *               MODELE GATT_MONERIE                   *
  18. *  UO2 STANDARD COMPRESSIBLE AVEC COUPLAGE STATIQUE   *
  19. *                                                     *
  20. *  MAILLAGE:                                          *
  21. *     EPROUVETTE PART DE CAMEMBERT                    * 
  22. *                                                     *
  23. *  CHARGEMENT:                                        *
  24. *     DEPLACEMENT VERTICAL IMPOSE                     *
  25. *       TRACTION - COMPRESSION                        *
  26. *     TEMPERATURE CONSTANTE                           *
  27. *     DENSITE DE FISSIONS CONSTANTE                   *
  28. *     PRIMAIRE - MECANISMES 1 ET 2 - IRRADIATION      * 
  29. *     DENSIFICATION - GONFLEMENT                      *
  30. *******************************************************          
  31. *
  32. * repertoire des fichiers "divers"
  33. DIVERS = VENV 'CASTEM_DIVERS';
  34. *
  35. GRAPH    = FAUX ;
  36. LISTCOUR = VRAI ;
  37. *
  38. NA   = 1                             ;
  39. NR   = 1                             ;
  40. H    = 6.2e-3                        ;
  41. D    = 5.e-3                         ;
  42. R    = D/2.                          ;
  43. HS2  = H/2.                          ;
  44. *
  45. OO   = 0.     0.         0.          ;
  46. A1   = R      0.         0.          ;
  47. A2   = R      0.         HS2         ;
  48. A3   = 0.     0.         HS2         ;
  49. *
  50. LB   = 'DROIT' NR  OO A1             ;
  51. LD   = 'DROIT' NA  A1 A2             ;
  52. LH   = 'DROIT' NR  A2 A3             ;
  53. LG   = 'DROIT' NA  A3 OO             ;
  54. *
  55. SU1  = 'DALL' LB  LD  LH  LG  'PLAN' ;
  56. *
  57. SU2 = SU1 'TOUR' 30. OO A3 ;
  58. VOL1 = 'VOLU' 1 SU1 SU2 ;
  59. 'ELIM' (D/1000.) VOL1 ;
  60. VOL1 = 'REGE' VOL1 ;
  61. SUA = 'POIN' ('COOR' 2 VOL1) 'INFERIEUR' (D/1000.) ;
  62. SUB = 'POIN' ('COOR' 3 VOL1) 'INFERIEUR' (D/1000.) ;
  63. SUH = 'POIN' ('COOR' 3 VOL1) 'SUPERIEUR' (HS2 - (D/1000.)) ;
  64. LG = VOL1 'POIN'  'DROIT' OO A3 (D/1000) ; 
  65. *
  66. MODL1= MODE VOL1 MECANIQUE ELASTIQUE VISCOPLASTIQUE GATT_MONERIE ;
  67. *
  68. * ----------------------*
  69. * Materiau GATT_MONERIE *
  70. * ----------------------*
  71. TE1  = 1400. + 273.  ;
  72. PO   = 4.52E-2       ;
  73. DF1  = 1.E18         ;
  74. TA = @GATTPAR ('CHAINE' DIVERS '/fichier_gatt') ;
  75. *
  76. * fluage primaire rendu significatif pour UO2 standard
  77.  TA.'KPUO'   = 1E3 * TA.'KPUO' ;
  78. * 
  79. MATREE = MATE MODL1 'YOUN' (TA.'YOUN') ; 
  80. PP = 'MANU' 'CHML' MODL1 'T' TE1 'PORO' PO RIGIDITE ; 
  81. EE = 'VARI' 'NUAG' MODL1 MATREE PP ;
  82. *
  83. MATR11 = 'MATE' MODL1  'YOUN' EE  'NU' 0.3  'RHO' 10950.  'ALPH' 0. 'TALP' 0. 'TREF' 1.;
  84. *
  85. MATR12 = 'MATE' MODL1 
  86.  'R'    (TA.'R')    'DG0' (TA.'DG0') 'DG'  (TA.'DG')
  87.  'K1'   (TA.'K1')   'M1'  (TA.'M1')  'Q1'  (TA.'Q1')  'N1'   (TA.'N1') 
  88.  'K2'   (TA.'K2')   'M2'  (TA.'M2')  'Q2'  (TA.'Q2')  'N2'   (TA.'N2') 
  89.  'OMEG' (TA.'OMEG') 'H'   (TA.'H')   'Q'   (TA.'Q')   'BETA' (TA.'BETA')
  90.  'K'    (TA.'K')    'A'   (TA.'A')   'Q3'  (TA.'Q3')  'N3'   (TA.'N3')
  91.  'CR'   (TA.'CR')   'CR1' (TA.'CR1') 'CR2' (TA.'CR2') 'CR3'  (TA.'CR3');
  92. *
  93. MATR13 = 'MATE' MODL1  'KP'   (TA.'KPUO')   'AP'  (TA.'AP')
  94.                        'BP'   (TA.'BP')     'QP'  (TA.'QP') ;
  95. *
  96. MATR14 = 'MATE' MODL1 
  97.  'ADEN' (TA.'ADEN') 'KGON' (TA.'KGON') 
  98.  'POR0' (TA.'POR0') 'BUMI' (TA.'BUMI') 'EFIS' (TA.'EFIS') ;
  99. *
  100. * TYPE = 0. combustible UO2            sinon combustible AFA3GLAA
  101. * COMP = 0. combustible compressible   sinon incompressible
  102. * DYN  = 0. couplage statique          sinon dynamique
  103. *
  104. MATR1 = MATR11 'ET' MATR12 'ET' MATR13 'ET' MATR14 ;
  105. *
  106. * -----------------------------------------------------*
  107. * Conditions aux limites + deplacement impose sur CLZH *
  108. * -----------------------------------------------------*
  109. CLZB = 'BLOQ' UZ SUB                   ;
  110. CLZH = 'BLOQ' UZ SUH                   ;
  111. CLXG  = 'BLOQ' UX LG                   ;
  112. CLYG  = 'BLOQ' UY SUA                  ;
  113. CLT  = CLZB 'ET' CLZH 'ET' CLXG 'ET' CLYG ;
  114. *
  115. TMIL = 1.E6 ;
  116. TFIN = 2.E6 ;
  117. *
  118. RHO0 = 1. - TA.'POR0' ;
  119. AKBU = TA.'EFIS'*270./238./10950./RHO0*DF1 ;
  120. * CE QUI SUIT EST VRAI CAR LE FLUX DE FISSIONS EST CONSTANT 
  121. TBU = (TA.'BUMI' / AKBU) - 1. ;
  122. TTBU = ('ENTI' (TBU/10000.)) * 10000. ;
  123. *-------------------*
  124. * Instants calcules *
  125. *-------------------*
  126. 'SI' LISTCOUR ;
  127. *--------------
  128. LIST1 = 'PROG' 0   'PAS' 50  300  'PAS' 100  1000 'PAS' 1000  10000
  129.                    'PAS' 10000. TTBU
  130.                    TBU (TTBU+10000.) (TTBU+20000.)      
  131.                    'PAS' 10000. TMIL ;
  132. 'SINON' ;
  133. *--------
  134. LIST1 = 'PROG' 0   'PAS' 50  300  'PAS' 100  1000 'PAS' 1000  10000
  135.                    'PAS' 10000. TTBU
  136.                    TBU (TTBU+10000.) (TTBU+20000.)      
  137.                    'PAS' 10000. TMIL 
  138.                    'PAS' 100. (TMIL + ((TFIN - TMIL) / 200.))
  139.                    'PAS' 1000. (TMIL + ((TFIN - TMIL) / 20.))
  140.                    'PAS' 2000. (TMIL + ((TFIN - TMIL) / 4.))
  141.                    'PAS' 10000. TFIN ;
  142. 'FINSI' ;
  143. *--------
  144. * --------------------------*
  145. * Chargement en temperature *
  146. * --------------------------*
  147. CHTEMP   = 'MANU' 'CHPO' VOL1 1 'T' 1.          ;
  148. EVT      = 'EVOL' 'MANU' ('PROG' 0.  (2.*TFIN)) 
  149.                        ('PROG' TE1 TE1)         ;
  150. CHARTEMP = 'CHAR' 'T' CHTEMP EVT                ;
  151. * ---------------------------------*
  152. * Chargement en densite de fission *
  153. * ---------------------------------*
  154. CHFISS   = 'MANU' 'CHPO' VOL1 1 'DFIS' 1.       ;
  155. EVF      = 'EVOL' 'MANU' ('PROG' 0.  (2.*TFIN)) 
  156.                          ('PROG' DF1 DF1)       ;
  157. CHARFISS = 'CHAR' 'DFIS' CHFISS EVF             ;
  158. * ---------------------------------*
  159. * Chargement en deplacement impose *
  160. * ---------------------------------*
  161. DEPZ     = 'DEPI' CLZH 1                   ; 
  162. DELTAZ   = HS2/200.                        ;
  163. EVEPS    = 'EVOL' 'MANU' 
  164.           ('PROG' 0. TMIL   TFIN (2.*TFIN))
  165.           ('PROG' 0. DELTAZ 0.    0.)      ;
  166. CHARMECA = 'CHAR' 'DIMP' DEPZ EVEPS        ;
  167. *
  168. CHARTOT  = CHARMECA 'ET' CHARTEMP 'ET' CHARFISS ;
  169. * ---------------------------------------*
  170. * Variables internes initiales 'PORO'=PO *
  171. * ---------------------------------------*
  172. VAR00 = 'ZERO' MODL1 'VARINTER'                                    ;
  173. VAR01 = 'MANU' 'CHML' MODL1 'PORO' PO 
  174.                             'TYPE' 'VARIABLES INTERNES' 'STRESSES' ;
  175. VAR0 = VAR00 + VAR01                                               ;
  176. *
  177. *
  178. TAB1 = TABLE                           ;
  179. TAB1.'TEMPERATURES' = TABLE            ;
  180. TAB1.'VARIABLES_INTERNES'= TABLE       ;
  181. TAB1.'BLOCAGES_MECANIQUES' = CLT       ;
  182. TAB1.'MODELE' = MODL1                  ;
  183. TAB1.'CHARGEMENT' = CHARTOT            ;
  184. TAB1.'TEMPERATURES' . 0 = CHTEMP       ;
  185. TAB1.'VARIABLES_INTERNES' . 0 = VAR0   ; 
  186. TAB1.'CARACTERISTIQUES' = MATR1        ;
  187. TAB1.'TEMPS_CALCULES' = LIST1          ;
  188. TAB1.'TEMPS_SAUVES' = LIST1            ;
  189. *
  190. TMASAU                   = TABLE       ;
  191. tab1 . 'MES_SAUVEGARDES' = TMASAU      ;
  192. TMASAU .'DEFTO' = VRAI                 ;
  193. TMASAU .'DEFIN' = VRAI                 ;
  194. *
  195. PASAPAS TAB1                           ;
  196. *
  197. AP    = TA.'AP'        ;
  198. BP    = TA.'BP'        ;
  199. N1    = TA.'N1'        ;
  200. N2    = TA.'N2'        ;
  201.  
  202. * Facteurs multiplicatifs dus au dopage par le Chrome
  203. WC1 = 'TANH' ( (TA.'CR' - TA.'CR2') / TA.'CR3' ) ;
  204. WC1 = 1. + ( 0.5 * TA.'CR1' * (1. + WC1) )       ;
  205. CV  = 180. / PI                                  ;
  206. WC2 = 1. - ( 'COS' (CV * TA.'DG' / TA.'DG0') )   ;
  207. WC2 = 2. * (TA.'DG0'**TA.'M2') * WC2             ;
  208.  
  209. BUMI  = TA.'BUMI'      ;
  210. AKEVD = AKBU*TA.'KGON' ;
  211. ADEN  = TA.'ADEN'      ; 
  212. KGON  = TA.'KGON'      ;
  213. * -------------------------------------------------------------------*
  214. * Calcul de la cte AAAA intervenant ds le calcul de la def. de dens. *
  215. * -------------------------------------------------------------------*
  216. BUMAX0=60.D0*BUMI ;
  217. CRIT=1.D-10 ;
  218. 'REPE' BLOC 100 ;         
  219.   BUMAX = BUMI* ('EXP' (1. - (ADEN/(KGON*BUMAX0)))) ;
  220.   BUMAX = (0.2*BUMAX) + (0.8*BUMAX0) ;
  221.   TEST='ABS' ((BUMAX-BUMAX0)/BUMAX0) ;
  222.   'SI' ('<' TEST CRIT) ; 
  223.     'QUIT' BLOC ; 
  224.   'FINS' ;
  225.   BUMAX0=BUMAX ;
  226. 'FIN' BLOC ;
  227. AAAA = (-1.D0*RHO0*(ADEN-(KGON*BUMAX))) /
  228.                 ((1.D0+ADEN)*(LOG(BUMAX/BUMI)))  ;
  229. *
  230. * -----------------------*
  231. * Controle des resultats *
  232. * -----------------------*
  233. SS = TAB1 . 'CONTRAINTES'                   ;
  234. VV = TAB1 . 'VARIABLES_INTERNES'            ;
  235. IN = TAB1 . 'DEFORMATIONS_INELASTIQUES'     ;
  236. NCONT = ('DIME' (TAB1 . 'CONTRAINTES')) - 1 ; 
  237. *
  238. T1     = 0.        ;
  239. SMZZ1  = 0.        ;
  240. FF1    = TA.'POR0' ;
  241. ERMAX1 = 0.        ;
  242. ERMAX2 = 0.        ;
  243. *
  244. LTT     = 'PROG' ;
  245. LDFF    = 'PROG' ;
  246. LEVFF   = 'PROG' ;
  247. LEVP3   = 'PROG' ;
  248. LEVTH   = 'PROG' ;
  249. LEVCALC = 'PROG' ;
  250. * 
  251. 'REPE' BLOC NCONT ;
  252. *
  253. * -------------------------------------
  254. * VITESSE DE DEFORMATION THEORIQUE EVTH
  255. * -------------------------------------
  256.   T2   = 'EXTR' (TAB1.'TEMPS_SAUVES') (&BLOC + 1) ;
  257.   EVTH = DELTAZ / HS2 / TMIL                      ;
  258.   'SI' (> T2 (TMIL+0.1))                          ;
  259.     EVTH = -1. * DELTAZ / HS2 / (TFIN - TMIL)     ; 
  260.   'FINS'                                          ;
  261. * ----------------------------------------------------
  262. * SMZZ EST PREPONDERANTE DEVANT LES AUTRES CONTRAINTES
  263. * ----------------------------------------------------
  264.   SMZZ    = 'MAXI' ('EXCO' SS.&BLOC 'SMZZ') ;
  265.   SSM     = SMZZ / 3.                       ;
  266.   SSEQ    = 'ABS' SMZZ                      ;
  267. * Deviateur des contraintes
  268.   SSPRIM1 = -1. * SMZZ / 3                  ;
  269.   SSPRIM2 = -1. * SMZZ / 3                  ;
  270.   SSPRIM3 =  2. * SMZZ / 3                  ;
  271. * ---------------------------------------------
  272. * DEFORMATION VISCO-PLASTIQUE EQUIVALENTE EVPEQ
  273. * ---------------------------------------------
  274.   EVXX  = 'MAXI' ('EXCO' IN.&BLOC 'EIXX')                           ;
  275.   EVYY  = 'MAXI' ('EXCO' IN.&BLOC 'EIYY')                           ;
  276.   EVZZ  = 'MAXI' ('EXCO' IN.&BLOC 'EIZZ')                           ;
  277.   EVH   = (EVXX+EVYY+EVZZ) / 3.                                     ;
  278.   EVPEQ = ((EVXX - EVH)**2) + ((EVYY - EVH)**2) + ((EVZZ - EVH)**2) ;
  279.   EVPEQ = ((2./3.) * EVPEQ)**0.5                                    ;
  280. * ------------------------------------------
  281. * VITESSE DE DEFORMATION VISCO-PLASTIQUE EVP
  282. * ------------------------------------------
  283. *-- fluage primaire
  284. *
  285. 'SI' ('<' EVPEQ 1E-10) ; EVPEQ = 1E-10 ; 'FINSI' ;
  286. *
  287.   EVP01 = 1.5 * TA.'KPUO' * 
  288.   ('EXP' (-1.*TA.'QP'/(TA.'R'*TE1))) * 
  289.   ( (SSEQ**(AP-1)) / (EVPEQ**BP) ) * SSPRIM1 ;
  290. *
  291.   EVP02 = 1.5 * TA.'KPUO' * 
  292.   ('EXP' (-1.*TA.'QP'/(TA.'R'*TE1))) * 
  293.   ( (SSEQ**(AP-1)) / (EVPEQ**BP) ) * SSPRIM2 ;
  294. *
  295.   EVP03 = 1.5 * TA.'KPUO' * 
  296.   ('EXP' (-1.*TA.'QP'/(TA.'R'*TE1))) * 
  297.   ( (SSEQ**(AP-1)) / (EVPEQ**BP) ) * SSPRIM3 ;
  298. *
  299. *-- fluage secondaire (2 mecanismes)
  300. *
  301.   PP = 'MAXI' ('EXCO' VV.&BLOC 'PORO') ;
  302. *
  303.   A1  = (N1* (PP**(-1./N1) - 1.)**(-2.*N1/(N1+1.)))      ;
  304.   B1  = (1. + (2.*PP/3.))/ ((1. - PP) **(2.*N1/(N1+1.))) ;
  305.   AB1 = (9. * A1) / ( (4.*B1) + A1 )                     ;
  306.   BA1 = B1 / ( B1 + (A1/4.) )                            ;
  307. *
  308.   GSSEQ = ((BA1 * (SSEQ**2)) + (AB1 * (SSM**2))) ** 0.5  ;
  309. *
  310.   A2 = (N2* (PP**(-1./N2) - 1.)**(-2.*N2/(N2+1.))) ;
  311.   B2 = (1. + (2.*PP/3.))/ ((1. - PP) **(2.*N2/(N2+1.))) ;
  312. *
  313.   EVP11 = 0.5 * (TA.'K1' * (TA.'DG'**TA.'M1') * WC1 *
  314.   ('EXP' (-1.*TA.'Q1'/(TA.'R'*TE1))) * 
  315.   (((A1*((1.5*SSM)**2)) + (B1*(SSEQ ** 2)))**((N1-1.)/2.)) *
  316.   ((A1*1.5*SSM) + (3.*B1*SSPRIM1))) ; 
  317. *
  318.   EVP21 = 0.5 * (TA.'K2' * WC2 * ('EXP' (-1.*TA.'Q2'/(TA.'R'*TE1))) *
  319.   (((A2*((1.5*SSM)**2)) + (B2*(SSEQ ** 2)))**((N2-1.)/2.)) *
  320.   ((A2*1.5*SSM) + (3.*B2*SSPRIM1))) ; 
  321. *
  322.   EVP12 = 0.5 * (TA.'K1' * (TA.'DG'**TA.'M1') * WC1 *
  323.   ('EXP' (-1.*TA.'Q1'/(TA.'R'*TE1))) * 
  324.   (((A1*((1.5*SSM)**2)) + (B1*(SSEQ ** 2)))**((N1-1.)/2.)) *
  325.   ((A1*1.5*SSM) + (3.*B1*SSPRIM2))) ; 
  326. *
  327.   EVP22 = 0.5 * (TA.'K2' * WC2 * ('EXP' (-1.*TA.'Q2'/(TA.'R'*TE1))) * 
  328.   (((A2*((1.5*SSM)**2)) + (B2*(SSEQ ** 2)))**((N2-1.)/2.)) *
  329.   ((A2*1.5*SSM) + (3.*B2*SSPRIM2))) ; 
  330. *
  331.   EVP13 = 0.5 * (TA.'K1' * (TA.'DG'**TA.'M1') * WC1 *
  332.   ('EXP' (-1.*TA.'Q1'/(TA.'R'*TE1))) * 
  333.   (((A1*((1.5*SSM)**2)) + (B1*(SSEQ ** 2)))**((N1-1.)/2.)) *
  334.   ((A1*1.5*SSM) + (3.*B1*SSPRIM3))) ; 
  335. *
  336.   EVP23 = 0.5 * (TA.'K2' * WC2 * ('EXP' (-1.*TA.'Q2'/(TA.'R'*TE1))) * 
  337.   (((A2*((1.5*SSM)**2)) + (B2*(SSEQ ** 2)))**((N2-1.)/2.)) *
  338.   ((A2*1.5*SSM) + (3.*B2*SSPRIM3))) ; 
  339. *
  340.   PSI1 = TA.'K1' * WC1 * (TA.'DG'**TA.'M1')/(N1+1.) *
  341.   ('EXP' (-1.*TA.'Q1'/(TA.'R'*TE1))) * 
  342.   (((A1*((1.5*SSM)**2)) + (B1*(SSEQ ** 2)))**((N1+1.)/2.)) ;
  343. *
  344.   PSI2 = TA.'K2' * WC2/(N2+1.) * ('EXP' (-1.*TA.'Q2'/(TA.'R'*TE1))) *
  345.   (((A2*((1.5*SSM)**2)) + (B2*(SSEQ ** 2)))**((N2+1.)/2.)) ;
  346. *
  347.   EVPC1 = 0.5 * TA.'BETA' / TA.'H' * TA.'Q' * TA.'OMEG' *
  348.   (GSSEQ**(-1.*TA.'Q' - 2.)) *
  349.       (1. -
  350.   (('TANH' ((TE1 - (TA.'OMEG' * (GSSEQ**(-1.*TA.'Q'))))  / TA.'H'))**2))
  351.    * (PSI2 - PSI1) * ( ((AB1*SSM)/3.) +  (1.5*BA1*SSPRIM1) ) ;
  352. *
  353.   EVPC2 = 0.5 * TA.'BETA' / TA.'H' * TA.'Q' * TA.'OMEG' *
  354.   (GSSEQ**(-1.*TA.'Q' - 2.)) *
  355.       (1. -
  356.   (('TANH' ((TE1 - (TA.'OMEG' * (GSSEQ**(-1.*TA.'Q'))))  / TA.'H'))**2))
  357.    * (PSI2 - PSI1) * ( ((AB1*SSM)/3.) +  (1.5*BA1*SSPRIM2) ) ;
  358. *
  359.   EVPC3 = 0.5 * TA.'BETA' / TA.'H' * TA.'Q' * TA.'OMEG' *
  360.   (GSSEQ**(-1.*TA.'Q' - 2.)) *
  361.       (1. -
  362.   (('TANH' ((TE1 - (TA.'OMEG' * (GSSEQ**(-1.*TA.'Q'))))  / TA.'H'))**2))
  363.    * (PSI2 - PSI1) * ( ((AB1*SSM)/3.) +  (1.5*BA1*SSPRIM3) ) ;
  364. *
  365.   TETA = 0.5 * TA.'BETA' *
  366.       (1. + 
  367.       ('TANH' ((TE1 - (TA.'OMEG' * (GSSEQ**(-1.*TA.'Q')))) / TA.'H'))) ;
  368. *
  369.   EVP1 = EVP01 + ((1. - TETA) * EVP11) + (TETA * EVP21) + EVPC1 ; 
  370.   EVP2 = EVP02 + ((1. - TETA) * EVP12) + (TETA * EVP22) + EVPC2 ; 
  371.   EVP3 = EVP03 + ((1. - TETA) * EVP13) + (TETA * EVP23) + EVPC3 ;
  372. * -------------------------------------
  373. * VITESSE DE DEFORMATION ELASTIQUE EVEL
  374. * -------------------------------------
  375.   DSMZZ = (SMZZ - SMZZ1) / (T2 - T1) ;
  376.   EVEL = DSMZZ / ('MAXI' EE) ;
  377. * ----------------------------------
  378. * VITESSE DE DEFORMATION IRRADIATION
  379. * ----------------------------------
  380.   EVIR1 = 1.5 * TA.'A' * DF1 * (SSEQ **(TA.'N3' - 1.)) * 
  381.        ('EXP' (-1.*TA.'Q3'/(TA.'R'*TE1))) * SSPRIM1 ;
  382.   EVIR2 = 1.5 * TA.'A' * DF1 * (SSEQ **(TA.'N3' - 1.)) * 
  383.        ('EXP' (-1.*TA.'Q3'/(TA.'R'*TE1))) * SSPRIM2 ;
  384.   EVIR3 = 1.5 * TA.'A' * DF1 * (SSEQ **(TA.'N3' - 1.)) * 
  385.        ('EXP' (-1.*TA.'Q3'/(TA.'R'*TE1))) * SSPRIM3 ;
  386. * ------------------------------------
  387. * VITESSE DE DEFORMATION DENSIFICATION
  388. * ------------------------------------
  389. * CE QUI SUIT EST VRAI CAR LE FLUX DE FISSIONS EST CONSTANT
  390.   BU = AKBU * T2 ;
  391.   'SI' (BU '>' BUMI) ;
  392.     NUMER = (RHO0 * RHO0 * AKEVD) - (RHO0 * AAAA * AKEVD) +
  393.             (RHO0 * AAAA * AKEVD * ('LOG' (BU / BUMI))) -
  394.             (RHO0 * AAAA / T2) ; 
  395.     DENOM = (RHO0 + (AAAA * ('LOG' (BU / BUMI)))) * 
  396.             (RHO0 + (AAAA * ('LOG' (BU / BUMI)))) ;
  397.     EVD = -1. * (AKEVD - (NUMER/DENOM)) / 3. ;
  398.   'SINO' ;
  399.     EVD = 0. ;
  400.   'FINS' ;
  401. * ---------------------------------
  402. * VITESSE DE DEFORMATION GONFLEMENT
  403. * ---------------------------------
  404. * CE QUI SUIT EST VRAI CAR LE FLUX DE FISSIONS EST CONSTANT
  405.   EVG = AKEVD/3. ;
  406. * -------------------------------
  407. * VITESSE DE DEFORMATION SELON ZZ
  408. * -------------------------------
  409.   EVCALC = ((1.+(TA.'K'*DF1))*EVP3) + EVEL + EVIR3 + EVD + EVG ;
  410.   ECART1 = (EVCALC - EVTH) / EVTH ;
  411.   ERMAX1 = 'MAXI' ('PROG' ('ABS' ECART1) ERMAX1) ;
  412. * -------------------
  413. * VITESSE DE POROSITE
  414. * -------------------
  415.   FF = 'MAXI' ('EXCO' (VV . &BLOC) 'PORO') ;
  416.   DFF = (FF - FF1) / (T2 - T1) ; 
  417.   EVFF = (3.*EVD) + 
  418.          ((1. - FF) * (1.+(TA.'K'*DF1))*(EVP1+EVP2+EVP3)) +
  419.          ((1. - FF) * (EVIR1 + EVIR2 + EVIR3)) ;
  420.   ECART2 = ('ABS' (DFF - EVFF)) / FF ; 
  421.   ERMAX2 = 'MAXI' ('PROG' ('ABS' ECART2) ERMAX2) ;
  422. *
  423.   LTT = LTT 'ET' ('PROG' T2) ;
  424.   LEVP3 = LEVP3 'ET' ('PROG' EVP3) ;
  425.   LEVCALC = LEVCALC 'ET' ('PROG' EVCALC) ;
  426.   LEVTH = LEVTH 'ET' ('PROG' EVTH) ;
  427.   LDFF = LDFF 'ET' ('PROG' DFF) ;
  428.   LEVFF = LEVFF 'ET' ('PROG' EVFF) ;
  429. *
  430.   FF1   = FF ;      
  431.   SMZZ1 = SMZZ ;
  432.   T1 = T2 ; 
  433. *
  434. 'FIN' BLOC ;
  435. *
  436. 'SI' ( ERMAX1 '&lt;EG' 0.05 );
  437.    'ERRE' 0;
  438. 'SINO';
  439.    'MESS' 'ERREUR MAXIMALE VITESSE DEFORMATION :' 
  440.            ERMAX1 '> 0.05 ' ; 
  441.    'ERRE' 5;
  442. 'FINS';
  443. *
  444. 'SI' ( ERMAX2 '&lt;EG' 0.05 );
  445.    'ERRE' 0;
  446. 'SINO';
  447.    'MESS' 'ERREUR MAXIMALE POROSITE :' 
  448.            ERMAX2 '> 0.05 ' ; 
  449.    'ERRE' 5;
  450. 'FINS';
  451. *
  452. 'SI' GRAPH ;
  453.   'TITR' 'Tridimensionnel : Vitesses de Deformation'    ;
  454.   EVEVP  = 'EVOL' 'MANU' LTT 'Temps'   LEVP3   'Vitesse';
  455.   EVEVC  = 'EVOL' 'MANU' LTT 'Temps'   LEVCALC 'Vitesse';
  456.   EVEVTH = 'EVOL' 'MANU' LTT 'Temps'  LEVTH   'Vitesse' ;
  457.   TAD = TABLE                                           ;
  458.   TAD . 1 = 'TIRC'                                      ;
  459.   TAD . 3 = 'TIRR'                                      ; 
  460.   TAD . 'TITRE'     = TABLE                             ;
  461.   TAD . 'TITRE' . 1 = 'Viscoplastique Analytique'       ;
  462.   TAD . 'TITRE' . 2 = 'Totale Calculee'                 ;
  463.   TAD . 'TITRE' . 3 = 'Totale Analytique'               ;
  464.   'DESS' (EVEVP 'ET' EVEVC 'ET' EVEVTH) TAD 'LEGE'      ;
  465. *
  466.   'TITR' 'Tridimensionnel : Vitesses de variation de la porosite' ;
  467.   EVDFF  = 'EVOL' 'MANU' LTT 'Temps' LDFF 'Vitesse'               ;
  468.   EVEVFF = 'EVOL' 'MANU' LTT 'Temps' LEVFF 'Vitesse'              ;
  469.   TAF = TABLE                                                     ;
  470.   TAF . 2 = 'TIRR'                                                ; 
  471.   TAF . 'TITRE'     = TABLE                                       ;
  472.   TAF . 'TITRE' . 1 = 'Calculee'                                  ;
  473.   TAF . 'TITRE' . 2 =  'Analytique'                               ;
  474.   'DESS' (EVDFF 'ET' EVEVFF) TAF 'LEGE'                           ;
  475. 'FINS' ;
  476. *
  477. 'FIN';
  478.  
  479.  
  480.  
  481.  
  482.  
  483.  
  484.  
  485.  
  486.  
  487.  
  488.  
  489.  
  490.  
  491.  
  492.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales