Télécharger la plaquette Cast3M


fr en

Télécharger flamhms.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  flamhms.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. GRAPH = FAUX ;
  5.  
  6. ***********************************************************
  7. * COMBUSTION EN REGIME LAMINAIRE - MODELE TRAVIS          *
  8. * ON TESTE LES VALEURS DE PRESSION ET DE TEMPERATURE AICC * 
  9. ***********************************************************
  10.  
  12. opti elem qua8 ;
  13. opti isov suli ;
  14.  
  15. nx = 8 ;
  16. ny = 8 ;
  17.  
  18. p1 = -1. 0 ;
  19. p2 = 1. 0 ;
  20. p3 = 1. 2.0 ;
  21. p4 = -1. 2.0 ;
  22. bas = p1 d nx p2 ;
  23. dro = p2 d ny p3 ;
  24. hau = p3 d nx p4 ;
  25. gau = p4 d ny p1 ;
  26.  
  27. MT = 'DALLER' BAS DRO HAU GAU 'PLAN' ;
  28.  
  29. ***************************
  30. * MODELES 'NAVIER_STOKES' *
  31. ***************************
  32.  
  33.  MMT = CHAN MT QUAF ;
  34. $MT = 'MODE' MMT 'NAVIER_STOKES' 'MACRO' ;
  35. DOMA $MT 'IMPR' ;
  36. mt = doma $mt maillage ;
  37. CNT = CONT MT ;
  38.  
  39. WALL = (BAS ET DRO ET HAU ET GAU) CHAN QUAF ;
  40. ELIM (WALL ET MMT) 1.E-4;
  41.  
  42. $WALL = 'MODE' WALL 'NAVIER_STOKES' 'MACRO' ;
  43.  
  44. VOL = 'DOMA' $MT 'VOLUME' ;
  45. VOLT = 'SOMT' VOL ;
  46.  
  47. **********************
  48. * LIEU DE L'ALLUMAGE *
  49. **********************
  50.  
  51. PA = (DOMA $MT SOMMET) POIN 'PROC' (0. 0.2) ;
  52.  
  53. *********************************************************************
  54. * PROCEDURE CALCUL1
  55. *********************************************************************
  56. DEBPROC CALCUL1 ;
  57. ARGU RVX*'TABLE' ;
  58.  
  59. RV = RVX.'EQEX' ;
  60. RVP = RV.'PRESSION' ;
  61.  
  62. SI ( RV.PASDETPS.'NUPASDT' < 30 ) ;
  63. RV.PASDETPS.'DELTAT' = 0.001 ;
  64. FINSI ;
  65.  
  66. * filtres sur fractions massiques et calcul de la fraction massique d'azote
  67.  
  68. YH2  = RV.INCO.'YH2' ;
  69. YO2  = RV.INCO.'YO2' ;
  70. YH2O = RV.INCO.'YH2O' ;
  71. YH2  = KOPS YH2 '|<' 0. ;
  72. YO2  = KOPS YO2 '|<' 0. ;
  73. YH2O = KOPS YH2O '|<' 0. ;
  74.  
  75. RV.INCO.'YH2' =  YH2 ;
  76. RV.INCO.'YO2'  = YO2 ;
  77. RV.INCO.'YH2O' = YH2O ;
  78. RV.INCO.'YN2'  = KOPS 1.0 '-' RV.INCO.'YH2O' ;
  79. RV.INCO.'YN2'  = KOPS RV.INCO.'YN2' '-' RV.INCO.'YH2' ;
  80. RV.INCO.'YN2'  = KOPS RV.INCO.'YN2' '-' RV.INCO.'YO2' ;
  81.  
  82. * calcul de la constante des gaz et de la temperature
  83.  
  84. R = KOPS (KOPS YH2 '*' RH2) '+' (KOPS YO2 '*' RO2) ;
  85. R = KOPS R '+' (KOPS RV.INCO.'YN2' '*' RN2) ;
  86. R = KOPS R '+' (KOPS YH2O '*' RH2O) ;
  87. RV.INCO.'R'  = KCHT $MT 'SCAL' 'SOMMET' R ;
  88. T = KOPS RV.INCO.'PSIN' '/' R ; 
  89. RV.INCO.'TN' = KCHT $MT 'SCAL' 'SOMMET' T ;
  90.  
  91. * calcul de rho à partir de la loi d'état des gaz parfaits
  92.  
  93. RV.INCO.'RHO' = KOPS (RV.INCO.'PM') '/' (RV.INCO.'PSIN') ;
  94. RV.INCO.'RHOC' = NOEL $MT RV.INCO.'RHO' ;
  95. RV.INCO.'RHOC' = KCHT $MT 'SCAL' 'CENTRE' (RV.INCO.'RHOC') ;
  96. RHOM = (SOMT (KOPS RV.INCO.'RHOC' '*' VOL))/VOLT ;
  97. RV.INCO.'RHOM' = RHOM ;
  98.  
  99. * calcul du terme (rho-rhom)*g de la QDM
  100.  
  101. DRHO = KOPS (RV.INCO.'RHOC') '-' (RV.INCO.'RHOM') ;
  102. rogx = KCHT $MT SCAL CENTRE 0. ;
  103. rogy = KCHT $MT SCAL CENTRE (-9.81*DRHO) ;
  104. rogx = nomc 'UX' rogx 'NATU' 'DISCRET' ;
  105. rogy = nomc 'UY' rogy 'NATU' 'DISCRET' ;
  106. RV.INCO.'ROG' = KCHT $MT VECT CENTRE (rogx ET rogy) ;
  107.  
  108. * calcul la vitesse à partir de la qdm
  109.  
  110. GN = RV.INCO.'GN' ;
  111. gnx= kcht $MT scal sommet (exco 'UX' gn) ;
  112. gny= kcht $MT scal sommet (exco 'UY' gn) ;
  113. unx = kops gnx '/' RV.INCO.'RHO' ;
  114. uny = kops gny '/' RV.INCO.'RHO' ;
  115. unx = nomc 'UX' unx 'NATU' 'DISCRET' ;
  116. uny = nomc 'UY' uny 'NATU' 'DISCRET' ;
  117. un = kcht $MT vect sommet (unx et uny) ;
  118. RV.INCO.'UN' = un ;
  119.  
  120.  as2 ama1  = 'KOPS' 'MATRIK' ;
  121.  FINPROC as2 ama1 ;
  122.  
  123. *********************************************************************
  124. * PROCEDURE CALCUL2
  125. *********************************************************************
  126. DEBPROC CALCUL2 ;
  127. ARGU RVX*'TABLE' ;
  128.  
  129. RV = RVX.'EQEX' ;
  130. RVP = RV.'PRESSION' ;
  131.  
  132. * on récupère le pas de temps
  133.  
  134. Dt = RV.PASDETPS.'DELTAT' ;
  135. Dt = Dt * RV.'ALFA' ;
  136.  
  137. * combustion et mise a jour du cp et (gamma-1)/gamma
  138.  
  139. YH2 YO2 YN2 YH2O Q = 'FLAM' 'LAMINAIR'
  140.      (RV.INCO.'RHO') (RV.INCO.'CV') 'LINEAIRE' (RV.INCO.'R')
  141.      (RV.INCO.'YH2') (RV.INCO.'YO2') (RV.INCO.'YN2')
  142.      (RV.INCO.'YH2O') (RV.INCO.'TN') Dt ;
  143.  
  144. RV.INCO.'YH2' = KCHT $MT SCAL SOMMET YH2 ;
  145. RV.INCO.'YO2' = KCHT $MT SCAL SOMMET YO2 ;
  146. RV.INCO.'YN2' = KCHT $MT SCAL SOMMET YN2 ;
  147. RV.INCO.'YH2O' = KCHT $MT SCAL SOMMET YH2O ;
  148. RV.INCO.'Q' = KCHT $MT SCAL SOMMET Q ;
  149.  
  150. RC  = NOEL $MT RV.INCO.'R' ;
  151. CVC = NOEL $MT RV.INCO.'CV' ;
  152. CPC = KOPS RC '+' CVC ;
  153.  
  154. RV.INCO.'alpha' = KOPS lambda '/' RV.INCO.'RHOC' ;
  155. RV.INCO.'alpha' = KOPS RV.INCO.'alpha' '/' CPC ;
  156. RV.INCO.'zuzu'  = KOPS RC '/' CPC ;
  157.  
  158. * calcul l'intégrale se trouvant dans le terme Dp/Dt.
  159.  
  160. ZT = KOPS (RV.INCO.'PSIN') '-' (RV.INCO.'PSI1') ;
  161. ZT = KOPS ZT '/' Dt ;
  162. ZT = KOPS ZT '/' (RV.INCO.'PSIN') ;
  163.  
  164. ZZ = KOPS ZT '*' RV.INCO.'RHO' ;
  165. ZZ = NOEL $MT ZZ ;
  166. ZZ = KCHT $MT 'SCAL' 'CENTRE' ZZ ;
  167. ZZT = SOMT ( KOPS ZZ '*' VOL ) ;
  168.  
  169. RV.INCO.'PSI1' = KCHT $MT 'SCAL' 'SOMMET' (RV.INCO.'PSIN') ;
  170.  
  171. * Evolution de la pression moyenne
  172.  
  173. dPdt = ZZT ;
  174. dPdt = dPdt*(RV.INCO.'PM')/VOLT/RV.INCO.'RHOM' ;
  175. MESSAGE 'dPdt = ' dPdt ;
  176.  
  177. * terme source de l'équation d'énergie
  178.  
  179. QC = NOEL $MT RV.INCO.'Q' ;
  180. QC = KCHT $MT 'SCAL' 'CENTRE' QC ;
  181. TOTO = KOPS QC '+' dPdt ;
  182. TOTO = KOPS TOTO '/' RV.INCO.'RHOC' ;
  183. TOTO = KOPS TOTO '*' RV.INCO.'zuzu' ;
  184. RV.INCO.'S' = KCHT $MT 'SCAL' 'CENTRE' TOTO ;
  185.  
  186. * terme source équation de Poisson
  187.  
  188. Z1 = dPdt/RV.INCO.'PM' ;
  189. ZP = KOPS RV.INCO.'RHOC' '*' Z1 ;
  190. ZS = KOPS ZP '-' ZZ ;
  191. ZZS = KOPS ZS '*' VOL ;
  192. ZZS = ZZS * (-1.0) ;
  193. RV.INCO.'ZS' = KCHT $MT 'SCAL' 'CENTRE' ZZS ;
  194.  
  195. * calcul de l'évolution de la pression 
  196.  
  197. RV.INCO.'PM' = RV.INCO.'PM' + (dPdt*dt) ;
  198.  
  199. * affichage informations toutes les 5 iterations
  200.  
  201. DD = RV.PASDETPS.'NUPASDT' ;
  202. NN = DD/5 ;
  203. LO = (DD-(5*NN)) EGA 0 ;
  204. SI ( LO ) ;
  205. MESSAGE '==========================================================' ;
  206. MESSAGE 'TEMPS = ' RV.'PASDETPS'.'TPS' 'PRESSION = ' RV.INCO.'PM' 
  207.   'MIN TEMP = ' (MINI RV.INCO.'TN') 'MAX TEMP = ' (MAXI RV.INCO.'TN') ;
  208. MESSAGE 'MASSE INITIALE = ' MASINI ' MASSE ACTUELLE = ' 
  209.         (RV.INCO.'RHOM'*VOLT) ;
  210. PP = PROG RV.INCO.'PM' ;
  211. PT = PROG RV.PASDETPS.'TPS' ;
  212. RV.INCO.'TEMPS' = RV.INCO.'TEMPS' ET PT ;
  213. RV.INCO.'PRESS' = RV.INCO.'PRESS' ET PP ;
  214. MESSAGE '==========================================================' ;
  215. FINSI ;
  216.  
  217.  as2 ama1  = 'KOPS' 'MATRIK' ;
  218.  FINPROC as2 ama1 ;
  219.  
  220. *========================================================*
  221. *               DONNEES DU CALCUL DE DISTRIBUTION        *
  222. *========================================================*
  223.  
  224. *--------------------------------------
  225. * masses molaires et constantes des gaz
  226. *--------------------------------------
  227. MH2 = 2.0E-3 ;
  228. MO2 = 32.0E-3 ;
  229. MN2 = 28.0E-3 ;
  230. MH2O = 18.0E-3 ;
  231.  
  232. Rg = 8.313 ;
  233.  
  234. RH2 = Rg/MH2 ;
  235. RO2 = Rg/MO2 ;
  236. RN2 = Rg/MN2 ;
  237. RH2O = Rg/MH2O ;
  238.  
  239. *----------------------------------------------------------
  240. * fractions molaires des differents constituants du melange
  241. *----------------------------------------------------------
  242. XH2 = 0.075 ;
  243. XH2O = 0. ;
  244. XO2 = 0.21*(1.0 - XH2 - XH2O) ;
  245. XN2 = 1.0 - XH2 - XH2O - XO2 ;
  246.  
  247. *---------------------------------------------
  248. * masse molaire du melange et constante du gaz
  249. *---------------------------------------------
  250. M = (XH2*MH2) + (XO2*MO2) + (XN2*MN2) + (XH2O*MH2O) ;
  251. R = Rg/M ;
  252.  
  253. *------------------------------------------------------------
  254. * pression, temperature et densite du melange (loi d'etat GP)
  255. *------------------------------------------------------------
  256. P = 0.9E5 ;
  257. T = 400.0 ;
  258. PSI = R*T ;
  259. RHO = P/PSI ;
  260. PSIWALL = PSI ;
  261.  
  262. *------------------------------------------------
  263. * fractions massiques des differents constituants
  264. *------------------------------------------------
  265. YH2 = XH2*MH2/M ;
  266. YO2 = XO2*MO2/M ;
  267. YN2 = XN2*MN2/M ;
  268. YH2O = XH2O*MH2O/M ;
  269.  
  270. *------------------------------------------------------------------
  271. * Cp des différents constituants et du mélange (supposés constants)
  272. *------------------------------------------------------------------
  273. CPH2 = 13514.04 + (1.684537*T) ;
  274. CPH2O = 1715.632 + (0.552805*T) ;
  275. CPN2 = 1006.15 + (0.1387166*T) ;
  276. CPO2 = 907.580 + (0.1420522*T) ;
  277.  
  278. CP = (YH2*CPH2) + (YH2O*CPH2O) + (YO2*CPO2) + (YN2*CPN2) ;
  279.  
  280. gamma = CP/(CP-R) ;
  281.  
  282. *----------------------------------------------------
  283. * calcul d'une vitesse de référence (pour les tracés)
  284. *----------------------------------------------------
  285.  
  286. uref = gamma*R*T ;
  287. uref = uref**0.5 ;
  288. uref = 0.01*uref ;
  289. ampl = 1./uref ;
  290.  
  291.  
  292. *------------------------------------------------------------------------
  293. * Prandtl, Schmidt, viscosité (loi de Sutherland), conductivité thermique
  294. * coefficients de diffusion moléculaire  
  295. *------------------------------------------------------------------------
  296. Pr = 0.7 ;
  297.  
  298. Mu = 1.716E-5*((T/273.0)**1.5)*(273.0+110.5)/(T+110.5) ;
  299. Nu = Mu/RHO ;
  300. Lambda = Mu*CP/Pr ;
  301.  
  302. alpha = Lambda/RHO/CP ;
  303.  
  304. DH2O = 2.55E-5 ;
  305. DH2 = 7.12E-5 ;
  306. DO2 = 2.06E-5 ;
  307. DIF = 1.E-9 ;
  308.  
  309. *==============================================================
  310. * TABLE EQEX CONTENANT LES EQUATIONS A RESOUDRE :           
  311. *  0) FILTRE K-E
  312. *  1) QUANTITE DE MOUVEMENT     --- OPERATEUR NSKE
  313. *  2) EQUATION DE L'ENERGIE     --- OPERATEUR TSCAL
  314. *  3) TRANSPORT DES ESPECES     --- OPERATEUR TSCAL
  315. * AINSI QUE 2 PROCEDURES (CALCUL1 ET CALCUL2) POUR L'ALGORITHME
  316. * 'FAIBLE MACH'
  317. *  4) CONDITIONS AUX LIMITES
  318. *==============================================================
  319.  
  320. RV = 'EQEX' $MT 'ITMA' 5000 'ALFA' 0.6 'TFINAL' 10.0
  321.  'ZONE' $MT 'OPER' 'CALCUL1'
  322.  'OPTI' 'CONS'
  323.  'ZONE' $MT 'OPER'      'NS' MU 'UN' 'ROG'        'INCO' 'GN'
  324.  'OPTI' 'NOCONS' 
  325.  'ZONE' $MT 'OPER'      'TSCAL' 'alpha' 'UN' 'S'  'INCO' 'PSIN'
  326. ;
  327.  
  328. RV = 'EQEX' RV
  329.  'OPTI' 'NOCONS' 
  330.  'ZONE' $MT 'OPER'      'TSCAL' DIF 'UN' 0.0      'INCO' 'YH2'
  331.  'OPTI' 'NOCONS'
  332.  'ZONE' $MT 'OPER'      'TSCAL' DIF 'UN' 0.0      'INCO' 'YO2'
  333.  'OPTI' 'NOCONS'
  334.  'ZONE' $MT 'OPER'      'TSCAL' DIF 'UN' 0.0      'INCO' 'YH2O'
  335. ;
  336. RV = 'EQEX' RV
  337.  'ZONE' $MT 'OPER'      'CALCUL2' 
  338.  'OPTI' 'CENTREE'
  339.  'ZONE' $MT 'OPER'      'DFDT' 1. 'GN'   'DELTAT' 'INCO' 'GN'
  340.  'ZONE' $MT 'OPER'      'DFDT' 1. 'PSIN' 'DELTAT' 'INCO' 'PSIN'
  341.  'ZONE' $MT 'OPER'      'DFDT' 1. 'YH2'  'DELTAT' 'INCO' 'YH2'
  342.  'ZONE' $MT 'OPER'      'DFDT' 1. 'YO2'  'DELTAT' 'INCO' 'YO2'
  343.  'ZONE' $MT 'OPER'      'DFDT' 1. 'YH2O' 'DELTAT' 'INCO' 'YH2O'
  344.  ;
  345.  
  346. RV = 'EQEX' RV
  347.  'CLIM' 'GN' 'UIMP' (DRO ET GAU) 0.0 
  348.         'GN' 'VIMP' (HAU ET BAS) 0.0 ;
  349.  
  350. *===========================================================
  351. * TABLE EQPR POUR L'EQUATION DE POISSON (SOLVEUR ELLIPTIQUE) 
  352. *===========================================================
  353.  
  354. RVP = 'EQPR' $MT KTYPI 1
  355.         'ZONE' $MT  'OPER' 'PRESSION' 'ZS'
  356.         'PIMP' 0.  ;
  357.  
  358. *==========================================================
  359. * TABLE INCO CONTENANT LES INCONNUES ET DONNEES DU PROBLEME 
  360. *==========================================================
  361.  
  362.   RV.'PRESSION' = RVP ;
  363.   RV.'NOMVI' = 'GN' ;
  364.  
  365.   RV.'INCO' = 'TABLE' 'INCO' ;
  366.   RVP.'INCO' = RV.'INCO' ;
  367.  
  368. * vitesse et quantité de mouvement
  369.   RV.INCO.'UN' = kcht $MT VECT SOMMET (0. 1.E-5);
  370.   RV.INCO.'GN' = kcht $MT VECT SOMMET (0. 1.E-5);
  371. * température
  372.   RV.INCO.'PSIN' = kcht $MT SCAL SOMMET   PSI ;
  373.   RV.INCO.'PSI1' = kcht $MT SCAL SOMMET   PSI ;
  374.   RV.INCO.'TN'   = kcht $MT SCAL SOMMET   T   ;
  375.   RV.INCO.'R'    = kcht $MT SCAL SOMMET   R   ;
  376.   RV.INCO.'CV'   = kcht $MT SCAL SOMMET   (CP/gamma) ;
  377. * masse volumique
  378.   RV.INCO.'RHO' = kcht $MT SCAL SOMMET  RHO    ;
  379.   RV.INCO.'RHOC'= kcht $MT SCAL CENTRE  RHO    ;
  380.   RV.INCO.'RHOM'= RHO ;
  381. * fractions massiques
  382.   RV.INCO.'YH2' = kcht $MT SCAL SOMMET  YH2   ;
  383.   RV.INCO.'YO2' = kcht $MT SCAL SOMMET  YO2   ;
  384.   RV.INCO.'YN2' = kcht $MT SCAL SOMMET  YN2   ;
  385.   RV.INCO.'YH2O'= kcht $MT SCAL SOMMET  YH2O   ;
  386. * termes sources (Poisson/énergie/QDM)
  387.   RV.INCO.'S'=kcht $MT SCAL CENTRE   0.    ;
  388.   RV.INCO.'Q'=kcht $MT SCAL SOMMET   0.    ;
  389.   RV.INCO.'ROG'=kcht $MT VECT CENTRE   (0. 0.)     ;
  390.   RV.INCO.'ZS' = KCHT $MT SCAL CENTRE 0.0 ;
  391. * diffusivite thermique
  392.   RV.INCO.'alpha' = KCHT $MT SCAL CENTRE alpha ;
  393.   RV.INCO.'zuzu'  = KCHT $MT SCAL CENTRE ((gamma-1)/gamma) ;
  394. * pression
  395.   RV.INCO.'PM' = P ;
  396. * progressions contenant certaines données
  397.   RV.INCO.'TEMPS' = PROG 0. ;
  398.   RV.INCO.'PRESS' = PROG P ;
  399.   RV.INCO.'MTOTA' = PROG (RHO*VOLT) ;
  400.  
  401. RV.INCO.'YH2u' = RV.INCO.'YH2' ;
  402.  
  403. M = KOPS (RV.INCO.'YH2'/MH2) '+' (RV.INCO.'YO2'/MO2) ;
  404. M = KOPS M '+' (RV.INCO.'YN2'/MN2)  ;
  405. M = KOPS M '+' (RV.INCO.'YH2O'/MH2O) ;
  406. M = KOPS 1. '/' M ;
  407.  
  408. XH2 = KOPS RV.INCO.'YH2' '*' M ;
  409. XH2 = XH2/MH2 ;
  410. XH2 = XH2*100. ;
  411.  
  412. CA = MANU 'CHPO' PA 1 SCAL 3100. ;
  413. TA = KCHT $MT 'SCAL' 'SOMMET' CA ;
  414. RV.INCO.'TN' = (RV.INCO.'TN' ET TA) ;
  415.  
  416. SI ( GRAPH ) ;
  417. trace rv.inco.'TN' MT 14 'TITR' 'temperature initiale [K]' ;
  418. FINSI ;
  419.  
  420. RV.INCO.'PSIN' = KOPS RV.INCO.'R' '*' RV.INCO.'TN' ;
  421. RV.INCO.'RHO' = KOPS RV.INCO.'PM' '/' RV.INCO.'PSIN' ;
  422. RV.INCO.'RHOC' = NOEL $MT RV.INCO.'RHO' ;
  423.  
  424. VOL = DOMA $MT 'VOLUME' ;
  425. VOLT = SOMT VOL ;
  426.  
  427. MESSAGE 'VOLUME TOTAL = ' VOLT ;
  428. RHOM = SOMT (KOPS RV.INCO.'RHOC' '*' VOL) ;
  429. RHOM = RHOM/VOLT ;
  430. RHO = RHOM ;
  431.  
  432. MASINI = KOPS RV.INCO.'RHOC' '*' VOL ;
  433. MASINI = SOMT MASINI ;
  434. MESSAGE 'MASSE INITIALE = ' MASINI ;
  435.  
  436. RV.'TFINAL' = 1.0 ;
  437. exec rv ;
  438.  
  439. SI ( GRAPH ) ;
  440. M = KOPS (RV.INCO.'YH2'/MH2) '+' (RV.INCO.'YO2'/MO2) ;
  441. M = KOPS M '+' (RV.INCO.'YN2'/MN2)  ;
  442. M = KOPS M '+' (RV.INCO.'YH2O'/MH2O) ;
  443. M = KOPS 1. '/' M ;
  444.  
  445. XH2 = KOPS RV.INCO.'YH2' '*' M ;
  446. XH2 = XH2/MH2 ;
  447. XH2 = XH2*100. ;
  448. TRACE XH2 MT CNT 14 'TITR' 'FRACTION VOL. HYDROGENE' ;
  449. FINSI ;
  450.  
  451. RV.'TFINAL' = 3.0 ;
  452. exec rv ;
  453.  
  454. SI ( GRAPH ) ;
  455. TAB1 = TABLE ;
  456. TAB1.1 = 'MARQ LOSA REGU' ;
  457. TAB1.'TITRE' = TABLE ;
  458. TAB1.'TITRE' . 1 = 'MOT' 'PRESSURE' ;
  459. EVOL1 = 'EVOL' 'MANU' 'TIME [s]' RV.INCO.'TEMPS'
  460.         'Press. [Pa]' RV.INCO.'PRESS' ;
  461. 'DESS' EVOL1 'LEGE' TAB1 'MIMA' ;
  462. FINSI ;
  463.  
  464. PM = RV.INCO.'PM' ;
  465. TM = NOEL $MT RV.INCO.'TN' ;
  466. TM = SOMT( KOPS TM '*' VOL) / VOLT ;
  467.  
  468. ERRP = (PM-2.574E5)/2.574E5 ;
  469. ERRP = 100.*(ABS ERRP) ;
  470. ERRT = (TM-1188.)/1188. ;
  471. ERRT = 100.*(ABS ERRT) ;
  472.  
  473. MESSAGE 'PAICC CALCULEE = ' PM 'ERREUR = ' (ERRP) '%' ;
  474. MESSAGE 'TAICC CALCULEE = ' TM 'ERREUR = ' (ERRT) '%' ;
  475.  
  476. SI ( ERRP > 2. ) ;
  477.         ERREUR 5 ;
  478. FINSI ;
  479. SI ( ERRT > 2. ) ;
  480.         ERREUR 5 ;
  481. FINSI ;
  482.  
  483. FIN ;
  484.  
  485.  
  486.  
  487.  
  488.  
  489.  
  490.  
  491.  
  492.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales