Télécharger la plaquette Cast3M


fr en

Télécharger fluendo3d_fibre.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : fluendo3d_fibre.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. * test du modele de beton fibre (these de Romain Gontero, 2022)
  6. * ----------------------------------------------------------------
  7. *
  8. * Romain Gontero,  Alain Sellier, Alain Millard, Thierry Vidal
  9. * mercredi 4 janvier 2023
  10. *
  11. *-----------------------------------------------------------------------
  12. * Exemple de calcul d un element fini en beton fibre
  13. * la presence de fibre est signale par l inficateur FIBR qui est a 1 
  14. *-----------------------------------------------------------------------
  15. *
  16. 'OPTI' 'DIME' 3 'ELEM' CUB8;
  17. GRAPH = FAUX;
  18. *MAILLAGE
  19. N1=1;
  20. *N2 POUR LA HAUTEUR
  21. N2=1;
  22. DENS1=0.2;
  23. DENS2=0.2;
  24. L1=0.1;
  25. H1=0.2;
  26. P1=0. 0. 0.;
  27. P2=L1 0. 0.;
  28. P3=L1 L1 0.;
  29. P4=0. L1 0.;
  30. P33=L1 L1 H1;
  31. P11=0. 0. H1;
  32. P22=L1 0. H1;
  33. P44=0. L1 H1;
  34. D12='DROI' N1 P1 P2;
  35. D23='DROI' N1 P2 P3;
  36. D34='DROI' N1 P3 P4;
  37. D41='DROI' N1 P4 P1;
  38. D111='DROI'  P1 P11 'DINI' DENS1 'DFIN' DENS2;
  39. D222='DROI'  P2 P22 'DINI' DENS1 'DFIN' DENS2;
  40. D333='DROI'  P3 P33 'DINI' DENS1 'DFIN' DENS2;
  41. D444='DROI'  P4 P44 'DINI' DENS1 'DFIN' DENS2;
  42. D2233='DROI' N1 P22 P33;
  43. D3344='DROI' N1 P33 P44;
  44.  
  45. SURF1='DALLER' D12 D23 D34 D41;
  46. SURF2=SURF1 'PLUS' (0. 0. H1);
  47. VOL1=SURF1 'VOLU' TRANS (0. 0. H1) 'DINI' DENS1 'DFIN' DENS2;
  48. SXZ0=D12 TRANS  (0. 0. H1) 'DINI' DENS1 'DFIN' DENS2;
  49. SYZ0=D41 TRANS  (0. 0. H1) 'DINI' DENS1 'DFIN' DENS2;
  50. SDRAD1= SYZ0 'PLUS' (L1 0 0);
  51. 'ELIM' 1.E-4 VOL1 (SURF2 'ET' SXZ0 'ET' SYZ0 'ET' P33 'ET' D333 'ET' D444 'ET' D222 
  52.  'ET' D111 'ET' D2233 'ET' D3344 'ET' SDRAD1);
  53.  
  54. 'SI' (GRAPH);
  55.     'TRAC' VOL1 QUAL CACH;
  56. 'FINSI';
  57.  
  58.  
  59. MOD1=MODELE VOL1 MECANIQUE ELASTIQUE ISOTROPE 'VISCOPLASTIQUE' 'FLUENDO3D';    
  60.  
  61. * BETON
  62. RT0=9.5;
  63. E0=40000.;
  64. EP0T=RT0/E0;
  65. GFT0=1.0E-4;
  66. MATB1= 'MATE' MOD1 YOUN E0 NU 0.2 RHO 2400. ALPH 1.0E-5 FIBR 1 NREN 0 ;
  67. * YOUN : MODULE D YOUNG HOMOGENEISE INITIAL
  68. * NU   : COEFFICIENT DE POISSON HOMOGENEISE INITIAL
  69. * ALPH : COEFF DE DILATATION THERMIQUE
  70. * FIBR : ENTIER À METTRE À 1 DANS LE MODÈLE DE BÉTON EN PRÉSENCE DE FIBRES, 0 EN L'ABSENCE DE FIBRES
  71. * NREN : NOMBRE DE RENFORTS
  72.  
  73. * ENDOMMAGEMENT
  74. MATD1= 'MATE' MOD1 YORF E0 NURF 0.2  HREF 1. HYDR 1. 
  75. HYDS 0.2 RT RT0 EPT EP0T GFT GFT0 RC 150. EPC 2.0E-3 DELT 0.75
  76. BETA 0.15 EKDC 5.0E-3 REF 5. GFR 1.0E-4 ALTC 0. TSTH 45. DT80 0.15 ;
  77. * HYDR : DEGRE D HYDRATATION
  78. * HREF : HYDRATATION DE REFERENCE POUR LES DONNEES DEPENDANTES DE L HYDRATATION
  79. * HYDS : HYDRATATION SEUIL DE PERCOLATION MECANIQUE
  80. * RT   : RESISTANCE A LA TRACTION POUR L HYDRATATION DE REFERENCE 
  81. * EPT  : DEFORMATION AU PIC DE TRACTION POUR ...
  82. * GFT  : ENERGIE DE FISSURATION EN TRACTION ...
  83. * RC   : RESISTANCE A LA COMPRESSION ...
  84. * EPC  : DEFORMATION AU PIC DE COMPRESSION ...
  85. * DELT : INFLUENCE DE LA PRESSION DE CONFINEMENT SUR LA RESISTANCE AU CISAILLEMENT
  86. * BETA : DILATANCE POST PIC DE COMPRESSION
  87. * EKDC : DEFORMATION CARACTERISTIQUE POUR L ENDOMMAGEMENT DE COMPRESSION
  88. * REF  : CONTRAINTE DE REFERMETURE DE FISSURE...
  89. * GFR  : ENERGIE DE REFERMETURE DE FISSURE...
  90. * 'SI' ON EST EN 2D LA DIMENSION TRANSVERSALE EST DIM3 
  91.  
  92. * EFFETS DE L EAU 
  93. MATGW1='MATE' MOD1 PORO 0.12 VW 0.12 BSHR 0.5 MSHR 44. MVGN 0.5 DCDW 0.0 
  94.  CSHR 0. HSHR 1.0E5 TTKW 40. TTRW 20. KWRT 0.25 KWRC 0.1;
  95. * PORO : POROSITÉ
  96. * VW   : VOLUME D'EAU
  97. * BSHR : COEFFICEIENT DE BIOT POUR L EAU
  98. * MSHR : CONTRAINTE  CAPILLAIRE MOYENNE EN SECHAGE
  99. * MVGN : NON LINERAITE DE L ISOTHERME
  100. * DCDW : COUPLAGE MICRO-FISSURATION HYDRIQUE / ENDOMMAGEMENT DE COMPRESSION
  101. * EKDW : DEFORMATION CARACTERISTIQUE  DE L ENDOMMAGEMENT HYDRIQUE DE TRACTION
  102. * KSHR : COEFF DE CONCENTRATION DE CONTRAINTE POUR LA PRESSION D EAU
  103. * HSHR : MODULE D ECROUISSAGE POUR LA RESISTANCE LOCAL A LA DEPRESSION CAPILLAIRE
  104. * TTKW : ECART DE TEMPERATURE CARACTERISTIQUE POUR LE VOLUTION DE LA CONTRAINTE CAPILLAIRE
  105. * KWRT : INFLUENCE DE LA PRESSION CAPILLAIRE MOYENNE SUR LA RESISTANCE A LA TRACTION
  106. * KWRC : INFLUENCE DE LA PRESSION CAPILLAIRE MOYENNE SUR LA RESISTANCE A LA COMPRESSION
  107.  
  108. * FLUAGE
  109. MATF1='MATE' MOD1  TAUK 10. YKSY 5.1 TAUM 14. EKFL 0.7E-4 TTRF 20.
  110. XFLU 1. NRJM 20000. DFMX 0. ;
  111. * TAUK : TEMPS CARACTERISTIQUE DU FLUAGE REVERSIBLE ICI ENJOURS
  112. * YKSY :  DEFORMATION ELASTIQUE / DEFORMATION DE FLUAGE REVERSIBLE
  113. * TAUM : TEMPS CARACTERISTIQUE DU FLUAGE PERMANENT ICI EN JOUR
  114. * EKFL : POTENTIEL DE FLUAGE PERMANENT
  115. * TTRF : TEMPERATURE DE REFERENCE POUR LEES DONNES DE FLUAGE
  116. * XFLU : AMPLIFICATION NON LINEAIRE DU FLUAGE À 60% DE RC
  117. * NRJM : ENERGIE D ACTIVATION DU FLUAGE
  118. * DFMX : ENDOMMAGEMENT MAXI PAR FLUAGE
  119.  
  120.  
  121. * PARAMETRES POUR LES FIBRES (CAS DU TEST SUR UN EF) cf. PhD Romain Gontero (2022)
  122. MATFIB1= 'MATE' MOD1  RHOF 0.03 RTEC 9.5 DIFI 2.0E-4 LOFI 12.0E-3 HFI 8.0E6 TMAX 7. TD 6.
  123. SK 1.0E-3 FABO 2.0E-6 ALEC 35. MECR 8. LCAN 1.0E-3 MUF 0.5 YOFI 2.0E5 LECH 0.2 MW 8.
  124. FU 2500.  FYF 2400. EOF1 1. EOF2 1. EOF3 50. VF11 1. VF12 0. VF13 0. VF21 0. VF22 1. VF23 0. ;
  125. * 'FIBR'  :  entier à mettre à 1 dans le modèle de béton en présence de fibres, 0 en l'absence de fibres
  126. * 'RHOF'  :  densité volumique de fibres
  127. * 'RTEC'  :  résistance moyenne à la traction du béton issue d'un essai de référence de longueur LECH dans la direction de traction
  128. * 'LECH'  :  longueur de l'essai de référence dans la direction de traction
  129. * 'MW  '  :  coefficient de Weibull lié à la dispersion des résistances à la traction du béton
  130. * 'DIFI'  :  diamètre des fibres
  131. * 'LOFI'  :  longueur des fibres
  132. * 'HFI '  :  rigidité de l'interface fibre-matrice
  133. * 'TMAX'  :  contrainte de début de décollement de l'interface fibre-matrice
  134. * 'TD  '  :  contrainte de frottement fibre-matrice en zone décollée
  135. * 'SK  '  :  glissement caractéristique d'abrasion de l'interface en phase d'arrachement des fibres
  136. * 'MECR'  :  module d'écrouissage (contrainte) liée à l'accumulation de particules à l'interface fibre-matrice en phase d'arrachement des fibres
  137. * 'LCAN'  :  longueur ancrée caractéristique liée à l'impact de l'ancrage sur l'abrasion fibre-matrice phase d'arrachement des fibres
  138. * 'FABO'  :  force d'about lié à un défaut d'extrémité des fibres
  139. * 'ALEC'  :  angle d'ouverture du pentaèdre d'écaillage (°)
  140. * 'MUF '  :  coefficient de frottement fibre-matrice pour les fibres inclinées par rapport à la direction d'extraction
  141. * 'YOFI'  :  module d'Young des fibres
  142. * 'FU  '  :  contrainte ultime admissible par une fibre
  143. * 'FYF '  :  limite élastique des fibres
  144. * 'EOF1'  :  valeur de l'ellipsoïde d'orientation des fibres dans la direction VF1
  145. * 'EOF2'  :  valeur de l'ellipsoïde d'orientation des fibres dans la direction VF2
  146. * 'EOF3'  :  valeur de l'ellipsoïde d'orientation des fibres dans la direction VF3
  147. * 'VF11'  :  composante 1 du premier vecteur principal d'inclinaison des fibres
  148. * 'VF12'  :  composante 2 du premier vecteur principal d'inclinaison des fibres
  149. * 'VF13'  :  composante 3 du premier vecteur principal d'inclinaison des fibres
  150. * 'VF21'  :  composante 1 du second vecteur principal d'inclinaison des fibres
  151. * 'VF22'  :  composante 2 du second vecteur principal d'inclinaison des fibres
  152. * 'VF23'  :  composante 3 du second vecteur principal d'inclinaison des fibres   
  153.  
  154. * ASSEMBLAGE DIFFERENTES COMPOSANTES DU MATERIAU
  155. MAT1=MATD1 'ET' MATF1 'ET' MATGW1 'ET' MATB1 'ET' MATFIB1; 
  156.  
  157. *CHARGEMENT
  158. *DÉPLACEMENT 
  159. CL1='BLOQ' SURF1 UZ;
  160. CL2='BLOQ' SURF2 UZ;
  161. CL3='BLOQ' SXZ0 UY;
  162. CL4='BLOQ' SYZ0 UX;
  163. CL0=CL1 'ET' CL2 'ET' CL3 'ET' CL4;
  164. CD1='DEPI' CL2 1.;
  165.  
  166. *LISTE POUR LE TEST SUR PLUSIEURS EF
  167. LIST1=1.0E-4*('PROG' 0. PAS 0.02 1. PAS 0.1 5. PAS 0.4 10.);
  168.  
  169. *CONSTRUCTION DE LA LISTE DES TEMPS
  170. N1='DIME' LIST1;
  171. LIST2='PROG' 0.;
  172. X0=0.;
  173. X2=0.;
  174. 'REPE' BOU1 (N1-1);
  175.  X1='EXTR' LIST1 (&BOU1+1);
  176.  DX2='ABS'(X1-X0);
  177.  X0=X1;
  178.  X2=X2+DX2;
  179.  LIST2=LIST2 'ET' ('PROG' X2);
  180. 'FIN' BOU1 ;
  181.  
  182. EVOL1='EVOL' 'MANU' 'TEMPS' LIST2 'DEPI' LIST1;
  183. 'SI' GRAPH;
  184.     'DESS' EVOL1 ;
  185. 'FINSI';
  186.  
  187. * CHARGEMENT
  188. CHAR1= 'CHAR' 'MECA' CD1 EVOL1;
  189.  
  190. TAB1='TABLE';
  191. TAB1.MODELE=MOD1;
  192. TAB1.CARACTERISTIQUES=MAT1;
  193. TAB1.BLOCAGES_MECANIQUES=CL0;
  194. TAB1.CHARGEMENT=CHAR1;
  195. TAB1.PRECISION=1.0E-4;
  196. TAB1.PROCESSEURS='MOT' 'COMPORTEMENT';
  197. TAB1.TEMPS_CALCULES=LIST2;
  198. PASAPAS TAB1;
  199.  
  200. ******************************
  201. * EXPLOITATION DES RESULTATS *
  202. ******************************
  203.  
  204. *FORCE DEPLACEMENT
  205. EVOLFZ2=@GLOBAL TAB1 CL2 EVOL1 FZ;
  206.  
  207. 'SI' (GRAPH);
  208.     'DESS' EVOLFZ2;
  209. 'FINSI';
  210.  
  211. VAL1=6.78478E-02;
  212. VAL2=1.44792E-01;
  213. VAL3=1.18949E-01;
  214.  
  215. LISTF1='EXTR' EVOLFZ2 'ORDO';
  216. T1='EXTR' LISTF1 16;
  217. T2='EXTR' LISTF1 82;
  218. T3='EXTR' LISTF1 104;
  219.  
  220. 'SI' ((T1-VAL1)**2 > 1.0E-8);
  221.     'MESS' 'ERREUR DE VERIFICATION 1';
  222.     'ERRE' 5;
  223. 'FINSI';
  224.  
  225. 'SI' ((T2-VAL2)**2 > 1.0E-8);
  226.     'MESS' 'ERREUR DE VERIFICATION 2';
  227.     'ERRE' 5;
  228. 'FINSI';
  229.  
  230. 'SI' ((T3-VAL3)**2 > 1.0E-8);
  231.     'MESS' 'ERREUR DE VERIFICATION 3';
  232.     'ERRE' 5
  233. 'SINON';
  234.     'ERRE' 0;
  235. 'FINSI';
  236.  
  237. 'FIN';
  238.  
  239.  
  240.  
  241.  
  242.  
  243.  
  244.  
  245.  
  246.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales