Télécharger la plaquette Cast3M


fr en

Télécharger formation_pasapas_1_initial.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : formation_pasapas_1_initial.dgibi
  2. *
  3. *----------------------------------------------------------------------*
  4. *              FORMATION AVANCEE SUR LA PROCEDURE PASAPAS              *
  5. *                                                                      *
  6. * Flexion d'une poutre en grands deplacements avec chargemet suiveur   *
  7. *                                                                      *
  8. * Ce fichier constitue la mise donnee initiale du probleme et realise  *
  9. * - le maillage                                                        *
  10. * - la definition du modele et des parametres materiaux                *
  11. * - la definition du chargement sur la configuration initiale          *
  12. * - la resolution avec PASAPAS en hypothese petites perturbations      *
  13. * - le post traitement du deplacement de la poutre                     *
  14. *----------------------------------------------------------------------*
  15.  
  16.  
  17.  
  18.  
  19.  
  20. ** Options de trace / Plotting options
  21. itrac = FAUX ;
  22. ***OPTI 'TRAC' 'PSC' ;
  23. ipsc = EGA (VALE 'TRAC') 'PSC' ;
  24.  
  25. ** Options generales / general options
  26. OPTI 'DIME' 2 'ELEM' 'SEG2' ;
  27.  
  28. ** Maillage / Mesh
  29. p1   = 0. 0. ;
  30. p2   = 0. 1. ;
  31. l1   = DROI 25 p1 p2 ;
  32.  
  33. ** Modele et materiau / Model and material properties
  34. mo1  = MODE l1 'MECANIQUE' 'ELASTIQUE' 'POUT' ;
  35. ma1  = MATE mo1 'YOUN' 50.E6 'NU' 0.3 'SECT' 1.E-2 'INRZ' 1.E-4 ;
  36.  
  37. ** Blocages de la base / Clamping the base
  38. blo1 = BLOQ 'DEPL' 'ROTA' p1 ;
  39.  
  40. ** Chargement en effort impose / Load with imposed force
  41. f1   = FORC (1. 0.) p2 ;
  42. ev1  = EVOL 'MANU' 'Temps' (PROG 0. 1.) 'Coef' (PROG 0. 4.E4) ;
  43. cha1 = CHAR 'MECA' f1 ev1 ;
  44.  
  45. ** Resolution
  46. tab1                         = TABL ;
  47. tab1 . 'MODELE'              = mo1 ;
  48. tab1 . 'CARACTERISTIQUES'    = ma1 ;
  49. tab1 . 'BLOCAGES_MECANIQUES' = blo1 ;
  50. tab1 . 'CHARGEMENT'          = cha1 ;
  51. tab1 . 'TEMPS_CALCULES'      = PROG 0. 'PAS' 0.005 1. ;
  52. tab1 . 'GRANDS_DEPLACEMENTS' = VRAI ;
  53. tab1 . 'K_SIGMA'             = FAUX ;
  54. PASAPAS tab1 ;
  55.  
  56. ** Post-traitement / Post-processing
  57. tt   = tab1 . 'TEMPS' ;
  58. tu1  = tab1 . 'DEPLACEMENTS' ;
  59. tr1  = tab1 . 'REACTIONS' ;
  60. def0 = DEFO l1 (tu1 . 0) 0. ;
  61. * trace des deformees / plotting deformed shape
  62. SI ipsc ;
  63.   OPTI 'FTRA' 'exo_1_deformee.ps' ;
  64. FINSI ;
  65. box  = (-0.8 -0.18) ET (0.85 1.) COUL 'JAUN' ;
  66. REPE b1 (DIME tt) ;
  67.   i1   = &b1 - 1 ;
  68.   tps1 = tt . i1 ;
  69.   u1   = tu1 . i1 ;
  70.   r1   = tr1 . i1 ;
  71.   v1   = VECT r1 2.E-5 'FORC' 'ROUG' ;
  72.   def1 = DEFO (l1 ET box) u1 1. v1 'BLEU' ;
  73.   SI itrac ;
  74.     TRAC (def0 ET def1) 'TITR' (CHAI 'Deformee au temps ' tps1) ;
  75.   FINSI ;
  76. FIN b1 ;
  77. * evolution temporelle des deplacements / time evolution of displacements
  78. tleg               = TABL ;
  79. tleg . 'TITRE'     = TABL ;
  80. tleg . 'TITRE' . 1 = 'Ux' ;
  81. tleg . 'TITRE' . 2 = 'Uy' ;
  82. evux1 = EVOL 'ROUG' 'TEMP' tab1 'DEPLACEMENTS' 'UX' p2 ;
  83. evuy1 = EVOL 'BLEU' 'TEMP' tab1 'DEPLACEMENTS' 'UY' p2 ;
  84. SI ipsc ;
  85.   OPTI 'FTRA' 'exo_1_evol.ps' ;
  86. FINSI ;
  87. SI itrac ;
  88.   DESS (evux1 ET evuy1) 'TITR' 'Deplacements vs Temps' 'LEGE' 'SO' tleg 'TITY' 'DEPLACEMENT' ;
  89. FINSI ;
  90.  
  91. FIN ;
  92.  
  93.  
  94.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales