Exemples de jeux de données Cast3M

************************************************************************
*      Cas test elementaire pour la loi d'endommagement de Mazars      *
*              Donnees d'entree : parametres materiaux                 *
*              Essai uniaxial 3D traction/compression                  *
*                                                                      *
* Le test est realise avec plusieurs modes de calcul :                 *
*   1) Traction                                                        *
*   2) Compression                                                     *
*                                                                      *
* TRA = VRAI -> Essai en traction                                      *
* TRA = FAUX -> Essai en compression                                   *
* GRAP = VRAI -> Affichage des courbes                                 *
*                                                                      * 
* Vérification des essais par rapport aux equations de référence       *
*                                                                      *
* Cas test utilisant comme donnees d'entree les parametres materiau du *
* beton. Autre implementation du modele de mazars, mais le modele est  *
* identique au modèle de mazars implemente initialement dans Castem    *
************************************************************************
 
OPTI DIME 3 ;
OPTI ELEM CUB8 ;
 
GRAP = FAUX ;
 
***OPTION TRACTION (VRAI) OU COMPRESSION (FAUX) ***
LL = PROG -1. 1. ;
 
REPE TRA_COMP 2 ;
 
BOO_VAL = EXTR LL &TRA_COMP ;
 
SI (BOO_VAL EGA -1.) ;
***TRACTION***
  BOO = VRAI ;
SINON ;
***COMPRESSION***
  BOO = FAUX ;
FINSI ;
 
TRA = BOO ;
 
P0 = 0 0 0 ;
P1 = 1.0 0 0 ;
D1 = DROI 1 P1 P0 ;
S1 = D1 TRAN 1 (0 0 1.0) ;
V1 = S1 VOLU TRAN 1 (0 1.0 0) ;
 
* CRÉATION DU MODELE
*** MODELISATION DU BETON
*** Parametres d'entree du modele
FT = 3.0E+6 ;
YG = 30.0E+9 ;
BETA = 1.06 ;
NU = 0.2 ;
FC = 30E6 ;
KPIC = 2e-3 ;
SRES = 1E5 ;
TAU = 0.5 ;
 
*** equation pour trouver les parametres du modele de mazars
*** a partir des parametres materiaux
EPS = FT/YG ;
BC  = 1/(KPIC * NU * 1.41421356237) ;
AC  = (FC/(KPIC*YG)-(BC*EPS))/((EXP (BC*EPS-1))- (BC*EPS)) ;
AT  = 1 - (SRES/(YG*EPS)) ;
BT  = 1 + TAU / EPS ;
 
 
MOD1 = MODE V1 MECANIQUE ELASTIQUE ISOTROPE ENDOMMAGEMENT MAZARS_INI ;
MAT1 = MATE MOD1 'YOUN' YG 'FTRA' FT 'FCOM' FC 'KPIC' KPIC 'SRES' SRES 
       'TAU' TAU 'BETA' BETA 'NU' NU ; 
 
*** Conditions aux limites
PB  = V1 POIN PLAN (0 0 0) (0 1 0) (1 0 0) 1E-4 ;
CL1 = BLOQ PB 'UZ' ;
PY  = V1 POIN PROC (0 0 0) ;
CL2 = BLOQ PY 'UY' ;
PX  = V1 POIN PROC (0 1.0 0) ;
LX  = V1 POIN 'DROI' (0 0 0) (1 0 0) 0.0001 ;
CL3 = BLOQ LX 'UY' ;
LY  = V1 POIN 'DROI' (0 0 0) (0 1 0) 0.0001 ;
CL4 = BLOQ LY 'UX' ;
**DEFINITION DU CHARGEMENT
PH = V1 POIN PLAN (0 0 1.0) (1 0 1.0) (0 1 1.0) 1E-4 ;
CLDEP = BLOQ PH 'UZ' ;
 
 
 
SI TRA ;
*** deplacement impose en traction
  DEIM = 7E-4 ;
*** paramtres mazars
  AA = AT ; BB = BT ;
*** Facteur devant epsilon -> epsilon eq
  FAC = 1 ;
SINON ;
  DEIM = -7e-3 ;
  AA = AC ; BB = BC ;
  FAC = NU * (-1)*((2.)**(1/2.)) ;
FINSI ;
 
DEP1 = DEPI CLDEP DEIM ;
PROG1 = PROG 0. 1 ;
PROG2 = PROG 0. 1 ;
EVOL1 = EVOL MANU PROG1 PROG2 ;
CHAR1 = CHAR DEP1 EVOL1 DIMP ;
 
PROG3 = PROG 0. PAS (1/100.) 1. ;
 
**** Calcul du modele theorique avec equation de mazars
*contraintes
st = PROG ;
*endommagement
dt = PROG ;
REPE b1 (DIME PROG3) ;
  EPP = (EXTR PROG3 &b1) * DEIM * FAC ;
  SI ( EPP '>EG' EPS) ;
    DDD = 1 - (((1 - AA) * EPS) / EPP) - (AA * (EXP ((BB * (EPS - EPP))))) ;
    DDD = MINI (PROG DDD (1-(1e-8))) ;
  SINON ;
    DDD = 0. ;
  FINSI ;
  sst = (1 - ((1*DDD))) * YG * EPP / FAC ;
  st = st ET (PROG sst) ;
  dt = dt ET (PROG DDD) ;
FIN b1 ;
 
def = PROG3 * DEIM ;
EVT = EVOL ROUG MANU def st ;
EVD = EVOL BLEU MANU def dt ;
 
 
 
***** Calcul aux EF modele de Mazars
 
TAB1                       = TABLE ;
TAB1 . MODELE              = MOD1 ;
TAB1 . CARACTERISTIQUES    = MAT1 ;
TAB1 . BLOCAGES_MECANIQUES = CL1 ET CL2 ET CL3 ET CL4 ET CLDEP ;
TAB1 . CHARGEMENT          = CHAR1 ;
TAB1 . TEMPS_CALCULES      = PROG3 ;
 
 
 
PASAPAS TAB1 ;
 
 
 
IND = DIME (TAB1.DEPLACEMENTS) ;
DEUZ = PROG ;
DESZ = PROG ;
DAM = PROG ;
I = 0 ;
PZ = V1 POIN PROC (0 0 1.0) ;
REPETER BOU1 IND ;
  SZZ = (EXTR TAB1.CONTRAINTES.I 'SMZZ' 1 1 1) ;
  DESZ = DESZ ET (PROG SZZ) ;
  UZZ = EXTR TAB1.DEPLACEMENTS.I 'UZ' PZ ;
  DD = (EXTR TAB1.VARIABLES_INTERNES.I 'D' 1 1 1) ;
  DAM = DAM ET (PROG DD) ;
  DEUZ = DEUZ ET (PROG UZZ) ;
  I = I+1 ;
FIN BOU1 ;
EV1 =  EVOL MANU DEUZ DESZ ;
EV2 = EVOL MANU DEUZ DAM ;
SI GRAP ;
DESS (EV1 ET EVT) ;
DESS (EV2 ET EVD) ;
FINSI ;
 
***************CALCUL ERREUR*****************
*Suppression la premiere valeur (éviter de diviser par 0)
st = ENLE st 1 ;
DESZ = ENLE DESZ 1 ;
MESS 'ECART EQUATION/MODELE' ;
EC = MAXI(ABS ((st - DESZ) / (st ))) ;
LIST EC ;
cri = 1E-6 ;
SI (EC > cri) ;
  ERRE 5 ;
FINSI ;
 
FIN TRA_COMP ;
 
FIN ;