Accueil | Cast3M

* fichier : fluendo3d_helmholtz.dgibi
************************************************************************
************************************************************************
*
* test de la formulation non-locale differentielle avec fluendo3d
* ----------------------------------------------------------------
*
* Alain Sellier, Alain Millard  mercredi 4 janvier 2023
*
*-----------------------------------------------------------------------
* Exemple de calcul non local avec une formulation d'Helmholtz
* a plusieurs variables, en 3D sur un tirant de section variable.
* 6 variables d'Helmholtz sont utilisees dans un contexte a coefficients
* constant (sans sous iteration de HelmHoltz). Les variables 
* correspondent aux increments du tenseur de plasticite en traction 
* du modele FLUENDO3D. Dans ce modele des variables internes nommees
* DNL1 a DNL6 permettent de diffuser les increments avec une longueur
* caracteristique lc0, les increments sont sommes dans ENL1 a ENL6,
* ces dernieres variables sont alors utilisees pour calculer 
* un endommagement orthotrope
*-----------------------------------------------------------------------
 
 
* test formulation Helmholtz avec Fluendo3d
opti dime 3 elem cub8;
* graphique en fin de calcul si VRAI
complet=FAUX;
arret=VRAI;
test=VRAI;
L1=0.05;
H1=0.05;
H2=0.04;
*nombre d element sur 1/2 longueur
n1=10;
DH12=(H1-H2)/2;
P1=0. 0. 0.;
P2=L1 Dh12 0.;
P3=L1 (DH12+H2) 0.;
P4=0. H1 0.;
P5=L1 DH12 (DH12+H2);
L12= P1 n1 droi p2;
l23= p2 1 droi p3;
l34=p3 n1 droi p4;
l41=p4 1 droi p1;
surf1=daller l12 l23 l34 l41;
app1=(l41 tran 1 (0. 0. H1)) coul roug;
vol1=surf1 volu tran 'PROG' (prog 0. H1) (0. 0. H1);
vol2=vol1 syme 'PLAN' p2 p3 p5;
surf2=(app1 syme 'PLAN' p2 p3 p5) coul vert;
elim vol2 surf2 0.001;
elim app1 vol1 0.001;
vol3=vol1 et vol2;
elim vol3 0.001;
*trac vol3;
 
*blocage
blo0 = BLOQ P4 UZ;
blo1 = BLOQ P1 UX UY UZ;
blo2 = BLOQ APP1 UX  ;
blo3 = BLOQ SURF2 UX ;
blo4 = blo0 et blo1 et blo2 et blo3 ;
 
*deplcement impose
dep3 = DEPI blo3 1. ;
temps1 = prog 0. 1. ;
coef1 = prog 0. 5.0e-5 ;
evol1 = evol manu 'TEMPS' temps1 'COEF' coef1 ;
char1 = char 'DIMP' dep3 evol1 ;
 
*modele
mod1=MODELE vol3 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 
 'VISCOPLASTIQUE' 'FLUENDO3D' 'NON_LOCAL' 'HELM'  'V_MOYENNE'  
 ( MOTS  'ENL1' 'ENL2' 'ENL3' 'ENL4' 'ENL5' 'ENL6');
 
*materiau
rt0=3.8;
rc0 = 38.;
*ep0=1.5e-4;
E0=32000.;
ept0=1.0*rt0/e0;
gft0 = 1.10e-4 ;
 
*Beton
matb1= MATE mod1 YOUN E0 NU 0.2 RHO 2400. ALPH 1.0e-5 NREN 0;
 
* endommagement
matd1= MATE mod1 YORF E0 NURF 0.2  HREF 1. HYDR 1.  
HYDS 0.2 RT rt0 EPT ept0 GFT gft0 RC rc0 EPC 2.0e-3 DELT 0.75
BETA 0.15 EKDC 5.0e-3 REF 3. GFR 2.0e-4 ALTC 0. ;
 
* effets de l eau 
matgw1=MATE mod1 PORO 0.12 VW 0.12 BSHR 0.5 MSHR 44. MVGN 0.5 DCDW 0.0 
 CSHR 0.  TTKW 40. TTRW 20. KWRT 0.25 KWRC 0.1;
 
* fluage
matf1=MATE mod1  TAUK 10. YKSY 5.1 TAUM 10. EKFL 0.7e-4 TTRF 20.
XFLU 1. NRJM 20000. DFMX 0. ;
 
*Weibull scale effect : note cf below to prepar Vmax field
*matw1=MATE mod1 VREF 2.1e-4 VMAX 2.1e-4 CVRT 0.15  DHI1 0.5; 
 
*---------NON LOCAL ------------
 
* 1ere variable non locale *****
 
*longueur de diffusion
lc0=0.02;
*coeff de diffusion
dh0=(lc0**2)/2.d0;
 
*diffusion des composantes du tenseur des increment de deformations plastiques
 
* DNL1=dexx
matnl1=MATE mod1 'CAP1' 1.  'BLO1' 0. 'DEP1' 0. 'INI1' 0. 'LIN1' 1.
                 'DH11' dh0 'V111' 1. 'V112' 0. 'V113' 0.
                 'DH12' 0.  'V121' 0. 'V122' 1. 'V123' 0.
                 'DH13' 0.  'V131' 0. 'V132' 0. 'V133' 1.;
* DNL2=deyy
matnl2=MATE mod1 'CAP2' 1.  'BLO2' 0. 'DEP2' 0. 'INI2' 0. 'LIN2' 1.
                 'DH21' 0.  'V211' 1. 'V212' 0. 'V213' 0.
                 'DH22' dh0 'V221' 0. 'V222' 1. 'V223' 1.
                 'DH23' 0.  'V231' 0. 'V232' 0. 'V233' 1.;
* DNL3=dezz
matnl3=MATE mod1 'CAP3' 1.  'BLO3' 0. 'DEP3' 0. 'INI3' 0. 'LIN3' 1.
                 'DH31' 0.  'V311' 1. 'V312' 0. 'V313' 0.
                 'DH32' 0.  'V321' 0. 'V322' 1. 'V323' 0.
                 'DH33' dh0 'V331' 0. 'V332' 0. 'V333' 1.;
* DNL4=dexy
matnl4=MATE mod1 'CAP4' 1.  'BLO4' 0. 'DEP4' 0. 'INI4' 0. 'LIN4' 1.
                 'DH41' (dh0/2.) 'V411' 1. 'V412' 0. 'V413' 0.
                 'DH42' (dh0/2.) 'V421' 0. 'V422' 1. 'V423' 0.
                 'DH43' 0.  'V431' 0. 'V432' 0. 'V433' 1.;
* DNL5=dexz
matnl5=MATE mod1 'CAP5' 1.  'BLO5' 0. 'DEP5' 0. 'INI5' 0. 'LIN5' 1.
                 'DH51' (dh0/2.) 'V511' 1. 'V512' 0. 'V513' 0.
                 'DH52' 0.0 'V521' 0. 'V522' 1. 'V523' 0.
                 'DH53' (dh0/2.) 'V531' 0. 'V532' 0. 'V533' 1.;
* DNL6=deyz
matnl6=MATE mod1 'CAP6' 1.  'BLO6' 0. 'DEP6' 0. 'INI6' 0. 'LIN6' 1.
                 'DH61' 0.0 'V611' 1. 'V612' 0. 'V613' 0.
                 'DH62' (dh0/2.) 'V621' 0. 'V622' 1. 'V623' 0.
                 'DH63' (dh0/2.) 'V631' 0. 'V632' 0. 'V633' 1.;
*-----------------------------------------------------------------------
 
*material chracteristics assemblage
mat1=matb1 ET matd1 ET matf1 ET matgw1 
           ET matnl1 ET matnl2 ET matnl3
           ET matnl4 ET matnl5 ET matnl6 ; 
 
tab1=table;
tab1.mova=mot 'EPT1';
tab1.modele=mod1;
tab1.caracteristiques=mat1;
tab1.blocages_mecaniques=blo4;
tab1.chargement=char1; 
list3 = prog 0. pas 0.01 0.4 ;
*liste des temps calcules 
tab1.temps_calcules=list3 ;
tab1.precision=1.0E-4;
TAB1.processeurs= CHAINE  'AUTOMATIQUE';
*controleurs pour les sous iteration de Helmholtz
TAB1.MAXSOUSITERATION  = 500;
TAB1.PRECSOUSITERATION  = 1.0E-6;
pasapas tab1;
 
************************************************************************
* exploitation des resultats
************************************************************************
 
*force deplacement
evolfx1=@global tab1 blo3 evol1 FX;
si (test);
 n1=20; fref1=7.14727E-03;
 n2=40; fref2=4.51279E-03;
 LISTF1='EXTR' EVOLFX1 'ORDO';
 fcal1='EXTR' LISTF1 (n1+1);
 fcal2='EXTR' LISTF1 (n2+1);
 err1 = abs ((fref1 - fcal1)/fref1) ; 
 err2 = abs ((fref2 - fcal2)/fref2) ;
 si ((err1 < 1.e-3) et (err2 < 5.e-3)) ;
    erre 0 ;
 sinon ;
    erre 5 ;
 finsi ;
finsi;
 
 
*exemple de traces
si (complet);
    dess evolfx1;
    ech1=prog 0. pas 0.01 1.;
    n1=dime tab1.temps;
    def1=defo tab1.deplacements.(n1-1) vol3;
    dt11= exco 'ENL1' tab1.variables_internes.(n1-1) ;
    trac dt11 mod1 def1 titr 'deformation plastique 6 ';
    cmod1 = exco 'WPL0' tab1.variables_internes.(n1-1) ;
    trac cmod1  mod1 def1 ;
    dt11= exco 'DTRA' tab1.variables_internes.(n1-1) ;
    trac dt11  mod1 def1  (prog 0. pas 0.05 1.);
finsi;
 
si(arret);
    fin;
finsi;