Exemples de jeux de données Cast3M

* fichier forgeage.dgibi
* section : thermomecanique plasticite grands deplacements
*----------------------------------------------------------------------*
*                     F O R G E A G E . D G I B I                      *
*----------------------------------------------------------------------*
* Objet :                                                              
* -------
*
*    Exemple de simulation du forgeage d'un tube en compression simple.
* On applique un effort sur le bord superieur du tube, le deplacement
* de sa partie inferieure etant bloque axialement. Le tube est soumis
* a un champ de temperature variant quadratiquement de 0 a 1000 degres
* du haut vers le bas.
*
*    Le tube a un comportement elastoplastique avec ecroissage lineaire
* isotrope. Ses carateristiques diminuent avec la temperature. Il se 
* deforme donc essentiellement dans sa partie chaude, comme dans le cas
* d'une mise en forme par forgeage.
*
*    On suppose que le tube est initialement a la temperature decrite.
* On calcule l'equilibre pas a pas, en appliquant la charge de facon
* croissante.
*
*    Le calcul est realise en grands deplacements. On utilise des 
* elements finis quadratiques a integration selective (BBAR) pour limiter
* les effets de verrouillage numerique dus a l'incompressibilite plastique.
*
*    Enfin, on regularise le maillage au cours du calcul a l'aide de
* l'operateur DEDU ADAP appele dans PERSO1 afin de limiter l'ecrasement
* des mailles sur le bas du maillage.
*
* Description :
* -------------
*
* Type de calcul : Mecanique, Plastique, Grands Deplacements
* Mode de calcul : 2D AXIS
* Type d'element : QUA8, TRI6
* Chargement     : Temperature, Force
*
*----------------------------------------------------------------------*
 
opti dime 2 elem qua8 mode axis ;
 
* ig1      : activation traces
* complet  : calcul complet
ig1      = faux ;
complet  = faux ;
 
*------------------------- Geometrie, maillage ------------------------*
 
* Parametres :
* ep1    : epaissseur du tube (m)
* lo1    : longueur du tube (m)
* Ri1    : rayon interieure du tube (m)
* hr1    : hauteur remaillage (m)
* de1    : densite maillage fin
* de2    : densite maillage grossier
ep1      = 1.0e-3 ;
lo1      = 3.e-3 ;
Ri1      = 5.e-3 ;
hr1      = 2.e-3 ;
de1      = 0.03e-3 ;
de2      = 0.25e-3 ;
de3      = de2 ;
de0      = 0.5 * de1 ;
 
* Points :
P1       = Ri1 0 ;
P2       = P1 plus (ep1 0) ;
P3       = P2 plus (0 hr1) ;
P4       = Ri1 hr1 ;
P5       = Ri1 lo1 ;
 
* Maillage du haut :
lm2      =  P4 droi P3 dini de3 dfin de3 ;
s2       = lm2 tran (P5 moin P4) dini de3 dfin de3 ;
s2       =  s2 coul gris ;
 
* Maillage du bas :
lb1      =  P1 droi P2 dini de0 dfin de0 ;
ld1      =  P2 droi P3 dini de0 dfin de2 ;
lm1      = lm2 ;
lg1      =  P4 droi P1 dini de2 dfin de0 ;
sr1      = surf (lb1 et ld1 et lm1 et lg1) ;
sr1      = sr1 coul oran ;
 
* Maillage "total"
s0       = sr1 et s2 ;
 
* Optimisation Sr1 avec DEDU ADAP :
opti mode plan ;
chde1    = mesu dens sr1 ;
chde1    = born chde1 scal comp de1 de2 ;
clada1   = (bloq depl (lg1 et ld1)) et (bloq depl (lb1 et lm1)) et (rela mili sr1) ;
chada1   = dedu adap sr1 clada1 dens chde1 ;
clada1   = (bloq uy lb1) et (bloq depl (ld1 et lm1 et lg1)) et (rela mili sr1) ;
srX      = (sr1 plus (0 0)) coul blan ;
form chada1 ;
opti mode axis ;
* Fin optimisation
 
si ig1 ;
  trac s0 titr ' Maillage tube' ;
  mbox1    = boite sr1 ;
  trac s0 boit mbox1 titr ' Zoom partie raffinee' ;
  trac (sr1 et srX) titr ' Maillage initial (blanc) / apres adaptation (orange)' ;
fins ;
 
*------------------------ Modelisation mecanique ----------------------*
 
* Caracteristiques materielles :
evym1    = evol roug manu 'T' (prog 0. 1000.) 'YOUN' (prog 210.e9 10.e9) ;
ecro0    = evol bleu manu 'EPSE' (prog 0. 1.) 'ECRO' (prog 300.e6 600.e6) ;
ecro1000 = evol vert manu 'EPSE' (prog 0. 1.) 'ECRO' (prog  10.e6  20.e6) ;
ecro1    = (nuag comp 'T' 0. comp 'ECRO' ecro0) et (nuag comp 'T' 1000. comp 'ECRO' ecro1000) ;
si ig1 ;
  dess evym1 titr 'Module de Young vs. temperature' ;
  tleg1    = table ;
  tleg1 . titre = table ;
  tleg1 . titre . 1 = 'T =    0 deg.' ;
  tleg1 . titre . 2 = 'T = 1000 deg.' ;
  dess ecro1 titr 'Courbes ecrouissage vs. temperature' lege tleg1 ;
fins ;
 
* Temperature initiale / imposee ;
chz1     = s0 coor 2 ;
cht1     = (((chz1 - lo1 / lo1) ** 2) * 1000.) nomc 'T' ;
 
mod1     = mode s0 mecanique elastique plastique isotrope bbar ;
chtref1  = chan cham mod1 cht1 ;
mat1     = mate mod1 youn evym1 nu 0.3 ecro ecro1 alph 1.e-5 tref chtref1 talp. 0. ;
 
* CL mecanique :
lh1      = s2 cote 3 ;
clmb1    = bloq uz lb1 ;
clmh1    = rela ense uz lh1 ;
 
* Force impose :
fimp1    = forc (0 -4000.) lh1 ;
ev1      = evol manu temp (prog 0. 1.) dimp (prog 0. 1.) ;
cgm1     = char meca fimp1 ev1 ;
 
* Chargement en temperature :
chz1     = s0 coor 2 ;
cht1     = (((chz1 - lo1 / lo1) ** 2) * 1000.) nomc 'T' ;
ev0      = evol manu temp (prog 0. 1.e12) dimp (prog 1. 1.) ;
cgt1     = char 'T' cht1 ev0 ;
 
si ig1 ;
  trac ((lh1 chan poi1) coul roug et s0) titr ' Noeuds deplacement impose' ;
  trac cht1 s0 titr 'Temperature imposee' ;
fins ;
 
*------------------------------- PERSO1 -------------------------------*
 
* Adaptation maillage avec PERSO1 :
debp perso1 tu1*table ;
wtab1    = tu1.wtable ;
 
* Sauvegarde configuration :
si (exis tu1 config_adaptation) ;
  iadap1   = dime tu1.config_adaptation ;
  tu1.config_adaptation.iadap1 = form ;
sino ;
  tu1.config_adaptation   = table ;
  tu1.config_adaptation.0 = form ;
fins ;
 
* Retour config. initiale & sortie si fin de calcul :
tps1     = tu1.'ESTIMATION'.'TEMPS' ;
tpsmax1  = (tu1.temps_calcules) maxi ;
si (tps1 ega tpsmax1) ;
  mess ' ***** PERSO1 : retour config. initiale' ;
  form (tu1.config_adaptation.0) ;
  quit perso1 ;
fins ;
 
* Adaptation :
geoada1  = tu1.donnees_perso1.geom   ;
rigada1  = tu1.donnees_perso1.clad   ;
chdens1  = tu1.donnees_perso1.chdens ;
epsm1    = tu1.donnees_perso1.seuil  ;
 
* Sauvegarde seuil adaptation :
si (exis wtab1 epsm_remail) ;
  seui1    = wtab1.epsm_remail ;
sino ;
  seui1    = epsm1 ;
fins ;
eps1     = tu1.estimation.deformations ;
epmax1   = maxi abs eps1 ;
 
* Test adaptation :
si (epmax1 > seui1) ;
  mess '  ***** PERSO1 : Adaptation maillage ' ;
  list seui1 ; list epsm1 ;
  wtab1.epsm_remail = seui1 + epsm1 ;
 
* Adaptation maillage avec DEDU ADAP :
  dep1     = tu1.estimation.deplacements ;
  conf1    = form dep1 ;
  opti mode plan ;
  chada1   = dedu adap geoada1 rigada1 dens chdens1 ;
  srx1     = (geoada1 plus (0 0)) coul blan ;
  form chada1 ;
  opti mode axis ;
  si ig1 ;
    trac nclk (srx1 et geoada1) titr 'Maillage initial (blanc) / adapte (orange)' ;
  fins ;
  form (-1.*dep1) ;
fins ;
 
finp ;
 
*------------------------- Resolution PASAPAS -------------------------*
 
ltca1    = prog 0. PAS 0.02 0.4 PAS 0.005 1. ;
si complet ;
  ltsa1    = prog 0. pas 0.02 1. ;
sino ;
  ltca1    = ltca1 extr (lect 1 pas 1 10) ;
  ltsa1    = ltca1 ;
fins ;
 
tpas1                      = table ;
tpas1. modele              = mod1 ;
tpas1. caracteristiques    = mat1 ;
tpas1. chargement          = cgm1 et cgt1 ;
tpas1. blocages_mecaniques = clmb1 et clmh1 ;
 
tpas1. grands_deplacements = vrai ;
tpas1. predicteur          = mot hpp ;
tpas1. lagrangien          = mot reactualise ;
 
tpas1. temps_calcules      = ltca1 ;
tpas1. temps_sauves        = ltsa1 ;
 
tpas1. procedure_perso1       = vrai ;
tpas1. donnees_perso1         = table ;
tpas1. donnees_perso1. geom   = sr1 ;
tpas1. donnees_perso1. clad   = clada1 ;
tpas1. donnees_perso1. chdens = chde1 ;
tpas1. donnees_perso1. seuil  = 0.05 ;
 
pasapas tpas1 ;
 
*-------------------------- Post-traitement ---------------------------*
 
if1      = (tpas1.temps) dime - 1 ;
depf1    = tpas1.deplacements.if1 ;
modf1    = mod1 ;
 
si ig1 ;
  conf0    = form ;
  form depf1 ;
 
  epsf1    = tpas1.estimation.deformations ;
  trac epsf1 modf1 titr 'Deformations en fin de calcul' ;
 
  sigf1    = tpas1.contraintes.if1 ;
  sigf1    = 1.e-6 * sigf1 ;
  trac sigf1 modf1 titr 'Contraintes en fin de calcul' ;
 
  form conf0 ;
fins ;
 
mbox1    = boite s0 ;
liso1   = prog -200. pas 25. 50. ;
def1    = vide deforme ;
repe b1 if1 ;
  depi1    = tpas1.deplacements.&b1 ;
  sigi1    = tpas1.contraintes.&b1 ;
  sigi1    = 1.e-6 * sigi1 ;
  form tpas1.config_adaptation.&b1 ;
  defi1    = defo s0 depi1 1. (exco sigi1 smzz smzz) mod1 ;
  form tpas1.config_adaptation.0 ;
  def1     = def1 et defi1 ;
  si (ega (vale trac) 'PSC') ;
    trac defi1 liso1 boit mbox1 ;
  fins ;
fin b1 ;
si ig1 ;
  trac anim def1 liso1 ; 
fins ;
 
fin ;
*----------------------------------------------------------------------*
*                 F I N   F O R G E A G E . D G I B I                  *
*----------------------------------------------------------------------*