Exemples de jeux de données Cast3M

* fichier frottement_hpp.dgibi
* section : mecanique, contact, frottement
*----------------------------------------------------------------------*
*                F R O T T E M E N T _ H P P . D G I B I               *
*----------------------------------------------------------------------*
* Objet :
* -------
*
*  Cet exemple calcule le glissement d'un lopin carre, auquel on impose
*  une pression en face superieure et un deplacement a son cote droit.
*  La condition de contact-frottement est imposee sur la ligne du bas.
*
*  La condition de contact-frottant est imposee a l'aide d'une relation
*  non-associee (voir syntaxe 'RELA' CHPO1 'DUAL' CHPO2). La direction
*  de glissement est supposee dans le sens UX > 0. Cette condition est
*  imposee par un blocage (voir BLOQ MINI).
*
*  Le probleme est alors resolu avec RESOU.
*
*  La solution calculee montre que le point en bas a gauche du lopin ne
*  satisfait pas la condition de frottement. Il conviendrait donc de
*  modeliser le probleme en definissant un modele de contact frottant
*  et de le resoudre avec PASAPAS.
*
*  Cet exemple illustre l'utilisation d'une relation non associee.
*  
* Description :
* -------------
*
* Type de calcul : Mecanique, RESOU
* Mode de calcul : 2D
* Type d'element : QUA4
* Chargement     : deplacement impose, pression, contact-frottement,
*                  relation non-associee
*
*----------------------------------------------------------------------*
opti dime 2 elem qua4 ; 
 
* Pour affichages, mettre IG1 a VRAI :
IG1      = faux ;
 
*---------------- Maillage / Modele / Caracteristqiues ----------------*
 
* Maillage :
l1       = (0 0) droi 10 ( 1 0) ; 
s1       = l1 tran 1 (0 1) ;
si ig1 ;
  trac s1 titr 'Maillage lopin' ;
fins ;
 
* Modele / caracteristiques :
mo1      = mode s1 mecanique ; 
ma1      = mate mo1 youn 20.e9 nu 0.3 ; 
 
*---------------- Conditions aux limites / Chargement -----------------*
 
* Blocage sens glissement :
cl1      = bloq mini ux l1 ;
si ig1 ;
  trac ((extr cl1 mail mult) coul roug et S1) titr 'Blocage direction de glissement Ux > 0' ;
fins ;
 
* Deplacement impose bord droit :
l2       = s1 cote 2 ; 
cl2      = bloq ux l2 ; 
dcl2     = depi cl2 2.5e-4 ;
si ig1 ;
  vdimp1   = vect (dcl2 exco flx ux) depl vert ;
  trac vdimp1 S1 titr (chai 'Deplacement impose : Ux =' 2.5e-4) ;
fins ;
 
* Pression imposee bord sup. :
l3       = s1 cote 3 ; 
pr1      = 1.e7 ;
f1       = press mass mo1 l3 pr1 ;
si ig1 ;
  trac (vect f1 forc vert) S1 titr (chai 'Effort applique :  FY =' 1.e4 ' kN') ; 
fins ;
 
* Condition non-associee de contact-frottement :
mu1      = 0.2 ;       comm coef. de frottement ;
clf1     = vide rigidite ;
repe bf1 (nbno l1) ;
  pi1      = l1 poin &bf1 ;
  mpi1     = manu poi1 pi1 ;
  chuy1    = manu chpo mpi1 1 uy +1.0 ;
  chfx1    = manu chpo mpi1 2 fx mu1 fy -1. ;
  clfi1    = rela mini chuy1 dual chfx1 ;
  clf1     = clf1 et clfi1 ;
fin bf1 ;
 
si IG1 ;
  trac ((extr clf1 mail mult) coul roug et S1) titr 'Bord condition de contact-frottement, Uz > 0' ;
fins ;
 
*----------------------------- Resolution -----------------------------*
 
* Assemblage des matrices :
rig1     = rigi mo1 ma1 ;
clm1     = clf1 et cl2 et cl1 ;
rigt1    = rig1 et clm1 ;
 
* Resolution :
dep1     = reso rigt1 (F1 et dcl2) ;
 
*---------------------------POST TRAITEMENT----------------------------*
 
* Deplacements :
si ig1 ;
  trac dep1 s1 titr 'Deplacement solution' ;
fins ;
*list (exco dep1 ux) ;
*list (exco dep1 uy) ;
 
* Deformee :
def0     = defo dep1 s1 0. blan ;
def1     = defo dep1 s1    roug ;
si ig1 ;
  trac (def1 et def0 ) titr 'Deformees initiale (blanc) et finale' ;
fins ;
 
* Reactions :
* RELA non-associee de contact-frottement :
reaf1    = reac dep1 clf1 ;
vrf1     = vect reaf1 forc bleu 1.e-7 ;
si ig1 ;
  trac vrf1 s1 titr 'Reaction RELA non-associee de contact-frottement' ;
fins ;
*list reaf1 ;
 
* Blocage direction de glissement :
reaf2    = reac dep1 cl1 ;
si (non (vide reaf2)) ;
  vrf2     = vect reaf2 forc vert 1.e-7 ;
  si ig1 ;
    trac vrf2 s1 titr 'Reaction blocage direction de glissement' ;
  fins ;
*  list reaf2 ;
  si ig1 ;
    trac (vrf1 et vrf2) s1 titr 'Reactions RELA non-associee et blocage glissement' ;
  fins ;
 
* On verifie que la resultant au coin bas gauche est negative ou nulle :
  P1       = L1 poin 1 ;
  Rxp1     = (extr reaf1 FX P1) + (extr reaf2 FX P1) ;
  opti echo 0 ; saut 1 lign ;
  mess ' *****  Resultante de frottement au point bas gauche :' ;
  mess (chai ' > FX =' (1.e-3 * Rxp1 enti) ' kN') ;
  saut 1 lign ; opti echo 1 ;
  si (Rxp1 > 0.) ;
    opti echo 0 ; saut 1 lign ;
    mess ' > La resultante de frottement est dans orientee dans le sens du glissement au coin en bas a gauche.' ;
    mess ' > La direction de glissement devrait etre inversee en ce point.' ;
    saut 1 lign ; opti echo 1 ;
  fins ;
 
fins ;
 
* Reaction point application deplacement :
rea2     = reac dep1 cl2  ;
si ig1 ;
  trac (vect rea2  forc bleu) s1 titr 'Reaction deplacement impose' ;
fins ;
*list rea2 ;
 
* Evolution deplacement ligne L1 :
evuxl1   = evol vert chpo dep1 ux l1 ;
si ig1 ;
  dess evuxl1 titr 'Evolution deplacement Ux le long du plan de contact-frottement' ;
fins ;
*list evuxl1 ;
evuyl1   = evol chpo dep1 uy l1 ;
*dess evuyl1 ;
*list evuyl1 ;
 
*----------------------------- Validation -----------------------------*
 
* Test condition de contact (Uy >EG 0 en L1) :
Uyminl1  = (extr evuyl1 ordo) mini ;
si (Uyminl1 < -1.e-14) ;
  erre 5 ;
fins ;
 
* Test condition de frottement (Fx = - µ N) :
P2       = L1 poin proc (1 0) ;
RxP2     = extr reaf1 FX P2 ;
RyP2     = extr reaf1 FY P2 ;
err1     = abs (mu1 * RyP2 + RxP2) ;
si (err1 > 1.e14) ;
  erre 5 ;
fins ;
 
*---------- F I N   F R O T T E M E N T _ H P P . D G I B I -----------*
fin ;