Exemples de jeux de données Cast3M

* fichier : chaboche2.dgibi
* section : Mecanique Viscoplastique
*----------------------------------------------------------------------*
*                           CHABOCHE2.DGIBI                            *
*----------------------------------------------------------------------*
*
* Objet :
* -------
*
* Test de validation d'une loi de comportement de materiau.
* Loi de comportement elastoviscoplastique de Chaboche.
*
*
* Description :
* -------------
* Essai de traction-compression.
*
* Type de calcul : Mecanique
* Mode de calcul : 2D axisymetrique
* Type d'element : QUA4
* Chargement     : Deplacement impose
* Reference      : solution comparee a la loi ONERA
* Objectif       : Ecart relatif sur la contrainte SMZZ < 1.e-4
*
* Reference :
* ----------- 
* L&M : J. Lemaitre, J.-L. Chaboche, "Mecanique des materiaux solides",
*       Dunod, 2e edition, 1996.
*
*----------------------------------------------------------------------*
*
* Pour afficher les traces, mettre IGRAPH a vrai :
IGRAPH = faux ;
*
*------------------------ Maillage (1 element) ------------------------*
*
opti dime 2 elem qua8 mode axis ;
 
ne1 = 1 ;
l1  = (0 0) droi ne1 (1. 0.) ;
S1  =    l1 tran ne1 (0. 1.) ; 
 
l2  = s1 cote 2 ;
l3  = S1 cote 3 ;
l4  = S1 cote 4 ;
 
si IGRAPH ;
  trac qual S1 titr ' Maillage ' ;
fins ;
*
*---------------------- Modele & Carateristiques ----------------------*
*
* Par rapport aux parametres du modele presentes dans le L&M, p. 310 :
*   - CLM : coefficient C d'ecrouissage cinematique du L&M
*   - Gam : coefficient gamma d'ecrouissage cinematique du L&M
* les coefficients d'ecrouissage du modele de Cast3M sont :
*   - C = Gam
*   - A = CLM / Gam
* Valeurs des parametres du modele pour acier 316L a 20 degC (L&M, p. 319) :
SIGY1 = 82.e6 ;
N1    = 24. ;
K1    = 151.e6 ;
CLM   = 162400.e6 ;
Gam   = 2800. ;
A1    = CLM / Gam ;
C1    = Gam   ;
Q1    = 142.e6 - SIGY1 ;
B1    = 8. ;
 
* Module d'Young et coeff. de Poisson :
YM1   = 200.e9 ;
NU1   = 0.3 ;
 
* Modeles & Caracteristiques :
mo1 = mode s1 mecanique elastique isotrope viscoplastique chaboche bbar ;
ma1 = mate mo1 'YOUN' YM1 'NU' NU1 'SIGY' SIGY1 
               'K'    K1  'N'  N1  'A'    A1    'C'    C1 'B' B1 'Q' Q1 ;
 
mo2 = 'MODE' S1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 'VISCOPLASTIQUE' 'ONERA' 'BBAR' ;
ma2 = 'MATE' mo2 'YOUN' YM1 'NU' NU1 'KK' SIGY1 
       'K0'   K1 'N'    N1 'B'    B1
       'ALFK' 0. 'ALFR' 1. 'ALF'  0.
       'A1'   A1 'C1'   C1 'BET1' 0. 'R1'   0.
       'A2'   0. 'C2'   0. 'BET2' 0. 'R2'   0.
       'PHI'  1. 'GAMA' 0. 'M'    0.
       'QMAX' 1. 'QSTA' 0. 'MU'   0. 'ETA'  0. ;
 
*-------------------------- CL & Chargement ---------------------------*
*
cl1 = bloq uz l1 ;
cl2 = bloq ur l4 ;
cl3 = bloq uz l3 ;
 
u1  = 0.002 ;
f1  = depi cl3 u1 ;
 
xt1  = 100. ;
ev1  = evol manu temp (xt1 * (prog 0. 1. 2.  3. 4. 6.))
                      (prog 0. 1. 0. -1. 0. 2.) ;
cgu1 = char dimp f1 ev1 ;
 
si IGRAPH ;
  trac qual (S1 et (l1 coul roug) et (l3 coul vert) et (l4 coul bleu))
    titr ' CL : Uz=0 en L1 (rouge), Ur=0 en L4 (bleu) et Uz impose sur L3 (vert)' ;
  dess (u1*ev1) titre ' Evolution temporelle du deplacement impose ';
fins ;
 
*------------------------- Resolution PASAPAS -------------------------*
*
* Modele de Chaboche :
ta1 = tabl ;
ta1.modele = mo1 ;
ta1.caracteristiques = ma1 ;
ta1.blocages_mecaniques = cl1 et cl2 et cl3 ;
ta1.chargement = cgu1 ;
ta1.temps_calcules = (prog 0. pas 0.1 6.) * xt1 ;
 
ta1.mes_sauvegardes = tabl ;
ta1.mes_sauvegardes.defin = vrai ;
 
pasapas ta1 ;
 
* Modele ONERA :
ta2 = tabl ;
ta2.modele = mo2 ;
ta2.caracteristiques = ma2 ;
ta2.blocages_mecaniques = cl1 et cl2 et cl3 ;
ta2.chargement = cgu1 ;
ta2.temps_calcules = ta1.temps_calcules ;
ta2.hypothese_deformations = 'LINEAIRE' ;
 
ta2.mes_sauvegardes = tabl ;
ta2.mes_sauvegardes.defin = vrai ;
 
chq0 = manu chml mo2 epse 0. qqq Q1 stresses ;
ta2.variables_internes = tabl ;
ta2.variables_internes.0 = chq0 ;
 
pasapas ta2 ;
 
*-------------------- Postraitement des resultats ---------------------*
 
nb1   = dime ta1.temps ;
ltps1 = prog ;
leps1 = prog ;
lsig1 = prog ;
lsig2 = prog ;
i1    = 0 ;
repe bo1 nb1 ;
  tpsi1 = ta1.temps.i1 ;
  depi1 = ta1.deplacements.i1 ;
  epsi1 = (epsi mo1 ma1 depi1) exco epzz scal maxi ;
  sigi1 = ta1.contraintes.i1 exco smzz scal maxi ;
  sigi2 = ta2.contraintes.i1 exco smzz scal maxi ;
  ltps1 = ltps1 et (prog tpsi1) ;
  leps1 = leps1 et (prog epsi1) ;
  lsig1 = lsig1 et (prog sigi1) ;
  lsig2 = lsig2 et (prog sigi2) ;
  i1    = i1 + 1 ;
fin bo1 ;
lsig1  = 1.e-6 * lsig1 ;
lsig2  = 1.e-6 * lsig2 ;
evezz1 = evol manu temps ltps1 epzz leps1 ;
evszz1 = evol roug manu temps ltps1 smzz lsig1 ;
evszz2 = evol vert manu temps ltps1 smzz lsig2 ;
evsve1 = evol roug manu epzz  leps1 smzz lsig1 ;
evsve2 = evol vert manu epzz  leps1 smzz lsig2 ;
 
* Affichages :
si IGRAPH ;
  tl1 = table ;
  tl1 . 1 = 'NOLI MARQ CROI' ;
  tl1 . titre = table ;
  tl1 . titre . 1 = 'ONERA' ;
  tl1 . titre . 2 = 'CHABOCHE' ;
  dess (evszz1 et evszz2) lege tl1
    titre ' Evolution temporelle de la contrainte de traction ' ;
  dess (evsve1 et evsve2) lege tl1 titre ' Courbe de traction ' ;
fins ;
 
*------------------------- Test de validation -------------------------*
*
err0 = (maxi abs (lsig2 - lsig1)) / (maxi abs lsig2) ;
 
opti echo 0 ;
saut 1 lign ;
mess '   Comparaison solution calculee / reference ' ;
mess '   ----------------------------------------- ' ;
mess '   Max.|SMZZ(cal.) - SMZZ(Ref.)| / Max.|SMZZ(cal.)| =' err0 ;
saut 1 lign ;
opti echo 1 ;
 
si (err0 > 1.e-4) ;
  erre 5 ;
fins ;
 
fin ;