Télécharger la plaquette Cast3M


fr en

Télécharger g_c_etoile_3D_1.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : g_c_etoile_3D_1.dgibi
  2. ****************************************************
  3. ****************************************************
  4. *                                                  *
  5. *       VALIDATION DE LA PROCEDURE G_THETA         *
  6. *   POUR UN DEFAUT CIRCONFERENTIEL DANS UN TUYAU   *
  7. *  SOLUTION DE REFERENCE : Ductile Fracture        *
  8. *  Handbook, A. Zahoor                             * 
  9. *                                                  *
  10. *                                                  *
  11. *  GEOMETRIE : tube                                *
  12. *                                                  *
  13. *  rayon interne du tube     : 500. MM             *
  14. *  epaisseur du tube         : 100. MM             *
  15. *  rayon moyen du tube       : 550. MM             *
  16. *  longueur de la fissure    :  50. MM             *
  17. *                                                  *
  18. *  MATERIAU : loi de Norton                        *
  19. *                                                  *
  20. *  Module d'Young         : 2.E5 MPa               *
  21. *  Coefficient de poisson : 0.3                    *
  22. *  Coefficient N (Norton) : 7                      *
  23. *  Coefficient A (Norton) : 3.E-24 /h/MPa^7        *
  24. *                                                  *
  25. *  CHARGEMENT :                                    *
  26. *                                                  *
  27. *  Traction pure          : 193.15 MPa             *
  28. *                                                  *
  29. *  SOLUTION ANALYTIQUE (APPROCHEE) :               *
  30. *                                                  *
  31. *  Intégrale C*                                    *
  32. *                C* = 0.25316 kJ/m^2/h             *
  33. *                                                  *
  34. ****************************************************
  35.  
  36. * VALIDATION COMPLETE OU JUSTE FONCTIONNEMENT
  37. VALIDATION = vrai ;
  38.  
  39. * I - REALISATION DU CALCUL
  40. * -------------------------
  41.  
  42. * OPTIONS
  43. OPTI 'DIME' 3 'ELEM' 'CU20' 'DENS' 1. ;
  44.  
  45. * I.1 - MAILLAGE
  46. * **************
  47.  
  48. * GEOMETRIE :
  49. * R = RAYON INTERNE
  50. * B = EPAISSEUR
  51. * L = LONGUEUR DU TUBE
  52. * A = LONGUEUR DE LA FISSURE
  53. * ANR = ANGLE DE ROTATION
  54.  
  55. R = 500. ;
  56. B = 100. ;
  57. A = B/2. ;
  58. L = 1.5*R ;
  59. ANR = 0.5 ;
  60.  
  61. DIS1 = A/8. ;
  62. P1 = 0. 0. 0. ;
  63. P2 = (A - DIS1) 0. 0. ;
  64. P3 = A 0. 0. ;
  65. P4 = (A - DIS1) 0. DIS1 ;
  66. P5 = A 0. DIS1 ;
  67. P6 = 0. 0. (6.*DIS1) ;
  68. P7 = (A - DIS1) 0. (6.*DIS1) ;
  69. P8 = A 0. (6.*DIS1) ;
  70. SUT = SURF 'PLAN' (DROI 2 P2 P3 DROI 2 P4 DROI 1 P2) ;
  71. SUT = SUT ET (SUT SYME 'DROI' P4 P3) ;
  72. SUT = SUT ET (REGL (DROI 1 P4 P5) (DROI 1 P7 P8) 'DINI' DIS1 'DFIN' DIS1) ;
  73. L1 = DROI P1 P2 'DINI' DIS1 'DFIN' DIS1 ;
  74. L2 = DROI P6 P7 'DINI' DIS1 'DFIN' DIS1 ;
  75. SUT = SUT ET (REGL L1 L2 'DINI' DIS1 'DFIN' DIS1) ;
  76. P9 = 0. 0. (8.*DIS1) ;
  77. P10 = A 0. (8.*DIS1) ;
  78. L1 = (DROI P6 P7 'DINI' DIS1 'DFIN' DIS1) ET (DROI 1 P7 P8) ;
  79. L2 = DROI P9 P10 'DINI' (2.*DIS1) 'DFIN' (2.*DIS1) ;
  80. SUT = SUT ET (COUT L1 L2) ;
  81. VEC1 = 0. 0 .((L/2.) - (4.*DIS1) - (COOR 3 P9)) ;
  82. SU2 = TRAN L2 'DINI' (2*DIS1) 'DFIN' (2*DIS1) VEC1 ;
  83. P15 = 0. 0. L ;
  84. P16 = A 0. L ;
  85. SU3 = TRAN (DROI P15 P16 'DINI' (4.*DIS1) 'DFIN' (4.*DIS1))
  86.                         'DINI' (5.*DIS1) 'DFIN' (3.5*DIS1) (0. 0. (0. - (L/2.))) ;
  87. L1 = COTE 3 SU2 ;
  88. L2 = COTE 3 SU3 ;
  89. SUT = SUT ET SU2 ET SU3 ET (COUT L1 L2) ;
  90. L5 = (CONT SUT) ELEM 'APPUYE' (SUT POIN 'DROI' (0. 0. 0.) (B 0. 0.) 1.E-8) ;
  91. SUT = SUT ET (SYME SUT 'DROI' P3 P16) ;
  92. ELIM SUT 1.E-8 ;
  93. DEPL 'PLUS' SUT (R 0. 0.) ;
  94. NN = 1 ;
  95. PRF1 = 0. 0. 0. ;
  96. PRF2 = (0. 0. 1.E3) ;
  97. VOT = SUT VOLU NN 'ROTA' ANR PRF1 PRF2 ;
  98. CONT1 = CONT SUT ;
  99. L1 = COUL (CONT1 ELEM 'APPUYE'
  100.                         (SUT POIN 'DROI' (R 0. 0.) ((B+R) 0. 0.) 1.E-10)) 'ROUG' ;
  101. L2 = COUL (CONT1 ELEM 'APPUYE'
  102.                         (SUT POIN 'DROI' ((B+R) 0. 0.) ((B+R) 0. L) 1.E-10)) 'VERT' ;
  103. L3 = COUL (CONT1 ELEM 'APPUYE'
  104.                         (SUT POIN 'DROI' ((B+R) 0. L) (R 0. L) 1.E-10)) 'ROUG' ;
  105. L4 = COUL (CONT1 ELEM 'APPUYE'
  106.                         (SUT POIN 'DROI' (R 0. L) (R 0. 0.) 1.E-10)) 'VERT' ;
  107. LF = COUL (L1 ELEM 'COMPRIS' (SUT POIN 'PROC' (R 0. 0.))
  108.                                                                 (SUT POIN 'PROC' ((R+A) 0. 0.))) 'TURQ' ;
  109. NN = 1 ;
  110. SU1 = L1 ROTA NN ANR PRF1 PRF2 ;
  111. SU2 = L2 ROTA NN ANR PRF1 PRF2 ;
  112. PSUP = (COOR 3 VOT) POIN 'MAXI' ;
  113. SU3 = (ENVE VOT) ELEM 'APPUYE' PSUP ;
  114. SU3 = L3 ROTA NN ANR PRF1 PRF2 ;
  115. SU4 = L4 ROTA NN ANR PRF1 PRF2 ;
  116. SUF = LF ROTA NN ANR PRF1 PRF2 ;
  117. ELIM VOT (SU1 ET SU2 ET SU3 ET SU4 ET SUF) 1.E-10 ;
  118. FRONF = COTE 2 SUF ;
  119. P1 = L1 POIN 'INITIAL' ;
  120. P2 = L1 POIN 'FINAL' ;
  121. P3 = L2 POIN 'FINAL' ;
  122. P4 = L3 POIN 'FINAL' ;
  123. SINAN = SIN ANR ;
  124. COSAN = COS ANR ;
  125. P11 = VOT POIN 'PROC' ((R*COSAN) (R*SINAN) 0.) ;
  126. P12 = VOT POIN 'PROC' (((R+B)*COSAN) ((R+B)*SINAN) 0.) ;
  127. P13 = VOT POIN 'PROC' (((R+B)*COSAN) ((R+B)*SINAN) L) ;
  128. P14 = VOT POIN 'PROC' ((R*COSAN) (R*SINAN) L) ;
  129.  
  130.  
  131. * I.2 - MODELE ET MATERIAU
  132. * ************************
  133.  
  134. * PROPRIETES :
  135. * MYOUN = MODULE D'YOUNG
  136. * NU1 = COEFFICIENT DE POISSON
  137. * AF1, AF2, AF3 = COEFFICIENTS DE NORTON
  138.  
  139. MYOUN = 2.E5 ;
  140. NU1 = 0.3 ;
  141. AF1 = 3.E-23 ;
  142. AF2 = 7. ;
  143. AF3 = 1. ;
  144.  
  145. * MODELE
  146. MOD1 = MODE VOT 'MECANIQUE' 'ELASTIQUE' 'FLUAGE' 'NORTON' ;
  147. MAT1 = MATE MOD1 'YOUN' MYOUN 'NU' NU1 'AF1' AF1 'AF2' AF2 'AF3' AF3 
  148.          'SMAX' 0. ;
  149.  
  150.  
  151. * I.3 - CONDITIONS AUX LIMITES ET CHARGEMENT
  152. * ******************************************
  153.  
  154. * CHARGE LIMITE
  155. SIG0 = 320. ;
  156. SIG1 = 2.*(((R+B)**2.) - ((R+A)**2.))*SIG0/(((R+B)**2.) - (R**2.))/(3.**0.5) ;
  157. * CHARGEMENT
  158. FOR1 = PRES 'MASS' MOD1 (0.-SIG1) SU3 ;
  159. EVO1 = EVOL 'MANU' (PROG 0. 0.2 1.E20) (PROG 0. 1. 1.) ;
  160. CHA1 = CHAR 'MECA' FOR1 EVO1 ;
  161.  
  162. * CLS
  163. CL1 = SYMT 'DEPL' (SU1 DIFF SUF) P1 P2 P11 1.E-5 ;
  164. CL2 = SYMT 'DEPL' VOT P11 P12 P13 1.E-5 ;
  165. CL3 = SYMT 'DEPL' SUT P1 P2 P3 1.E-5 ;
  166. CL0 = CL1 ET CL2 ET CL3 ;
  167.  
  168.  
  169. * I.4 - APPEL A PASAPAS
  170. * *********************
  171.  
  172. TAB1 = TABL ;
  173. TAB1.'MODELE' = MOD1 ;
  174. TAB1.'CARACTERISTIQUES' = MAT1 ;
  175. TAB1.'BLOCAGES_MECANIQUES' = CL0 ;
  176. TAB1.'CHARGEMENT' = CHA1 ;
  177. LIS1 = PROG 0. PAS 0.02 0.2 PAS 0.05 1. PAS 0.5 10. PAS 5. 100. PAS 50. 1000.
  178.                 PAS 20. 1500. ;
  179. SI VALIDATION ;
  180.         TAB1.'TEMPS_CALCULES' = LIS1 ;
  181. SINON ;
  182.         TAB1.'TEMPS_CALCULES' = EXTR LIS1 (LECT 1 PAS 1 20) ;
  183. FINSI ;
  184. MES_SAUV = TABL ;
  185. MES_SAUV.'DEFIN' = VRAI ;
  186. TAB1.'MES_SAUVEGARDES' = MES_SAUV ;
  187. PASAPAS TAB1 ;
  188.  
  189. * COD
  190. COD = 2.*(EVOL 'TEMP' TAB1 'DEPLACEMENTS' 'UZ' P1) ;
  191. * DESS COD ;
  192.  
  193.  
  194. * II - APPEL A G_THETA ET COMPARAISON A LA SOLUTION ANALYTIQUE
  195. * ------------------------------------------------------------
  196.  
  197. * II.1 - APPEL A G_THETA
  198. * **********************
  199.  
  200. * ON CREE LA TABLE SUPTAB
  201. SUPTAB = TABL ;
  202. SUPTAB.'SOLUTION_PASAPAS' = TAB1 ;
  203. SUPTAB.'OBJECTIF' = 'C*' ;
  204. SUPTAB.'LEVRE_SUPERIEURE' = SUF ;
  205. SUPTAB.'FRONT_FISSURE' = FRONF ;
  206. SUPTAB.'COUCHE' = 4 ;
  207.  
  208. * ON APPELLE G_THETA
  209. G_THETA SUPTAB ;
  210. EVOL_GLOBAL = SUPTAB.'EVOLUTION_RESULTATS'.'GLOBAL';
  211. NDER = DIME SUPTAB.'RESULTATS' ;
  212. C_GT = SUPTAB.'RESULTATS'.(NDER-1).'GLOBAL' ;
  213.  
  214.  
  215. * II.2 - SOLUTION ANALYTIQUE
  216. * **************************
  217.  
  218. SI VALIDATION ;
  219.         H1 = 3.07 ;
  220.         C_AN = SIG0*AF1*(SIG0**AF2)*B*((1-(A/B))**2)*H1 ;
  221.         ERR1 = (ABS (C_AN - C_GT)) / C_AN ;
  222.         MESS  (CHAI 'ERREUR RELATIVE :' ' ' 'FORMAT' '(F4.1)' (100*ERR1) ' %') ;
  223.         SI (ERR1 > 0.05) ;
  224.                 ERRE 5 ;
  225.         FINSI ;
  226. FINSI ;
  227.  
  228. FIN ;
  229.  
  230.  
  231.  
  232.  
  233.  
  234.  
  235.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales