Télécharger la plaquette Cast3M


fr en

Télécharger enc2d_therm1.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : enc2d_therm1.dgibi
  2. *
  3. * 2D axisymetric air containment with convective heat transfer and heat losses
  4. * Same as enc2D-therco but without implicit wall coupling
  5. *
  6. 'OPTI' 'DIME' 2 'ELEM' 'CU20' 'MODE' 'AXIS' 'TRAC' 'PSC' 'DENS' 1. ;
  7. *
  8. COMPLET = FAUX ;
  9. GRAPH   = FAUX ;
  10. 'SI' COMPLET ;
  11.   nbit = 200 ;
  12.   DT0  = 2.  ;
  13.   n3 = 10   ;
  14.   ds1= 0.02 ;
  15.   ds2= 0.2  ;
  16. 'SINO' ;
  17.   nbit = 20 ;
  18.   DT0  = 2. ;
  19.   n3 = 10   ;
  20.   ds1= 0.02 ;
  21.   ds2= 0.2  ;
  22. 'FINSI' ;
  23. *
  24. * Mesh
  25. *
  26. p1 = 5.D-4  0. ;
  27. p2 = 0.5    0. ;
  28. p3 = 1.     0. ;
  29. p4 = 1.     2. ;                                                                                
  30. p41= 0.5    2. ;                                                                                
  31. p5 = 5.D-4  2. ;
  32. *
  33. bas    = p1 'DROI' 'DINI' ds1 'DFIN' ds2 p2
  34.             'DROI' 'DINI' ds2 'DFIN' ds1 p3 ;
  35. paroid = p3 'DROI' n3 p4 ;
  36. plaf   = p4 'DROI' 'DINI' ds1 'DFIN' ds2 p41
  37.             'DROI' 'DINI' ds2 'DFIN' ds1 p5 ;
  38. axe    = p5 'DROI' n3 p1 ;
  39. vtp    = (paroid 'TRAN' 2 (0.1  0.)) 'COUL' 'BLEU' ;
  40. parext = ('COTE' 3 vtp) 'COUL' 'ROUG' ;
  41. mt     = 'DALLER' bas paroid plaf axe ;
  42. *
  43. *- Data for execrxt.procedur
  44. *
  45. rxt = 'TABLE' ;
  46. rxt . 'VERSION' = 'V0' ;
  47. rxt . 'vtf'     = mt ;
  48. rxt . 'axe'     = axe ;
  49. rxt . 'vtp'     = vtp ;
  50. rxt . 'epsi'    = 1.e-4 ;
  51. *
  52. rxt . 'pi'     = 0.5 0.5 ;
  53. *
  54. rxt . 'DISCR' = 'QUAF'    ;
  55. rxt . 'KPRE'  = 'MSOMMET' ;
  56. rxt . 'DT0'   = DT0 ;
  57. *
  58. rxt . 'THERMP'  = VRAI ;
  59. rxt . 'THERCO'  = FAUX ;
  60. rxt . 'ROCP'    = 1.e4 ;
  61. rxt . 'LAMBDA'  = 40.  ;
  62. rxt . 'Tp0'     = 30.  ;
  63. rxt . 'ECHAN'   = 50.  ;
  64. *
  65. rxt . 'ECHEXT'  = VRAI   ;
  66. rxt . 'HEXT'    = 50.    ;
  67. rxt . 'TPEXT'   = 20.    ;
  68. rxt . 'parext'  = parext ;
  69. *
  70. rxt . 'MODTURB'  = 'NUTURB' ;
  71. rxt . 'NUT'      = 0.005    ;
  72. *
  73. rxt . 'TF0'  = 100.0 ;
  74. rxt . 'PT0'  = 1.0e5 ;
  75. *
  76. rxt . 'GRAPH'   = GRAPH ;
  77. rxt . 'DETMAT'  = VRAI ;
  78. rxt . 'RENU'    = 'RIEN' ;
  79. *
  80. *- Transient
  81. *
  82. EXECRXT  nbit rxt ;
  83. *
  84. *- Tests
  85. *
  86. 'SI' ('NON' COMPLET) ;
  87.   ERR1 = 0 ;
  88.   tic  = rxt . 'TIC' ;
  89. *
  90.   'LIST' tic . 'Tfm'   ;
  91.   'LIST' tic . 'PT'    ;
  92.   'LIST' tic . 'LMAXU' ;
  93.   ltfm = 'PROG' 
  94.    100.00       79.731       77.454       71.786       67.833
  95.    64.355       61.029       57.925       55.136       52.636
  96.    50.398       48.391       46.573       44.903       43.359
  97.    41.927       40.602       39.376       38.240       37.187
  98.    36.207 ;
  99.    lPT = 'PROG' 
  100.    1.00000E+05  98068.       92332.       91994.       91665.
  101.    90512.       89494.       88730.       88003.       87312.
  102.    86707.       86175.       85692.       85248.       84837.
  103.    84455.       84099.       83770.       83464.       83182.
  104.    82918. ;
  105.    Lmaxu = 'PROG' 
  106.    0.0000       0.0000      0.29154      0.46506      0.52465
  107.    0.48430      0.42198     0.35131      0.28534      0.22824
  108.    0.19253      0.17409     0.16273      0.15506      0.14841
  109.    0.14168      0.13494     0.12844      0.12257      0.11747
  110.    0.11309 ;
  111. *
  112.   evauz = 'EVOL' 'CHPO' ('EXCO' tic . 'UN' 'UY') ('INVE' axe) ;
  113.   evuz  = 'EXTR' evauz 'ORDO' ;
  114.   'LIST'  evuz ;
  115.   lrr = 'PROG' 
  116.   4.88090E-38  1.63432E-02  5.27145E-02  8.21404E-02  0.10017
  117.   0.11203      0.11314      0.10972      9.63041E-02  8.71612E-02
  118.   6.94869E-02  6.24003E-02  4.82692E-02  4.89579E-02  3.89615E-02
  119.   4.48514E-02  3.37560E-02  3.37986E-02  2.10628E-02  2.61349E-03
  120.  -1.42428E-37 ;
  121. *
  122.   ERtf = 'SOMM' ('ABS' (ltfm   - tic . 'Tfm'  )) / 80.  ;
  123.   ERPT = 'SOMM' ('ABS' (lPT    - tic . 'PT'   )) / 1.e5 ;
  124.   ERum = 'SOMM' ('ABS' (Lmaxu  - tic . 'LMAXU'))        ;
  125.   ER   = 'SOMM' ((evuz '-' lrr) '*' (evuz '-' lrr)) '*' 0.05 ;
  126.   'MESS' ' ERtf=' ERtf ' ERPT=' ERPT ' ERum=' ERum ;
  127.   'MESS' ' Ecart :' er ;
  128.   'SI' (ERtf '>' 2.e-4) ; ERR1 = ERR1 '+' 1 ; 'FINS' ;
  129.   'SI' (ERPT '>' 2.e-4) ; ERR1 = ERR1 '+' 1 ; 'FINS' ;
  130.   'SI' (ERum '>' 2.e-3) ; ERR1 = ERR1 '+' 1 ; 'FINS' ;
  131.   'SI' (er   '>' 2.e-4) ; ERR1 = ERR1 '+' 1 ; 'FINS' ;
  132.   'SI' ('NEG' ERR1 0) ;
  133.     'ERRE' 5 ;
  134.   'FINS' ;
  135. 'FINS' ;
  136. *
  137. *- Plots devoted to enc2d... cases
  138. *
  139. 'SI' rxt . 'GRAPH' ;
  140.   tbt = rxt . 'TBT' ;
  141.   tic = rxt . 'TIC' ;
  142. *
  143.   $vtf = rxt . 'GEO' . '$vtf' ;
  144.   vtf  = 'DOMA'  $vtf 'MAILLAGE' ;
  145.   'SI' ('EXIS' tic 'TP') ;
  146.     $vtp = rxt . 'GEO' . '$vtp' ;
  147.     vtp  = 'DOMA'  $vtp 'MAILLAGE' ;    
  148.   'FINS' ;
  149. *   
  150.   un   = tic . 'UN';
  151.   ung  = 'VECT' un 0.1 'UX' 'UY' 'JAUN' ;
  152.   tf   = tic . 'TF' ;
  153.   rho  = tic . 'RHO' ;
  154.   rair = tic . 'RAIR' ;
  155.   'SI' tbt . 'THE'    ; rhe  = tic . 'RHE'  ; 'FINS' ;
  156.   'SI' tbt . 'TH2'    ; rh2  = tic . 'RH2'  ; 'FINS' ;
  157.   'SI' tbt . 'TCO'    ; rco  = tic . 'RCO'  ; 'FINS' ;
  158.   'SI' tbt . 'TCO2'   ; rco2 = tic . 'RCO2' ; 'FINS' ;
  159.   'SI' tbt . 'VAPEUR' ; rvap = tic . 'RVAP' ; 'FINS' ;
  160. *
  161.   axe = 'CHAN' rxt . 'DISCR' axe ;
  162.   ixe = 'INVE' axe ;
  163. *
  164.   evauz = 'EVOL' 'CHPO' ('EXCO' un 'UY') ixe ;
  165.   'DESS' evauz
  166.   'TITR' 'Velocity with the z axis' 'MIMA'
  167.   'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' m/s' ;
  168. *
  169.   evatf = 'EVOL' 'CHPO' tf  ixe ;
  170.   'DESS' evatf
  171.   'TITR' 'Gas temperature with the z axis' 'MIMA'
  172.   'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' C' ;
  173.   'TRAC' tf vtf vtp 'TITR' ' Temperature' ;
  174.   evarh = 'EVOL' 'CHPO' rho ixe ;
  175.   'DESS' evarh
  176.   'TITR' 'Gas density with the z axis' 'MIMA'
  177.   'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  178.   'TRAC' rho vtf ('CONT' vtf) ung
  179.   'TITR' ' Density & velocity' ;
  180. *
  181.   'SI' tbt . 'THE'     ;
  182.     evahe  = 'EVOL' 'CHPO' rhe  ixe ;
  183.     'DESS' evahe
  184.     'TITRE' 'Helium density with the z axis' 'MIMA'
  185.     'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  186.     'TRAC' rhe vtf vtp 'TITR' ' He density' ;
  187.   'FINS' ;
  188.   'SI' tbt . 'TH2'     ;
  189.     evah2  = 'EVOL' 'CHPO' rh2  ixe ;
  190.     'DESS' evah2
  191.     'TITR' 'Hydrogen density with the z axis' 'MIMA'
  192.     'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  193.     'TRAC' rh2 vtf vtp 'TITR' ' H2 density' ;
  194.   'FINS' ;
  195.   'SI' tbt . 'TCO'     ;
  196.     evaco  = 'EVOL' 'CHPO' rco  ixe ;
  197.     'DESS' evaco
  198.     'TITR' 'CO density with the z axis' 'MIMA'
  199.     'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  200.     'TRAC' rco vtf vtp 'TITR' ' CO density' ;
  201.   'FINS' ;
  202.   'SI' tbt . 'TCO2'    ;
  203.     evaco2 = 'EVOL' 'CHPO' rco2 ixe ;
  204.     'DESS' evaco2
  205.     'TITR' 'CO2 density with the z axis' 'MIMA'
  206.     'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  207.     'TRAC' rco2 vtf vtp 'TITR' ' CO2 density' ;
  208.   'FINS' ;
  209.   'SI' tbt . 'VAPEUR' ;
  210.     evavap = 'EVOL' 'CHPO' rvap ixe ;
  211.     'DESS' evavap
  212.     'TITR' 'Steam density with the z axis' 'MIMA'
  213.     'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  214.     'TRAC' rvap vtf vtp 'TITR' ' Steam density' ;
  215.   'FINS' ;
  216. *
  217. * Wall temperature or air density (in cases enc2d with wall temperature 
  218. * only air is involved ; hence rair=rho and rho is plotted above))
  219.   'SI' ('EXIS' tic 'TP') ;
  220.     'TRAC' tic . 'TP' vtp 'TITR' ' Wall temperature' ;
  221.   'SINO' ;
  222.     evarair = 'EVOL' 'CHPO' rair ixe ;
  223.     'DESS' evarair
  224.     'TITR' 'Air density with the z axis' 'MIMA'
  225.     'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  226.     'TRAC' rair vtf vtp 'TITR' ' Air density' ;
  227.   'FINS' ;
  228. *
  229.   'SI' ('EXIS' tic 'KN') ;
  230.     'TRAC' tic . 'KN' vtf vtp 'TITR' ' KN' ;
  231.     'TRAC' tic . 'EN' vtf vtp 'TITR' ' EN' ;
  232.   'FINS' ;
  233. *
  234. 'FINS' ;
  235. *
  236. FIN ;
  237.  
  238.  
  239.  
  240.  
  241.  
  242.  
  243.  
  244.  
  245.  
  246.  
  247.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales