Télécharger la plaquette Cast3M


fr en

Télécharger burgerC.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  burgerC.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. COMPLET = FAUX ;
  6. SI ( COMPLET ) ;
  7.       NX = 30 ; NY = 30 ;
  8.       NITER = 500 ;
  9.       CFL = 0.8 ;
  10. SINON ;
  11.       NX = 10 ; NY = 10 ;
  12.       NITER = 180 ;
  13.       CFL = 0.8 ;
  14. FINSI ;
  15. GRAPH = 'N' ;
  16.  
  17. ***********************************************************
  18. * EQUATION DE CONVECTION NON-LINEAIRE Ut + div (F(U)) = 0 *
  19. * TSCAL OPTION CONS (conservatif) SUPGDC (par défaut)     *
  20. ***********************************************************
  21.  
  22. ********************************
  23. * PROCEDURE POUR TRACER COUPES *
  24. ********************************
  25.  
  26. DEBPROC TRCE ;
  27. ARGU M*'MAILLAGE' ;
  28. nb = nbel M ;
  29. R = (M poin 1) droi 1 (M poin 2) ;
  30. i=2 ; itma = nb-2 ;
  31. repeter bloc1 itma ;
  32. R = R et ((M poin i) droi 1 (M poin (i+1))) ;
  33. i=i+1 ;
  34. fin bloc1 ;
  35. FINPROC R ;
  36.  
  37. ***********************************************
  38. * PROCEDURE POUR CALCULER CHAMP DE VITESSE ET *
  39. * TESTER LA CONVERGENCE                       *
  40. ***********************************************
  41.  
  42. DEBPROC CALCUL ;
  43. ARGU RVX*'TABLE' ;
  44.  
  45. RV = RVX.'EQEX' ;
  46. CN = RV.INCO.'CN' ;
  47.  
  48. DD = RV.PASDETPS.'NUPASDT' ;
  49. NN = DD/5 ;
  50. LO = (DD-(5*NN)) EGA 0 ;
  51. SI ( LO ) ;
  52.  
  53. ERR = KOPS (RV.INCO.'CN') - (RV.INCO.'CNM1') ;
  54.  
  55. ELI = MAXI ERR 'ABS' ;
  56. ELI = (LOG (ELI + 1.0E-20))/(LOG 10.) ;
  57. MESSAGE 'ITER ' RV.PASDETPS.'NUPASDT' '   ERREUR LINF ' ELI ;
  58. IT = PROG RV.PASDETPS.'NUPASDT' ;
  59. ER = PROG ELI ;
  60. RV.INCO.'IT' = (RV.INCO.'IT') ET IT ;
  61. RV.INCO.'ER' = (RV.INCO.'ER') ET ER ;
  62. FINSI ;
  63.  
  64. VY = KCHT $DOMTOT 'SCAL' 'SOMMET' 'COMP' 'UY' 1.0 ; 
  65. VX1 = KOPS CN '/' 2. ;
  66. VX = NOMC 'UX' VX1 ;
  67. VV = KCHT $DOMTOT 'VECT' 'SOMMET' 'COMP' (MOTS 'UX' 'UY')
  68.         (VX ET VY) ;
  69. RV.INCO.'VITESSE' = VV ;
  70.  
  71. RV.INCO.'CNM1' = KCHT $DOMTOT 'SCAL' 'SOMMET' (RV.INCO.'CN') ;
  72. as2 ama1  = 'KOPS' 'MATRIK' ;
  73. FINPROC as2 ama1 ;
  74.  
  75. ****************************************************
  76.  
  78. opti elem tri3 ;
  80. titre 'Equation de Burger' ;
  81.  
  82. *************
  83. * DIFFUSION *
  84. *************
  85. DIF = 1.0E-10 ;
  86.  
  87. ************
  88. * MAILLAGE *
  89. ************
  90.  
  91. A1 = 0.0 0.0 ;
  92. A2 = 1.0 0.0 ;
  93. A3 = 1.0 1.0 ;
  94. A4 = 0.0 1.0 ;
  95.  
  96. FBAS = A1 'DROI' NX A2 ;
  97. FDRO = A2 'DROI' NY A3 ;
  98. FHAU = A3 'DROI' NX A4 ;
  99. FGAU = A4 'DROI' NY A1 ;
  100.  
  101. PA1 = FBAS POIN 'PROC' A1 ;
  102. PA2 = FBAS POIN 'PROC' A2 ;
  103. P12 = CHAN POI1 FBAS ;
  104. MA1 = P12 ELEM 'CONTENANT' PA1 ;
  105. MA2 = P12 ELEM 'CONTENANT' PA2 ;
  106.  
  107. SI ( COMPLET ) ;
  108. * maillage regulier 
  109. DOMTOT = 'DALL' FBAS FDRO FHAU FGAU 'PLAN' ;
  110. SINON ;
  111. * maillage non-structuré
  112. DOMTOT = (FBAS ET FDRO ET FHAU ET FGAU) 'SURF' 'PLAN' ;
  113. FINSI ;
  114.  
  115. *********************************
  116. * CREATION MODELE NAVIER-STOKES *
  117. *********************************
  118.  
  119. XDOMTOT = CHAN DOMTOT QUAF ;
  120. XFBAS   = CHAN FBAS   QUAF ;
  121. ELIM (XDOMTOT ET XFBAS) 1.E-3 ;
  122.  
  123. $DOMTOT = MODE XDOMTOT 'NAVIER_STOKES' LINE ;
  124. $FBAS   = MODE XFBAS   'NAVIER_STOKES' LINE ;
  125.  
  126. **************************************
  127. * INITIALISATION DU CHAMP DE VITESSE *
  128. **************************************
  129.  
  130. VX = KCHT $DOMTOT 'SCAL' 'SOMMET' 'COMP' 'UX' 0.0 ;
  131. VY = KCHT $DOMTOT 'SCAL' 'SOMMET' 'COMP' 'UY' 1.0 ;
  132. CHVIT=KCHT $DOMTOT 'VECT' 'SOMMET' 'COMP' (MOTS 'UX' 'UY') (VX ET VY) ;
  133.  
  134. ************************************
  135. * PROFIL DE LA SOLUTION A L'ENTREE *
  136. ************************************
  137.  
  138. XBAS = COOR 1 FBAS ;
  139. XBAS = NOMC 'UX' XBAS ;
  140. SOLUTION = 1.5 - (2.0*XBAS) ;
  141. CHP1 = KCHT $FBAS 'SCAL' 'SOMMET' 'COMP' 'UX' SOLUTION ;
  142. CHP1 = NOMC 'CN' CHP1 ;
  143.  
  144. ***********************
  145. * TABLE DE RESOLUTION *
  146. ***********************
  147.  
  148. RV = EQEX $DOMTOT 'ITMA' NITER 'ALFA' CFL
  149.         'ZONE' $DOMTOT 
  150.         'OPER' CALCUL 
  151.         'OPTI' 'CONS' 
  152.         'OPER' TSCAL DIF 'VITESSE' 0.0 'CN' 'INCO' 'CN'
  153.         'OPTI' 'CENTREE'
  154.         'OPER' 'DFDT' 1.   'CN' 'DELTAT'    'INCO' 'CN'
  155.         'CLIM' 'CN' 'TIMP' FBAS CHP1 
  156.         'CLIM' 'CN' 'TIMP' FGAU 1.5
  157.         'CLIM' 'CN' 'TIMP' FDRO (-0.5)  
  158.         'CLIM' 'CN' 'TIMP' MA1 (-1.5) 
  159.         'CLIM' 'CN' 'TIMP' MA2 (0.5) ;
  160.  
  161. RV.INCO = TABLE 'INCO' ;
  162. RV.INCO.'CN' = KCHT $DOMTOT 'SCAL' 'SOMMET' 0. ;
  163. RV.INCO.'VITESSE'= CHVIT ;
  164.  
  165. RV.INCO.'CNM1' = KCHT $DOMTOT 'SCAL' 'SOMMET' 1. ;
  166. RV.INCO.'IT' = PROG 1 ;
  167. RV.INCO.'ER' = PROG 0. ;
  168.  
  169. EXEC RV ;
  170.  
  171. *************************
  172. * ANALYSE DES RESULTATS *
  173. *************************
  174.  
  175. MESSAGE 'MAX = ' (MAXI RV.INCO.'CN') 'MAXTHEORIQUE = 1.5 ' ;
  176. MESSAGE 'MIN = ' (MINI RV.INCO.'CN') 'MINTHEORIQUE = -0.5 ' ;
  177.  
  178. SI ( (MINI RV.INCO.'ER') > -3.0 ) ;
  179.             ERREUR 5 ;
  180. FINSI ;
  181. SI ( (MAXI RV.INCO.'CN') > 1.65 ) ;
  182.             ERREUR 5 ;
  183. FINSI ;
  184. SI ( (MINI RV.INCO.'CN') < -0.60 ) ;
  185.             ERREUR 5 ;
  186. FINSI ;
  187.  
  188. ***********************
  189. * TRACE DES RESULTATS *
  190. ***********************
  191.  
  192. SI ( 'EGA' graph 'O') ;
  193.  
  194. UEXACT = KCHT $DOMTOT 'SCAL' 'SOMMET' 0. ;
  195. XX YY = 'COOR' (DOMA $DOMTOT SOMMET) ;
  196. REPETER BLOC1 (NBNO DOMTOT) ;
  197. P1 = (DOMA $DOMTOT SOMMET) POIN &BLOC1 ;
  198. X1 = 'EXTR' XX 'SCAL' P1 ;
  199. Y1 = 'EXTR' YY 'SCAL' P1 ;
  200. D1 = Y1 - (0.5*X1/0.75) ;
  201. D2 = Y1 - (2.0*(1.0-X1)) ;
  202. D3 = Y1 - 1.0 - (2.0*(X1-1.0)) ;
  203. BO1 = ( D1 > 0.) ;
  204. BO2 = ( D2 > 0.) ;
  205. BO3 = ( D3 > 0.) ;
  206. SI ( BO1 ET BO3 ) ;
  207. U1 = 1.5 ;
  208. SINON ;
  209. SI ( (NON BO1) ET (NON BO2) );
  210. U1 = (1.5-(2.0*X1))/(1.-(2.0*Y1)) ;
  211. SINON ;
  212. U1 = -0.5 ;
  213. FINSI ;
  214. FINSI ;
  215. C1 = MANU 'CHPO' P1 1 SCAL U1 ;
  216. C2 = KCHT $DOMTOT 'SCAL' 'SOMMET' C1 ;
  217. UEXACT = (UEXACT ET C2) ;
  218. FIN BLOC1 ;
  219.  
  220.  
  221. TRACE DOMTOT ;
  222. MESSAGE 'MAX = ' (MAXI RV.INCO.'CN') 
  223.         'MIN = ' (MINI RV.INCO.'CN') ;
  224. TRAC DOMTOT (RV.INCO.'CN') (CONT DOMTOT) ;
  225.  
  226. SI ( COMPLET ) ;
  227. P1 = DOMTOT POIN 'PROC' (0.0 0.7) ;
  228. P2 = DOMTOT POIN 'PROC' (1.0 0.7) ;
  229. P1P2 = DOMTOT POIN 'DROI' P1 P2 0.01 ;
  230. LI12 = TRCE P1P2 ;
  231.  
  232. XX = COOR 1 LI12 ;
  233.  
  234. EVOL1 = EVOL 'CHPO' (RV.INCO.'CN') SCAL LI12 ;
  235. EVOL2 = EVOL 'CHPO' XX SCAL LI12 ;
  236.  
  237. LIX = 'EXTR' EVOL2 ORDO ;
  238. LIU = 'EXTR' EVOL1 ORDO ;
  239. EVOL3 = EVOL 'MANU' 'X' LIX 'U(X)' LIU ;
  240.  
  241. EVOL4 = EVOL 'CHPO' UEXACT SCAL LI12 ;
  242. LIUEX = 'EXTR' EVOL4 ORDO ;
  243. EVOL5 = EVOL 'MANU' 'X' LIX 'UEXACT(X)' LIUEX ;
  244.  
  245. TAB1 = TABLE ;
  246. TAB1.1 = 'MARQ LOSA' ;
  247. DESS (EVOL3 ET EVOL5) 'XBOR' 0.0 1.0 'YBOR' -1. 2.
  248.                 'TITR' 'Coupe a y=0.7' TAB1 ; 
  249. FINSI ;
  250.  
  251. EVOL4 = EVOL 'MANU' 'ITERATIONS' (RV.INCO.'IT') 'LOG|E|inf'
  252.            (RV.INCO.'ER') ;
  253. DESS EVOL4 'XBOR' 0. 2000. 'YBOR' -20.0 0.0 ;
  254.  
  255. FINSI ;
  256.  
  257. FIN ;
  258.  
  259.  
  260.  
  261.  
  262.  
  263.  
  264.  
  265.  
  266.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales