Exemples de jeux de données Cast3M

* fichier : chaboche3.dgibi
* section : Mecanique Viscoplastique
* repertoire des fichiers "divers"
DIVERS = VENV 'CASTEM_DIVERS';
*
*----------------------------------------------------------------------*
*                           CHABOCHE3.DGIBI                            *
*----------------------------------------------------------------------*
*
* Objet :
* -------
*
* Test de validation d'une loi de comportement de materiau.
* Loi de comportement elastoviscoplastique de Chaboche.
* Validation de la loi de comportement en condition anisotherme.
*
*
* Description :
* -------------
* Test "Satoh" : dilatation thermique d'un element de volume empeche
*                suivant (O,z)
*
* Type de calcul : Thermomecanique
* Mode de calcul : TRIDIMENSIONNEL
* Type d'element : CUB8 
* Chargement     : Temperature imposee
* Reference      : solution obtenue avec SiDoLo, elle-meme validee
*                  par comparaison au logiciel Zebulon.
* Objectif       : Ecart relatif sur la contrainte SMZZ < 2%
*
* Remarque 1 :
* ------------
* Les instants de calcul et les valeurs imposees de la temperature
* sont celles de la solution de reference.
*
* Remarque 2 :
* ------------
* Solution de reference aimablement communiquee par Philippe PILVIN,
* Université de Bretagne Sud.
*
*----------------------------------------------------------------------*
*
* Pour afficher les traces, mettre IGRAPH a vrai :
IGRAPH = faux ;
*
*----------------------- Resultats de reference -----------------------*
*
* Lecture de la solution de reference :
ta2    = lire csv ('CHAINE' DIVERS '/chaboche3.txt') debu 3 sepa ' ' ;
 
* liste des temps de calcul ;
ltps1  = ta2.1 ;
* liste des valeurs de temeprature associee
lt1    = ta2.5 ;
* liste des valeurs de la contrainte SMZZ associee
lszz1  = ta2.3 ;
*
* Courbes d'evolution :
evtref = evol defa manu temps ltps1 'T' lt1 ;
evsref = evol defa manu temps ltps1 smzz lszz1 ;
evref  = evol defa manu 'T'   lt1   smzz lszz1 ;
 
*--------------------- Mise en donnees du calcul ----------------------*
*
opti dime 3 elem cub8 ; 
 
* Maillage d'un "cube unite" :
L1 = (0 0 0) droi 1 (1 0 0) ; 
S1 = L1 tran (0 1 0) 1 ; 
V1 = S1 volu tran 1 (0 0 1) ; 
 
si IGRAPH ;
  trac noeud elem V1 titr ' Maillage ' ;
fins ;
 
* Parametres de la loi de Chaboche :
ym1 = evol manu 'T' (prog 20. 600.) 'YOUN' (prog 190.e9 140.e9) ; 
nu1 = 0.3 ; 
al1 = 20.e-6 ; 
Sy1 = evol manu 'T' (prog 20. 600.) 'SIGY' (prog   82.e6   6.e6)  ;
gK0 = evol manu 'T' (prog 20. 600.) 'K   ' (prog  151.e6 150.e6)  ; 
pn1 = evol manu 'T' (prog 20. 600.) 'N   ' (prog   24.    12.)    ; 
gA1 = evol manu 'T' (prog 20. 600.) 'A   ' (prog   58.e6  82.7e6) ;
gC1 = evol manu 'T' (prog 20. 600.) 'C   ' (prog 2800.   300.)    ;
gQ1 = evol manu 'T' (prog 20. 600.) 'Q   ' (prog   60.e6  80.e6)  ;
pb1 = evol manu 'T' (prog 20. 600.) 'B   ' (prog    8.    10.)    ;
 
* Modele / Caracteristiques :
mo1 = 'MODE' V1  'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 'VISCOPLASTIQUE' 'CHABOCHE' ;
ma1 = 'MATE' mo1 'YOUN' ym1 'NU' nu1 'ALPH' al1 'TALP' 20. 'TREF' 20. 'SIGY' Sy1
                 'K'    gK0 'N'  pn1 'A'    gA1 'C'    gC1 'B'    pb1 'Q' gQ1 ;
 
* Blocages mecaniques :
ptx0 = V1 coor 1 poin infe 0.1 ;
pty0 = V1 coor 2 poin infe 0.1 ;
ptz0 = V1 coor 3 poin infe 0.1 ;
ptz1 = V1 coor 3 poin supe 0.9 ;
 
CLX0 = bloq ux ptx0 ;
CLY0 = bloq uy pty0 ;
CLZ0 = bloq uz (ptz0 et ptz1) ;
 
* Conditions initiales / Chargement :
* Evolution de la temperature :
CHT0 = manu chpo V1 1 'T' 1. ;
CGT0 = char T CHT0 evtref ;
 
* Pas de temps (si vrai, pas de temps / 2) :
si faux ;
  nbx   = dime ltps1 - 1 ;
  tps0  = extr ltps1 1 ;
  ltps2 = prog tps0 ;
  repe bx nbx ;
    tps1  = extr ltps1 (&bx + 1) ;
    dtps  = tps1 - tps0 ;
    tps2  = tps1 ;
    tps1  = 0.5*dtps + tps0 ;
    ltps2 = ltps2 et (prog tps1 tps2) ;
    tps0  = tps2 ;
  fin bx ;
sino ;
  ltps2 = ltps1 ;
fins ;
* Test discretisation plus grossiere :
*tps1  = ltps1 extr (dime ltps1) ;
*ltps2 = prog 0. pas (0.02*tps1) tps1 ;
 
* Resolution PASAPAS :
 
ta1                      = table ;
ta1.modele               = mo1 ;
ta1.caracteristiques     = ma1 ;
ta1.blocages_mecaniques  = clx0 et cly0 et clz0 ;
ta1.chargement           = cgt0 ;
ta1.temps_calcules       = ltps2 ;
ta1.hypothese_deformations = 'LINEAIRE' ;
 
PASAPAS ta1 ;
 
* Post-traitement de la courbe SMZZ vs T :
nb1  = dime ta1.temps ;
i1   = 0 ;
lt2   = prog ;
lszz2 = prog ;
repe b1 nb1 ;
  tpsi1 = ta1.temps.i1 ;
  ti1   = (tire ta1.chargement T tpsi1) maxi ;
  szzi1 = ta1.contraintes.i1 maxi avec (mots smzz) ;
  lt2   = lt2 et (prog ti1) ;
  lszz2 = lszz2 et (prog szzi1) ;
  i1    = i1 + 1 ;
fin b1 ;
lszz2  = 1.e-6 * lszz2 ;
evcal  = evol roug manu 'T'   lt2   smzz lszz2 ;
evscal = evol roug manu temps ltps2 smzz lszz2 ;
 
* Affichages :
si IGRAPH ;
  ta3    = table ;
  ta3 . 1 = chai 'TIRR MARQ ROND REGU' ;
  ta3 . 'TITRE' = table ;
  ta3 . 'TITRE' . 1 = mot 'Zebulon/SiDoLo' ;
  ta3 . 'TITRE' . 2 = mot 'Cast3M' ;
  dess (evsref et evscal) xbor -5. 65. ygra 5. ybor -250. 300. ygra 50. gril
    titr 'Essai Satoh : SMZZ (MPa) vs. temps (s) ' lege ta3 ;
  dess (evref et evcal) gril ybor -250. 300. ygra 50.
    titr 'Essai Satoh : SMZZ (MPa) vs. T (degC) ' lege ta3 ;
fins ;
*
* Test de validation :
lszz2 = ipol evscal ltps1 ;
err0  = (maxi abs (lszz2 - lszz1)) / (maxi abs lszz1) ;
 
opti echo 0 ;
saut 1 lign ;
mess '   Comparaison solution calculee / reference ' ;
mess '   ----------------------------------------- ' ;
mess '   Max.|SMZZ(cal.) - SMZZ(Ref.)| / Max.|SMZZ(cal.)| =' err0 ;
saut 1 lign ;
opti echo 1 ;
*
si (err0 > 0.02) ;
  erre 5 ;
fins ;
*
fin ;