Télécharger la plaquette Cast3M


fr en

Télécharger enc2D-therco.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : enc2D-therco.dgibi
  2. *
  3. * 2D axisymetric air containment with convective heat transfer and heat losses
  4. * with implicit wall coupling
  5. *
  6. 'OPTI' 'DIME' 2 'ELEM' 'CU20' 'MODE' 'AXIS' 'TRAC' 'PSC' 'DENS' 1. ;
  7. *
  8. COMPLET = FAUX ;
  9. GRAPH   = FAUX ;
  10. 'SI' COMPLET ;
  11.   nbit = 200 ;
  12.   DT0  = 2.  ;
  13.   n3 = 10   ;
  14.   ds1= 0.02 ;
  15.   ds2= 0.2  ;
  16. 'SINO' ;
  17.   nbit = 20 ;
  18.   DT0  = 2. ;
  19.   n3 = 10   ;
  20.   ds1= 0.02 ;
  21.   ds2= 0.2  ;
  22. 'FINSI' ;
  23. *
  24. * Mesh
  25. *
  26. p1 = 5.D-4  0. ;
  27. p2 = 0.5    0. ;
  28. p3 = 1.     0. ;
  29. p4 = 1.     2. ;                                                                                
  30. p41= 0.5    2. ;                                                                                
  31. p5 = 5.D-4  2. ;
  32. *
  33. bas    = p1 'DROI' 'DINI' ds1 'DFIN' ds2 p2
  34.             'DROI' 'DINI' ds2 'DFIN' ds1 p3 ;
  35. paroid = p3 'DROI' n3 p4 ;
  36. plaf   = p4 'DROI' 'DINI' ds1 'DFIN' ds2 p41
  37.             'DROI' 'DINI' ds2 'DFIN' ds1 p5 ;
  38. axe    = p5 'DROI' n3 p1 ;
  39. vtp    = (paroid 'TRAN' 2 (0.1  0.)) 'COUL' 'BLEU' ;
  40. parext = ('COTE' 3 vtp) 'COUL' 'ROUG' ;
  41. mt     = 'DALLER' bas paroid plaf axe ;
  42. *
  43. *- Data for execrxt.procedur
  44. *
  45. rxt = 'TABLE' ;
  46. rxt . 'VERSION' = 'V0' ;
  47. rxt . 'vtf'     = mt ;
  48. rxt . 'axe'     = axe ;
  49. rxt . 'vtp'     = vtp ;
  50. rxt . 'epsi'    = 1.e-4 ;
  51. *
  52. rxt . 'pi'     = 0.5 0.5 ;
  53. *
  54. rxt . 'DISCR' = 'QUAF'    ;
  55. rxt . 'KPRE'  = 'MSOMMET' ;
  56. rxt . 'DT0'   = DT0 ;
  57. *
  58. rxt . 'THERMP'  = VRAI ;
  59. rxt . 'THERCO'  = VRAI ;
  60. rxt . 'ROCP'    = 1.e4 ;
  61. rxt . 'LAMBDA'  = 40.  ;
  62. rxt . 'Tp0'     = 30.  ;
  63. rxt . 'ECHAN'   = 50.  ;
  64. *
  65. rxt . 'ECHEXT'  = VRAI   ;
  66. rxt . 'HEXT'    = 50.    ;
  67. rxt . 'TPEXT'   = 20.    ;
  68. rxt . 'parext'  = parext ;
  69. *
  70. rxt . 'MODTURB'  = 'NUTURB' ;
  71. rxt . 'NUT'      = 0.005    ;
  72. *
  73. rxt . 'TF0'  = 100.0 ;
  74. rxt . 'PT0'  = 1.0e5 ;
  75. *
  76. rxt . 'GRAPH'   = GRAPH ;
  77. rxt . 'DETMAT'  = VRAI ;
  78. rxt . 'RENU'    = 'RIEN' ;
  79. *
  80. *- Transient
  81. *
  82. EXECRXT  nbit rxt ;
  83. *
  84. *- Tests
  85. *
  86. 'SI' ('NON' COMPLET) ;
  87.   ERR1 = 0 ;
  88.   tic  = rxt . 'TIC' ;
  89. *
  90.   'LIST' tic . 'Tfm'   ;
  91.   'LIST' tic . 'PT'    ;
  92.   'LIST' tic . 'LMAXU' ;
  93.   ltfm  = 'PROG' 
  94.   100.00 79.731 75.907 70.463 66.107 62.547 59.177 56.024 53.208 50.712
  95.   48.492 46.514 44.732 43.103 41.601 40.217 38.942 37.768 36.686 35.687
  96.   34.761 ;
  97.   lPT   = 'PROG' 
  98.   1.E+05 98163.  92196.  91432.  91214.  90048.  88979.  88205.  87474.
  99.   86778. 86175.  85652.  85179.  84746.  84348.  83978.  83636.  83320.
  100.   83030. 82762.  82514. ;
  101.   Lmaxu = 'PROG'
  102.   0.0000 0.0000 0.27726 0.46757 0.53173 0.48772 0.42198 0.34861 0.28046
  103.   0.22235 0.19067 0.17366 0.16351 0.15670 0.15042 0.14375 0.13703
  104.   0.13065 0.12498 0.12010 0.11590 ;
  105. *
  106.   evauz = 'EVOL' 'CHPO' ('EXCO' tic . 'UN' 'UY') ('INVE' axe) ;
  107.   evuz  = 'EXTR' evauz 'ORDO' ;
  108.   'LIST'  evuz ;
  109.   lrr = 'PROG' 
  110.   1.06346E-38 1.70711E-02 5.47591E-02 8.44109E-02 0.10286 0.11490 0.1159
  111.   0.11211 9.81260E-02 8.83944E-02 7.00422E-02 6.27103E-02 4.83255E-02
  112.   4.94239E-02 3.96408E-02 4.61403E-02 3.49523E-02 3.52144E-02
  113.   2.25213E-02 3.17761E-03 -1.02140E-37 ;
  114. *
  115.   ERtf = 'SOMM' ('ABS' (ltfm   - tic . 'Tfm'  )) / 80.  ;
  116.   ERPT = 'SOMM' ('ABS' (lPT    - tic . 'PT'   )) / 1.e5 ;
  117.   ERum = 'SOMM' ('ABS' (Lmaxu  - tic . 'LMAXU'))        ;
  118.   ER   = 'SOMM' ((evuz '-' lrr) '*' (evuz '-' lrr)) '*' 0.05 ;
  119.   'MESS' ' ERtf=' ERtf ' ERPT=' ERPT ' ERum=' ERum ;
  120.   'MESS' ' Ecart :' er ;
  121.   'SI' (ERtf '>' 2.e-4) ; ERR1 = ERR1 '+' 1 ; 'FINS' ;
  122.   'SI' (ERPT '>' 2.e-4) ; ERR1 = ERR1 '+' 1 ; 'FINS' ;
  123.   'SI' (ERum '>' 2.e-3) ; ERR1 = ERR1 '+' 1 ; 'FINS' ;
  124.   'SI' (er   '>' 2.e-4) ; ERR1 = ERR1 '+' 1 ; 'FINS' ;
  125.   'SI' ('NEG' ERR1 0) ;
  126.     'ERRE' 5 ;
  127.   'FINS' ;
  128. 'FINS' ;
  129. *
  130. *- Plots devoted to enc2d... cases
  131. *
  132. 'SI' rxt . 'GRAPH' ;
  133.   tbt = rxt . 'TBT' ;
  134.   tic = rxt . 'TIC' ;
  135. *
  136.   $vtf = rxt . 'GEO' . '$vtf' ;
  137.   vtf  = 'DOMA'  $vtf 'MAILLAGE' ;
  138.   'SI' ('EXIS' tic 'TP') ;
  139.     $vtp = rxt . 'GEO' . '$vtp' ;
  140.     vtp  = 'DOMA'  $vtp 'MAILLAGE' ;    
  141.   'FINS' ;
  142. *   
  143.   un   = tic . 'UN';
  144.   ung  = 'VECT' un 0.1 'UX' 'UY' 'JAUN' ;
  145.   tf   = tic . 'TF' ;
  146.   rho  = tic . 'RHO' ;
  147.   rair = tic . 'RAIR' ;
  148.   'SI' tbt . 'THE'    ; rhe  = tic . 'RHE'  ; 'FINS' ;
  149.   'SI' tbt . 'TH2'    ; rh2  = tic . 'RH2'  ; 'FINS' ;
  150.   'SI' tbt . 'TCO'    ; rco  = tic . 'RCO'  ; 'FINS' ;
  151.   'SI' tbt . 'TCO2'   ; rco2 = tic . 'RCO2' ; 'FINS' ;
  152.   'SI' tbt . 'VAPEUR' ; rvap = tic . 'RVAP' ; 'FINS' ;
  153. *
  154.   axe = 'CHAN' rxt . 'DISCR' axe ;
  155.   ixe = 'INVE' axe ;
  156. *
  157.   evauz = 'EVOL' 'CHPO' ('EXCO' un 'UY') ixe ;
  158.   'DESS' evauz
  159.   'TITR' 'Velocity with the z axis' 'MIMA'
  160.   'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' m/s' ;
  161. *
  162.   evatf = 'EVOL' 'CHPO' tf  ixe ;
  163.   'DESS' evatf
  164.   'TITR' 'Gas temperature with the z axis' 'MIMA'
  165.   'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' C' ;
  166.   'TRAC' tf vtf vtp 'TITR' ' Temperature' ;
  167.   evarh = 'EVOL' 'CHPO' rho ixe ;
  168.   'DESS' evarh
  169.   'TITR' 'Gas density with the z axis' 'MIMA'
  170.   'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  171.   'TRAC' rho vtf ('CONT' vtf) ung
  172.   'TITR' ' Density & velocity' ;
  173. *
  174.   'SI' tbt . 'THE'     ;
  175.     evahe  = 'EVOL' 'CHPO' rhe  ixe ;
  176.     'DESS' evahe
  177.     'TITRE' 'Helium density with the z axis' 'MIMA'
  178.     'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  179.     'TRAC' rhe vtf vtp 'TITR' ' He density' ;
  180.   'FINS' ;
  181.   'SI' tbt . 'TH2'     ;
  182.     evah2  = 'EVOL' 'CHPO' rh2  ixe ;
  183.     'DESS' evah2
  184.     'TITR' 'Hydrogen density with the z axis' 'MIMA'
  185.     'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  186.     'TRAC' rh2 vtf vtp 'TITR' ' H2 density' ;
  187.   'FINS' ;
  188.   'SI' tbt . 'TCO'     ;
  189.     evaco  = 'EVOL' 'CHPO' rco  ixe ;
  190.     'DESS' evaco
  191.     'TITR' 'CO density with the z axis' 'MIMA'
  192.     'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  193.     'TRAC' rco vtf vtp 'TITR' ' CO density' ;
  194.   'FINS' ;
  195.   'SI' tbt . 'TCO2'    ;
  196.     evaco2 = 'EVOL' 'CHPO' rco2 ixe ;
  197.     'DESS' evaco2
  198.     'TITR' 'CO2 density with the z axis' 'MIMA'
  199.     'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  200.     'TRAC' rco2 vtf vtp 'TITR' ' CO2 density' ;
  201.   'FINS' ;
  202.   'SI' tbt . 'VAPEUR' ;
  203.     evavap = 'EVOL' 'CHPO' rvap ixe ;
  204.     'DESS' evavap
  205.     'TITR' 'Steam density with the z axis' 'MIMA'
  206.     'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  207.     'TRAC' rvap vtf vtp 'TITR' ' Steam density' ;
  208.   'FINS' ;
  209. *
  210. * Wall temperature or air density (in cases enc2d with wall temperature 
  211. * only air is involved ; hence rair=rho and rho is plotted above))
  212.   'SI' ('EXIS' tic 'TP') ;
  213.     'TRAC' tic . 'TP' vtp 'TITR' ' Wall temperature' ;
  214.   'SINO' ;
  215.     evarair = 'EVOL' 'CHPO' rair ixe ;
  216.     'DESS' evarair
  217.     'TITR' 'Air density with the z axis' 'MIMA'
  218.     'GRIL' 'POIN' 'GRIS' 'TITX' 'z' 'TITY' ' kg/m3' ;
  219.     'TRAC' rair vtf vtp 'TITR' ' Air density' ;
  220.   'FINS' ;
  221. *
  222.   'SI' ('EXIS' tic 'KN') ;
  223.     'TRAC' tic . 'KN' vtf vtp 'TITR' ' KN' ;
  224.     'TRAC' tic . 'EN' vtf vtp 'TITR' ' EN' ;
  225.   'FINS' ;
  226. *
  227. 'FINS' ;
  228. *
  229. FIN ;
  230.  
  231.  
  232.  
  233.  
  234.  
  235.  
  236.  
  237.  
  238.  
  239.  
  240.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales