Télécharger la plaquette Cast3M


fr en

Télécharger g_c_etoile_axis_1.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : g_c_etoile_axis_1.dgibi
  2. ****************************************************
  3. ****************************************************
  4. *                                                  *
  5. *       VALIDATION DE LA PROCEDURE G_THETA         *
  6. *   POUR UN DEFAUT CIRCONFERENTIEL DANS UN TUYAU   *
  7. *  SOLUTION DE REFERENCE : Ductile Fracture        *
  8. *  Handbook, A. Zahoor                             * 
  9. *                                                  *
  10. *                                                  *
  11. *  GEOMETRIE : tube                                *
  12. *                                                  *
  13. *  rayon interne du tube     : 500. MM             *
  14. *  epaisseur du tube         : 100. MM             *
  15. *  rayon moyen du tube       : 550. MM             *
  16. *  longueur de la fissure    :  50. MM             *
  17. *                                                  *
  18. *  MATERIAU : loi de Norton                        *
  19. *                                                  *
  20. *  Module d'Young         : 2.E5 MPa               *
  21. *  Coefficient de poisson : 0.3                    *
  22. *  Coefficient N (Norton) : 7                      *
  23. *  Coefficient A (Norton) : 3.E-24 /h/MPa^7        *
  24. *                                                  *
  25. *  CHARGEMENT :                                    *
  26. *                                                  *
  27. *  Traction pure          : 193.15 MPa             *
  28. *                                                  *
  29. *  SOLUTION ANALYTIQUE (APPROCHEE) :               *
  30. *                                                  *
  31. *  Intégrale C*                                    *
  32. *                C* = 0.25316 kJ/m^2/h             *
  33. *                                                  *
  34. ****************************************************
  35.  
  36. * VALIDATION COMPLETE OU JUSTE FONCTIONNEMENT
  37. VALIDATION = vrai ;
  38.  
  39. * I - REALISATION DU CALCUL
  40. * -------------------------
  41.  
  42. * OPTIONS
  43. OPTI 'DIME' 2 'ELEM' 'QUA8' 'MODE' 'AXIS' ;
  44.  
  45. * I.1 - MAILLAGE
  46. * **************
  47.  
  48. * GEOMETRIE :
  49. * R = RAYON INTERNE
  50. * B = EPAISSEUR
  51. * L = LONGUEUR DU TUBE
  52. * A = LONGUEUR DE LA FISSURE
  53.  
  54. R = 500. ;
  55. B = 100. ;
  56. A = B/2. ;
  57. L = 4.*R ;
  58.  
  59.  
  60. * AUTOUR DU FRONT
  61. DENS1 = A/100. ;
  62. DENS DENS1 ;
  63. PF = A 0. ;
  64. R1 = DENS1 ;
  65. R2 = DENS1 ;
  66. C1 = PF ;
  67. SF = VIDE 'MAILLAGE' ;
  68. REPE ICOUCH 8 ;
  69.         C2 = (CERC (PF MOIN (R2 0.)) PF (PF PLUS (0. R2))) CERC PF (PF PLUS (R2 0.)) ;
  70.         SF = SF ET (COUT C1 C2) ;
  71.         R1 = 1.3*R1 ;
  72.         R2 = R1 + R2 ;
  73.         C1 = C2 ;
  74.         DENS R1 ;
  75. FIN ICOUCH ;
  76. * TRAC SF ;
  77.  
  78. * PASSAGE DU CERCLE A UN RECTANGLE
  79. DENS (A/3.) ;
  80. P0 = 0. 0. ;
  81. P1 = B 0. ;
  82. P2 P3 = P0 P1 PLUS (0. A) ;
  83. P11 = C2 POIN 1 ;
  84. L1 = P11 DROI P0 ;
  85. N = (NBEL L1)*-1 ;
  86. P12 = C2 POIN 4 ;
  87. L2 = P12 DROI N P2 ;
  88. P13 = C2 POIN 10 ;
  89. L3 = P13 DROI N P3 ;
  90. P14 = C2 POIN 13 ;
  91. L4 = P14 DROI P1 ;
  92. C2 = INVE C2 ;
  93. LIGH = P2 DROI P3 ;
  94. SC1 = DALL L1 (P0 DROI P2) (INVE L2) (C2 ELEM 'COMPRIS' P12 P11) ;
  95. SC2 = DALL L2 LIGH (INVE L3) (C2 ELEM 'COMPRIS' P13 P12) ;
  96. SC3 = DALL L3 (P3 DROI P1) (INVE L4) (C2 ELEM 'COMPRIS' P14 P13) ;
  97. SC = SC1 ET SC2 ET SC3 ;
  98.  
  99. * EXTENSION VERTICALE
  100. DENS (A/2.) ;
  101. MREST1 = LIGH TRAN (0. (2.*A)) 'DINI' (40*DENS1) 'DFIN' (50*DENS1) ;
  102.  
  103. * DERAFFINEMENT
  104. L1 = MREST1 COTE 3 ;
  105. YY1 = COOR 2 (POIN L1 'INIT') ;
  106. L2 = DROI 3 (B (YY1 + (0.7*A))) (0. (YY1 + (0.7*A))) ;
  107. S1 = COUT L1 L2 ;
  108.  
  109. * EXTENSION VERTICALE FINALE
  110. YY1 = COOR 2 (POIN L2 'INIT') ;
  111. MREST2 = L2 TRAN (0. (L-YY1)) 'DINI' (80*DENS1) 'DFIN' (150*DENS1) ;
  112.  
  113. * ASSEMBLAGE ET TRANSLATION
  114. SUT = SF ET SC ET MREST1 ET S1 ET MREST2 ;
  115. DEPL 'PLUS' SUT (R 0.) ;
  116. * TRAC SUT ;
  117.  
  118. * EXTRACTION DES LIGNES NECESSAIRES POUR LE CALCUL
  119. CONT1 = CONT SUT ;
  120. L1 = CONT1 ELEM 'APPUYE' (SUT POIN 'DROIT' (R 0.) ((B+R) 0.) 1.E-10) ;
  121. L2 = CONT1 ELEM 'APPUYE' (SUT POIN 'DROIT' ((B+R) 0.) ((B+R) L) 1.E-10) ;
  122. L3 = CONT1 ELEM 'APPUYE' (SUT POIN 'DROIT' ((B+R) L) (R L) 1.E-10) ;
  123. L4 = CONT1 ELEM 'APPUYE' (SUT POIN 'DROIT' (R L) (R 0.) 1.E-10) ;
  124. L5 = CONT1 ELEM 'COMPRIS' P1 PF ;
  125.  
  126.  
  127. * I.2 - MODELE ET MATERIAU
  128. * ************************
  129.  
  130. * PROPRIETES :
  131. * MYOUN = MODULE D'YOUNG
  132. * NU1 = COEFFICIENT DE POISSON
  133. * AF1, AF2, AF3 = COEFFICIENTS DE NORTON
  134.  
  135. MYOUN = 2.E5 ;
  136. NU1 = 0.3 ;
  137. AF1 = 3.E-23 ;
  138. AF2 = 7. ;
  139. AF3 = 1. ;
  140.  
  141. * MODELE
  142. MOD1 = MODE SUT 'MECANIQUE' 'ELASTIQUE' 'FLUAGE' 'NORTON' ;
  143. MAT1 = MATE MOD1 'YOUN' MYOUN 'NU' NU1 'AF1' AF1 'AF2' AF2 'AF3' AF3 
  144.      'SMAX' 0.;
  145.  
  146.  
  147. * I.3 - CONDITIONS AUX LIMITES ET CHARGEMENT
  148. * ******************************************
  149.  
  150. * CHARGE LIMITE
  151. SIG0 = 320. ;
  152. SIG1 = 2.*(((R+B)**2.) - ((R+A)**2.))*SIG0/(((R+B)**2.) - (R**2.))/(3.**0.5) ;
  153. * CHARGEMENT
  154. FOR1 = PRES 'MASS' MOD1 (0.-SIG1) L3 ;
  155. EVO1 = EVOL 'MANU' (PROG 0. 0.2 1.E20) (PROG 0. 1. 1.) ;
  156. CHA1 = CHAR 'MECA' FOR1 EVO1 ;
  157.  
  158. * CLS
  159. CL1 = BLOQ 'UZ' L5 ;
  160.  
  161.  
  162. * I.4 - APPEL A PASAPAS
  163. * *********************
  164.  
  165. TAB1 = TABL ;
  166. TAB1.'MODELE' = MOD1 ;
  167. TAB1.'CARACTERISTIQUES' = MAT1 ;
  168. TAB1.'BLOCAGES_MECANIQUES' = CL1 ;
  169. TAB1.'CHARGEMENT' = CHA1 ;
  170. LIS1 = PROG 0. PAS 0.02 0.2 PAS 0.05 1. PAS 0.5 10. PAS 5. 100. PAS 50. 1000
  171.                 PAS 20. 1500. ;
  172. SI VALIDATION ;
  173.         TAB1.'TEMPS_CALCULES' = LIS1 ;
  174. SINON ;
  175.         TAB1.'TEMPS_CALCULES' = EXTR LIS1 (LECT 1 PAS 1 20) ;
  176. FINSI ;
  177. MES_SAUV = TABL ;
  178. MES_SAUV.'DEFIN' = VRAI ;
  179. TAB1.'MES_SAUVEGARDES' = MES_SAUV ;
  180. PASAPAS TAB1 ;
  181.  
  182.  
  183. * II - APPEL A G_THETA ET COMPARAISON A LA SOLUTION ANALYTIQUE
  184. * ------------------------------------------------------------
  185.  
  186. * II.1 - APPEL A G_THETA
  187. * **********************
  188.  
  189. * ON RECUPERE LA FISSURE
  190. LF = CONT1 ELEM 'COMPRIS' PF P0 ;
  191.  
  192. * ON CREE LA TABLE SUPTAB
  193. SUPTAB = TABL ;
  194. SUPTAB.'SOLUTION_PASAPAS' = TAB1 ;
  195. SUPTAB.'OBJECTIF' = 'C*' ;
  196. SUPTAB.'LEVRE_SUPERIEURE' = LF ;
  197. SUPTAB.'FRONT_FISSURE' = PF ;
  198. SUPTAB.'COUCHE' = 4 ;
  199.  
  200. * ON APPELLE G_THETA
  201. G_THETA SUPTAB ;
  202. NDER = DIME SUPTAB.'RESULTATS' ;
  203. C_GT = SUPTAB.'RESULTATS'.(NDER-1) ;
  204.  
  205.  
  206. * II.2 - SOLUTION ANALYTIQUE
  207. * **************************
  208.  
  209. SI VALIDATION ;
  210.         H1 = 3.07 ;
  211.         C_AN = SIG0*AF1*(SIG0**AF2)*B*((1-(A/B))**2)*H1 ;
  212.         ERR1 = (ABS (C_AN - C_GT)) / C_AN ;
  213.         MESS  (CHAI 'ERREUR RELATIVE :' ' ' 'FORMAT' '(F4.1)' (100*ERR1) ' %') ;
  214.         SI (ERR1 > 0.13) ;
  215.                 ERRE 5 ;
  216.         FINSI ;
  217. FINSI ;
  218.  
  219. FIN ;
  220.  
  221.  
  222.  
  223.  
  224.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales