Télécharger la plaquette Cast3M


fr en

Télécharger g_decouplage_7.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : g_decouplage_7.dgibi
  2. ****************************************************
  3. ****************************************************
  4. *                                                  *
  5. *      VERIFICATION DE LA PROCEDURE G_THETA        *
  6. *    POUR LE CALCUL DE KIII POUR UNE FISSURE       *
  7. *         PENNY-SHAPED DANS UN CYLINDRE            *
  8. *                        -                         *
  9. *    COMPARAISON ENTRE LE RESULTAT DE DECOUPLAGE   *
  10. *          EN 3D ET UNE SOLUTION ANALYTIQUE        *
  11. *                (ELEMENTS STANDARDS)              *
  12. *                                                  *
  13. *  SOLUTION ANALYTIQUE TIREE DE :                  *
  14. *  "THE STRESS ANALYSIS OF CRACKS HANDBOOK"        * 
  15. *  TADA, PARIS AND IRWIN (2000)                    *
  16. *                                                  *
  17. ****************************************************
  18.  
  19. * I - CALCUL 3D
  20. * -------------
  21.  
  22. * OPTIONS ET BOOLEEN POUR LES TRACERS
  23. OPTI 'DIME' 3 'ELEM' 'CUB8' ;
  24. BTRAC = FAUX ;
  25.  
  26. * PROPRIETES MATERIAU
  27. YOUN1 NU1 = 2.E5 0.3 ;
  28.  
  29. * I.1 - MAILLAGE
  30. * **************
  31.  
  32. * PARAMETRES GEOMETRIQUES
  33. * LP = RAYON DE LA FISSURE
  34. * L2 = RAYON DU CYLINDRE
  35. * H2 = HAUTEUR DU CYLINDRE
  36. L1 H1 LP = 10. 5. 5. ;
  37. L2 = L1 + 0.8 ;
  38. H2 = H1 + 11. ;
  39. DENS1 = 0.75 ;
  40. DENS DENS1 ;
  41.  
  42. * RECTANGLE AUTOUR DE LA FISSURE
  43. P1 = DENS1 0. 0. ;
  44. P2 = DENS1 H1 0. ;
  45. P3 = L1 H1 0. ;
  46. P4 = L1 0. 0. ;
  47. D1 = DROI P1 P2 ;
  48. S1 = D1 TRAN ((0.-DENS1) 0. 0.) ;
  49. N1 = ((ENTI ((L1 - DENS1) / DENS1)) / 2) * 2 ;
  50. D2 = DROI N1 P2 P3 ;
  51. D3 = DROI P3 P4 ;
  52.  
  53. * DERAFFINEMENT
  54. P5 = (LP - DENS1) 0. 0. ;
  55. P6 = (LP - DENS1) DENS1 0. ;
  56. P7 = (LP + DENS1) DENS1 0. ;
  57. P8 = (LP + DENS1) 0. 0. ;
  58. D4 = DROI (NBEL D1) P5 P6 ;
  59. D5 = DROI (NBEL D2) P6 P7 ;
  60. D6 = DROI (NBEL D3) P7 P8 ;
  61. DENS2 = DENS1 / H1 ;
  62. S2 = (D1 ET D2 ET D3) REGL (D4 ET D5 ET D6) 'DINI' DENS1 'DFIN' DENS2 ;
  63.  
  64. * DERNIERE RANGEE D'ELEMENTS AU NIVEAU DE L'AXE DU CYLINDRE
  65. * (SI ON NE FAIT PAS CA IL Y A DES PROBLEMES LORS DE REGE)
  66. PP = LP 0. 0. ;
  67. D7 = DROI (N1/2) (DROI (N1/2) P8 PP) P5 ;
  68. S3 = DALL D4 D5 D6 D7 'PLAN' ;
  69. SURF1 = S1 ET S2 ET S3 ;
  70.  
  71. * EXTENSIONS HORIZONTALE ET VERTICALE
  72. PSUP = (COOR 2 SURF1) POIN 'MAXI' ;
  73. ELSUP = (CONT SURF1) ELEM 'APPUYE' PSUP ;
  74. S4 = ELSUP TRAN (0. (H2 - H1) 0.) ;
  75. SURF1 = SURF1 ET S4 ;
  76. PDROI = (COOR 1 SURF1) POIN 'MAXI' ;
  77. ELDROI = (CONT SURF1) ELEM 'APPUYE' PDROI ;
  78. S5 = ELDROI TRAN ((L2 - L1) 0. 0.) ;
  79. SURF1 = SURF1 ET S5 ;
  80.  
  81. * DEFINITION DU VOLUME AVEC ROTA
  82. NFRON = 8 ;
  83. VOLU1 = SURF1 VOLU NFRON 'ROTA' 360. (0. 1. 0.) (0. 0. 0.) ;
  84. * ON APPELLE ELIM PUIS ON FAIT REGE POUR OBTENIR DES PRISMES SUR L'AXE
  85. ELIM VOLU1 1.E-10 ;
  86. VOLU1 = REGE VOLU1 ;
  87. VOLU2 = VOLU1 SYME 'PLAN' (0. 0. 0.) (1. 0. 0.) (0. 0. 1.) ;
  88. OMEGA1 = VOLU1 ET VOLU2 ;
  89.  
  90. * DEFINITION DE LA FISSURE ET FUSION DES NOEUDS COINCIDENTS
  91. * PARTIE SUP
  92. ENVE1 = ENVE VOLU1 ;
  93. POIN1 = (COOR 2 ENVE1) POIN 'MINI' ;
  94. ELEM1 = ENVE1 ELEM 'APPUYE' POIN1 ;
  95. R1 = (((COOR 1 ELEM1)**2) + ((COOR 3 ELEM1)**2))**0.5 ;
  96. POIN1 = R1 POIN 'EGINFE' (LP + 0.02) ;
  97. LVSUP = ELEM1 ELEM 'APPUYE' POIN1 ;
  98. LVSUP = ORIE LVSUP 'POIN' (0. 1. 0.) ;
  99. LIGSUP = ELEM1 DIFF LVSUP ;
  100. * PARTIE INF
  101. ENVE2 = ENVE VOLU2 ;
  102. POIN2 = (COOR 2 ENVE2) POIN 'MAXI' ;
  103. ELEM2 = ENVE2 ELEM 'APPUYE' POIN2 ;
  104. R2 = (((COOR 1 ELEM2)**2) + ((COOR 3 ELEM2)**2))**0.5 ;
  105. POIN2 = R2 POIN 'EGINFE' (LP + 0.02) ;
  106. LVINF = ELEM2 ELEM 'APPUYE' POIN2 ;
  107. LVINF = ORIE LVINF 'POIN' (0. (-1.) 0.) ;
  108. LIGINF = ELEM2 DIFF LVINF ;
  109. * ELIMINATION
  110. ELIM LIGSUP LIGINF 1.E-10 ;
  111. * DEFINITION DU FRONT DE FISSURE
  112. FRONFISS = (CONT LIGSUP) INTE (CONT LVSUP) ;
  113. SI BTRAC ;
  114.     TRAC SURF1 ;
  115.     TRAC 'CACH' (VOLU1 ET (LVSUP COUL 'ROUG') ET (LIGSUP COUL 'VERT')) ;
  116. FINSI ;
  117.  
  118.  
  119. * I.2 - MODELE, MATERIAU ET CL
  120. * ****************************
  121.  
  122. * MODELE ET MATERIAU
  123. MOD1 = MODE OMEGA1 'MECANIQUE' 'ELASTIQUE' ;
  124. MAT1 = MATE MOD1 'YOUN' YOUN1 'NU' NU1 ;
  125. RIG1 = RIGI MOD1 MAT1 ;
  126.  
  127. * CL EN EFFORTS
  128. DOMEGA1 = ENVE OMEGA1 ;
  129. PSUP = (COOR 2 OMEGA1) POIN 'MAXI' ;
  130. SSUP = DOMEGA1 ELEM 'APPUYE' PSUP ;
  131. PINF = (COOR 2 OMEGA1) POIN 'MINI' ;
  132. SINF = DOMEGA1 ELEM 'APPUYE' PINF ;
  133. CHPO1 = PRES 'MASS' MOD1 1. (SSUP ET SINF) ;
  134. X Y Z = COOR (SSUP ET SINF) ;
  135. CHPO2 = (NOMC 'FX' X) + (NOMC 'FY' (0.*Y)) + (NOMC 'FZ' Z) ;
  136. MFOR = MOTS 'FX' 'FY' 'FZ' ;
  137. NCHPO2 = (PSCA CHPO2 CHPO2 MFOR MFOR)**0.5 ;
  138. CHPO2 = CHPO2 / (NCHPO2 + 1.E-30) ;
  139. T1 = PVEC CHPO1 CHPO2 MFOR MFOR MFOR ;
  140. SI BTRAC ;
  141.     VEC1 = VECT T1 'FORC' ;
  142.     TRAC 'CACH' VEC1 OMEGA1 ;
  143. FINSI ;
  144.  
  145. * CL EN DEPLACEMENTS
  146. P1 = PSUP POIN 'DROIT' (0. 0. 0.) (0. 1. 0.) ;
  147. P2 = PINF POIN 'DROIT' (0. 0. 0.) (0. 1. 0.) ;
  148. PMIL = DOMEGA1 POIN 'PLAN' (0. 0. 0.) (1. 0. 0.) (0. 0. 1.) ;
  149. P3 = (COOR 1 PMIL) POIN 'MAXI' ;
  150. P4 = (COOR 1 PMIL) POIN 'MINI' ;
  151. BLOQ1 = BLOQ (MOTS 'UX' 'UZ') (P1 ET P2) ;
  152. BLOQ3 = BLOQ 'UZ' P3 ;
  153. RELA1 = RELA 'UY' P1 + 'UY' P2 ;
  154. BLOQ0 = BLOQ1 ET BLOQ3 ET RELA1 ;
  155.  
  156.  
  157. * I.3 - RESOLUTION PUIS G-THETA
  158. * *****************************
  159.  
  160. * RESO
  161. U1 = RESO (RIG1 ET BLOQ0) T1 ;
  162.  
  163. * G_THETA
  164. SUPTAB = TABL ;
  165. SUPTAB.'MODELE' = MOD1 ;
  166. SUPTAB.'CARACTERISTIQUES' = MAT1 ;
  167. SUPTAB.'BLOCAGES_MECANIQUES' = BLOQ0 ;
  168. SUPTAB.'CHARGEMENTS_MECANIQUES' = T1 ;
  169. SUPTAB.'OBJECTIF' = MOT 'DECOUPLAGE' ;
  170. SUPTAB.'LEVRE_SUPERIEURE' = LVSUP ;
  171. SUPTAB.'LEVRE_INFERIEURE' = LVINF ;
  172. SUPTAB.'COUCHE' = 3 ;
  173. SUPTAB.'FRONT_FISSURE' = FRONFISS ;
  174. SUPTAB.'SOLUTION_RESO' = U1 ;
  175.  
  176. G_THETA SUPTAB ;
  177.  
  178. K3D = VIDE 'EVOLUTIO' ;
  179. REPE IMOD 3 ;
  180.     MMOD = EXTR 'III' 1 &IMOD ;
  181.     EVO1 = EVOL 'CHPO' SUPTAB.'CHPO_RESULTATS' (CHAI 'K' &IMOD) FRONFISS ;
  182.     K3D = K3D ET (EXTR EVO1 'COUR' 1) ;
  183. FIN IMOD ;
  184.  
  185.  
  186. * II - SOLUTION ANALYTIQUE
  187. * ------------------------
  188.  
  189. SFRO = EXTR (EXTR K3D 'COUR' 1) 'ABSC' ;
  190. * KI ET KII DOIVENT ETRE NULS
  191. KA1 = 0.*SFRO ;
  192. KA2 = 0.*SFRO ;
  193. A B = LP L2 ;
  194. T = 2.*PI*(B**3)/3. ;
  195. TAUN = 2.*T*A / (PI*((B**4) - (A**4))) ;
  196. ASB = A / B ;
  197. GASB = 4 / (3.*PI) * (1. + (0.5*ASB) + (3./8.*(ASB**2)) + (5./16.*(ASB**3)) 
  198.                             - (93./128.*(ASB**4)) + (0.038*(ASB**5))) ;
  199. F1ASB = GASB * ((1. - ASB)**0.5) ;
  200. KAIII = TAUN * ((PI*A)**0.5) *F1ASB ;
  201. * KIII EST CONSTANT
  202. KA3 = (0.*SFRO) + KAIII ;
  203. KANA = EVOL 'MANU' SFRO KA1 ;
  204. KANA = KANA ET (EVOL 'MANU' SFRO KA2) ;
  205. KANA = KANA ET (EVOL 'MANU' SFRO KA3) ;
  206.  
  207.  
  208. * III - COMPARAISON
  209. * -----------------
  210.  
  211. * PRECISIONS ATTENDUES POUR L'ERREUR RELATIVE EN NORME L2
  212. L_PREC = PROG 0.01 0.01 0.02 ;
  213. TAB1 = TABL ;
  214. * LES RESULTATS NUMERIQUES SONT IDENTIFIES AVEC DES CARRES
  215. TAB1.(1) = CHAI 'MARQ CARR' ;
  216. REPE IMOD 3 ;
  217. * BOUCLE SUR LES MODES
  218.     SAUT 'LIGNE' ;
  219.     MMOD = EXTR 'III' 1 &IMOD ;
  220.     KNUM1 = (EXTR K3D 'COUR' &IMOD) COUL 'BLEU' ;
  221.     KANA1 = (EXTR KANA 'COUR' &IMOD) COUL 'ROUG' ;
  222.     SI BTRAC ;
  223.         DESS (KNUM1 ET KANA1) TAB1 'TITR' (CHAI 'K' &IMOD) ;
  224.     FINSI ;
  225. * ERREUR EN NORME L2
  226.     ERR1 = (INTG ((KNUM1 - KANA1)**2))**0.5 ;
  227.     PRE1 = EXTR L_PREC &IMOD ;
  228. * VALEUR DE COMPARAISON POUR L'ERREUR RELATIVE
  229.     CRI1 = ((INTG (KANA1**2))**0.5) * PRE1 ;
  230.     SI (EGA CRI1 0.) ;
  231.         CRI1 = CRI1 + 1.E-8 ;
  232.     FINSI ;
  233.     MESS 'ERREUR SUR LE CALCUL DE K' MMOD ' :'*30 ERR1 ;
  234.     MESS 'CRITERE' ' :'*30 CRI1 ;
  235.     SI (ERR1 >EG CRI1) ;
  236.         MESS 'ERREUR : L''ERREUR SUR K' MMOD ' DEPASSE LE CRITERE' ;
  237.         ERRE 5 ;
  238.     FINSI ;
  239. FIN IMOD ;
  240.  
  241. FIN ;
  242.  
  243.  
  244.  
  245.  
  246.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales