Télécharger la plaquette Cast3M


fr en

Télécharger g_c_etoile_coque_1.dgibi

Retour à la liste

Numérotation des lignes : 

  1. optio norm auto;
  2. * fichier : g_c_etoile_coque_1.dgibi
  3. ****************************************************
  4. ****************************************************
  5. *                                                  *
  6. *       VALIDATION DE LA PROCEDURE G_THETA         *
  7. *   POUR UN DEFAUT CIRCONFERENTIEL TRAVERSANT      *
  8. * DANS UN TUYAU MODELISE AVEC DES ELEMENTS COQUES  *
  9. *  SOLUTION DE REFERENCE : Ductile Fracture        *
  10. *  Handbook, A. Zahoor                             * 
  11. *                                                  *
  12. *                                                  *
  13. *  GEOMETRIE : tube                                *
  14. *                                                  *
  15. *  longueur du tube          : 3000. MM            *
  16. *  epaisseur du tube         :  17.5 MM            *
  17. *  rayon moyen du tube       :  350. MM            *
  18. *  longueur de la fissure    :   50. MM            *
  19. *                                                  *
  20. *  MATERIAU : loi de Norton                        *
  21. *                                                  *
  22. *  Module d'Young         : 2.E5 MPa               *
  23. *  Coefficient de poisson : 0.3                    *
  24. *  Coefficient N (Norton) : 7                      *
  25. *  Coefficient A (Norton) : 3.E-24 /h/MPa^7        *
  26. *                                                  *
  27. *  CHARGEMENT :                                    *
  28. *                                                  *
  29. *  Traction pure          : 240.78 MPa             *
  30. *                                                  *
  31. *  SOLUTION ANALYTIQUE (APPROCHEE) :               *
  32. *                                                  *
  33. *  Intégrale C*                                    *
  34. *                C* = 2.025 kJ/m^2/h               *
  35. *                                                  *
  36. ****************************************************
  37.  
  38. * VALIDATION COMPLETE OU JUSTE FONCTIONNEMENT
  39. VALIDATION = vrai ;
  40.  
  41. * I - REALISATION DU CALCUL
  42. * -------------------------
  43.  
  44. * OPTIONS
  45. OPTI 'DIME' 3 'ELEM' 'TRI3' ;
  46.  
  47. * I.1 - MAILLAGE
  48. * **************
  49.  
  50. * GEOMETRIE :
  51. * R = RAYON
  52. * E = EPAISSEUR
  53. * L = LONGUEUR
  54. * AN = ANGLE TOTAL DE LA FISSURE (15° < AN < 150°)
  55.  
  56. R = 350. ;
  57. E = R/10. ;
  58. L = 3000. ;
  59. AN = 45. ;
  60.  
  61.  
  62. * MAILLAGE
  63. DENS1 = R/350. ;
  64. DENS (100.*DENS1) ;
  65. A = COS (AN/2.) ;
  66. B = SIN (AN/2.) ;
  67. VECT0 = (R/50.) 0. (B*R/(50.*A)) ;
  68. VECT1 = 10.*VECT0 ;
  69. C0 = 0. 0. 0. ;
  70. CI = 0. (L/10.) 0. ;
  71. CII = 0. (L/5.) 0. ;
  72. C1 = 0. L 0. ;
  73. P1 = R 0. 0. ;
  74. FF = (A*R) 0. (B*R) ;
  75. XCI = IPOL (PROG 15 20 60 90 120 150) (PROG 41 8 5 4 3 3) AN ;
  76. LIS1 = PROG 23. 40. 70. 120. XCI ;
  77. LEC1 = LECT 3 4 4 4 5 ;
  78. TF = TABL ;
  79. TL = TABL ;
  80. TP = TABL ;
  81. REPE I (DIME LIS1) ;
  82.         FAC = EXTR LIS1 &I ;
  83.         N1 = EXTR LEC1 &I ;
  84.         A1 = (-1*R/FAC) 0. 0. ;
  85.         A2 = 0. (R/FAC) 0. ;
  86.         A3 = (R/FAC) 0. 0. ;
  87.         TF.&I = ((CERC N1 A1 C0 A2 CERC N1 C0 A3) TOUR (90.-(AN/2.)) C0 CI)
  88.                 DEPL PLUS VECT1 ;
  89.         TL.&I = TF.&I PROJ 'DIRE' VECT0 'CYLI' C0 CI P1 ;
  90.         TP.(&I + 1) = TL.&I POIN 'FINAL' ;
  91.         TP.(12 - &I) = TL.&I POIN 'INITIAL' ;
  92. FIN I ;
  93. P12 = (-1*R) 0. 0. ;
  94. P13 = (-1*R) (L/10.) 0. ;
  95. P14 = 0. (L/10.) R ;
  96. P15 = R (L/10.) 0. ;
  97. P16 = (-1*R) (L/5.) 0. ;
  98. P17 = 0. (L/5.) R ;
  99. P18 = R (L/5.) 0. ;
  100. P19 = (-1*R) L 0. ;
  101. P20 = 0. L R ;
  102. P21 = R L 0. ;
  103. XC5 = IPOL (PROG 15 20 60 90 120 150) (PROG 35 35 40 40 50 50) AN ;
  104. XC6 = IPOL (PROG 15 20 60 90 120 150) (PROG -1 -3 -4 -4 -5 -5) AN ;
  105. XC6 = ENTI XC6 ;
  106. LIMTF = (TP.(6) CERC XC6 C0 (INVE TL.(1)) 'DINI' (XC5*DENS1) 'DFIN' (30*DENS1))
  107.                         CERC XC6 C0 TL.(5) 'DINI' (30*DENS1) DFIN (XC5*DENS1) ;
  108. XC3 = IPOL (PROG 15 20 60 90 120 150) (PROG 2 2 4 5 5 5) AN ;
  109. LIMF = P1 CERC (ENTI XC3) C0 (INVE TL.(5)) ;
  110. XC4 = IPOL (PROG 15 20 60 90 120 150) (PROG 16 14 13 12 10 10) AN ;
  111. XC7 = IPOL (PROG 15 20 60 90 120 150) (PROG 3 20 20 30 30 33) AN ;
  112. LIMF = (LIMF  CERC (ENTI (0. - XC4)) C0 P12 'DINI' (XC7*DENS1)
  113.                 'DFIN' (160*DENS1)) DROI P13 CERC CI P14 CERC CI P15 ;
  114. XC2 = IPOL (PROG 15 20 60 90 120 150) (PROG 15 25 50 70 80 80) AN ;
  115. LIMF = LIMF ET (DROI -5 P15 P1 'DINI' (120*DENS1) 'DFIN' (XC2*DENS1)) ;
  116. SUF = LIMF SURF 'CYLI' C0 CI 'COUL' 'TURQ' ;
  117. Z1 = COUT TL.(4) FF 'COUL' 'ROUG' ;
  118. Z2 = COUT TL.(4) TL.(3) 'COUL' 'VERT' ;
  119. Z3 = COUT TL.(3) TL.(2) 'COUL' 'ROSE' ;
  120. Z4 = COUT TL.(2) TL.(1) 'COUL' 'ROUG' ;
  121. Z5 = LIMTF SURF 'CYLI' C0 CI 'COUL' 'BLEU' ;
  122. ZF = Z1 ET Z2 ET Z3 ET Z4 ET Z5 ;
  123. SUF = SUF ET ZF ;
  124. MIN = ((P15 CERC CI P14 CERC CI P13) TRAN 2 (0. (L/10.) 0.))
  125.                 TRAN 15 (0. (4.*(L/5.)) 0.) 'COUL' 'TURQ' ;
  126. TOUT = SUF ET MIN ;
  127. TOUT = ORIE TOUT 'POIN' (0. 0. 0.) ;
  128. LIG = COTE 3 MIN ;
  129. CONT1 = CONT TOUT ;
  130. LISY = ELEM CONT1 'COMP' FF P12 ;
  131. LIFI = ELEM CONT1 'COMP' FF P1 ;
  132. ELIM (TOUT ET LIG) 1.E-3 ;
  133. * TRAC 'QUAL' TOUT ;FIN ;
  134.  
  135.  
  136. * I.2 - MODELE ET MATERIAU
  137. * ************************
  138.  
  139. * PROPRIETES :
  140. * MYOUN = MODULE D'YOUNG
  141. * NU1 = COEFFICIENT DE POISSON
  142. * AF1, AF2, AF3 = COEFFICIENTS DE NORTON
  143.  
  144. MYOUN = 2.E5 ;
  145. NU1 = 0.3 ;
  146. AF1 = 3.E-23 ;
  147. AF2 = 7. ;
  148. AF3 = 1. ;
  149.  
  150. * MODELE MULTICOUCHE
  151. * ELEMENT POUR LE MODELE MULTICOUCHE
  152. IELEM = 268 ;
  153. ELEFIS = TOUT ELEM 'TRI3' IELEM ;
  154. * EPAISSEUR TOTALE
  155. EPAI_T = E ;
  156. * NOMBRE DE COUCHES ET LEUR EPAISSEUR
  157. NB_COU = 13 ;
  158. EPAI_C = EPAI_T * 1.E-6 ;
  159. * CREATION DU MODELE MULTICOUCHE
  160. EPAI_I = (EPAI_T - (EPAI_C*NB_COU))/(NB_COU - 1) ;
  161. TBEPAI = TABL ;
  162. TBEXCE = TABLE ;
  163. MOD_MUL = VIDE 'MMODEL' ;
  164. MAT_MUL = VIDE 'MCHAML' ;
  165. REPE I ((2*NB_COU) - 1) ;
  166.         EX1 = (EPAI_I + EPAI_C)*(&I - NB_COU)/2. ;
  167.         SI (EGA ((&I/2)*2) &I) ;
  168.                 EP1 = EPAI_I ;
  169.         SINON ;
  170.                 EP1 = EPAI_C ;
  171.         FINSI;
  172.         MOD_MU1 = MODE ELEFIS 'MECANIQUE' 'ELASTIQUE' 'FLUAGE' 'NORTON' 'DKT'
  173.                                                                 'CONS' (CHAI &I) ;
  174.         MAT_MU1 = MATE MOD_MU1 'YOUN' MYOUN 'NU' NU1 'AF1' AF1 'AF2' AF2 'AF3' AF3
  175.                                                     'SMAX' 0. 'EPAI' EP1 'EXCE' EX1 ;
  176.         MOD_MUL = MOD_MUL ET MOD_MU1 ;
  177.         MAT_MUL = MAT_MUL ET MAT_MU1 ;
  178. FIN I;
  179.  
  180. * RESTE DU MODELE
  181. MOD0 = MODE (TOUT DIFF ELEFIS) 'MECANIQUE' 'ELASTIQUE' 'FLUAGE' 'NORTON' 'DKT' ;
  182. MAT0 = MATE MOD0 'YOUN' MYOUN 'NU' NU1 'AF1' AF1 'AF2' AF2 'AF3' AF3 
  183.     'SMAX' 0. 'EPAI' E ;
  184.  
  185. * MODELE TOTAL
  186. MOD1 = MOD0 ET MOD_MUL ;
  187. MAT1 = MAT0 ET MAT_MUL ;
  188.  
  189.  
  190. * I.3 - CONDITIONS AUX LIMITES ET CHARGEMENT
  191. * ******************************************
  192.  
  193. * CHARGE LIMITE
  194. SIG0 = 320. ;
  195. TETARAD = (AN/2.)*(PI/180.) ;
  196. V1 = 0.5*(SIN (AN/2.)) ;
  197. V2 = (PI/180.)*(ATG V1 ((1. - (V1**2))**0.5)) ;
  198. P0 = 2*SIG0*R*E*(PI - TETARAD - (2.*V2)) ;
  199. * MESS 'P0 = ' P0 ;FIN ;
  200. * CHARGEMENT
  201. PINI3 = POIN LIG 'INITIAL' ;
  202. PFIN3 = POIN LIG 'FINAL' ;
  203. PMIL3 = (CHAN 'POI1' LIG) DIFF (PINI3 ET PFIN3) ;
  204. MOEXT = (P0/2) / ((NBNO LIG) - 1) ;
  205. MOMIL = MOEXT*(NBNO PMIL3) ;
  206. F01 = (FORC 'FY' MOEXT (PINI3 ET PFIN3)) ET (FORC 'FY' MOMIL PMIL3) ;
  207. EVT = EVOL 'MANU' 'T' (PROG 0. 0.1 1.E20) 'F(T)' (PROG 0. 1. 1.) ;
  208. CHA1 = CHAR F01 EVT ;
  209.  
  210. * CLS
  211. SXOZ = SYMT 'DEPL' 'ROTA' TP.(10) TP.(11) P12 LISY 1.E-8 ;
  212. SXOY = SYMT 'DEPL' P1 P12 P21 TOUT 1.E-8 ;
  213. CDL = BLOQ 'UX' (POIN LIG 'FINAL') ;
  214. COLIM = SXOZ ET SXOY ET CDL ;
  215.  
  216.  
  217. * I.4 - APPEL A PASAPAS
  218. * *********************
  219.  
  220. TAB1 = TABL ;
  221. TAB1.'MODELE' = MOD1 ;
  222. TAB1.'CARACTERISTIQUES' = MAT1 ;
  223. TAB1.'BLOCAGES_MECANIQUES' = COLIM ;
  224. TAB1.'CHARGEMENT' = CHA1 ;
  225. LIS1 = PROG 0. PAS 0.02 0.2 PAS 0.05 1. PAS 0.5 10. PAS 5. 100. PAS 50. 350. ;
  226. SI VALIDATION ;
  227.         TAB1.'TEMPS_CALCULES' = LIS1 ;
  228. SINON ;
  229.         TAB1.'TEMPS_CALCULES' = EXTR LIS1 (LECT 1 PAS 1 20) ;
  230. FINSI ;
  231. MES_SAUV = TABL ;
  232. MES_SAUV.'DEFIN' = VRAI ;
  233. TAB1.'MES_SAUVEGARDES' = MES_SAUV ;
  234. PASAPAS TAB1 ;
  235.  
  236. * COD
  237. * COD = 2.*(EVOL 'TEMP' TAB1 'DEPLACEMENTS' 'UY' P1) ;
  238. * DESS COD ;
  239. * DEF1 = DEFO TAB1.'DEPLACEMENTS'.((DIME TAB1.'TEMPS') - 1) TOUT ;
  240. * TRAC DEF1 ;
  241.  
  242.  
  243. * II - APPEL A G_THETA ET COMPARAISON A LA SOLUTION ANALYTIQUE
  244. * ------------------------------------------------------------
  245.  
  246. * II.1 - APPEL A G_THETA
  247. * **********************
  248.  
  249. * ON RECUPERE LA FISSURE
  250. LF = CONT1 ELEM 'COMPRIS' P1 FF ;
  251. * TRAC ((TOUT COUL 'BLAN') ET (LF COUL 'ROUG') ET (ELEFIS COUL 'BLEU')) ;
  252.  
  253. * ON CREE LA TABLE SUPTAB
  254. SUPTAB = TABL ;
  255. SUPTAB.'SOLUTION_PASAPAS' = TAB1 ;
  256. SUPTAB.'OBJECTIF' = 'C*' ;
  257. SUPTAB.'LEVRE_SUPERIEURE' = LF ;
  258. SUPTAB.'FRONT_FISSURE' = FF ;
  259. SUPTAB.'COUCHE' = 4 ;
  260. SUPTAB.'ELEMENT_MULTICOUCHE' = ELEFIS ;
  261. SUPTAB.'POINT_1' = CI ;
  262. SUPTAB.'POINT_2' = C0 ;
  263.  
  264. * ON APPELLE G_THETA
  265. G_THETA SUPTAB ;
  266. NDER = DIME SUPTAB.'RESULTATS' ;
  267. C_GT = SUPTAB.'RESULTATS'.(NDER-1).'GLOBAL' ;
  268.  
  269.  
  270. * II.2 - SOLUTION ANALYTIQUE
  271. * **************************
  272.  
  273. SI VALIDATION ;
  274.         H1 = 0.638 ;
  275.         C_AN = SIG0*AF1*(SIG0**AF2)*R*PI*(1. - (AN/360.))*H1 ;
  276.         ERR1 = (ABS (C_AN - C_GT)) / C_AN ;
  277.         MESS  (CHAI 'ERREUR RELATIVE :' ' ' 'FORMAT' '(F4.1)' (100*ERR1) ' %') ;
  278.         SI (ERR1 > 3.E-2) ;
  279.                 ERRE 5 ;
  280.         FINSI ;
  281. FINSI ;
  282.  
  283. FIN ;
  284.  
  285.  
  286.  
  287.  
  288.  
  289.  
  290.  
  291.  
  292.  
  293.  
  294.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales