Télécharger la plaquette Cast3M


fr en

Télécharger condens.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  condens.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. GRAPH = FAUX ;
  6.  
  7. ************************************************************************
  8. *   condens.dgibi : bas Mach + condensation en paroi                   *
  9. ************************************************************************
  10. *                     MODELE MISTRA AVEC CONDENSEURS                   *
  11. *                     ------------------------------                   *
  12. * INJECTION DE VAPEUR DANS UNE ENCEINTE FERMEE CONTENANT DE L'AIR      *
  13. * TEMPERATURE DE PAROI IMPOSEE (PAROI VERTICALE) NON CALCULEE          *
  14. * MODELE DE CONDENSATION : CHILTON-COLBURN + ANALOGIE HMT              *
  15. * ECHANGES PAR CONVECTION ET CONDENSATION                              *
  16. * EQUATION D'ENERGIE EN TEMPERATURE                                    *
  17. * ECOULEMENTS TURBULENTS                                               *
  18. * MAILLAGE 2D AXI FORMULATION EF QUA8                                  *
  19. * P. CORNET SEMT/TTMF 23 DECEMBRE 1998                                 *
  20. ************************************************************************
  21. *
  22. ************************************************************************
  23. * PROCEDURE FILTREKE                                                   *
  24. * VERSION    non encore évoluée à ce jour                              *
  25. ************************************************************************
  26. *
  27. * 4 arguments : U0 L0 NU UN
  28. *
  29. * Filtre sur K et Epsilon
  30. * - Echelle de vitesse (K**0.5) inférieure à une fraction (alfk)
  31. *   de Uref (vitesse caractéristique) (alfk=1 pour l'instant)
  32. *   Uref=max(UN,U0) 
  33. *  - K > K0 
  34. *  - Epsilon tel que l'echelle de longueur reste inférieure
  35. *   à (L0/a) où L0 = diamètre enceinte et a=f(Re)
  36. *   => Nut < Uref*L0/a
  37.  
  38.  DEBP FILTREKE ;
  39.  ARGU RX*TABLE ;
  40.  rv=rx.'EQEX' ;
  41.  rvp=rv.'PRESSION' ;
  42.  
  43.  rv=rx.'EQEX' ;
  44.  iarg=rx.'IARG' ;
  45.  si( non ( ega iarg 4)) ;
  46.  mess 'Procedure FILTREKE : nombre d arguments incorrect ' iarg ;
  47.  quitter FILTREKE  ;
  48.  finsi ;
  49.  si ( ega ('TYPE' rx.'ARG1') 'MOT     ') ;
  50.  U1=rv.'INCO'.(rx.'ARG1') ;
  51.  sinon ;
  52.  si ( ega ('TYPE' (rx.'ARG1')) 'FLOTTANT') ;
  53.  U1=rx.'ARG1' ;
  54.  sinon ;
  55.  mess 'Procedure FILTREKE : type argument 1 invalide ' ;
  56.  quitter FILTREKE ;
  57.  finsi ;
  58.  finsi ;
  59.  
  60.  si ( ega ('TYPE' rx.'ARG2') 'MOT     ') ;
  61.  L0=rv.'INCO'.(rx.'ARG2') ;
  62.  sinon ;
  63.  si ( ega ('TYPE' (rx.'ARG2')) 'FLOTTANT') ;
  64.  L0=rx.'ARG2' ;
  65.  sinon ;
  66.  mess 'Procedure FILTREKE : type argument 2 invalide ' ;
  67.  quitter FILTREKE ;
  68.  finsi ;
  69.  finsi ;
  70.  
  71.  si ( ega ('TYPE' rx.'ARG3') 'MOT     ') ;
  72.  NU=rv.'INCO'.(rx.'ARG3') ;
  73.  sinon ;
  74.  si ( ega ('TYPE' (rx.'ARG3')) 'FLOTTANT') ;
  75.  NU=rx.'ARG3' ;
  76.  sinon ;
  77.  mess 'Procedure FILTREKE : type argument 3 invalide ' ;
  78.  quitter FILTREKE ;
  79.  finsi ;
  80.  finsi ;
  81.  
  82.  si ( ega ('TYPE' rx.'ARG4') 'MOT     ') ;
  83.  UN=rv.'INCO'.(rx.'ARG4') ;
  84.  sinon ;
  85.  si ( ega ('TYPE' (rx.'ARG4')) 'CHPOINT') ;
  86.  UN=rx.'ARG4' ;
  87.  sinon ;
  88.  mess 'Procedure FILTREKE : type argument 4 invalide ' ;
  89.  quitter FILTREKE ;
  90.  finsi ;
  91.  finsi ;
  92.  
  93.  nic=dime (rx.'LISTINCO') ;
  94.  si( non ( ega nic 2)) ;
  95.  mess 'Procedure FILTREKE : nombre d inconnues incorrect ' nic ;
  96.  quitter FILTREKE ;
  97.  finsi ;
  98.  
  99.  nomi1=extr 1 (rx.'LISTINCO');
  100.  nomi2=extr 2 (rx.'LISTINCO');
  101.  nom1= mot (text (chai nomi1)) ;
  102.  nom2= mot (text (chai nomi2)) ;
  103.  
  104.  en=rv.'INCO'.nom2 ;
  105.  kn=rv.'INCO'.nom1 ;
  106.  
  107.  Rec=100.;
  108.  k0 = 1.e-10 ;
  109.  cnu=0.09;
  110.  
  111.  lcu=extr un 'COMP'      ;
  112.  mdu=un lcu 'PSCA' un lcu;
  113.  mdu=mdu ** 0.5 ;
  114.  
  115.  Re=kops (kops (kops mdu '*' L0) '/' nu) '+' (Rec / 10.) ;
  116.  a= exp (kops Rec '/' Re ) ;
  117.  
  118.  mdu = kops mdu '|<' u1 ;
  119.  mdu2= kops mdu '*' mdu ;
  120.  
  121.  kn=kops kn '|<' k0 ;
  122.  kn=kops kn '>|' mdu2 ;
  123.  
  124.  E0= kops (kops kn '**' 1.5) '*' (a / L0) ;
  125.  en=kops en '|<' E0 ;
  126.  
  127.  rv.'INCO'.nom2=en ;
  128.  rv.'INCO'.nom1=kn ;
  129.  
  130.  finproc ;
  131.  
  132. ************************************************************************
  133. * PROCEDURE CALCUL1                                                    *
  134. ************************************************************************
  135.  
  136. DEBPROC CALCUL1 ;
  137. ARGU RVX*'TABLE' ;
  138. RV = RVX.'EQEX' ;
  139. $MT = RV.'DOMAINE' ;
  140.  
  141. * on récupère le pas de temps (tn - tn-1)
  142.  
  143. DT = RV.PASDETPS.'DELTAT-1' ;
  144. SI (RV.PASDETPS.'NUPASDT' EGA 1) ;
  145. RV.PASDETPS.'DELTAT' = 1.0E-5 ;
  146. DT = 0. ;
  147. FINSI ;
  148.  
  149. * filtre sur la fraction massique de vapeur et calcul fraction air
  150.  
  151. YH2O = RV.INCO.'YH2O' ;
  152. YH2O = KOPS YH2O '|<' 0. ;
  153. YH2O = KOPS YH2O '>|' 1. ;
  154. YAIR = KOPS 1.0 '-' YH2O ;
  155. RV.INCO.'YAIR' = YAIR ;
  156.  
  157. * calcul de Cv, Cp et R du mélange
  158.  
  159. CV1 = kops YH2O '*' CVH2O ;
  160. CV2 = kops YAIR '*' CVAIR ;
  161. CV  = kops CV1  '+' CV2   ;
  162.  
  163. CP1 = kops YH2O '*' CPH2O ;
  164. CP2 = kops YAIR '*' CPAIR ;
  165. CP  = kops CP1  '+' CP2   ;
  166.  
  167. RR1 = kops YH2O '*' RH2O ;
  168. RR2 = kops YAIR '*' RAIR ;
  169. RR  = kops RR1  '+' RR2  ;
  170.  
  171. RV.INCO.'CV' = CV ;
  172. RV.INCO.'CP' = CP ;
  173. RV.INCO.'RN' = RR ;
  174.  
  175. * calcul de la densité totale moyenne 0D (kg/m3)
  176.  
  177. Q0  = RV.INCO.'DEBIT' ;
  178. QC  = RV.INCO.'QC' ;
  179. DRO = DT*(Q0+QC)/VOLT ;
  180. ROT0D = RV.INCO.'ROT0D' + DRO ;
  181. RV.INCO.'ROT0D' = ROT0D ;
  182.  
  183. * calcul de la densité de vapeur moyenne 0D (kg/m3)
  184.  
  185. QV = Q0*YH2Ojet ;
  186. DROV = DT*(QV+QC)/VOLT ;
  187. ROV0D = RV.INCO.'ROV0D' + DROV ;
  188. RV.INCO.'ROV0D' = ROV0D ;
  189.  
  190. * calcul de l'énergie emmenée par la condensation (W)
  191.  
  192. TNP = KCHT $PCON  SCAL SOMMET  RV.INCO.'TN' ;
  193. CVT = KOPS  CVH2O '*' TNP ;
  194. ENC = KOPS  CVT '*' RV.INCO.'FCOND' ;
  195. ENC = RV.'DI' '*' ENC ;
  196. ENC = SOMT ENC ;
  197.  
  198. * calcul de l'énergie emmenée par la convection (W)
  199.  
  200. ROP = KCHT $PCON  SCAL SOMMET  RV.INCO.'RHO' ;
  201. CPP = KCHT $PCON  SCAL SOMMET  CP ;
  202. RCP = KOPS  ROP '*' CPP ;
  203. DTP = KOPS  TNP '-' RV.INCO.'TC' ;
  204. RCT = KOPS  RCP '*' DTP ;
  205. EHI = NOEL $PCON  RCT ;
  206. EHI = KOPS  EHI '*' RV.INCO.'H' ;
  207. EHI = KOPS  EHI '*' SURFC ;
  208. EHI = SOMT  EHI ;
  209.  
  210. * calcul de l'énergie moyenne 0D (J/m3)
  211.  
  212. DES = (Q0*EMjet) + Etran - ENC - EHI ;
  213. DES = DES*DT/VOLT ;
  214. ES0D = RV.INCO.'ES0D' + DES ;
  215. RV.INCO.'ES0D' = ES0D ;
  216.  
  217. * Cp et Cv 0D du mélange
  218.  
  219. YV0D = ROV0D/ROT0D ;
  220. YA0D = 1.0 - YV0D ;
  221. CP0D = (YV0D*CPH2O) + (YA0D*CPAIR) ;
  222. CV0D = (YV0D*CVH2O) + (YA0D*CVAIR) ;
  223.  
  224. * calcul de la pression moyenne 0D
  225.  
  226. GAM0D = CP0D/CV0D ;
  227. RV.INCO.'PR0D' = (GAM0D - 1.0)*ES0D ;
  228.  
  229. * calcul de la masse volumique du melange
  230.  
  231. PSIN = KOPS (RV.INCO.'TN') '*' (RV.INCO.'RN') ;
  232. RHO = KOPS (RV.INCO.'PM') '/' PSIN ;
  233. ROM = KOPS  RV.'D0' '*' RHO ;
  234. ROM = (somt ROM)/VOLT ;
  235. DRO1 = RV.INCO.'ROT0D' - ROM ;
  236. DRHO = KCHT $MT SCAL SOMMET DRO1 ;
  237. RV.INCO.'RHO' = KOPS  RHO '+' DRHO ;
  238. RV.INCO.'RHO1' =  RHO ;
  239. RV.INCO.'RHOC' = NOEL $MT RV.INCO.'RHO' ;
  240.  
  241. * contrainte sur rhoh2o pour conservation 0D
  242.  
  243. ROVM = kops  YH2O '*' RHO ;
  244. ROVM = kops  RV.'D0'  '*' ROVM ;
  245. ROVM = (somt ROVM)/VOLT ;
  246. DROV = RV.INCO.'ROV0D' - ROVM ;
  247. DYV = DROV/ROM ;
  248. DYH2O = kcht $mt SCAL SOMMET DYV ;
  249. YH2OC = kops  YH2O '+' DYH2O ;
  250. YH2OF = kops YH2OC '|<' 0. ;
  251. YH2OF = kops YH2OF '>|' 1. ;
  252. RV.INCO.'YH2O' = YH2OF ;
  253.  
  254. * contrainte sur l'énergie e=rho.Cv.T pour conservation 0D
  255.  
  256. RCV = KOPS  RHO '*' CV ;
  257. ENM = KOPS  RV.INCO.'TN' '*' RCV ;
  258. ENM = KOPS  RV.'D0'  '*' ENM ;
  259. ENM = (SOMT ENM)/VOLT ;
  260. DEN = RV.INCO.'ES0D' - ENM ;
  261. RCVM = KOPS  RV.'D0'  '*' RCV ;
  262. RCVM = (SOMT RCVM)/VOLT ;
  263. DTN = DEN/RCVM ;
  264. DTN = KCHT  $MT  SCAL SOMMET  DTN ;
  265. RV.INCO.'TN' = KOPS  RV.INCO.'TN' '+' DTN ;
  266.  
  267. * calcul du terme (rho-rhom)*g de la QDM
  268.  
  269. DRHO = KOPS (RV.INCO.'RHOC') '-' (RV.INCO.'ROT0D') ;
  270. rogx = KCHT (RV.'DOMAINE') SCAL CENTRE 0. ;
  271. rogy = KCHT (RV.'DOMAINE') SCAL CENTRE (-9.81*DRHO) ;
  272. rogx = nomc 'UX' rogx 'NATU' 'DISCRET' ;
  273. rogy = nomc 'UY' rogy 'NATU' 'DISCRET' ;
  274. RV.INCO.'ROG' = KCHT (RV.'DOMAINE') VECT CENTRE (rogx ET rogy) ;
  275.  
  276. * calcul la vitesse à partir de la qdm
  277.  
  278. GN = RV.INCO.'GN' ;
  279. gnx= kcht (rv.'DOMAINE') scal sommet (exco 'UX' gn) ;
  280. gny= kcht (rv.'DOMAINE') scal sommet (exco 'UY' gn) ;
  281. unx = kops gnx '/' RV.INCO.'RHO' ;
  282. uny = kops gny '/' RV.INCO.'RHO' ;
  283. unx = nomc 'UX' unx 'NATU' 'DISCRET' ;
  284. uny = nomc 'UY' uny 'NATU' 'DISCRET' ;
  285. un = kcht (RV.'DOMAINE') vect sommet (unx et uny) ;
  286. RV.INCO.'UN' = un ;
  287.  
  288. * calcul de nut et uet (pour FPT)
  289.  
  290. RV.INCO.'NUT' = KOPS (RV.INCO.'MUT') '/' (RV.INCO.'RHOC') ;
  291. RV.INCO.'UTC' = KCHT $PCON SCAL CENTRE RV.INCO.'UET' ;
  292.  
  293. *-------------------------------------------------*
  294. * calcul du flux condensé Jv par Chilton-Colburn  *
  295. * et la corrélation de convection naturelle       *
  296. *   Sh = kL/Dv = 0.13 (Gr Sc)**1/3                *
  297. *   Jv = k ro (Yv - Yvsat)   en kg/m²s            *
  298. *-------------------------------------------------*
  299.  
  300. * pression de saturation à l'interface
  301.  
  302. TC = KOPS (RV.INCO.'TC') '-' 273.15 ;
  303. PSAT = KOPS  TC '/' 100. ;
  304. PSAT = KOPS  PSAT '**' 4 ;
  305. PSAT = KOPS  PSAT '*' 1.0E5 ;
  306.  
  307. * pression de vapeur pres de la paroi
  308.  
  309. YVP = KCHT  $PCON SCAL SOMMET RV.INCO.'YH2O' ;
  310. RVT = KOPS  RH2O '*' TNP ;
  311. ROV = KOPS  ROP '*' YVP ;
  312. PV = KOPS  ROV '*' RVT ;
  313.  
  314. * masse volumique à l'interface
  315.  
  316. RVTI = KOPS  RH2O '*' RV.INCO.'TC' ;
  317. ROVI = KOPS  PSAT '/' RVTI ;
  318. RATI = KOPS  RAIR '*' RV.INCO.'TC' ;
  319. PAIR = KOPS  RV.INCO.'PM' '-' PSAT ;
  320. RAVI = KOPS  PAIR '/' RATI ;
  321. ROI = KOPS  ROVI '+' RAVI ;
  322.  
  323. * fraction massique vapeur à l'interface
  324.  
  325. YVI = KOPS  ROVI '/' ROI ;
  326. RV.INCO.'YVS' = YVI ;
  327. RV.INCO.'YVI' = NOEL $PCON YVI ;
  328.  
  329. * coefficient de diffusion de la vapeur dans l'air (m2/s)
  330.  
  331. AA = 2.2 / RV.INCO.'PM' ;
  332. TFP = KOPS TNP '/' 273. ;
  333. DV = KOPS TFP '**' 1.75 ;
  334. DV = KOPS DV '*' AA ;
  335.  
  336. * coefficient d'échange de masse k (m/s)
  337.  
  338. BB = 0.13 * (9.81 * RV.INCO.'ROT0D' / MU)**0.33333 ;
  339. DRO = KOPS  ROP '-' ROI ;
  340. DRO = ABS  DRO ;
  341. DRO = KOPS  DRO '**' 0.33333 ;
  342. KK = KOPS DV '**' 0.66667 ;
  343. KK = KOPS KK '*' DRO ;
  344. KK = KOPS KK '*' BB ;
  345. RV.INCO.'K' = KK ;
  346.  
  347. * fonction indicatrice de la condensation
  348.  
  349. DPV = KOPS  PV '-' PSAT ;
  350. IND = DPV  MASQUE  'EGSUP'  0. ;
  351. IND = KCHT $PCON SCAL SOMMET IND ;
  352.  
  353. * coefficient d'échange pour yh2o (kg/m2s)
  354.  
  355. KRO = KOPS  KK '*' ROP ;
  356. KRO = KOPS  KRO '*' IND ;
  357. RV.INCO.'KS' = KRO ;
  358. RV.INCO.'KY' = NOEL $PCON KRO ;
  359.  
  360. * calcul de la masse de vapeur condensée QC (kg/s)
  361.  
  362. DYV = KOPS  YVP '-' RV.INCO.'YVS' ;
  363. FCOND = KOPS  DYV '*' RV.INCO.'KS' ;
  364. QC  = RV.'DI' '*' FCOND ;
  365. QC  = (SOMT QC)*(-1.)  ;
  366. RV.INCO.'FCOND' = FCOND ;
  367. RV.INCO.'QC' = QC ;
  368.  
  369. * suivi masse condensée
  370.  
  371. RV.INCO.'MCOND' = RV.INCO.'MCOND' + (QC*DT) ;
  372.  
  373. * suivi des inconnues OD et messages
  374.  
  375. DD = RV.PASDETPS.'NUPASDT' ;
  376. NN = DD/NSAUV ;
  377. LO = (DD-(NSAUV*NN)) EGA 0 ;
  378. SI ( LO ) ;
  379. MESSAGE '============================================================' ;
  380.  
  381. * suivi pression, masse vol tot, temperature, enthalpie OD, condensation
  382.  
  383. RV.INCO.'PT0D' = RV.INCO.'PT0D' et (prog RV.INCO.'PR0D') ;
  384. R0D = (YV0D*RH2O) + (YA0D*RAIR) ;
  385. PVAP = RV.INCO.'PR0D'*YV0D*RH2O/R0D ;
  386. PAIR = RV.INCO.'PR0D'*YA0D*RAIR/R0D ;
  387. RV.INCO.'PV0D' = RV.INCO.'PV0D' et (prog PVAP) ;
  388. RV.INCO.'PA0D' = RV.INCO.'PA0D' et (prog PAIR) ;
  389. RV.INCO.'RO0D' = RV.INCO.'RO0D' et (prog RV.INCO.'ROT0D') ;
  390. T0D = ES0D/ROT0D/CV0D - 273.15 ;
  391. RV.INCO.'T0D' = RV.INCO.'T0D' et (prog T0D) ;
  392. H0D = GAM0D * ES0D / ROT0D + LAT ;
  393. RV.INCO.'H0D' = RV.INCO.'H0D' et (prog H0D) ;
  394. QC1 = -1.* QC ;
  395. RV.INCO.'FCDST' = RV.INCO.'FCDST' et (prog QC1)  ;
  396.  
  397. ener = kops RV.INCO.'RHO' '*' RV.INCO.'CV' ;
  398. ener = kops ener '*' RV.INCO.'TN' ;
  399. ener = noel $mt ener ;
  400. ener = kops ener '*' vol ;
  402. RV.INCO.'ETOT' = RV.INCO.'ETOT' et (prog ener) ;
  403. en2  = ES0D*VOLT ;
  404. RV.INCO.'ET0D' = RV.INCO.'ET0D' et (prog en2) ;
  405.  
  406. FINSI ;
  407.  
  408. FINPROC ;
  409.  
  410. ************************************************************************
  411. * PROCEDURE CALCUL2                                                    *
  412. ************************************************************************
  413.  
  414. DEBPROC CALCUL2 ;
  415. ARGU RVX*'TABLE' ;
  416. RV = RVX.'EQEX' ;
  417. $MT = RV.'DOMAINE' ;
  418.  
  419. * on récupère le pas de temps
  420.  
  421. Dt = RV.PASDETPS.'DELTAT' ;
  422. Dt = Dt * RV.'ALFA' ;
  423.  
  424. * calcul de l'intégrale se trouvant dans le terme Dp/Dt.
  425.  
  426. RV.INCO.'PSIN' = KOPS (RV.INCO.'TN') '*' (RV.INCO.'RN') ;
  427. ZT = KOPS (RV.INCO.'PSIN') '-' (RV.INCO.'PSI1') ;
  428. ZT = KOPS ZT '/' Dt ;
  429. ZT = KOPS ZT '/' (RV.INCO.'PSIN') ;
  430. ZZ = KOPS ZT '*' RV.INCO.'RHO' ;
  431. ZZ = NOEL $MT ZZ ;
  432. ZZ = KCHT $MT 'SCAL' 'CENTRE' ZZ ;
  433. ZZT = SOMT ( KOPS ZZ '*' VOL ) ;
  434. RV.INCO.'PSI1' = KCHT $MT 'SCAL' 'SOMMET' (RV.INCO.'PSIN') ;
  435.  
  436. * calcul de dP/dt
  437.  
  438. * Q0 = 'DBIT' RV.INCO.'GN' $BAS ;
  439. dPdt = ZZT + RV.INCO.'DEBIT' + RV.INCO.'QC' ;
  440. dPdt = dPdt*(RV.INCO.'PM')/VOLT/RV.INCO.'ROT0D' ;
  441.  
  442. * terme source de l'équation d'énergie (terme en dP/dt)
  443.  
  444. CPC = NOEL $MT RV.INCO.'CP' ;
  445. SE = KOPS dPdt '/' RV.INCO.'RHOC' ;
  446. SE = KOPS SE   '/' CPC ;
  447. RV.INCO.'SE' = KCHT $MT 'SCAL' 'CENTRE' SE ;
  448.  
  449. * terme source équation de Poisson
  450.  
  451. Z1 = dPdt/RV.INCO.'PM' ;
  452. ZP = KOPS RV.INCO.'RHOC' '*' Z1 ;
  453. ZS = KOPS ZP '-' ZZ ;
  454. ZZS = KOPS ZS '*' VOL ;
  455. ZZS = ZZS * (-1.0) ;
  456. RV.INCO.'SP' = KCHT $MT 'SCAL' 'CENTRE' ZZS ;
  457.  
  458. * calcul de l'évolution de la pression 
  459.  
  460. RV.INCO.'PM' = RV.INCO.'PM' + (dPdt*dt) ;
  461.  
  462. * affichage informations toutes les NSAUV iterations
  463. ************************************************************************
  464.  
  465. DD = RV.PASDETPS.'NUPASDT' ;
  466. NN = DD/NSAUV ;
  467. LO = (DD-(NSAUV*NN)) EGA 0 ;
  468. SI ( LO ) ;
  469.  
  470.   mess 'TEMPS (s) = ' RV.PASDETPS.'TPS' 'PRESSION (Pa) =' RV.INCO.'PM' ;
  471. PT = PROG RV.'PASDETPS'.'TPS' ;
  472. PP = PROG RV.INCO.'PM' ;
  473. PMas = MASINI + ( RV.INCO.'DEBIT' * RV.PASDETPS.'TPS')
  474.  +  RV.INCO.'MCOND' ;
  475. PMTH = PROG PMas ;
  476. RHO  = RV.INCO.'RHO1' ;
  477. RHO  = noel $mt RHO  ;
  478. RHO  = kops  RHO '*' VOL ;
  479. ROM  = somt  RHO  ;
  480. PMTO = PROG  ROM  ;
  481.  RV.INCO.'TEMPS' = RV.INCO.'TEMPS' ET PT ;
  482.  RV.INCO.'PRESS' = RV.INCO.'PRESS' ET PP ;
  483.  RV.INCO.'MTOTA' = RV.INCO.'MTOTA' ET PMTO ;
  484.  RV.INCO.'MTHEO' = RV.INCO.'MTHEO' ET PMTH ;
  485.  
  486. RHOH2O = KOPS RV.INCO.'RHO' '*' RV.INCO.'YH2O' ;
  487. RHOAIR = KOPS RV.INCO.'RHO' '*' RV.INCO.'YAIR' ;
  488. RHOH2OC = NOEL $MT RHOH2O ;
  489. RHOAIRC = NOEL $MT RHOAIR ;
  490. MASH2O = SOMT (KOPS RHOH2OC '*' VOL) ;
  491. MASAIR = SOMT (KOPS RHOAIRC '*' VOL) ;
  492.  MESSAGE 'MASSES (kg): H2O =' MASH2O  'AIR =' MASAIR
  493.   'TOTALE = ' (MASH2O + MASAIR) ;
  494. PMH2O = PROG MASH2O ;
  495. PMAIR = PROG MASAIR ;
  496. PMAIRT= PROG (MAIRINI + (RV.INCO.'DEBIT' * RV.PASDETPS.'TPS'* YAIRJet));
  497. PMH2OT= PROG (MH2OINI + (RV.INCO.'DEBIT' *
  498.  RV.PASDETPS.'TPS'* YH2OJet)  + RV.INCO.'MCOND');
  499. RV.INCO.'PMH2O' = RV.INCO.'PMH2O' ET PMH2O ;
  500. RV.INCO.'PMAIR' = RV.INCO.'PMAIR' ET PMAIR ;
  501. RV.INCO.'PMH2OT' = RV.INCO.'PMH2OT' ET PMH2OT ;
  502. RV.INCO.'PMAIRT' = RV.INCO.'PMAIRT' ET PMAIRT ;
  503.  
  504. FINSI ;
  505.  
  506. FINPROC ;
  507.  
  508. ************************************************************************
  509. *                       GENERATION DU MAILLAGE                         *
  510. ************************************************************************
  511. *
  512. * cuve cylindrique de rayon interieur RA
  513. *                  de hauteur HA
  514. *                  de rayon d'injection RJ.
  515. *------------------------------------------
  516.  
  517.   'OPTION' 'DIME'  2 'ELEM' 'QUA8' ;
  518.   'OPTION' 'ISOV'  'LIGN' ;
  519.   'OPTION' 'MODE' 'AXIS' ;
  520.  
  521. * Dimensions de la cuve et de la zone d'injection
  522.  
  523.   HA = 6.2 ;
  524.   RA = 1.9 ;
  525.   RJ = 0.1 ;
  526.  
  527. * Nombre d'elements injection et cotés
  528. *   en MACRO, N réel = n x 2
  529.  
  530.   nj  = 1  ;
  531.   nr  = 10 ;
  532.   nh  = 20 ;
  533.  
  534. * Definition des points utiles pour la creation du maillage
  535. * ---------------------------------------------------------
  536. *
  537. *                   B0| BJ            B1
  538. *                     .----------------|   
  539. *                     |                |
  540. *                     .                |   
  541. *                     |                |   
  542. *                     .                |   
  543. *                     |                |   
  544. *                     .                |   
  545. *                     |                |   
  546. *                     .                |
  547. *                     |                |   
  548. *                     .                |   
  549. *                     |                |  
  550. *                     .                |  
  551. *                     |                |   
  552. *                     .                |   
  553. *                     |                |   
  554. *                     .                |   
  555. *                     |                |
  556. *                     .----------------|
  557. *                   A0| |AJ           A1
  558. *
  559. * ----------------------------------------------------------------------
  560.  
  561.   A0  = 0.    0.   ;
  562.   AJ  = RJ    0.   ;
  563.   A1  = RA    0.   ;
  564.    B0  = 0.    HA   ;
  565.   BJ  = RJ    HA   ;
  566.   B1  = RA    HA   ;
  567.  
  568. * Définition des segments
  569.  
  570.   A0J = A0 'DROI' nj AJ ;
  571.   AJ1 = AJ 'DROI' nr A1 ;
  572.  
  573.   B0J = B0 'DROI' nj BJ ;
  574.   BJ1 = BJ 'DROI' nr B1 ;
  575.  
  576.   AB0 = A0 'DROI' nh B0 ;
  577.   AB1 = A1 'DROI' nh B1 ;
  578.  
  579.   A01 = A0J ET AJ1 ;
  580.   B01 = B0J ET BJ1 ;
  581.  
  582. * Maillage total
  583.  
  584.   MT = 'DALL' A01 AB1 B01 AB0 ;
  585.   'ORIENTER' MT ;
  586.  
  587. * Lignes pour conditions aux limites et post-traitement
  588.  
  589.   AXE = AB0 ;
  590.   BAS = A01 ;
  591.   INJ = A0J ;
  592.   BAS2 = AJ1 ;
  593.   HAUT = B01 ;
  594.   PCON = AB1 ;
  595.   PTOT = AJ1 ET PCON ET ('INVE' HAUT) ;
  596.  
  597. * Définition des tables domaine
  598.  
  599.   $MT      = 'DOMA' MT   1.E-5    'MACRO' impr;
  600.   $INJ     = 'DOMA' INJ           'MACRO' 'INCL' $MT 1.e-5 ;
  601.   $AXE     = 'DOMA' AXE           'MACRO' 'INCL' $MT 1.e-5 ;
  602.   $BAS     = 'DOMA' BAS           'MACRO' 'INCL' $MT 1.e-5 ;
  603.   $PCON    = 'DOMA' PCON          'MACRO' 'INCL' $MT 1.e-5 ;
  604.   $PTOT    = 'DOMA' PTOT          'MACRO' 'INCL' $MT 1.e-5 ;
  605.  
  606. * Maillage final
  607.  
  608.   MT = $MT.MAILLAGE ;
  609.  
  610.   CNT = CONT MT ;
  611.   INJ = INJ COUL ROUG ;
  612.   PCON = PCON COUL VERT ;
  613.   AXE = AXE COUL JAUN ;
  614.  
  615. * TRAC (BAS ET AXE ET PCON ET HAUT) ;
  616. * TRAC (MT ET INJ ET PCON ET AXE) ;
  617. * TRAC (PTOT ET AXE) ;
  618.  
  619. * Volume, nbre d'éléments, surface condensante
  620.  
  621.   VOL = 'DOMA' $MT 'VOLUME' ;
  622.   VOLT = 'SOMT' VOL ;
  623.   NEMT = NBEL MT ;
  624.   SURFC = 'DOMA' $PCON 'VOLUME' ;
  625.   SURFT = 'SOMT' SURFC ;
  626.  
  627.  
  628. ************************************************************************
  629. *                          DONNEES PHYSIQUES                           *
  630. ************************************************************************
  631.  
  632. *--------------------------------------
  633. * masses molaires et constantes des gaz
  634. *--------------------------------------
  635.  
  636. MH2O = 18.0E-3 ;
  637. MAIR = 28.8E-3 ;
  638.  
  639. Rg = 8.313 ;
  640.  
  641. RH2O = Rg/MH2O ;
  642. RAIR = Rg/MAIR ;
  643.  
  644. *------------------------------------------------
  645. * fractions massiques des differents constituants
  646. *------------------------------------------------
  647.  
  648. YAIR = 0.664;
  649.  
  650. YH2O = 1-YAIR ;
  651.  
  652. *---------------------------------------------
  653. * constante du gaz
  654. *---------------------------------------------
  655.  
  656. R = (RH2O*YH2O)+(RAIR*YAIR) ;
  657.  
  658. *------------------------------------------------------------
  659. * pression, temperature et densite du melange (loi d'etat GP)
  660. *------------------------------------------------------------
  661.  
  662. Pbar = 1.5  ;
  663. T°C  = 100. ;
  664.  
  665. P = Pbar /1.013 ;
  666. P = P * 1.0E5 ;
  667. T = T°C + 273.15 ;
  668. PSI = R*T ;
  669. RHO = P/PSI ;
  670.  
  671. *-------------------------------------------------------------
  672. * Masse volumique des constituants
  673. *-------------------------------------------------------------
  674.  
  675. RHOAIR= P*YAIR/(T*R);
  676. RHOH2O= RHOAIR*YH2O/YAIR;
  677.  
  678. *---------------------
  679. * pressions partielles
  680. *---------------------
  681.  
  682. PH2O = RHOH2O*RH2O*T ;
  683. PAIR = RHOAIR*RAIR*T ;
  684.  
  685. *----------------------------------------------------------
  686. * fractions molaires des differents constituants du melange
  687. *----------------------------------------------------------
  688.  
  689. XH2O = PH2O/P ;
  690. XAIR = PAIR/P ;
  691.  
  692. *---------------------------------------------
  693. * Masse molaire du mélange
  694. *---------------------------------------------
  695.  
  696. M = (XH2O*MH2O) + (XAIR*MAIR) ;
  697.  
  698. *----------------------------------------------------
  699. * Cp et Cv des différents constituants et du mélange
  700. *----------------------------------------------------
  701.  
  702. CPH2O = 1715.632 + (0.552805*T) ;
  703. CPN2 = 1006.15 + (0.1387166*T) ;
  704. CPO2 = 907.580 + (0.1420522*T) ;
  705. CPAIR = (0.2*CPO2) + (0.8*CPN2) ;
  706. CVH2O = CPH2O - RH2O ;
  707. CVAIR = CPAIR - RAIR ;
  708.  
  709. CP = (YH2O*CPH2O) + (YAIR*CPAIR) ;
  710. CV = (YH2O*CVH2O) + (YAIR*CVAIR) ;
  711.  
  712. gamma = CP/(CP-R) ;
  713.  
  714. *------------------------
  715. * Caractéristiques du jet
  716. *   (Qjet en kg/s)
  717. *------------------------
  718.  
  719. XH2OJet = 1.0 ;
  720. XAIRJet = 1.0 - XH2OJet ;
  721. YAIRJet = 0. ;
  722. YH2OJet = 1-YAIRJet;
  723. MJet = (XH2OJet*MH2O) + (XAIRJet*MAIR) ;
  724. RJet = Rg/MJet ;
  725. CVJet = (YH2OJet*CVH2O) + (YAIRJet*CVAIR) ;
  726.  
  727. SJet = PI*RJ*RJ ;
  728.  
  729. *°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°
  730. *                                                                      °
  731. *                        ATTENTION :                                   °
  732. *                                                                      °
  733. *          Pour que le débit effectif soit 'Q0' kg/s                   °
  734. *                                                                      °
  735. *             il faut que Qjet imposé soit < Q0                        °
  736. *                                                                      °
  737. *  ==> imposer un certain Qjet par tatonnement et vérifier ensuite     °
  738. *      avec l'opérateur DBIT que l'on a bien le débit voulu            °
  739. *                                                                      °
  740. *°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°
  741. * nr = 10 , QJet = 0.069124 => Q0 effectif = 0.149999079999999979 kg/s
  742. *
  743.  
  744.   TJ°C = 180.      ;
  745.   QJet = 0.069124  ;
  746.   GJet = QJet/SJet ;
  747. * Q0 = QJet ;
  748.   Q0 = 0.149999079999999979 ;
  749.  
  750. TJet = TJ°C + 273.15 ;
  751. PSIJet = Rjet*Tjet ;
  752. RhoJet = P/PSIJet ;
  753. EMJet = CVJet*TJet ;
  754. EJet = Q0*EMJet ;
  755. UJet = GJet/RhoJet ;
  756.  
  757. * K et epsilon
  758.  
  759.   KJet = 4.3E-3*UJet*UJet ;
  760.   EPJet = 4.3E-4*(UJet**3.)/RJ ;
  761.  
  762. * énergie de transvasement PUjSj
  763.  
  764. Etran = Q0*Rjet*Tjet ;
  765.  
  766. *-------------------------------------------------
  767. * energie, enthalpie massique et masses du melange
  768. *-------------------------------------------------
  769.  
  770. ESini = RHO*CV*T ;
  771. ETini = ESini*VOLT ;
  772. Pini = (gamma-1.)*ESini ;
  773. LAT = 2.3E6 ;
  774. MASINI = RHO*VOLT ;
  775. Hini = gamma*ETini/MASINI + LAT ;
  776.  
  777. MH2OINI = MASINI*YH2O ;
  778. MAIRINI = MASINI*YAIR ;
  779.  
  780. *--------------------------------------------------
  781. * vitesses de référence (tracés, filtre, fct paroi)
  782. *--------------------------------------------------
  783.  
  784. ampl = 0.25/Ujet ;
  785. U0 = 1.0*UJet ;
  786. L0 = 0.7 ;
  787. UET0 = Ujet/10.0 ;
  788. YP = 0.05 ;
  789. YPT= 0.05 ;
  790.  
  791. *------------------------------------------------------------------------
  792. * Prandtl, Schmidt, viscosité (loi de Sutherland), conductivité thermique
  793. * coefficients de diffusion moléculaire, coeff. d'échange par convection
  794. *------------------------------------------------------------------------
  795.  
  796. Pr = 0.7 ;
  797. Prt = 1.0 ;
  798. Sct = 1.0 ;
  799.  
  800. MUvap = 1.6E-5 ;
  801. MU = 1.716E-5*((T/273.0)**1.5)*(273.0+110.5)/(T+110.5) ;
  802. NU = MU/RHO ;
  803. Lambda = Mu*CP/Pr ;
  804. alpha = Lambda/RHO/CP ;
  805.  
  806. DH2O = 2.55E-5 ;
  807. DH2 = 7.12E-5 ;
  808. DO2 = 2.06E-5 ;
  809.  
  810. H1 = 10.0 ;
  811. H2 = H1/CP/RHO ;
  812.  
  813. *-----------------------------------
  814. * température initiale du condenseur
  815. *-----------------------------------
  816.  
  817. TP°C =  40. ;
  818.  
  819. Tcond = TP°C + 273.15 ;
  820.  
  821. *-----------------------------------
  822. * Reynolds et Richardson d'injection
  823. *-----------------------------------
  824.  
  825. VD = Q0 / (RHOjet*Sjet) ;
  826. RI0 = (RHO - RHOjet)*2.0*RJ*9.81 / (RHO*VD*VD) ;
  827. RE0 = RHOjet*VD*2.0*RJ / MUvap ;
  828.  
  829. opti echo 0 ;
  830. mess '______________________________________________________________';
  831. mess ' ' ;
  832. mess 'VOLUME FLUIDE (m3) =' VOLT  ;
  833. mess 'NOMBRE D ELTS TOTAL =' nemt  ;
  834. mess 'SURFACE DE CONDENSATION (m2) =' SURFT  ;
  835. mess 'MASSE TOTALE ini ='  MASINI  'MAIRini =' MAIRINI
  836.  'MH2Oini =' MH2OINI ;
  837. mess 'YH2Oini =' YH2O  'YAIRini =' YAIR ;
  838. mess 'RHOini =' RHO  'RHOH2Oini =' RHOH2O  'RHOAIRini =' RHOAIR ;
  839. mess 'RTini =' PSI  'RTjet =' PSIJet  ;
  840. mess 'ETOTini (J) =' ETini 'Ejet (J/s) =' Ejet ;
  841. mess 'ESini (J/m3) =' ESini ;
  842. mess 'Etransv (J/s) =' Etran  ;
  843. mess 'CPAIR =' CPAIR  'CPH2O =' CPH2O  'CPini =' CP ;
  844. mess 'CVAIR =' CVAIR  'CVH2O =' CVH2O  'CVini =' CV ;
  845. mess 'GAMMA =' gamma  ;
  846. mess 'RAIR =' RAIR  'RH2O =' RH2O  'Rini =' R ;
  847. mess 'YH2OJet =' YH2OJet  'YAIRJet =' YAIRJet ;
  848. mess 'RHOjet =' RhoJet 'Gjet =' GJet  'UJet =' UJet ;
  849. mess 'NU =' nu  'MU =' MU  'alpha gaz =' alpha   ;
  850. mess 'RICHARDSON =' RI0  'REYNOLDS =' RE0  ;
  851. mess 'Pression en Pa =' P  'Pression en bar =' Pbar;
  852. mess 'Vdéb =' VD ;
  853. mess '______________________________________________________________';
  854. opti echo 1 ;
  855.  
  856. * opti donn 5 ;
  857.  
  858. *=====================================================================*
  859. * TABLE EQEX CONTENANT LES EQUATIONS A RESOUDRE :                     *
  860. *  0) FILTRE K-E                                                      *
  861. *  1) QUANTITE DE MOUVEMENT     --- OPERATEUR NSKE                    *
  862. *  2) EQUATION DE L'ENERGIE     --- OPERATEUR TSCAL                   *
  863. *  3) TRANSPORT DES ESPECES     --- OPERATEUR TSCAL                   *
  864. * AINSI QUE 2 PROCEDURES (CALCUL1 ET CALCUL2) POUR L'ALGORITHME       *
  865. * 'FAIBLE MACH'                                                       *
  866. *  4) CONDITIONS AUX LIMITES                                          *
  867. *=====================================================================*
  868.  
  869. RV = 'EQEX' $MT    'ITMA'   200       'ALFA' 0.9  'TFINAL' 2.5 
  870.  'ZONE' $MT    'OPER' 'CALCUL1'
  871.   'ZONE' $MT    'OPER' 'FILTREKE' U0 L0 NU 'UN'  'INCO'      'KN' 'EN'
  872.    'ZONE' $PTOT  'OPER' 'FPU'      NU  'UET' YP   'INCO' 'UN' 'KN' 'EN'
  873.     'OPTI' 'CONS' 'SUPG'
  874.  'ZONE' $MT 'OPER' 'NSKE' 'RHOC' MU 'MUT'
  875.   'UN' 'ROG' 'INCO' 'GN' 'KN' 'EN' ;
  876.  
  877. RV = 'EQEX' RV
  878.  'ZONE' $PCON 'OPER' 'FPT' 1. NU 1. alpha 'UTC' YPT 'H' 'TP' 'INCO' 'TN'
  879.  'OPTI' 'NOCONS' 'SUPG'
  880.  'ZONE' $MT    'OPER' 'TSCAL' alpha 'UN' 'SE' 'NUT'  Prt  'INCO' 'TN' 
  881.   'ZONE' $PCON  'OPER' 'ECHI'     'KY'  'YVI'            'INCO' 'YH2O'
  882.   'OPTI' 'NOCONS' 'SUPG'
  883.   'ZONE' $MT    'OPER' 'TSCAL' DH2O 'UN'  0.  'NUT' SCT  'INCO' 'YH2O'
  884.   'ZONE' $MT    'OPER' 'CALCUL2' ;
  885.  
  886.  
  887. *===================== conditions aux limites ==========================
  888.  
  889. RV = 'EQEX' RV 'CLIM' 'GN' 'UIMP' (AXE  et PCON)  0.
  890.      'GN' 'VIMP' (BAS2 et HAUT)  0. 'GN' 'UIMP'  INJ   0.
  891.      'GN' 'VIMP'  INJ    GJet  'KN' 'TIMP'  INJ    KJet
  892.      'EN' 'TIMP'  INJ    EPJet ;
  893. RV = 'EQEX' RV 'CLIM' 'TN'   'TIMP' INJ    TJet
  894.  'YH2O' 'TIMP' INJ    YH2OJet ;
  895.  
  896. *===========================================================
  897. * TABLE EQPR POUR L'EQUATION DE POISSON (SOLVEUR ELLIPTIQUE) 
  898. *===========================================================
  899.  
  900. RVP = 'EQPR' $MT    KTYPI 1 'ZONE' $MT 
  901.     'OPER' 'PRESSION' 'SP' 'PIMP' 0.  ;
  902.  
  903.  
  904. *==========================================================
  905. * TABLE INCO CONTENANT LES INCONNUES ET DONNEES DU PROBLEME 
  906. *==========================================================
  907.  
  908.   RV.'PRESSION' = RVP ;
  909.   RV.'NOMVI' = 'GN' ;
  910.   RV.'INCO' = 'TABLE' 'INCO' ;
  911.   RVP.'INCO' = RV.'INCO' ;
  912.  
  913.   $FLUID = $MT ;
  914.   $PAROI = $PTOT ;
  915.  
  916. * inconnues des équations différentielles
  917.  
  918.   RV.INCO.'GN' = kcht $FLUID VECT SOMMET (0. 0.) ;
  919.   RV.INCO.'EN' = kcht $FLUID SCAL SOMMET   1.E-5 ;
  920.   RV.INCO.'KN' = kcht $FLUID SCAL SOMMET   1.E-5 ;
  921.   RV.INCO.'YH2O'= kcht $FLUID SCAL SOMMET  YH2O  ;
  922.   RV.INCO.'TN'   = kcht $FLUID SCAL SOMMET  T    ;
  923.  
  924. * matrices masse pour calcul des moyennes aux noeuds
  925.  
  926.   RV.'D0' = DOMA $FLUID 'XXDIAGSI' ;
  927.   RV.'DI' = DOMA $PCON  'XXDIAGSI' ;
  928.  
  929. * variables 0D : masse totale, masse vapeur, energie, pression
  930.  
  931.   RV.INCO.'ROT0D' = RHO    ;
  932.   RV.INCO.'ROV0D' = RHOH2O ;
  933.   RV.INCO.'ES0D' =  ESini ;
  934.   RV.INCO.'PR0D' =  P    ;
  935.  
  936. * debit de masse injecté, masse condensée
  937.  
  938.   RV.INCO.'DEBIT' = Q0 ;
  939.   RV.INCO.'MASCD' = 0. ;
  940.  
  941. * inconnues auxiliaires
  942.  
  943.   RV.INCO.'UN' = kcht $FLUID VECT SOMMET (0. 0.) ;
  944.   RV.INCO.'PSIN' = kcht $FLUID SCAL SOMMET   PSI ;
  945.   RV.INCO.'PSI1' = kcht $FLUID SCAL SOMMET   PSI ;
  946.  
  947. * variables modèle de turbulence
  948.  
  949.   RV.INCO.'UET' = kcht $PTOT  SCAL CENTRE  UET0 ;
  950.   RV.INCO.'UTC' = kcht $PCON  SCAL CENTRE  UET0 ;
  951.   RV.INCO.'MUT' = kcht $FLUID SCAL CENTRE  Mu ;
  952.   RV.INCO.'NUT' = kcht $FLUID SCAL CENTRE  Nu ;
  953.  
  954. * masse volumique
  955.  
  956.   RV.INCO.'RHO' = kcht $FLUID SCAL SOMMET  RHO    ;
  957.   RV.INCO.'RHO1'= kcht $FLUID SCAL SOMMET  RHO    ;
  958.   RV.INCO.'RHOC'= kcht $FLUID SCAL CENTRE  RHO    ;
  959.  
  960. * fractions massiques
  961.  
  962.   RV.INCO.'YAIR' = kcht $FLUID SCAL SOMMET  YAIR   ;
  963.  
  964. * Cv, R, et Cp du mélange
  965.  
  966.   RV.INCO.'CV' = kcht $FLUID SCAL SOMMET CV ;
  967.   RV.INCO.'RN' = kcht $FLUID SCAL SOMMET R  ;
  968.   RV.INCO.'CP' = kcht $FLUID SCAL SOMMET CP ;
  969.  
  970. * à la paroi coef d'ech, frac vap, temp, flux de masse
  971.  
  972.   RV.INCO.'H'   = kcht $PCON SCAL CENTRE  H2  ;
  973.   RV.INCO.'K'   = kcht $PCON SCAL CENTRE  0.  ;
  974.   RV.INCO.'KY'  = kcht $PCON SCAL CENTRE  0.  ;
  975.   RV.INCO.'KS'  = kcht $PCON SCAL SOMMET  0.  ;
  976.   RV.INCO.'YVI' = kcht $PCON SCAL CENTRE  0.  ;
  977.   RV.INCO.'YVS' = kcht $PCON SCAL SOMMET  0.  ;
  978.   RV.INCO.'TC'  = kcht $PCON SCAL SOMMET  Tcond ;
  979.   RV.INCO.'TP'  = kcht $PCON SCAL CENTRE  Tcond ;
  980.   RV.INCO.'FCOND' = kcht $PCON SCAL SOMMET  0. ;
  981.   RV.INCO.'QC'  = 0. ;
  982.   RV.INCO.'MCOND' = 0. ;
  983.  
  984. * termes sources (Poisson/énergie/QDM)
  985.  
  986.   RV.INCO.'SP' = KCHT $FLUID SCAL CENTRE   0.    ;
  987.   RV.INCO.'SE' = kcht $FLUID SCAL CENTRE   0.    ;
  988.   RV.INCO.'ROG'= kcht $FLUID VECT CENTRE (0. 0.) ;
  989.  
  990. * pression
  991.  
  992.   RV.INCO.'PM' = P ;
  993.  
  994. * suivi des valeurs moyennes calculées en 2D
  995.  
  996.   RV.INCO.'TEMPS' = PROG 0. ;
  997.   RV.INCO.'PRESS' = PROG P  ;
  998.   RV.INCO.'MTOTA' = PROG MASINI ;
  999.   RV.INCO.'MTHEO' = PROG MASINI ;
  1000.   RV.INCO.'ETOT'  = PROG ETini  ;
  1001.   RV.INCO.'PMH2O' = PROG MH2OINI ;
  1002.   RV.INCO.'PMAIR' = PROG MAIRINI ;
  1003.   RV.INCO.'PMH2OT' = PROG MH2OINI ;
  1004.   RV.INCO.'PMAIRT' = PROG MAIRINI ;
  1005.   RV.INCO.'FCDST'  = PROG 0. ;
  1006.  
  1007. * suivi des variables purement 0D
  1008.  
  1009.   RV.INCO.'MT0D' = prog MASINI  ;
  1010.   RV.INCO.'MV0D' = prog MH2OINI ;
  1011.   RV.INCO.'PT0D' = prog P       ;
  1012.   RV.INCO.'PV0D' = prog PH2O    ;
  1013.   RV.INCO.'PA0D' = prog PAIR    ;
  1014.   RV.INCO.'ET0D' = prog ETini   ;
  1015.   RV.INCO.'RO0D' = prog RHO     ;
  1016.   RV.INCO.'T0D'  = prog (T-273.15) ;
  1017.   RV.INCO.'H0D'  = prog Hini    ;
  1018.  
  1019. *===================================================================*
  1020. *                    EXECUTION ET SAUVEGARDE                        *
  1021. *===================================================================*
  1022.  
  1023. * on gardera une valeur tous les NSAUV pas de temps
  1024.  
  1025. NSAUV     =  20 ;
  1026. RV.'FIDT' = NSAUV ;
  1027.  
  1028. exec rv ;
  1029.  
  1030. *===================================================================*
  1031. *                         POST TRAITEMENT                           *
  1032. *===================================================================*
  1033. SI GRAPH ;
  1034.  
  1036.  
  1037.   TRAC MT 'TITR' 'MAILLAGE ' ;
  1038.  
  1039.   MFLUID = MT ;
  1040.  
  1041.   gn1 = 'VECT' (RV.'INCO'.'GN') ampl UX UY VERT ;
  1042.   'TRAC' gn1  mt cnt
  1043.    'TITR' ' CHAMP DE LA VITESSE MASSIQUE rho.u (Kg.m-².s-1)' ;
  1044.  
  1045.   un1 = 'VECT' (RV.'INCO'.'UN') ampl UX UY VERT ;
  1046.   'TRAC' un1  mt cnt 'TITR' ' CHAMP DE VITESSES U (m/s)' ;
  1047.  
  1048.   Vy = EXCO UY RV.INCO.'UN' ;
  1049.   EVOLVP = evol CHPO Vy AXE ;
  1050.   DESS EVOLVP TITX 'AXE (m)' TITY 'Vitesse (m/s)'
  1051.    TITR 'VITESSE LE LONG DE L AXE (m/s)';
  1052.  
  1053.   EVOLVP = evol CHPO Vy PCON ;
  1054.   DESS EVOLVP TITX 'PAROI COND. (m)' TITY 'Vitesse (m/s)'
  1055.    TITR 'VITESSE LE LONG DE LA PAROI CONDENSANTE (m/s)';
  1056.  
  1057.   EVOLC  = evol CHPO RV.INCO.'FCOND' PCON ;
  1058.   DESS EVOLC TITX 'PAROI COND. (m)' TITY 'FLUX (kg/m2s)'
  1059.    TITR 'FLUX DE CONDENSATION SUR LA PAROI VERTICALE (kg/m2s)';
  1060.  
  1061.   'TRAC'      RV.'INCO'.'RHO' MFLUID cnt
  1062.    'TITR' 'CHAMP DE LA MASSE VOLUMIQUE: RHO (Kg.m-3)' ;
  1063.  
  1064.   'TRAC'      RV.'INCO'.'YH2O' MFLUID  cnt
  1065.    'TITR' 'CHAMP DE LA FRACTION MASSIQUE DE VAPEUR YH2O' ;
  1066.  
  1067.  
  1068.      TN = kops RV.'INCO'.'TN'  '-' 273.15 ;
  1069.   'TRAC'      TN  MFLUID  cnt 'TITR' 'TEMPERATURE DU GAZ (en °C)' ;
  1070.  
  1071.     nut = RV.INCO.'NUT' ;
  1072.     nutnu = kops NUT '/' NU ;
  1073.     nutnu = elno $fluid nutnu ;
  1074.   'TRAC'      NUTNU   MFLUID  cnt
  1075.    'TITR' 'VISCOSITE TURBULENTE ADIMENSIONNEE: NUT/NU' ;
  1076.  
  1077.  
  1078.  
  1079. EVOLP1 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'PRESSION'
  1080.  RV.INCO.'PRESS' ;
  1081. EVOLP2 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'PRESSION'
  1082.  RV.INCO.'PT0D' ;
  1083. EVOLP3 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'PRESSION'
  1084.  RV.INCO.'PV0D' ;
  1085. EVOLP4 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'PRESSION'
  1086.  RV.INCO.'PA0D' ;
  1087. EVOLP1 = EVOLP1 coul vert ;
  1088. TAB1 = TABLE ;
  1089. TAB1.1 = 'REGU MARQ CROI ' ;
  1090. TAB1.2 = 'REGU MARQ PLUS ' ;
  1091. TAB1.3 = 'REGU MARQ CARR ' ;
  1092. TAB1.4 = 'REGU MARQ TRIA ' ;
  1093. TAB1 . 'TITRE' = TABLE ;
  1094. TAB1.'TITRE' . 1 = MOT 'PTOT MULTI-D' ;
  1095. TAB1.'TITRE' . 2 = MOT 'PTOT 0D' ;
  1096. TAB1.'TITRE' . 3 = MOT 'P VAPEUR 0D' ;
  1097. TAB1.'TITRE' . 4 = MOT 'P AIR 0D' ;
  1098.   DESS (EVOLP1 ET EVOLP2 ET EVOLP3 ET EVOLP4) LEGE MIMA TAB1
  1099.    TITR 'PRESSIONS MOYENNES (Pa)' ;
  1100.   DESS (EVOLP1 ET EVOLP2) LEGE MIMA TAB1 TITR 'PRESSION TOTALE (Pa)' ;
  1101.  
  1102. EVOLR = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'RHO 0D' RV.INCO.'RO0D';
  1103.   DESS  EVOLR MIMA TITR  'MASSE VOLUMIQUE MOYENNE (kg/m-3)' ;
  1104.  
  1105. EVOLT = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'TEMPERATURE'
  1106.  RV.INCO.'T0D' ;
  1107.   DESS  EVOLT MIMA TITR  'TEMPERATURE MOYENNE (°C)' ;
  1108.  
  1109. EVOLH = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'ENTHALPIE'
  1110.  RV.INCO.'H0D' ;
  1111.   DESS  EVOLH MIMA TITR  'ENTHALPIE MASSIQUE MOYENNE (J/kg)' ;
  1112.  
  1113. EVOLF = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'FLUX CONDENSE'
  1114.  RV.INCO.'FCDST' ;
  1115.   DESS  EVOLF MIMA TITR  'FLUX DE MASSE CONDENSEE (kg/s)' ;
  1116.  
  1117.  
  1118. EVOLM1 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'MASSE [kg]'
  1119.  RV.INCO.'MTHEO' ;
  1120. EVOLM2 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'MASSE [kg]'
  1121.  RV.INCO.'MTOTA' ;
  1122. EVOLM1 = EVOLM1 COUL ROUG ;
  1123. EVOLM2 = EVOLM2 COUL VERT ;
  1124. TAB1 = TABLE ;
  1125. TAB1.1 = 'REGU MARQ CROI' ;
  1126. TAB1.2 = 'REGU MARQ PLUS' ;
  1127. TAB1 . 'TITRE' = TABLE ;
  1128. TAB1.'TITRE' . 1 = MOT 'THEORIQUE' ;
  1129. TAB1.'TITRE' . 2 = MOT 'BILAN MULTI-D' ;
  1130. DESS (EVOLM1 ET EVOLM2) LEGE MIMA TAB1 titr 'MASSE TOTALE (kg)' ;
  1131.  
  1132.  
  1133. EVOLM1 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'MASSE H2O kg'
  1134.  RV.INCO.'PMH2OT' ;
  1135. EVOLM2 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'MASSE H2O kg'
  1136.  RV.INCO.'PMH2O' ;
  1137. EVOLM1 = EVOLM1 COUL ROUG ;
  1138. EVOLM2 = EVOLM2 COUL VERT ;
  1139. TAB1 = TABLE ;
  1140. TAB1.1 = 'REGU MARQ CROI ' ;
  1141. TAB1.2 = 'REGU MARQ PLUS ' ;
  1142. TAB1 . 'TITRE' = TABLE ;
  1143. TAB1.'TITRE' . 1 = MOT 'THEORIQUE' ;
  1144. TAB1.'TITRE' . 2 = MOT 'BILAN MULTI-D' ;
  1145. DESS (EVOLM1 ET EVOLM2)  LEGE MIMA TAB1 titr 'MASSE H2O (kg)' ;
  1146.  
  1147.  
  1148. EVOLM1 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'MASSE AIR kg'
  1149.  RV.INCO.'PMAIRT' ;
  1150. EVOLM1 = EVOLM1 COUL ROUG ;
  1151. EVOLM2 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'MASSE AIR kg'
  1152.  RV.INCO.'PMAIR' ;
  1153. EVOLM2 = EVOLM2 COUL VERT ;
  1154. TAB1 = TABLE ;
  1155. TAB1.1 = 'REGU MARQ CROI ' ;
  1156. TAB1.2 = 'REGU MARQ PLUS ' ;
  1157. TAB1 . 'TITRE' = TABLE ;
  1158. TAB1.'TITRE' . 1 = MOT 'THEORIQUE' ;
  1159. TAB1.'TITRE' . 2 = MOT 'BILAN MULTI-D' ;
  1160.   DESS (EVOLM1 ET EVOLM2) LEGE TAB1 titr 'MASSE AIR (kg)' ;
  1161.  
  1162.  
  1163. EVOLE1 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'ENERGIE'
  1164.  RV.INCO.'ETOT' ;
  1165. EVOLE2 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'ENERGIE'
  1166.  RV.INCO.'ET0D' ;
  1167. EVOLE1 = EVOLE1 coul vert ;
  1168. TAB1 = TABLE ;
  1169. TAB1.1 = 'REGU MARQ CROI ' ;
  1170. TAB1.2 = 'REGU MARQ CARR ' ;
  1171. TAB1 . 'TITRE' = TABLE ;
  1172. TAB1.'TITRE' . 1 = MOT 'MULTI-D' ;
  1173. TAB1.'TITRE' . 2 = MOT '0D' ;
  1174. DESS (EVOLE1 ET EVOLE2) LEGE MIMA TAB1 TITR 'ENERGIE TOTALE (J)' ;
  1175.  
  1176. FINSI ;
  1177.  
  1178. *===================================================================*
  1179. *            TESTS DE BON FONCTIONNEMENT (à 5 %)                    *
  1180. *===================================================================*
  1181.  
  1182. DELTAP = (P - RV.INCO.'PM' - 1673.)/1673. ;
  1183. MH2O = RV.INCO.'ROV0D' * VOLT ;
  1184. DELTAM = (MH2OINI - MH2O - 0.586)/0.586 ;
  1185.  
  1186. SI ( (ABS DELTAP) > 0.05 ) ;
  1187.    ERREUR 5 ;
  1188. FINSI ;
  1189.  
  1190. SI ( (ABS DELTAM) > 0.05 ) ;
  1191.    ERREUR 5 ;
  1192. FINSI ;
  1193.  
  1194. FIN ;
  1195.  
  1196.  
  1197.  
  1198.  
  1199.  
  1200.  
  1201.  
  1202.  
  1203.  
  1204.  
  1205.  
  1206.  
  1207.  
  1208.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales