Télécharger la plaquette Cast3M


fr en

Télécharger g_decouplage_8.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : g_decouplage_8.dgibi
  2. ****************************************************
  3. ****************************************************
  4. *                                                  *
  5. *      VERIFICATION DE LA PROCEDURE G_THETA        *
  6. *    POUR LE CALCUL DE KIII POUR UNE FISSURE       *
  7. *         PENNY-SHAPED DANS UN CYLINDRE            *
  8. *                        -                         *
  9. *    COMPARAISON ENTRE LE RESULTAT DE DECOUPLAGE   *
  10. *          EN 3D ET UNE SOLUTION ANALYTIQUE        *
  11. *                      (XFEM)                      *
  12. *                                                  *
  13. *  SOLUTION ANALYTIQUE TIREE DE :                  *
  14. *  "THE STRESS ANALYSIS OF CRACKS HANDBOOK"        * 
  15. *  TADA, PARIS AND IRWIN (2000)                    *
  16. *                                                  *
  17. ****************************************************
  18.  
  19. * I - CALCUL 3D
  20. * -------------
  21.  
  22. * OPTIONS ET BOOLEEN POUR LES TRACERS
  23. OPTI 'DIME' 3 'ELEM' 'CUB8' ;
  24. BTRAC = FAUX ;
  25.  
  26. * PROPRIETES MATERIAU
  27. YOUN1 NU1 = 2.E5 0.3 ;
  28.  
  29. * I.1 - MAILLAGE
  30. * **************
  31.  
  32. * PARAMETRES GEOMETRIQUES
  33. * LP = RAYON DE LA FISSURE
  34. * L1 = RAYON DU CYLINDRE
  35. * H1 = HAUTEUR DU CYLINDRE
  36. L1 H1 LP = 10. 15. 5. ;
  37. PRE1 = 1.E-10 ;
  38.  
  39. * RECTANGLE AUTOUR DE LA FISSURE
  40. P1 = (LP/2.) 0. 0. ;
  41. P2 = (LP/2.) (LP/2.) 0. ;
  42. P3 = (3.*LP/2.) (LP/2.) 0. ;
  43. P4 = (3.*LP/2.) 0. 0. ;
  44. N1 = 2 * 2 ;
  45. N2 = 2 * N1 ;
  46. D1 = DROI N1 P1 P2 ;
  47. D2 = DROI N2 P2 P3 ;
  48. D3 = DROI N1 P3 P4 ;
  49. DENS1 = LP / 2. / N1 ;
  50. CONT1 = D1 ET D2 ET D3 ;
  51.  
  52. * RAFFINEMENT VERS LA POINTE DE FISSURE
  53. RAPP2 = 0.2 ;
  54. DENS2 = DENS1*RAPP2 ;
  55. CONT2 = CONT1 HOMO RAPP2 (LP 0. 0.) ;
  56. S1 = CONT1 REGL CONT2 'DINI' DENS1 'DFIN' DENS2 ;
  57. CONT2 = DROI N2 CONT2 (CONT2 POIN 'INIT') ;
  58. S2 = SURF CONT2 'PLANE' ;
  59. S2 = S2 COUL 'ROUG' ;
  60. SURF1 = S1 ET S2 ;
  61. * TRAC SURF1 ;FIN ;
  62.  
  63. * DERAFFINEMENT VERS L'EXTERIEUR DU CYLINDRE
  64. RAPP3 = (L1 - (LP/2.)) / LP ;
  65. DENS3 = DENS1*RAPP3 ;
  66. CONT3 = (D2 ET D3) HOMO RAPP3 P1 ;
  67. S3 = (D2 ET D3) REGL CONT3 'DINI' DENS1 'DFIN' DENS3 ;
  68. S3 = S3 COUL 'BLEU' ;
  69. SURF1 = SURF1 ET S3 ;
  70. * TRAC SURF1 ;FIN ;
  71.  
  72. * EXTENSION VERTICALE
  73. PSUP = (COOR 2 S3) POIN 'MAXI' ;
  74. ELSUP = (CONT S3) ELEM 'APPUYE' PSUP ;
  75. H0 = MAXI (COOR 2 S3) ;
  76. DENS4 = DENS3 * H1 / H0 ;
  77. S4 = ELSUP TRAN 'DINI' DENS3 'DFIN' DENS4 (0. (H1 - H0) 0.) ;
  78. S4 = S4 COUL 'VERT' ;
  79. SURF1 = SURF1 ET S4 ;
  80. * TRAC SURF1 ;FIN ;
  81.  
  82. * DEFINITION DU VOLUME AVEC ROTA
  83. * NFRONT DOIT ETRE UN MULTIPLE DE 4
  84. NFRON = 8 ;
  85. NFRON = (NFRON / 4) * 4 ;
  86. VOLU1 = SURF1 VOLU NFRON 'ROTA' 360. (0. 1. 0.) (0. 0. 0.) ;
  87. ELIM VOLU1 PRE1 ;
  88. * TRAC 'CACH' VOLU1 'COUPE' (0. 0. 0.) (1. 0. 0.) (0. 1. 0.) ;FIN ;
  89.  
  90. * CENTRE DU CYLINDRE
  91. CERC1 = CERC NFRON 'ROTA' 360. P1  (0. 1. 0.) (0. 0. 0.) ;
  92. ELIM CERC1 VOLU1 PRE1 ;
  93. A1 = (LP/2.) / 2. ;
  94. N3 = NFRON / 4 ;
  95. DENS5 = A1 * (2.**0.5) / N3 ;
  96. CAR1 = DROI N3 (A1 0. 0.) (0. 0. A1) ;
  97. CAR1 = DROI N3 CAR1 ((0.-A1) 0. 0.) ;
  98. CAR1 = DROI N3 CAR1 (0. 0. (0.-A1)) ;
  99. CAR1 = DROI N3 CAR1 (CAR1 POIN 'INIT') ;
  100. S5 = SURF CAR1 'PLANE' ;
  101. S6 = CERC1 REGL 'DINI' DENS1 'DFIN' (DENS5) CAR1 ;
  102. SBASE = S5 ET S6 ;
  103. PL1 = (LP/2.) 0. 0. ;
  104. PL2 = (LP/2.) H1 0. ;
  105. PLIG1 = VOLU1 POIN 'DROIT' PL1 PL2 PRE1 ;
  106. LIG1 = (CHAN 'LIGNE' VOLU1) ELEM 'APPUYE' PLIG1 ;
  107. ELIM LIG1 (PL1 ET PL2) PRE1 ;
  108. LIG1 = LIG1 ELEM 'COMPRIS' PL1 PL2 ;
  109. VOLU2 = (SBASE VOLU 'GENE' LIG1) COUL 'VIOL' ;
  110. ELIM VOLU1 VOLU2 PRE1 ;
  111. * TRAC 'CACH' (VOLU1 ET VOLU2) 'COUPE' (0. 0. 0.) (1. 0. 0.) (0. 1. 0.) ;FIN ;
  112.  
  113. * DEFINITION DE LA FISSURE ET FUSION DES NOEUDS COINCIDENTS
  114. V1 = VOLU1 ET VOLU2 ;
  115. ENV1 = ENVE V1 ;
  116. V2 = V1 SYME 'PLAN' (0. 0. 0.) (1. 0. 0.) (0. 0. 1.) ;
  117. V0 = (V1 COUL 'BLEU') ET (V2 COUL 'ROUG') ;
  118. ELIM V1 V2 PRE1 ;
  119. PMED = V0 POIN 'PLAN' (0. 0. 0.) (1. 0. 0.) (0. 0. 1.) PRE1 ;
  120. X Y Z = COOR PMED ;
  121. R = ((X**2) + (Z**2))**0.5 ;
  122. PLEV = R POIN 'EGINFE' (LP + PRE1) ;
  123. LEV1 = ENV1 ELEM 'APPUYE' PLEV ;
  124. LEV1 = (LEV1 PLUS (0. 0. 0.)) COUL 'VIOL' ;
  125. LEV1 = ORIE LEV1 (0. 1. 0.) ;
  126.  
  127. * DEFINITION DU FRONT DE FISSURE
  128. FRON1 = (CONT LEV1) COUL 'VERT' ;
  129. * TRAC (LEV1 ET FRON1) ;FIN ;
  130.  
  131.  
  132. * I.2 - MODELE, MATERIAU ET CL
  133. * ****************************
  134.  
  135.  
  136. * DECOUPAGE EN ZONE XFEM ET ZONE FEM
  137. VXFEM = ENV1 ELEM 'APPUYE' PLEV ;
  138. NCOUCH = 2 ;
  139. REPE ICOUCH (NCOUCH + 1) ;
  140.     VXFEM = V0 ELEM 'APPUYE' 'LARGEMENT' VXFEM ;
  141. FIN ICOUCH ;
  142. VXFEM = VXFEM COUL 'VERT' ;
  143. VFEM = (DIFF V0 VXFEM) COUL 'VIOL' ;
  144. P1 P2 P3 = (0. 0. 0.) (1. 0. 0.) (0. 1. 0.) ;
  145. SI BTRAC ;
  146.     TRAC 'CACH' (VFEM ET VXFEM) 'COUPE' P1 P2 P3 ;
  147. FINSI ;
  148.  
  149. * MODELE ET MATERIAU ZONE XFEM
  150. MOD1 = MODE VXFEM 'MECANIQUE' 'ELASTIQUE' 'XC8R' ;
  151. MAT1 = MATE MOD1 'YOUN' YOUN1 'NU' NU1 ;
  152. PSI0 PHI0 = PSIP VXFEM LEV1 'DEUX' FRON1 ;
  153. CHE1X = TRIE MOD1 PSI0 PHI0 ;
  154. RELAX = RELA MOD1 ;
  155.  
  156. * MODELE ET MATERIAU ZONE FEM
  157. MOD2 = MODE VFEM 'MECANIQUE' 'ELASTIQUE' ;
  158. MAT2 = MATE MOD2 'YOUN' YOUN1 'NU' NU1 ;
  159.  
  160. MODTOT = MOD1 ET MOD2 ;
  161. MATTOT = MAT1 ET MAT2 ;
  162. RIGTOT = RIGI MATTOT MODTOT ;
  163.  
  164. * CL EN EFFORTS
  165. DV0 = ENVE V0 ;
  166. PSUP = (COOR 2 V0) POIN 'MAXI' ;
  167. SSUP = DV0 ELEM 'APPUYE' PSUP ;
  168. PINF = (COOR 2 V0) POIN 'MINI' ;
  169. SINF = DV0 ELEM 'APPUYE' PINF ;
  170. CHPO1 = PRES 'MASS' MODTOT 1. (SSUP ET SINF) ;
  171. X Y Z = COOR (SSUP ET SINF) ;
  172. CHPO2 = (NOMC 'FX' X) + (NOMC 'FY' (0.*Y)) + (NOMC 'FZ' Z) ;
  173. MFOR = MOTS 'FX' 'FY' 'FZ' ;
  174. NCHPO2 = (PSCA CHPO2 CHPO2 MFOR MFOR)**0.5 ;
  175. CHPO2 = CHPO2 / (NCHPO2 + 1.E-30) ;
  176. T1 = PVEC CHPO1 CHPO2 MFOR MFOR MFOR ;
  177. SI BTRAC ;
  178.     VEC1 = VECT T1 'FORC' ;
  179.     TRAC 'CACH' VEC1 V0 ;
  180. FINSI ;
  181.  
  182. * CL EN DEPLACEMENTS
  183. P1 = PSUP POIN 'DROIT' (0. 0. 0.) (0. 1. 0.) PRE1 ;
  184. P2 = PINF POIN 'DROIT' (0. 0. 0.) (0. 1. 0.) PRE1 ;
  185. PMIL = DV0 POIN 'PLAN' (0. 0. 0.) (1. 0. 0.) (0. 0. 1.) PRE1 ;
  186. P3 = (COOR 1 PMIL) POIN 'MAXI' ;
  187. P4 = (COOR 1 PMIL) POIN 'MINI' ;
  188. BLOQ1 = BLOQ (MOTS 'UX' 'UZ') (P1 ET P2) ;
  189. BLOQ3 = BLOQ 'UZ' P3 ;
  190. RELA1 = RELA 'UY' P1 + 'UY' P2 ;
  191. BLOQ0 = BLOQ1 ET BLOQ3 ET RELA1 ;
  192.  
  193.  
  194. * I.3 - RESOLUTION PUIS G-THETA
  195. * *****************************
  196.  
  197. * RESO
  198. U1 = RESO (RIGTOT ET BLOQ0 ET RELAX) T1 ;
  199.  
  200. * G_THETA
  201. SUPTAB = TABL ;
  202. SUPTAB.'MODELE' = MODTOT ;
  203. SUPTAB.'CARACTERISTIQUES' = MATTOT ;
  204. SUPTAB.'BLOCAGES_MECANIQUES' = BLOQ0 ;
  205. SUPTAB.'CHARGEMENTS_MECANIQUES' = T1 ;
  206. SUPTAB.'OBJECTIF' = MOT 'DECOUPLAGE' ;
  207. SUPTAB.'PSI' = PSI0 ;
  208. SUPTAB.'PHI' = PHI0 ;
  209. SUPTAB.'COUCHE' = NCOUCH ;
  210. SUPTAB.'FRONT_FISSURE' = FRON1 ;
  211. SUPTAB.'SOLUTION_RESO' = U1 ;
  212.  
  213. G_THETA SUPTAB ;
  214.  
  215. K3D = VIDE 'EVOLUTIO' ;
  216. REPE IMOD 3 ;
  217.     MMOD = EXTR 'III' 1 &IMOD ;
  218.     EVO1 = EVOL 'CHPO' SUPTAB.'CHPO_RESULTATS' (CHAI 'K' &IMOD) FRON1 ;
  219.     K3D = K3D ET (EXTR EVO1 'COUR' 1) ;
  220. FIN IMOD ;
  221.  
  222.  
  223. * II - SOLUTION ANALYTIQUE
  224. * ------------------------
  225.  
  226. SFRO = EXTR (EXTR K3D 'COUR' 1) 'ABSC' ;
  227. * KI ET KII DOIVENT ETRE NULS
  228. KA1 = 0.*SFRO ;
  229. KA2 = 0.*SFRO ;
  230. A B = LP L1 ;
  231. T = 2.*PI*(B**3)/3. ;
  232. TAUN = 2.*T*A / (PI*((B**4) - (A**4))) ;
  233. ASB = A / B ;
  234. GASB = 4 / (3.*PI) * (1. + (0.5*ASB) + (3./8.*(ASB**2)) + (5./16.*(ASB**3)) 
  235.                             - (93./128.*(ASB**4)) + (0.038*(ASB**5))) ;
  236. F1ASB = GASB * ((1. - ASB)**0.5) ;
  237. KAIII = TAUN * ((PI*A)**0.5) *F1ASB ;
  238. * KIII EST CONSTANT
  239. KA3 = (0.*SFRO) + KAIII ;
  240. KANA = EVOL 'MANU' SFRO KA1 ;
  241. KANA = KANA ET (EVOL 'MANU' SFRO KA2) ;
  242. KANA = KANA ET (EVOL 'MANU' SFRO KA3) ;
  243.  
  244.  
  245. * III - COMPARAISON
  246. * -----------------
  247.  
  248. * PRECISIONS ATTENDUES POUR L'ERREUR RELATIVE EN NORME L2
  249. L_PREC = PROG 0.01 0.01 0.04 ;
  250. TAB1 = TABL ;
  251. * LES RESULTATS NUMERIQUES SONT IDENTIFIES AVEC DES CARRES
  252. TAB1.(1) = CHAI 'MARQ CARR' ;
  253. IND1 = 2 ;
  254. IND2 = (NBEL FRON1) - 1 ;
  255. REPE IMOD 3 ;
  256. * BOUCLE SUR LES MODES
  257.     SAUT 'LIGNE' ;
  258.     MMOD = EXTR 'III' 1 &IMOD ;
  259.     KNUM1 = (EXTR K3D 'COUR' &IMOD) COUL 'BLEU' ;
  260.     KANA1 = (EXTR KANA 'COUR' &IMOD) COUL 'ROUG' ;
  261.     SI BTRAC ;
  262.         DESS (KNUM1 ET KANA1) TAB1 'TITR' (CHAI 'K' &IMOD) ;
  263.     FINSI ;
  264. * ERREUR EN NORME L2
  265.     ERR1 = (INTG ((KNUM1 - KANA1)**2) 'INDI' IND1 IND2)**0.5 ;
  266.     PRE1 = EXTR L_PREC &IMOD ;
  267. * VALEUR DE COMPARAISON POUR L'ERREUR RELATIVE
  268.     CRI1 = ((INTG (KANA1**2) 'INDI' IND1 IND2)**0.5) * PRE1 ;
  269.     SI (EGA CRI1 0.) ;
  270.         CRI1 = CRI1 + 1.E-8 ;
  271.     FINSI ;
  272.     MESS 'ERREUR SUR LE CALCUL DE K' MMOD ' :'*30 ERR1 ;
  273.     MESS 'CRITERE' ' :'*30 CRI1 ;
  274.     SI (ERR1 >EG CRI1) ;
  275.         MESS 'ERREUR : L''ERREUR SUR K' MMOD ' DEPASSE LE CRITERE' ;
  276.         ERRE 5 ;
  277.     FINSI ;
  278. FIN IMOD ;
  279.  
  280. FIN ;
  281.  
  282.  
  283.  
  284.  
  285.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales