Télécharger la plaquette Cast3M


fr en

Télécharger formation_pasapas_2_initial.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : formation_pasapas_2_initial.dgibi
  2. *
  3. *----------------------------------------------------------------------*
  4. *              FORMATION AVANCEE SUR LA PROCEDURE PASAPAS              *
  5. *                                                                      *
  6. * Rupture d'une eprouvette entaillee en traction                       *
  7. * Comportement elastique lineaire                                      *
  8. *                                                                      *
  9. * Ce fichier constitue la mise donnee initiale du probleme et realise  *
  10. * - le maillage                                                        *
  11. * - la definition du modele et des parametres materiaux                *
  12. * - la definition du chargement                                        *
  13. * - la resolution avec PASAPAS                                         *
  14. * - le post traitement (contraintes, courbe force/deplacement)         *
  15. *----------------------------------------------------------------------*
  16.  
  17.  
  18.  
  19.  
  20.  
  21. ** Options de trace / Plotting options
  22. itrac = FAUX ;
  23. ***OPTI 'TRAC' 'PSC' ;
  24. ipsc  = EGA (VALE 'TRAC') 'PSC' ;
  25.  
  26. ** Options generales / General options
  27. OPTI 'DIME' 2 'ELEM' 'TRI6' 'MODE' 'PLAN' 'CONT' ;
  28.  
  29. ** Maillage / Mesh
  30. OPTI 'DENS' 0.1 ;
  31. p1   = 0.   0. ;
  32. p2   = 1. 0. ;
  33. p3   = 1.   1. ;
  34. p4   = 0.55 1. ;
  35. p7   = 0.45 1. ;
  36. p8   = 0. 1. ;
  37. OPTI 'DENS' 0.005 ;
  38. pc   = 0.5 0.5 ;
  39. p5   = pc PLUS ( 0.005 -0.0025) ;
  40. p6   = pc PLUS (-0.005 -0.0025) ;
  41. con  = DROI p1 p2 DROI p3 DROI p4 DROI p5 CERC pc p6 DROI p7 DROI p8 DROI p1 ;
  42. s1   = SURF con ;
  43. l1   = con ELEM 'COMP' p8 p1 ;
  44. l2   = con ELEM 'COMP' p2 p3 ;
  45.  
  46. ** Modele et materiau / Model and material properties
  47. mo   = MODE s1 'MECANIQUE' ;
  48. ma   = MATE mo 'YOUN' 210.E9 'NU' 0.3 ;
  49.  
  50. ** Blocages mecaniques / mechanical blocking
  51. bl1   = BLOQ 'UX' l1 ;
  52. bl2   = BLOQ 'UX' l2 ;
  53. bl3   = BLOQ 'UY' (p1 ET p2) ;
  54. bl    = bl1 ET bl2 ET bl3 ;
  55.  
  56. ** Chargement en deplacement impose / Load with imposed displacement
  57. u2    = DEPI bl2 0.025 ;
  58. ev1   = EVOL 'MANU' (PROG 0. 1.) (PROG 0. 1.) ;
  59. cha   = CHAR 'DIMP' u2 ev1 ;
  60. SI ipsc ;
  61.   OPTI 'FTRA' 'exo_2_chargement.ps' ;
  62. FINSI ;
  63. SI itrac ;
  64.   TRAC (VECT u2 'FLX' ' ' 'VERT') ((RIGI mo ma) ET bl1 ET bl3) ;
  65. FINSI ;
  66.  
  67. ** Resolution
  68. tab1                         = TABL ;
  69. tab1 . 'MODELE'              = mo ;
  70. tab1 . 'CARACTERISTIQUES'    = ma ;
  71. tab1 . 'BLOCAGES_MECANIQUES' = bl ;
  72. tab1 . 'CHARGEMENT'          = cha ;
  73. tab1 . 'TEMPS_CALCULES'      = PROG 0.1 'PAS' 0.05 1. ;
  74. PASAPAS tab1 ;
  75.  
  76. ** Post-traitement / Post-processing
  77. liso  = PROG 0. 'PAS' 0.5E9 20.E9 ;
  78. *box   = (0. -0.2) ET (1. 1.4) ;
  79. nt1   = DIME (tab1 . 'TEMPS') ;
  80. SI ipsc ;
  81.   OPTI 'FTRA' 'exo_2_sigma.ps' ;
  82. FINSI ;
  83. REPE b1 nt1 ;
  84. * contraintes / stresses
  85.   sg1   = tab1 . 'CONTRAINTES' . (&b1 - 1) ;
  86. * modele / model
  87.   msh1  = EXTR sg1 'MAIL' ;
  88.   mo1   = REDU mo msh1 ;
  89. * contraintes principales / principal stresses
  90.   sp1   = EXCO 'SI11' (PRIN sg1 mo1) ;
  91. * deplacements / displacements
  92.   u1    = tab1 . 'DEPLACEMENTS' . (&b1 - 1) ;
  93. * deformee / deformed shape
  94.   def1  = DEFO s1 u1 5. ;
  95. * traces / plot
  96.   SI itrac ;
  97.     TRAC sp1 mo1 def1 con liso ;
  98.   FINSI ;
  99. FIN b1 ;
  100.  
  101. FIN ;
  102.  
  103.  
  104.  
  105.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales