Télécharger la plaquette Cast3M


fr en

Télécharger damage_tc_3d.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : damage_tc_3d.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *******************************************************
  5. *  Cas test de l'implantation numérique du modele
  6. *  DAMAGE_TC 3D
  7. *******************************************************
  8. * Développé par :  
  9. *     Benjamin Richard 
  10. * Contact :  
  11. *     Benjamin.Richard@lmt.ens-cachan.fr 
  12. * Institution : 
  13. *     CEA\DEN\DANS\DM2S\SEMT\EMSI
  14. *******************************************************
  15. * Les cas de charges sont entrés : 
  16. * - 1 : Traction monotone
  17. * - 2 : Compression monotone
  18. * - 3 : Traction cyclique
  19. * - 4 : Compression cyclique
  20. * - 5 : Traction/compression cyclique
  21. *******************************************************
  22. * Choix du cas de charge
  23. ncas  = 1;
  24. graph=mot 'N';
  25.  
  26. *******************************************************
  27.  
  28. *
  29. *-------------- Options de calcul ---------------------
  30. *
  31. OPTION DIME 3 ELEM CUB8;
  32.  
  33. *
  34. *-------------- Definition de la geometrie ------------
  35. *
  36. P1 = 0. 0. 0.;
  37. P2 = 1. 0. 0.;
  38. P3 = 1. 1. 0.;
  39. P4 = 0. 1. 0.;
  40. P5 = 0. 0. 1. ;
  41.  
  42. L1 = P1 DROIT 1 P2 ;
  43. L2 = P2 DROIT 1 P3 ;
  44. L3 = P3 DROIT 1 P4 ;
  45. L4 = P4 DROIT 1 P1 ;
  46.  
  47. LTOT = L1 ET L2 ET L3 ET L4 ;
  48. SURF1 = SURF LTOT PLANE;
  49. VOLTO =VOLU SURF1 1 TRANS P5;
  50. SURF2= FACE VOLTO 2;
  51.  
  52. VOLTOT = VOLTO;
  53.  
  54. *
  55. *------- Définition des conditions aux limites --------
  56. *----------- et des déplacements imposés --------------
  57. *
  58. CL  = BLOQ SURF1 UZ;
  59. CLL = BLOQ P1 'DEPL';
  60. CLL = CLL ET (bloq p2 'UY');
  61. CL1 = BLOQ SURF2 Uz;
  62.  
  63. D1 = DEPI CL1 1;
  64.  
  65. *
  66. *----- Définition du modèle ---------------------------
  67. *
  68. MOD1   = MODE VOLTOT MECANIQUE ELASTIQUE ISOTROPE 
  69.          ENDOMMAGEMENT DAMAGE_TC;
  70.  
  71. *
  72. *----- Paramètres matériaux ---------------------------
  73. * 
  74.  
  75. * Young's modulus
  76. YG = 36.e9 ;
  77.  
  78. * Poisson ratio
  79. NUB = 0.20 ;
  80.  
  81. * Material density
  82. RHOM = 2210 ;
  83.  
  84. * Fracture energy
  85. Gvalm = 300. ;
  86.  
  87. * Tension limit strength
  88. ftulm = 3.3e6 ;
  89.  
  90. * Drop Factor for Peak Tensile Stress
  91. redcm = 1.7e6 ;
  92.  
  93. * Elastic Limit Compressive Stress
  94. fc01m = -25.e6 ;
  95.  
  96. * Equi-biaxial Compressive Ratio
  97. rt45m = 1.18 ;
  98.  
  99. * Compressive Peak Stress
  100. fcu1m = -42.5e6 ;
  101.  
  102. * Ultimate Limit Strain
  103. extum = -0.015;
  104.  
  105. * Reference Stress for Plastic Parameter
  106. strpm = -22.e6 ;
  107.  
  108. * Reference Strain for Plastic Parameter
  109. extpm = -0.001 ;
  110.  
  111. * Fitting Point 1 (Strain)
  112. ext1m = -0.006 ;
  113.  
  114. * Fitting Point 1 (Stress)
  115. str1m = -35.e6 ;
  116.  
  117. * Fitting Point 2 (Strain)
  118. ext2m = -0.008 ;
  119.  
  120. * Fitting Point 2 (Stress)
  121. str2m = -22.e6 ;
  122.  
  123. * NCRIT - 1 exponential softening
  124. *       - 2 linear softening
  125. ncrim = 1 ;
  126.  
  127. * Computation of the element size field
  128. jaco1 = jaco mod1 ;
  129. jaco2 = chan 'RIGIDITE' mod1 jaco1 ;
  130. hlenm = jaco2**(1./3.) ; 
  131.  
  132.  
  133. mat1 = mate mod1  YOUN  yg NU nub RHO rhom HLEN hlenm
  134.                    GVAL Gvalm FTUL ftulm REDC redcm FC01 fc01m
  135.                    RT45 rt45m FCU1 fcu1m STRU extum EXTP extpm
  136.                    STRP strpm EXT1 ext1m STR1 str1m EXT2 ext2m
  137.                    STR2 str2m NCRI ncrim ;
  138. *
  139. *----- Définition des cas de charge -------------------
  140. *
  141.  
  142. SI (EGA ncas 1) ;
  143. LI1  = PROG 0. 1.;
  144. LI2  = PROG 0. 4.0e-4;
  145. LIS1 = PROG 0. PAS 0.02 1.;
  146. FINSI;
  147.  
  148. SI (EGA ncas 2) ;
  149. LI1  = PROG 0.  1.;
  150. LI2  = PROG 0. -8.0e-3;
  151. LIS1 = PROG 0. PAS 0.02 1.;
  152. FINSI;
  153.  
  154. SI (EGA ncas 3) ;
  155. LI1  = PROG 0. 1. 2. 3. 4. 5.;
  156. LI2  = PROG 0. 1.5e-4 9.5e-6 2.0E-4 3.0E-5 2.5E-4;
  157. LIS1 = PROG 0. PAS 0.02 5.;
  158. FINSI;
  159.  
  160. SI (EGA ncas 4) ;
  161. LI1  = PROG 0. 1. 2. 3. 4. 5.;
  162. LI2  = PROG 0. -3.0e-3 -1.5e-4 -5.0E-3 -3.5E-4 -8.0E-3;
  163. LIS1 = PROG 0. PAS 0.02 5.;
  164. FINSI;
  165.  
  166. SI (EGA ncas 5) ;
  167. LI1  = PROG 0. 1. 2. 3. 4. 5. 6.;
  168. LI2  = PROG 0. 5.0e-4 -3.0e-3 -1.5E-4 -5.0E-3 -3.5E-4 -8.0E-3;
  169. LIS1 = PROG 0. PAS 0.02 2;
  170. FINSI;
  171.  
  172. EV = EVOL MANU LI1 LI2 ;
  173. CHA1 = CHAR 'DIMP' D1 EV ;
  174.  
  175. *
  176. *----------- Calcul par l'operateur PASAPAS ------------
  177. *
  178.  
  179. TAB1 = TABLE ;
  180. TAB1.'BLOCAGES_MECANIQUES' = CL ET CLL ET CL1;
  181. TAB1.'MODELE' = MOD1;
  182. TAB1.'MOVA' = 'RIEN';
  183. TAB1.'CHARGEMENT' = CHA1;
  184. TAB1.'CARACTERISTIQUES' = MAT1;
  185. TAB1.'TEMPS_CALCULES' = LIS1;
  186. TAB1.'MAXITERATION' = 10;
  187.  
  188. PASAPAS TAB1 ;
  189.  
  190. *
  191. *----------- Courbe effort-deplacement -----------------
  192. *
  193.  
  194. Si (ega graph 'O');
  195. ev2=@global tab1 CL1 EV fz;
  196. DESS EV2;
  197. finsi;
  198.  
  199. nn=dime tab1.deplacements;
  200. nn=nn-1;
  201. ee=tab1.variables_internes.nn;
  202.  
  203. aa = extr ee 'DAMT' 1 1 1 ;
  204. list aa;
  205. err =  abs (aa  - 0.97626) / 0.97626  ;
  206. message ' erreur relative ';
  207. list err;
  208. si (err > 1.e-3);
  209. erreur (5);
  210. finsi; 
  211.  
  212. fin;
  213.  
  214.  
  215.  
  216.  
  217.  
  218.  
  219.  
  220.  
  221.  
  222.  
  223.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales