Exemples de jeux de données Cast3M

* fichier : fluendo3d_beton_arme.dgibi
************************************************************************
************************************************************************
*
* test de la formulation beton_arme du mdele fluendo3d
* ----------------------------------------------------------------------
*
* Alain Sellier, Stephane Multon, Pierre Morenon, Daniela Vo
* mercredi 4 janvier 2023
*
*-----------------------------------------------------------------------
* Exemple de calcul d un element charge en traction
*-----------------------------------------------------------------------
graph1=FAUX;
 
OPTI DIME 3 ELEM CUB8;
 
cas1='SELLIER';
n1=1;
n2=1;
l1=0.1;
h1=0.5;
p1=0. 0. 0.;
p2=l1 0. 0.;
p3=l1 l1 0.;
p4=0. l1 0.;
p33=l1 l1 h1;
p11=0. 0. h1;
p22=l1 0. h1;
p44=0. l1 h1;
d12=DROI n1 p1 p2;
d23=DROI n1 p2 p3;
d34=DROI n1 p3 p4;
d41=droi n1 p4 p1;
d111=droi n2 p1 p11;
d222=droi n2 p2 p22;
d333=droi n2 p3 p33;
d444=droi n2 p4 p44;
d2233=droi n1 p22 p33;
d3344=droi n1 p33 p44;
 
surf1=DALLER d12 d23 d34 d41 PLAN;
surf2=SURF1 PLUS (0. 0. h1);
vol1=surf1 VOLU TRANS n2 (0. 0. h1);
sxz0=d12 TRANS n2 (0. 0. h1);
syz0=d41 TRANS n2 (0. 0. h1);
elim 1.e-4 vol1 (surf2 et sxz0 et syz0 et p33 et d333 et d444 et d222 
 et d111 et d2233 et d3344);
si (graph1) ;   
    trac vol1 qual;
finsi;
 
 
 
*beton
rt0=4.;
E0=40000.;
n00=1.;
ep0=n00*(rt0/E0);
*comment faire varier hydratation et teneur en eau 
evh1=evol manu 'HYD1' (prog -1. 1.) 'HYDR' (prog -1. 1.);
evw1=evol manu 'W1' (prog -1. 1.) 'VW' (prog -1. 1.);
 
*modele
MOD1= MODE VOL1 MECANIQUE ELASTIQUE ISOTROPE VISCOPLASTIQUE FLUENDO3D;
 
*noyau lineaire
matef1= MATE mod1 YOUN 51000. NU 0.2 RHO 2400. ALPH 1.0e-5 NREN 1 
 TREF 20. TALP 20.;
 
*matrice
matd1= MATE mod1 YORF E0 NURF 0.2 HYDR evh1 HREF 1. 
 HYDS 0.2 RT rt0 EPT 1.0e-4 GFT 1.0e-4 RC 63. EPC 2.0e-3 DELT 1.
 BETA 0.15 EKDC 2.0e-3 REF 5. GFR 1.0e-4 TSTH 45. DT80 0.15 
 DALR 1.0e-5 ALTC 0. ;
 
* effets de l eau 
matgw1=MATE mod1 PORO 0.12 VW evw1 BSHR 0.25 MSHR 65. MVGN 0.5 
  TTKW 40. DCDW 0.50  SKDW 12.5 CSHR 2.0  KWRT 0.00  KWRC 0.00;
 
*fluage
matf1=MATE mod1  TAUK 0.7 YKSY 5.1 TAUM 10.0 EKFL 0.7e-4 TTRF 20. 
 XFLU 1. NRJM 20000. DFMX 0. MDTT 5. TDTT 1.0 WDTT 0.02 PDTT 2.0 ; 
 
*tres jeune age (avant percolation)
matja=mate mod1 YOJA 0.2 NUJA 0.49 SSJA 0.01 DLJA 0.4 TMJA 0.1; 
 
*renfort
Er1=210.0e3;
sy1=560.;
matr1=MATE mod1 roa1 0.05 deq1 0.012 yor1 Er1 syr1 sy1 HPL1 2000. 
 tyr1 6. vr11 0. vr12 0. vr13 1. SUR1 667. EPU1 0.07 WPR1 1. 
 HIR1 40000.;
 
*assemblage des composantes materiau
mat1=matef1 et matd1 ET matf1  ET matgw1 et matja et matr1; 
 
*blocage meca     
cl1=bloq sxz0 uy;
cl2=bloq surf1 uz;
cl3=bloq syz0 ux;
cl4=bloq surf2 uz;
cl0=cl1 et cl2 et cl3 et cl4;
cd1=depi cl4 1.;
rig1=rela 1. 'UY' d444 - 1. 'UY' d333;
rig2=rela 1. 'UX' d222 - 1. 'UX' d333;
rig3=rela 1. 'UX' d23 - 1. 'UX' d2233;
rig4=rela 1. 'UY' d34 - 1. 'UY' d3344;
rig5=rela 1. 'UY' d333 - 1. 'UX' d333;
dep1=depi rig1 1.;
dep2=depi rig2 1.;
dep3=depi rig3 1.;
dep4=depi rig4 1.;
dep5=depi rig5 1.;
 
* chargement meca
list1=prog 0. 1. 100.;
 
*construction de la liste des temps
n1=dime list1;
list2=prog 0.;
x0=0.;
x2=0.;
repe bou1 (n1-1);
 x1=extr list1 (&bou1+1);
 dx2=abs(x1-x0);
 x0=x1;
 x2=x2+dx2;
 list2=list2 et (prog x2);
fin bou1;
list list2;
 
*amplitude du chargement
list1=(h1*(ep0/n00))*list1;
list3=prog 0. (extr list2 2) (extr list2 (dime list2));
list4=prog 0. 0. 0.;
evol4=evol manu 'TEMPS' list3 'COEF' list4;
evol1=evol manu 'TEMPS' list2 'DEPI' list1;
si (graph1) ;
    dess evol1 titre 'chargement';
finsi;
char1= char meca cd1 evol1;
char2= char meca dep1 evol4;
char3= char meca dep2 evol4;
char4= char meca dep3 evol4;
char5= char meca dep4 evol4;
char5=char meca dep5 evol4;
 
*hydratation evolutive lors du chargement (non exploite ici)
hyd1=manu chpo vol1 'HYD1' 1.;
lht1=list3;
lhc1=prog 1. 1. 1.;
evh1=evol manu 'TEMPS' list3 'COEFF' lhc1;
*dess evh1 titr 'Hydratation';
chah1=char 'HYD1' hyd1 evh1;
 
*teneur en eau imposee (non exploite ici)
w1=manu chpo vol1 'W1' 1.;
lwt1=list3;
lwc1=prog 0.12 0.12 0.12;
evw1=evol manu 'TEMPS' lwt1 'COEFF' lwc1;
*dess evw1 titr 'Vw(t)';
chaw1=char 'W1' w1 evw1;
 
*calcul
tab1=table;
tab1.modele=mod1;
tab1.caracteristiques=mat1;
tab1.blocages_mecaniques=cl0 et rig1 et rig2 et rig3 et rig4 et rig5;
tab1.chargement=char1 et char2 et char3 et char3 et char4 et chah1
et chaw1;
tab1.mova=mot 'DTRA';
tab1.precision=1.0e-4;
tab1.precflex=tab1.precision;
tab1.mes_sauvegardes=table;
tab1.mes_sauvegardes.defto=vrai;
tab1.processeurs=mot 'MONO_PROCESSEUR';
tmax0=extr list2 (dime list2);
dt0=extr list2 2;
dt0=dt0/2.;
list5=prog 0. pas dt0 tmax0;
tab1.temps_calcules=list5;
pasapas tab1;
 
************************************************************************
* exploitation des resultats
************************************************************************
 
evolfz2=@global tab1 cl4 evol1 FZ;
n1=40; fref1=2.10717E-01;
n2=80; fref2=2.81503E-01;
LISTF1='EXTR' evolfz2 'ORDO';
fcal1='EXTR' LISTF1 (n1+1);
fcal2='EXTR' LISTF1 (n2+1);
err1 = abs ((fref1 - fcal1)/fref1) ; 
err2 = abs ((fref2 - fcal2)/fref2) ;
si ((err1 < 1.e-3) et (err2 < 1.e-3)) ;
    erre 0 ;
sinon ;
    erre 5 ;
finsi ;
 
si (graph1) ;
    list4=extr evolfz2 'ORDO';
    list5=extr evolfz2 'ABSC';
    list6=(l1**-2)*list4;
    list7=(h1**-1)*list5;
    evolsz2=evol manu 'epzz' list7 'szz' list6;
    dess evolsz2 titr 'sigma epsilon';
finsi;
fin;