Télécharger la plaquette Cast3M


fr en

Télécharger formation_pasapas_3_initial.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : formation_pasapas_3_initial.dgibi
  2. *
  3. *----------------------------------------------------------------------*
  4. *              FORMATION AVANCEE SUR LA PROCEDURE PASAPAS              *
  5. *                                                                      *
  6. * Chauffage d'une plaque par une source de chaleur variable            *
  7. * dependante de la temperature                                         *
  8. *                                                                      *
  9. * Ce fichier constitue la mise donnee initiale du probleme et realise  *
  10. * - le maillage                                                        *
  11. * - la definition du modele et des parametres materiaux                *
  12. * - la definition du chargement (convection + source constante)        *
  13. * - la resolution avec PASAPAS                                         *
  14. * - le post traitement                                                 *
  15. *----------------------------------------------------------------------*
  16.  
  17.  
  18.  
  19.  
  20.  
  21. ** Options de trace / Plotting options
  22. itrac = FAUX ;
  23. ***OPTI 'TRAC' 'PSC' ;
  24. ipsc  = EGA (VALE 'TRAC') 'PSC' ;
  25.  
  26. ** Options generales
  27. OPTI 'DIME' 2 'ELEM' 'QUA8' ;
  28.  
  29. ** Maillage
  30. p1    = 0. 0. ;
  31. p2    = 1. 0. ;
  32. l12   = DROI 20 p1 p2 ;
  33. mail  = l12 TRAN 20 (0. 1.) ;
  34. ptx   = (mail COOR 1) POIN 'EGINFE' 0.25001 ;
  35. pty   = (ptx  COOR 2) POIN 'EGINFE' 0.25001 ;
  36. sou   = mail ELEM 'APPU' 'STRI' pty ;
  37. nsou  = DIFF mail sou ;
  38. lext  = (mail COTE 2) ET (mail COTE 3) ;
  39. p2    = mail 'POIN' 'PROC' (1. 1.) ;
  40. SI itrac ;
  41.   SI ipsc ;
  42.     OPTI 'FTRA' 'exo_3_maillage.ps' ;
  43.   FINSI ;
  44.   TRAC 'FACE' ((sou COUL 'ORAN') ET (nsou COUL 'CYAN')) ((CONT sou) ET (CONT nsou))  ;
  45. FINSI ;
  46.  
  47. ** Modeles et materiaux
  48. mocod = MODE mail 'THERMIQUE' 'CONDUCTION' ;
  49. macod = MATE mocod 'K' 317. 'C' 128.
  50.                    'RHO' 19300. 'TINI' 20. ;
  51. * convection
  52. mocov = MODE lext 'THERMIQUE' 'CONVECTION' ;
  53. macov = MATE mocov 'H' 150. 'TC' 20. ;
  54.  
  55. ** Chargement (source)
  56. mosou = REDU mocod sou ;
  57. psou  = SOUR mosou 4.E6 sou ;
  58. chsou = CHAR 'Q' psou ;
  59.  
  60. **Resolution avec PASAPAS
  61. tab1                      = TABL ;
  62. tab1 . 'MODELE'           = mocod ET mocov ;
  63. tab1 . 'CARACTERISTIQUES' = macod ET macov ;
  64. tab1 . 'CHARGEMENT'       = chsou ;
  65. tab1 . 'TEMPS_CALCULES'   = PROG 0. 'PAS' (1.E5 / 50.) 1.E5 ;
  66. PASAPAS tab1 ;
  67.  
  68. ** Post-traitement
  69. n1    = DIME (tab1 . 'TEMPS_CALCULES') ;
  70. liso  = PROG 20. 'PAS' ((1800. - 20.) / 20.) 1800. ;
  71. SI ipsc ;
  72.   OPTI 'FTRA' 'exo_3_temperature.ps' ;
  73. FINSI ;
  74. REPE b1 n1 ;
  75.   tps1  = tab1 . 'TEMPS' . (&b1 - 1) ;
  76.   p100  = ENTI (100. * tps1 / 1.E5) ;
  77.   te1   = tab1 . 'TEMPERATURES' . (&b1 - 1) ;
  78.   SI itrac ;
  79.     TRAC te1 mail (CONT mail) liso 'TITR' (CHAI 'Temperature au temps' tps1 ' (' p100 '%)') ;
  80.   FINSI ;
  81. FIN b1 ;
  82. ev1   = EVOL 'ROUG' 'TEMP' tab1 'TEMPERATURES' 'T' p1 ;
  83. ev2   = EVOL 'BLEU' 'TEMP' tab1 'TEMPERATURES' 'T' p2 ;
  84. tl    = TABL ;
  85. tl . 'TITRE' = TABL ;
  86. tl . 'TITRE' . 1 = 'Coin inf. gauche' ;
  87. tl . 'TITRE' . 2 = 'Coin sup. droite' ;
  88. SI itrac ;
  89.   SI ipsc ;
  90.     OPTI 'FTRA' 'exo_3_evol.ps' ;
  91.   FINSI ;
  92.   DESS (ev1 ET ev2) 'LEGE' 'SE' tl 'TITR' 'Temperature vs Temps' 'YBOR' 0. 2000. ;
  93. FINSI ;
  94.  
  95. FIN ;
  96.  
  97.  
  98.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales