Exemples de jeux de données Cast3M

*---------------------  F U S I O N 2 . D G I B I ---------------------*
* fichier : fusion2.dgibi
* section : Mecanique, Plastique
*----------------------------------------------------------------------*
* Cas-test de validation de l'option FUSION avec modele de Chaboche.   *
*                                                                      *
* Simulation d'une essai de traction cyclique (1 cycle),               *
* Puis, chauffage au-dessus de TFusion pour restaurer ecrouissage,     *
* Puis, nouvelle traction cyclique.                                    *
*                                                                      *
* On compare les courbes de traction avant et apres restauration :     *
* elles doivent etre identiques au decalage a l'origine pres.          *
*                                                                      *
* Description :                                                        *
* -------------                                                        *
* Type de calcul : mecanique, plastique                                *
* Mode de calcul : 3D                                                  *
* Type d'element : CUB8                                                *
* Chargement     : Effort impose                                       *
*                                                                      *
*----------------------------------------------------------------------*
opti dime 3 elem cub8 ;
 
* Pour affichages, mettre IG1 a VRAI :
ig1      = faux ;
 
*opti trac psc eptr 5 ;
 
ig1      = ig1 ou (ega (vale trac) 'PSC') ;
 
*------------------------------ Modele EF -----------------------------*
 
* Temperature essai :
T0      = 20. ;
 
* Maillage cube unite :
L1      = (0 0 0) droi 1 (1 0 0) ;
S1      = L1 tran 1 (0 1 0) ;
V1      = S1 volu tran 1 (0 0 1) ;
 
si ig1 ;
  trac V1 titr 'Traction sur un cube unite' ;
fins ;
 
* Donnees 316L :
t316L   = biblio '316L' refe 4 ;
 
* Modele et Caracteristiques :
mod1    = mode V1 mecanique elastique plastique chaboche2 fusion ;
*mod1    = mode V1 mecanique elastique plastique chaboche2 ;
mat1    = mate mod1 'YOUN' t316L.'YOUN' 'NU' t316L.'NU' 'ALPH' t316L.'ALPH'
                    'R0'   t316L.'R0'   'RM' t316L.'RM' 'B' t316L.'B'
                    'A1'   t316L.'A1'   'C1' t316L.'C1' 'A2' t316L.'A2' 'C2' t316L.'C2' 
                    'PSI'  1. 'OMEG' 0. 'TREF' T0 'TALP' T0 'TFUS' 100. ;
*                    'PSI'  1. 'OMEG' 0. 'TREF' T0 'TALP' T0 ;
 
* CL (blocages) :
Sx0     = (V1 coor 1) poin infe 1.e-3 ;
Sy0     = (V1 coor 2) poin infe 1.e-3 ;
S2      = V1 face 2 ;
CLUS1   = bloq S1 uz ;
CLUX0   = bloq Sx0 ux ;
CLUY0   = bloq Sy0 uy ;
CLUS2   = bloq S2 uz ;
cl0     = CLUS1 et CLUX0 et CLUY0 et CLUS2 ;
cl0     = CLUS1 et CLUX0 et CLUY0 ;
 
* Deplacement impose :
DCLS2   = depi CLUS2 1. ;
 
* Force imposee :
FS2     = forc S2 'FZ' 1. ;
 
* Evolution temporelle :
fpoint1 =  20. ;
fmax1   = 400.e6 ;
tfmax1  = fmax1 / fpoint1 ;
lamp1   = prog 0.  0.75  -0.75  0.75  0.   0.   0.   0.75  -0.75  0.75  0. ;
ltps1   = prog 0.  0.75   2.25  3.75  4.5  5.5  6.5  7.25   8.75 10.25 11. ;
lamp1   = fmax1 * lamp1 ;
ltps1   = tfmax1 * ltps1 ;
ev1     = evol vert manu temp ltps1 lamp1 ;
 
* Chargement mecanique :
cg1     = char dimp DCLS2 ev1 ;
cg1     = char meca FS2   ev1 ;
 
* Chargement thermique :
cht1    = manu chpo V1 1 'T' 1. ;
 lamp2   = prog 0.  0.     0.    0.    0.   1.   0.   0.     0.    0.    0. ;
*ltps1   = prog 0.  0.75   2.25  3.75  4.5  5.5  6.5  7.25   8.75 10.25 11. ;
lamp2   = (100 * lamp2) + T0 ;
ev2     = evol roug manu temp ltps1 lamp2 ;
cgt1    = char t cht1 ev2 ;
 
si ig1 ;
  dess ev1 titr 'Evolution temporelle de la force imposee' ;
  dess ev2 titr 'Evolution temporelle de la temperature imposee (TFUS = 100)' ;
fins ;
 
*------------------------- Resolution PASAPAS -------------------------*
 
tpas1                     = table ;
tpas1.modele              = mod1 ;
tpas1.caracteristiques    = mat1 ;
tpas1.chargement          = cg1 et cgt1 ;
tpas1.blocages_mecaniques = cl0 ;
tpas1.temps_calcules      = ltps1 raff (0.02*tfmax1) ;
 
list tpas1.temps_calcules ;
 
pasapas tpas1 ;
 
*----------------------- Visualisation resultat -----------------------*
 
* Courbe de traction a la temperature courante :
pz1      = S2 poin proc (0 0 1) ;
lu1      = prog ;
lu2      = prog ;
lu3      = prog ;
lf1      = prog ;
lf2      = prog ;
lf3      = prog ;
nb1      = dime (tpas1.temps) ;
repe b1 nb1 ;
  i1       = &b1 - 1 ;
  ui1      = (tpas1.deplacements.i1) extr 'UZ' pz1 ;
  szzi1    = ((tpas1.contraintes.i1) exco smzz) maxi ;
  fi1      = ((tpas1.reactions.i1) redu s1) resu ;
  si (non (vide fi1)) ;
    fi1      = extr fi1 'FZ' ((extr fi1 mail) poin 1) ;
  fins ;
  si (tpas1.temps.i1 &lt;EG (tfmax1 * 4.5)) ;
    lu1      = lu1 et ui1 ;
    lf1      = lf1 et szzi1 ;
  fins ;
  si ((tpas1.temps.i1 >EG (tfmax1 * 4.5)) et (tpas1.temps.i1 &lt;EG (tfmax1 * 6.5))) ;
    lu2      = lu2 et ui1 ;
    lf2      = lf2 et szzi1 ;
  fins ;
  si (tpas1.temps.i1 >EG (tfmax1 * 6.5)) ;
    lu3      = lu3 et ui1 ;
    lf3      = lf3 et szzi1 ;
  fins ;
fin B1 ;
evfu1    = evol vert manu 'dL/L (%)' (100.*lu1) 'F/So (MPa)' (1.e-6*lf1) ;
evfu2    = evol roug manu 'dL/L (%)' (100.*lu2) 'F/So (MPa)' (1.e-6*lf2) ;
evfu3    = evol bleu manu 'dL/L (%)' (100.*lu3) 'F/So (MPa)' (1.e-6*lf3) ;
evfu0    = evfu1 et evfu3 et evfu2 ;
 
si ig1 ;
  tleg1    = table ;
  tleg1.1  = mot 'TIRR MARQ S TRIA' ;
  tleg1.2  = mot 'POIN MARQ S ROND' ;
  tleg1.3  = mot 'NOLI MARQ S CARR' ;
  tleg1.titre   = table ;
  tleg1.titre.1 = 'Traction avant fusion' ;
  tleg1.titre.2 = 'Traction apres fusion' ;
  tleg1.titre.3 = 'Chauffage sans effort' ;
  dess evfu0 lege tleg1 gril point titr 'Courbes de traction cyclique 316L avant (vert) / apres (bleu) fusion (rouge = dilatation)' logo posy exce ;
fins ;
 
*-------------------- Validation de l'option FUSION -------------------*
 
lf3b     = lf3 ;
lu3b     = lu3 - (lu1 extr (dime lu1)) ;
evfu3b   = evol bleu manu 'dL/L (%)' (100.*lu3b) 'F/So (MPa)' (1.e-6*lf3b) ;
 
si ig1 ;
  dess (evfu1 et evfu3b) lege tleg1 titr 'Comparaison courbes apres recalage 2e traction a l''orgine' logo posy exce ;
fins ;
 
err1     = maxi abs (lu3b - lu1) / (maxi abs lu1) ;
err2     = maxi abs (lf3b - lf1) / (maxi abs lf1) ;
err0     = (prog err1 err2) maxi ;
opti echo 0 ;
saut 1 lign ;
mess (chai 'Erreur relative deplacement : err1 =' err1) ;
mess (chai 'Erreur relative effort      : err2 =' err2) ;
saut 1 lign ;
opti echo 1 ;
 
si (err0 > 5.e-3) ;
  erre 5 ;
fins ;
 
*---------------------  F U S I O N 2 . D G I B I ---------------------*
fin ;