Accueil | Cast3M

* fichier : g_decouplage_2.dgibi
****************************************************
****************************************************
*                                                  *
*      VERIFICATION DE LA PROCEDURE G_THETA        *
*    POUR LE CALCUL DES FIC POUR UNE FISSURE       *
*         PENNY-SHAPED DANS UN CYLINDRE            *
*                        -                         *
*     VERIFICATION DU CALCUL DE KII ET KIII VIA    *
*   DECOUPLAGE EN 3D AVEC UNE SOLUTION ANALYTIQUE  *
*                                                  *
*  SOLUTION ANALYTIQUE TIREE DE :                  *
*  "PENNY-SHAPED CRACKS", GUIDERA ET LARDNER 1974  *
*                                                  *
****************************************************
 
* I - CALCUL 3D COMPLET
* ---------------------
 
* OPTIONS ET BOOLEEN POUR LES TRACERS
OPTI 'DIME' 3 'ELEM' 'CUB8' ;
BTRAC = FAUX ;
 
* MAILLAGE AUTOUR DE LA FISSURE
L1 H1 LP = 10. 5. 5. ;
L2 = L1 + 10. ;
H2 = H1 + 5. ;
DENS1 = 0.85 ;
DENS DENS1 ;
 
P1 = DENS1 0. 0. ;
P2 = DENS1 H1 0. ;
P3 = L1 H1 0. ;
P4 = L1 0. 0. ;
D1 = DROI P1 P2 ;
S1 = D1 TRAN ((0.-DENS1) 0. 0.) ;
N1 = ((ENTI ((L1 - DENS1) / DENS1)) / 2) * 2 ;
D2 = DROI N1 P2 P3 ;
D3 = DROI P3 P4 ;
 
P5 = (LP - DENS1) 0. 0. ;
P6 = (LP - DENS1) DENS1 0. ;
P7 = (LP + DENS1) DENS1 0. ;
P8 = (LP + DENS1) 0. 0. ;
D4 = DROI (NBEL D1) P5 P6 ;
D5 = DROI (NBEL D2) P6 P7 ;
D6 = DROI (NBEL D3) P7 P8 ;
DENS2 = DENS1 / H1 ;
S2 = (D1 ET D2 ET D3) REGL (D4 ET D5 ET D6) 'DINI' DENS1 'DFIN' DENS2 ;
 
PP = LP 0. 0. ;
D7 = DROI (N1/2) (DROI (N1/2) P8 PP) P5 ;
S3 = DALL D4 D5 D6 D7 'PLAN' ;
SURF1 = S1 ET S2 ET S3 ;
 
PSUP = (COOR 2 SURF1) POIN 'MAXI' ;
ELSUP = (CONT SURF1) ELEM 'APPUYE' PSUP ;
S4 = ELSUP TRAN (0. (H2 - H1) 0.) ;
SURF1 = SURF1 ET S4 ;
PDROI = (COOR 1 SURF1) POIN 'MAXI' ;
ELDROI = (CONT SURF1) ELEM 'APPUYE' PDROI ;
S5 = ELDROI TRAN ((L2 - L1) 0. 0.) ;
SURF1 = SURF1 ET S5 ;
 
NFRON = 18 ;
VOLU1 = SURF1 VOLU NFRON 'ROTA' 360. (0. 1. 0.) (0. 0. 0.) ;
ELIM VOLU1 1.E-10 ;
VOLU1 = REGE VOLU1 ;
VOLU2 = VOLU1 SYME 'PLAN' (0. 0. 0.) (1. 0. 0.) (0. 0. 1.) ;
OMEGA1 = VOLU1 ET VOLU2 ;
 
* DEFINITION DE LA FISSURE ET FUSION DES NOEUDS COINCIDENTS
* PARTIE SUP
ENVE1 = ENVE VOLU1 ;
POIN1 = (COOR 2 ENVE1) POIN 'MINI' ;
ELEM1 = ENVE1 ELEM 'APPUYE' POIN1 ;
R1 = (((COOR 1 ELEM1)**2) + ((COOR 3 ELEM1)**2))**0.5 ;
POIN1 = R1 POIN 'EGINFE' (LP + 0.02) ;
LVSUP = ELEM1 ELEM 'APPUYE' POIN1 ;
LVSUP = ORIE LVSUP 'POIN' (0. 1. 0.) ;
LIGSUP = ELEM1 DIFF LVSUP ;
* PARTIE INF
ENVE2 = ENVE VOLU2 ;
POIN2 = (COOR 2 ENVE2) POIN 'MAXI' ;
ELEM2 = ENVE2 ELEM 'APPUYE' POIN2 ;
R2 = (((COOR 1 ELEM2)**2) + ((COOR 3 ELEM2)**2))**0.5 ;
POIN2 = R2 POIN 'EGINFE' (LP + 0.02) ;
LVINF = ELEM2 ELEM 'APPUYE' POIN2 ;
LVINF = ORIE LVINF 'POIN' (0. (-1.) 0.) ;
LIGINF = ELEM2 DIFF LVINF ;
* ELIMINATION
ELIM LIGSUP LIGINF 1.E-10 ;
* DEFINITION DU FRONT DE FISSURE
FRONFISS = (CONT LIGSUP) INTE (CONT LVSUP) ;
SI BTRAC ;
    TRAC SURF1 ;
    TRAC 'CACH' (VOLU1 ET (LVSUP COUL 'ROUG') ET (LIGSUP COUL 'VERT')) ;
FINSI ;
 
* MODELE ET MATERIAU
MOD1 = MODE OMEGA1 'MECANIQUE' 'ELASTIQUE' ;
YOUN1 NU1 = 2.E5 0.3 ;
MAT1 = MATE MOD1 'YOUN' YOUN1 'NU' NU1 ;
RIG1 = RIGI MOD1 MAT1 ;
 
* CL EN EFFORTS
SIG0 = ZERO MOD1 'CONTRAIN' ;
SIG1 = MANU 'CHML' MOD1 'SMXY' 1. 'STRESSES' ;
SIG2 = SIG0 + SIG1 ;
DOMEGA1 = ENVE OMEGA1 ;
DOMEGA1 = DIFF DOMEGA1 (LVSUP ET LVINF) ;
T1 = REDU (BSIG MOD1 SIG2) DOMEGA1 ;
 
* CL EN DEPLACEMENTS
PSUP = (COOR 2 DOMEGA1) POIN 'MAXI' ;
P1 = PSUP POIN 'DROIT' (0. 0. 0.) (0. 1. 0.) ;
PINF = (COOR 2 DOMEGA1) POIN 'MINI' ;
P2 = PINF POIN 'DROIT' (0. 0. 0.) (0. 1. 0.) ;
PMIL = DOMEGA1 POIN 'PLAN' (0. 0. 0.) (1. 0. 0.) (0. 0. 1.) ;
P3 = (COOR 1 PMIL) POIN 'MAXI' ;
P4 = (COOR 1 PMIL) POIN 'MINI' ;
BLOQ1 = BLOQ (MOTS 'UX' 'UZ') (P1 ET P2) ;
BLOQ3 = BLOQ 'UZ' P3 ;
RELA3 = RELA 'UY' P3 + 'UY' P4 ;
BLOQ0 = BLOQ1 ET BLOQ3 ET RELA3 ;
 
* RESO
U1 = RESO (RIG1 ET BLOQ0) T1 ;
 
* G_THETA
SUPTAB = TABL ;
SUPTAB.'MODELE' = MOD1 ;
SUPTAB.'CARACTERISTIQUES' = MAT1 ;
SUPTAB.'BLOCAGES_MECANIQUES' = BLOQ0 ;
SUPTAB.'CHARGEMENTS_MECANIQUES' = T1 ;
SUPTAB.'OBJECTIF' = MOT 'DECOUPLAGE' ;
SUPTAB.'LEVRE_SUPERIEURE' = LVSUP ;
SUPTAB.'LEVRE_INFERIEURE' = LVINF ;
SUPTAB.'COUCHE' = 3 ;
SUPTAB.'FRONT_FISSURE' = FRONFISS ;
SUPTAB.'SOLUTION_RESO' = U1 ;
 
G_THETA SUPTAB ;
K3D = SUPTAB.'CHPO_RESULTATS' ;
 
* II - SOLUTION ANALYTIQUE
* ------------------------
 
KANA = TABL ;
X Y Z = COOR FRONFISS ;
COSTH = X / (((X**2) + (Z**2))**0.5) ;
SINTH = Z / (((X**2) + (Z**2))**0.5) ;
KII = 2. / PI * ((PI * LP)**0.5) * (2./(2.-NU1)) * COSTH ;
KIII = 0. - (2./PI * ((PI * LP)**0.5) * (2.*(1.-NU1)/(2.-NU1)) * SINTH) ;
KANA = (NOMC 'K1' (0.*KII)) + (NOMC 'K2' KII) + (NOMC 'K3' KIII) ;
 
 
* III - COMPARAISON
* -----------------
 
EK3D = VIDE 'EVOLUTIO' ;
EKANA = VIDE 'EVOLUTIO' ;
REPE IMOD 3 ;
        MMOD = CHAI 'K' &IMOD ;
        EVO1 = EVOL 'BLEU' 'CHPO' K3D MMOD FRONFISS ;
        EVO2 = EVOL 'CHPO' KANA MMOD FRONFISS ;
        EK3D = EK3D ET (EXTR EVO1 'COUR' 1) ;
        EKANA = EKANA ET (EXTR EVO2 'COUR' 1) ;
FIN IMOD ;
SI BTRAC ;
        TMARQ = TABL ;
        CHAI1 = CHAI 'MARQ CARR' ;
        TMARQ.(1) TMARQ.(2) TMARQ.(3) = CHAI1 CHAI1 CHAI1 ;
    DESS (EK3D ET EKANA) TMARQ ;
FINSI ;
 
ACCEPT = TABL ;
ACCEPT.'K1' ACCEPT.'K2' ACCEPT.'K3' = 0.01 0.03 0.02 ;
REPE IMOD 3 ;
    MMOD = CHAI 'K' &IMOD ;
    CRIT1 = MAXI (K3D - KANA) 'ABS' 'AVEC' (MOTS MMOD) ;
    SI (NEG &IMOD 1) ;
        CMAX1 = MAXI KANA 'ABS' 'AVEC' (MOTS MMOD) ;
        MESS 'ERREUR RELATIVE SUR' ' ' MMOD ' :' (CRIT1 / CMAX1 * 100.) '%' ;
    SINON ;
        CMAX1 = 1.E-10 ;
    FINSI ;
    SI (CRIT1 > (CMAX1 * ACCEPT.MMOD)) ;
        MESS 'LA SOLUTION NUMERIQUE EST TROP ELOIGNEE DE LA SOLUTION' ;
        MESS 'ANALYTIQUE POUR LE CALCUL DU FIC EN MODE' ' ' MMOD ;
        ERRE 5 ;
    FINSI ;
FIN IMOD ;
 
FIN ;