Télécharger dessin.dgibi

Retour à la liste

* dessin.dgibi
************************************************************************
************************************************************************
*_____________________________________________________
*
* PROCEDURE WATERFALL (experimentale)
*_____________________________________________________
*
* tracé Waterfall Cast3M (experimental)   ____
*
*         /\              .
* _______/  \_/\____.-.._/ \__.---------._____
*
*                     /\
* _____/\_/\____.-.._/  \__.--.------._____
*
DEBP WATERFALL ev1*'EVOLUTION' y1*'LISTREEL'
               moty1/'MOT' moopt1/'LISTMOTS' zcoef1/'FLOTTANT';
 
* initialisations
  ZLOGY = FAUX;
* recup des entrees + verif
  n1 = DIME ev1;
  si (neg n1 (dime y1)); ERRE 625; finsi;
  si (neg (type moty1) (MOT 'MOT')); moty1='\c'; finsi;
  si (ega (type moopt1) (MOT 'LISTMOTS'));
*   veut-on changer l'echelle de y1
*   (sans toucher a celle des evolutions) ?
    ZLOGY = EXIS moopt1 'LOGY';
  finsi;
  si (neg (type zcoef1) (MOT 'FLOTTANT')); zcoef1=1.; finsi;
 
* calcul du facteur alpha
* recherche de l'amplitude des evolutions
  lindic1 lx1 lf1 = MAXI 'ABS' ev1;
*   maxf1 = MAXI 'ABS' lf1;
  maxf1 = (SOMM (ABS lf1)) / n1;
* recherche des espaces inter-y
  si ZLOGY;
    y1log = LOG y1;
    dy1 = ((maxi y1log) - (mini y1log)) / (n1 - 1);
  sinon;
    dy1 = ((maxi y1) - (mini y1)) / (n1 - 1);
  finsi;
* calcul de alpha
  alpha1 = zcoef1 * dy1 / maxf1;
 
* creation d'une nouvelle evolution prete a tracer
* recup des parametres de l'evolution de depart
  coco1   = EXTR ev1 'COUL';
  xlabel1 = EXTR ev1 'LEGX' 1;
*   ylabel1 = EXTR ev1 'LEGY' 1;
* on ordonne selon y1 decroissant
  li1 = lect 1 pas 1 n1;
  y2 li2 = ORDO 'DECROISSANT' y1 li1;
* boucle sur les evol elementaires --> nouvelle evol
  ev2 = VIDE 'EVOLUTIO';
  REPE BEV1 n1;
*   choix de l'evol a traiter en premier
    i2 = EXTR li2 &BEV1;
    y2j = EXTR y2 &BEV1;
*   dernier parametre : la couleur
    coco2 = EXTR coco1 i2;
    molege1 = CHAI moty1 '=' FORMAT '(G10.2)' y2j;
*   recup des listreels
    xprog2 = EXTR ev1 'ABSC' i2;
    fprog1 = EXTR ev1 'ORDO' i2;
*   application de alpha aux evolutions
    si ZLOGY;
*     de maniere a avoir LOG(f2) = LOG(y) + a*f1
      fprog2 = y2j * (exp (alpha1 * fprog1));
    sinon;
*     de maniere a avoir f2 = y + a*f1
      fprog2 = y2j + (alpha1 * fprog1);
    finsi;
*   stockage
    ev2 = ev2 et (EVOL coco2 'MANU' 'LEGE' molege1 xlabel1 xprog2 moty1 fprog2);
  FIN  BEV1;
 
FINP ev2;
*_____________________________________________________
 
 
*----------------------------------------------------------------------*
* cas-test de la directive DESSIN.                                     *
*----------------------------------------------------------------------*
  OPTI 'TRAC' 'PSC' 'EPTR' 5  ;
  OPTI 'POTR' 'HELVETICA_16'  ;
* remarque : il faudrait aussi tester avec
* OPTI TRAC 'X';
* OPTI TRAC 'OPEN' ;
 
* CB : TESTE DES CAS PARTICULIERS AYANT CONDUIT A DES ERREURS PAR LE PASSE
* 1
X1  =PROG -2. PAS 1. 750. ;
Y1  =EXP (-1. * X1);
EV1 = EVOL 'ROUG' MANU X1 Y1;
Tit1= CHAI 'Y=Exp(-X) sur une large gamme de X avec YBOR [0. ; 1.]';
DESS EV1 TITR Tit1 YBOR 0. 1.;
 
* 2
X11  =PROG -2. PAS 1. 750. ;
Y11  =EXP (-1. * X11);
EV11 = EVOL 'ROUG' MANU Y11 X11;
Tit1 = CHAI 'X=Exp(-Y) sur une large gamme de Y avec XBOR [0. ; 1.]';
DESS EV11 TITR Tit1 XBOR 0. 1.;
 
* 3
X2  = PROG -1 0. 1. 1.;
Y2  = PROG -1 0. 1. 1.;
EV2 = EVOL 'ROUG' MANU X2 Y2;
Tit1 = CHAI 'Y=X avec YBOR [0. ; 1.]';
DESS EV2 TITR Tit1 YBOR 0. 1.;
 
* 4
X21  = PROG -1 0. 1. 1.;
Y21  = PROG -1 0. 1. 1.;
EV21 = EVOL 'ROUG' MANU Y21 X21;
Tit1 = CHAI 'X=Y avec XBOR [0. ; 1.]';
DESS EV21 TITR Tit1 XBOR 0. 1.;
 
* 5
X3  = PROG 0. 1. ;
Y3  = PROG -0.1 1.2 ;
EV3 = EVOL 'ROUG' MANU X3 Y3;
Tit1 = CHAI 'YBOR [0. ; 1.]';
DESS EV3 TITR Tit1 YBOR 0. 1.;
 
* 6
X31  = PROG 0. 1. ;
Y31  = PROG -0.1 1.2 ;
EV31 = EVOL 'ROUG' MANU Y31 X31;
Tit1 = CHAI 'XBOR [0. ; 1.]';
DESS EV31 TITR Tit1 XBOR 0. 1.;
 
* 7
X4   = PROG 0. 1. ;
Y4   = PROG 1.2 -1.2 ;
EV4  = EVOL 'ROUG' MANU X4 Y4;
Tit1 = CHAI 'YBOR [0. ; 1.]';
DESS EV4 TITR Tit1 YBOR 0. 1.;
 
* 8
X41  = PROG 0. 1. ;
Y41  = PROG 1.2 -1.2 ;
EV41 = EVOL 'ROUG' MANU Y41 X41;
Tit1 = CHAI 'XBOR [0. ; 1.]';
DESS EV41 TITR Tit1 XBOR 0. 1.;
 
* 9
X5   = PROG 0. ;
Y5   = PROG 1.2 ;
EV5  = EVOL 'ROUG' MANU X5 Y5;
Tit1 = CHAI '1 seul point en [0. ; 1.2] et YBOR [0. ; 1.]';
DESS EV5 TITR Tit1 YBOR 0. 1.;
 
* 10
X51  = PROG 0. ;
Y51  = PROG 1.2 ;
EV51 = EVOL 'ROUG' MANU Y51 X51;
Tit1 = CHAI '1 seul point en [1.2 ; 0.] et XBOR [0. ; 1.]';
DESS EV51 TITR Tit1 XBOR 0. 1.;
 
* 11
X6   = PROG 0. ;
Y6   = PROG 0.5 ;
EV6  = EVOL 'ROUG' MANU X6 Y6;
Tit1 = CHAI '1 seul point en [0. ; 0.5] et YBOR [0. ; 1.]';
DESS EV6 TITR Tit1 YBOR 0. 1.;
 
* 12
X61  = PROG 0. ;
Y61  = PROG 0.5 ;
EV61 = EVOL 'ROUG' MANU Y61 X61;
Tit1 = CHAI '1 seul point en [0.5 ; 0.] et XBOR [0. ; 1.]';
DESS EV61 TITR Tit1 XBOR 0. 1.;
 
* 13
X7  = PROG  ;
Y7  = PROG  ;
EV7 = EVOL 'ROUG' MANU X7 Y7;
Tit1 = CHAI 'Evolution vide et YBOR [0. ; 1.]';
DESS EV7 TITR Tit1 YBOR 0. 1.;
 
* 14
X71  = PROG  ;
Y71  = PROG  ;
EV71 = EVOL 'ROUG' MANU Y71 X71;
Tit1 = CHAI 'Evolution vide et XBOR [0. ; 1.]';
DESS EV71 TITR Tit1 XBOR 0. 1.;
 
* 15
X8   = LECT  1  2  3  4  ;
Y8   = PROG -1. 1. 2. 3. ;
EV8  = EVOL 'ROUG' MANU X8 Y8 ;
Tit1 = CHAI 'Evolution avec LISTENTI en ABSCISSE et LISTREEL en ORDONNEES';
DESS EV8 TITR Tit1 ;
 
* 16
X9   = LECT  1  2  3  4 ;
Y9   = LECT -1  1  2  3 ;
EV9  = EVOL 'ROUG' MANU X9 Y9 ;
Tit1 = CHAI 'Evolution avec LISTENTI en ABSCISSE et LISTENTI en ORDONNEES';
DESS EV9 TITR Tit1 ;
 
* 17
X10  = PROG  1. 2. 3. 4.;
Y10  = LECT -1  1  2  3 ;
EV10 = EVOL 'ROUG' MANU X10 Y10 ;
Tit1 = CHAI 'Evolution avec LISTREEL en ABSCISSE et LISTENTI en ORDONNEES';
DESS EV10 TITR Tit1 ;
 
*
* ON TESTE D'ABORD LES ECHELLE ET GRADUATIONS ************************
* (SP)
EV1      = EVOL 'BLEU' 'MANU' (PROG -1. -0.5 0.5 1. 2.)
                              (PROG 1.E-3 0. 0. 5.E-4 7E-2) ;
DESS EV1 'TITR' ' Sans option' ;
 
DESS EV1 'XBOR' -1.5 2.5
'TITR' ' Bornes sur X [-1.5 2.5] ' ;
 
DESS EV1 'YBOR' -0.5E-2 7.5E-2
'TITR' ' Bornes sur Y [-0.5E-2 7.5E-2] ' ;
 
DESS EV1 'XBOR' -1.5 2.5 'YBOR' -0.5E-2 7.5E-2
'TITR' ' Bornes sur X & Y ' ;
 
DESS EV1 'XBOR' -1.5 2.5 'YBOR' -0.5E-2 7.5E-2
         'XGRA' +0.5     'YGRA' +0.5E-2
'TITR' ' Bornes sur X-Y & les intervalles de graduations donnes ' ;
 
DESS EV1 'XBOR' -1.5 2.5 'YBOR' -0.5E-2 7.5E-2
         'XGRA' +0.5     'YGRA' +0.5E-2
         'AXES' 'GRIL' 'POIN'
'TITR' ' La grille & les axes en PLUS ' ;
 
 
* ON TESTE ENSUITE D'AUTRES OPTIONS AVEC UN SYSTEME 2DDL **************
* LEGENDE, TITRES, CENTREMENT, GRILLE ...
* (BP)
* w donné en rad/s
T1=2.;
w1=(2.*pi)/T1;
T2=5.;
w2=(2.*pi)/T2;
xp = prog 0. PAS 0.1 20.;
 
* castem utilise les degrés
yp  = 100. * (sin ((180/pi)*w1*xp));
yp2 = 110. * (sin ((180/pi)*w2*xp));
 
ev1 = evol bleu manu xp yp;
ev2 = evol roug manu xp yp2;
 
tdess1 = tabl;
tdess1 . 1 = mot ' REMP MARQ PLUS REGU';
tdess1 . 'TITRE' = tabl;
ent1 = enti w1;
decim1 = (enti (10.*w1)) - (10*ent1);
ent2 = enti w2;
decim2 = (enti (10.*w2)) - (10*ent2);
tdess1 . 'TITRE' . 1 = chai '\W=' ent1 '.' decim1 'rad.s^{-1}';
tdess1 . 2 = mot 'MARQ ROND REGU';
tdess1 . 'TITRE' . 2 = chai '\W=' ent2 '.' decim2 'rad.s^{-1}';
 
DESS (ev1 et ev2)
'TITR' 'Déplacement x_{\W}(t) = sin(\Wt)'
'TITX' 't(s)'  'POSX' 'CENT'
'TITY' 'Dépl u_{A}^{1} (m)' 'POSY' 'CENT'
'LEGE' 'SO' tdess1;
 
DESS (ev1 et ev2)
'TITR' 'Déplacement x_{\W}(t) = sin(\Wt)'
'TITX' 't(s)'  'POSX' 'CENT'
'YBOR' -110. 110. 'YGRA' 22
'TITY' 'Dépl u_{A} (m^{1})' 'POSY' 'CENT'
'LEGE'  tdess1;
 
DESS (ev1 et ev2)
'TITR' 'Déplacement x_{\W}(t) = sin(\Wt)'
'TITX' 't(s)'
 'XBOR'  0. T2
 'YBOR' -110. 110. 'YGRA' 22.
'TITY' 'Déplacement x (m)'
'LEGE'  tdess1;
 
*** systeme 2ddl : fonction de tranfert : amplitude et phase ***
ev1tot = VIDE 'EVOLUTION';
ev2tot = VIDE 'EVOLUTION';
* liscoul = mots VIOL BLEU TURQ BLEU ORAN AZUR ROUG ;
liscoul = mots VIOL BLEU TURQ OLIV ORAN AZUR ROUG ;
tdess2 = tabl;
tdess2 . 1 = mot 'MARQ PLUS REGU';
tdess2 . 2 = mot 'MARQ ROND REGU';
tdess2 . 3 = mot 'MARQ CROI REGU';
tdess2 . 4 = mot 'MARQ CARR REGU';
tdess2 . 5 = mot 'MARQ TRIU REGU';
tdess2 . 6 = mot 'MARQ ETOI REGU';
tdess2 . 7 = mot 'MARQ TRID REGU';
tdess2 . 'TITRE' = tabl;
 
xi1 = 0.02 ; xi2 = 0.05;
xi1p = prog 0.001 0.002 0.01 0.02 0.05 0.1 0.15 ;
xi2p = xi1p * (xi2 / xi1);
 
nxi = dime xi1p;
ixi = 0;
repe Bxi nxi; ixi = ixi + 1 ;
 
xi1 = extr xi1p ixi;
xi2 = extr xi2p ixi;
mess ixi ' xi_1=' xi1 ' xi_2=' xi2 ;
 
moxi1 = chai (enti (1000 * (xi1 - (enti xi1))));
si (ega (dime moxi1) 1); moxi1 = chai '00' moxi1; fins;
si (ega (dime moxi1) 2); moxi1 = chai '0' moxi1; fins;
moxi1 = chai (enti xi1) '.' moxi1;
tdess2 . 'TITRE' . ixi = chai '\x_{1}=' (moxi1);
 
m1=2.; k1 = m1*(w1**2); c1 = 2.*xi1*w1*k1;
m2=1.; k2 = m2*(w2**2); c2 = 2.*xi2*w2*k2;
mess w1 m1 k1 c1;
mess w2 m2 k2 c2;
 
wpadim = prog 0. PAS 0.002 2.;
wp = w1 * wpadim;
np = dime wp;
unp = prog np*1.;
 
A_R =  ((k1 + k2)*unp) - ((wp**2)*m1);
A_I =  wp*(c1 + c2);
B_R =  -1.*k2*unp;
B_I =  -1.*c2*wp;
D_R =  (k2*unp) - ((wp**2)*m2);
D_I =  wp*c2;
 
Den_R = (A_R*D_R) - (A_I*D_I) - (B_R**2) + (B_I**2) ;
Den_I = (A_R*D_I) + (A_I*D_R) - (2.*B_R*B_I);
Den2 = (Den_R**2) + (Den_I**2);
 
* pour simplifier on excite seulement en F1 et en phase
F1_R = 1.;
Num11_R = ((Den_R*D_R) - (Den_I*D_I)) * F1_R;
Num11_I = ((Den_R*D_I) - (Den_I*D_R)) * F1_R;
Num12_R = -1.*((Den_R*B_R) - (Den_I*B_I)) * F1_R;
Num12_I = -1.*((Den_R*B_I) - (Den_I*B_R)) * F1_R;
 
X1_R = Num11_R / Den2;
X1_I = Num11_I / Den2;
X2_R = Num12_R / Den2;
X2_I = Num12_I / Den2;
 
X1_AMP = ((X1_R**2)+(X1_I**2))**0.5;
X1_PHA = ATG X1_I X1_R;
X2_AMP = ((X2_R**2)+(X2_I**2))**0.5;
X2_PHA = ATG X2_I X2_R;
 
ev1_amp = evol BLEU manu wpadim X1_AMP;
ev2_amp = evol ROUG manu wpadim X2_AMP;
ev1_pha = evol BLEU manu wpadim X1_PHA;
ev2_pha = evol ROUG manu wpadim X2_PHA;
 
si (xi1 ega 0.02);
tdess1 . 'TITRE' . 1 = mot 'X_{1}';
tdess1 . 'TITRE' . 2 = mot 'X_{2}';
 
* 'Y LOG + titres X et Y centres + LEGE XY'
tit2ddl = chai 'Système à 2ddl : '
 '\w_{1}=0.5 \w_{2}=0.2 \x_{1}=2% \x_{2}=5%';
DESS (ev1_amp et ev2_amp)
'LOGY' 'YBOR'  1.E-3 1.E1
'GRIL' 'POIN' 'GRIS'
'TITR' tit2ddl
'TITX' '\W (Hz)'  'POSX' 'CENT'
'TITY' 'amplitude |x| (m)' 'POSY' 'CENT'
'LEGE'  'XY' 1.5 0.8 tdess1;
 
DESS (ev1_pha et ev2_pha)
'YBOR' -180. 180.   'YGRA' 90.
'GRIL' 'POIN' 'GRIS'
'TITR' tit2ddl
'TITX' '\W (Hz)'  'POSX' 'CENT'
'TITY' 'phase \j(x) (m)' 'POSY' 'CENT'
'LEGE'  'XY' 1.5 160 tdess1;
 
fins;
 
ev1tot = ev1tot et (ev1_amp coul (extr liscoul ixi));
ev2tot = ev2tot et (ev2_amp coul (extr liscoul ixi));
 
fin Bxi;
 
 
* ON CONTINUE AVEC D'AUTRES OPTIONS
* (BP)
 
tit2 = chai 'Evolution avec l`amortissement \x';
DESS ev1tot
'GRIL' 'POIN' 'GRIS' 'TITR' tit2
'LOGY'
'TITX' '\W (Hz)'  'POSX' 'CENT'
'TITY' '|X_{1}| (m)' 'POSY' 'CENT'
'LEGE'  'XY' 1.45 9. tdess2;
*rem : 'amplitude |X_{1}| (m)' est trop long (limite a 20 caracteres)!
* 'TITY' 'amplitude |X_{1}| (m)' 'POSY' 'CENT'
 
* test de loption LIGNE_VARIABLE
* on définit les style des (np-1) segments
* (=0 lign, =2 tirr,  ...  =5 pointilles)
nps3 = np / 3;
ltirr2 = lect nps3*0 nps3*5 (np - 1 - (2*nps3))*1;
ltirr3 = lect nps3*1 nps3*2 (np - 1 - (2*nps3))*0;
tdess2 . 'LIGNE_VARIABLE' = TABL;
tdess2 . 'LIGNE_VARIABLE' . 2 = ltirr2;
tdess2 . 'LIGNE_VARIABLE' . 3 = ltirr2;
tdess2 . 'LIGNE_VARIABLE' . 5 = ltirr3;
DESS ev1tot
'GRIL' 'POIN' 'GRIS' 'TITR' tit2
 LOGY
'TITX' '\W (Hz)'  'POSX' 'CENT'
'TITY' '|X_{1}| (m)' 'POSY' 'CENT'
'LEGE'  'XY' 1.45 9. tdess2;
 
* test pour faire des waterfall (+ option REMP BLAN)
* (bp,2019)
* dess ev1tot;
ev1log = WATERFALL ev1tot xi1p '\x' (mots 'LOGY');
repe Bxi nxi;
  tdess2 . &Bxi = CHAI tdess2 . &Bxi ' REMP BLAN';
fin Bxi;
dess ev1log 'LOGY' 'LEGE' tdess2;
 
 
*----------------------------------------------------------------------*
* trace d'histogrammes                                                 *
*----------------------------------------------------------------------*
 
* bruit blanc Gaussien
NN = 10000 ;
LTIRAG1 = BRUI 'BLAN' 'GAUS' 0. 2. NN ;
LTIRAG2 = BRUI 'BLAN' 'GAUS' 0. 2. NN ;
* calcul du nombre de classes (entieres)
IMAX1 = ENTI 'SUPERIEUR' (MAXI LTIRAG1);
IMIN1 = ENTI 'INFERIEUR' (MINI LTIRAG1);
* boucle sur les classes
NC = IMAX1 - IMIN1;
LCOMPT1 = PROG NC*0. ;
LCOMPT2 = PROG NC*0. ;
IFIN1 = IMIN1;
REPE BC NC;
  IDEB1 = IFIN1;
  IFIN1 = IFIN1 + 1;
  NC1 = MASQ LTIRAG1 'COMPRIS' IDEB1 IFIN1 'SOMME';
  REMP LCOMPT1 &BC NC1;
  NC2 = MASQ LTIRAG2 'COMPRIS' IDEB1 IFIN1 'SOMME';
  REMP LCOMPT2 &BC NC2;
FIN  BC;
 
list LCOMPT1;
 
* test de la procedure @HISTOGR
TOPT1 = TABL ;
TOPT1 . 'HPOS' = FLOT IMIN1 ;
TOPT1 . 'DESS' = 'GRIL AXES' ;
TOPT1 . 'COUL' = mot 'OCEA';
@HISTOGR LCOMPT1 TOPT1 FAUX ;
 
* recup des evolutions pour trace plus evolues
rainbow = mots 'MARI' 'MARI' 'MARI' 'BLEU' 'BLEU' 'AZUR' 'CYAN' 'TURQ'
'VERT' 'OR' 'ORAN'  'ROUG'  'BRIQ' 'BRIQ' 'BRUN' 'BRUN' 'BRUN' ;
TOPT1 = TABL ; TOPT1 . 'COUL' = rainbow;
evhist1 Thist  = @HISTOGR LCOMPT1 TOPT1 VRAI ;
TOPT2 = TABL ; TOPT2 . 'COUL'  = rainbow;
TOPT2 . 'NOMS' = TABL;
repe b NC;  TOPT2 . 'NOMS' . &b = chai  &b ''; fin  b;
evhist2 Thist2 = @HISTOGR (-1.*LCOMPT2) TOPT2 VRAI ;
 
*DESS evhist1 Thist;
*DESS evhist2 Thist2;
* DESS (evhist1 et evhist2) Thist;
* avec Legende
repe b NC;
  Thist .       &b  = MOT 'REMP MARQ TRID';
*  Thist . (NC + &b) = MOT 'REMP MARQ TRIU';
  Thist . (NC + &b) = MOT 'MARQ TRIU';
fin b;
DESS (evhist1 et evhist2) Thist YBOR -2500 2500 YGRA 500;
 
 
*------------------------------------------------------*
* Test des couleurs                                    *
*------------------------------------------------------*
 
coul3 = mots 'INDI' 'VIOL' 'MARI' 'BLEU' 'AZUR' 'CYAN'
             'TURQ' 'OCEA' 'BOUT' 'VERT' 'OLIV' 'LIME'
             'JAUN'  'OR' 'BRON'
             'ORAN' 'CORA' 'ROUG' 'BRIQ'
             'BRUN' 'CARA' 'BEIG' 'KAKI' 'POUR' 'ROSE' 'PEAU' 'LAVA'
             'BLAN' 'GRIS' 'NOIR' ;
n3 = dime coul3;
xx = prog 0. 1.;
yy = prog 1. 1.;
ev = vide EVOLUTIO;
T = tabl;
repe b n3;
  c  = extr coul3 &b;
  ev = ev et (evol c 'MANU' xx (&b * yy));
  T . &b = chai 'LABEL' ' ' c ' REGU';
fin  b;
 
dess ev T XBOR 0. 1.2 ;
 
 
FIN ;
 
 
 

© Cast3M 2003 - Tous droits réservés.
Mentions légales