Télécharger la plaquette Cast3M


fr en

Télécharger bidecis.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : bidecis.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. *         MODELE HYPERELASTIQUE BIDERMAN INCOMPRESSIBLE              *
  6. *           EN GRANDES TRANSFORMATIONS - CONTRAINTES PLANES            *
  7. *                                                                      *
  8. *   TEST DE VALIDATION DU MODELE : CISAILLEMENT DANS LA DIRECTION X    *
  9. *   COMPARAISON AVEC LA SOLUTION ANALYTIQUE                            *
  10. *                                                                      *
  11. *                                                                      *
  12. *   Contribution de Laurent Gornet - Ecole Centrale de Nantes (2010)   *
  13. *======================================================================*
  14. *  Pour plus d'informations, voir la presentation de L. Gornet lors    *
  15. *  du Club Cast3m 2009, disponible sur le site Web de Cast3m.          *
  16. *======================================================================*
  17. *  Exemple d'utilisation d'un modele UMAT en grandes transformations   *
  18. *                                                                      *
  19. *  Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  20. *         ne peut contenir que des modeles de type UMAT. On ne peut    *
  21. *         pas melanger les derivees objectives et les modeles de C3m.  *
  22. *======================================================================*
  23.  
  24. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ECHO' 0 ;
  25. *
  26. * Mettre VRAI si l'on souhaite divers traces.
  27. GRAPH = FAUX ;
  28. *GRAPH = VRAI ;
  29. title = 'CHAINE' 'BIDERMAN  - ' 'CISAILLEMENT SIMPLE XY' ;
  30.  
  31. *======================================================================*
  32. *             Geometrie - Maillage                                     *
  33. *======================================================================*
  34. * Longueur (direction x) de la plaque/membrane :
  35. Lg_x = 1.8 ;
  36. * Largeur (direction y) de la plaque/membrane :
  37. Lg_y = 1. ;
  38. * Nombre d'elements selon les directions x et y :
  39. Nel_x = 5 ;
  40. Nel_y = 2 ;
  41. *
  42. 'OPTION' 'ELEM' 'QUA4' ;
  43. *
  44. P1 =  0.    0. ;
  45. P2 = Lg_x   0. ;
  46. P3 = Lg_x Lg_y ;
  47. P4 =  0.  Lg_y ;
  48. *
  49. L1 = 'DROITE' Nel_x P1 P2 ;
  50. L2 = 'DROITE' Nel_y P2 P3 ;
  51. L3 = 'DROITE' Nel_x P3 P4 ;
  52. L4 = 'DROITE' Nel_y P4 P1 ;
  53. *
  54. SU = 'DALLER' L1 L2 L3 L4 ;
  55. 'SI' GRAPH ;
  56.   'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  57. 'FINSI' ;
  58.  
  59. *======================================================================*
  60. *             Modele - Materiau - Caracteristiques (en Pa)             *
  61. *======================================================================*
  62. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'OU'
  63.       ('NEG' ('VALEUR' 'MODE') 'PLANCONT')) ;
  64.   'MESS' 'Ce modele ne fonctionne qu en 2D CONTRAINTES PLANES' ;
  65.   'ERREUR' 5 ;
  66. 'FINSI' ;
  67. *
  68. * Ne pas oublier de definir les parametres lies a l'elasticite.
  69. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  70. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  71. *
  72. LCMAT =MOTS 'YOUN' 'NU  ' 'C01' 'C10' 'C20' 'C30'  ;
  73. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'  
  74.                     'NON_LINEAIRE' 'UTILISATEUR'
  75.                     'NUME_LOI' 35  'C_MATERIAU' LCMAT ;
  76. * Calcul du Module d'Young
  77. * Coefficients du modele de BIDERMAN (en MPa) :
  78. C1 = 0.183  ;     C2 = 0.0034   ;
  79. *
  80. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  81. * du fait de l'incompressibilite inherente au modele.
  82. * Le module de Young YOU est alors connu, car, pour ce modele, le
  83. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  84. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  85. * de la traction. En fonction du niveau de deformation atteinte en 
  86. * traction, il faut augmenter cette valeur afin de pouvoir faire 
  87. * converger les calculs (module tangent en fin de calculs).
  88. * Prendre des valeurs superieures n'entraine pas de modification des
  89. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  90. *
  91. XNU = 0.499 ;
  92. YOUini = 3.*(2.*(C1+C2)) ;   YOU = 1000. * YOUini ;
  93. *
  94. *Parametres du modèle Bidermann : essais Treloar/Kawabata MPa
  95. C01 = 0.0233;
  96. C10 = 0.208 ;
  97. C20 = -0.0024 ;
  98. C30 = 0.0005 ;
  99. * 
  100. MA = MATE MO 'YOUN' YOU 'NU  ' XNU 'C01' C01 'C10' C10 
  101.        'C20' C20 'C30' C30 ;
  102.  
  103. *======================================================================*
  104. *             Conditions aux limites - Traction suivant UY             *
  105. *======================================================================*
  106. CTOT = 'CONTOUR' SU ;
  107. BL1 = 'BLOQUER' 'UX  ' CTOT ;
  108. BL2 = 'BLOQUER' 'UY  ' CTOT ;
  109. BLTOT = BL1 'ET' BL2 ;
  110. *
  111. * Definition des instants du chargement :
  112. t_deb = 0. ;   t_fin = 10. ;
  113. L_tps = 'PROG' t_deb t_fin ;
  114. * Cisaillement suivant X :
  115. UX_deb = 0. ;  UX_fin = 3. * Lg_y ;
  116. L_UX = 'PROG' UX_deb UX_fin ;
  117. EV_xy = 'EVOL' 'MANU' 'TEMPS' L_tps  'LAMX' L_UX ;
  118. chp_y = 'NOMC' 'UX  ' ('COORD' 2 CTOT) ;
  119. FF_xy = 'DEPIMP' BL1 chp_y ;
  120. CHARTOT = 'CHARGEMENT' 'DIMP' FF_xy EV_xy ;
  121.  
  122. *======================================================================*
  123. *             Initialisation de la table pour appel a PASAPAS          *
  124. *======================================================================*
  125. TAB1 = 'TABLE' ;
  126. TAB1.'MODELE' = MO ;
  127. TAB1.'CARACTERISTIQUES' = MA ;
  128. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  129. TAB1.'CHARGEMENT' = CHARTOT ;
  130. *TAB1.'PRECISION' = 1.E-6 ;
  131. *TAB1.'FTOL' = 1.E-5 ;
  132. *TAB1.'MTOL' = 1.E-5 ;
  133. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  134. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  135. TAB1.'HYPOTHESE_DEFORMATIONS' = MOT 'UTILISATEUR' ;
  136. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  137. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  138. *
  139. L_abs = TAB1.'TEMPS_SAUVES' ;
  140. n_abs = 'DIMENSION' L_abs ;
  141. *
  142. PASAPAS TAB1 ;
  143. *
  144. * Quelques traces de controle apres calculs
  145. 'SI' GRAPH ;
  146.   Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  147.   Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  148.   'TRACER' (Defo_0 'ET' Defo_1)
  149.            'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  150.   'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  151.            'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  152. 'FINSI' ;
  153. *
  154. *======================================================================*
  155. *             Construction de la solution analytique                   *
  156. *======================================================================*
  157. * Definitions :
  158. * - Cisaillement selon xy : Cisx = UX/Lg_y
  159. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  160. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  161. * Dans le cas du modele de BIDERMAN :
  162. *   dW/dI1 = C10+2*C20*(i1-3)+3*C30*(i1-3)**2 
  163. *   dW/dI2 = C01
  164. * Les contraintes de Cauchy sont calculables analytiquement :
  165. * - SCxx =  2.(Cisx**2).dW/dI1
  166. * - SCyy = -2.(Cisx**2).dW/dI2
  167. * - SCxy =  2.Cisx.(dW/dI1 + dW/dI2)
  168. * - SCzz = 0  (hypothese des contraintes planes)
  169. *
  170. Cisx  = ('IPOL' L_abs L_tps L_UX) / Lg_y ;
  171. L_z1 = Cisx * Cisx ;
  172. *LG
  173. L_Un  = 'PROG' n_abs '*' 1. ;
  174. L_tr = L_Un * 3.;
  175. I1 =  L_z1 + L_tr ;
  176. I2 = I1;
  177. ************************************************************************
  178. dWI1=(C10 * L_Un)+(2.*C20*(I1 - L_tr))+(3.*C30*((I1 - L_tr)**2.));
  179. dWI2=C01 * L_Un ;
  180. ************************************************************************
  181. *dWI1 = C1;
  182. *dWI2 = C2;
  183. SCxx_th =  2.*dWI1*L_z1 ;
  184. SCyy_th = -2.*dWI2*L_z1 ;
  185. SCxy_th =  2.*(dWI1+dWI2)*Cisx ;
  186.  
  187. *======================================================================*
  188. *             Comparaison des resultats avec la solution analytique    *
  189. *======================================================================*
  190. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  191. * calculees et les solutions analytiques correspondantes.
  192. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  193. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  194. *
  195. TabD = TAB1.'DEPLACEMENTS' ;
  196. TabS = TAB1.'CONTRAINTES' ;
  197. Confini = 'FORM' ;
  198. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  199. *
  200. SCxx = 'PROG' 0. ;
  201. SCyy = 'PROG' 0. ;
  202. SCxy = 'PROG' 0. ;
  203. 'REPETER' Boucle (n_abs - 1) ;
  204.   'FORM' (TabD.&Boucle) ;
  205.   VolSU = 'INTG' MO ChmUn ;
  206.   SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  207.   SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  208.   SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  209.   'FORM' Confini ;
  210. 'FIN' Boucle ;
  211. *
  212. *  LG gam  Cisx
  213. L_abs = Cisx;
  214. *
  215. 'SI' GRAPH ;
  216.   tlege = 'TABLE' ;
  217.   tlege. 1 = 'MARQ CROI' ;
  218.   tlege.'TITRE' = 'TABLE' ;
  219.   tlege.'TITRE'. 1 = 'Numerique' ;
  220.   tlege.'TITRE'. 2 = 'Analytique' ;
  221.   Evxx    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  222.   Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  223.   'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  224.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (MPa)') ;
  225.   Evyy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  226.   Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  227.   'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  228.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (MPa)') ;
  229.   Evxy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  230.   Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  231.   'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  232.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (MPa)');
  233. 'FINSI' ;
  234. *
  235. * Tests de bon fonctionnement :
  236. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) ;
  237. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) ;
  238. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) ;
  239. *
  240. MESS ' RESULTATS : ' title ;
  241. MESS ' ------------------------------------------------- ';
  242. 'SAUTER' 1 'LIGNE' ;
  243. 'MESS' '  Tests de bon fonctionnement :' ;
  244. 'MESS' ' -------------------------------' ;
  245. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  246. 'MESS' ' Ecart maximal absolu entre la valeur moyenne calculee' ;
  247. 'MESS' '                         et la '
  248.        'solution analytique associee' ;
  249. 'MESS' ' Composante XX : ' r_xx ' MPa' ;
  250. 'MESS' ' Composante YY : ' r_yy ' MPa' ;
  251. 'MESS' ' Composante XY : ' r_xy ' MPa' ;
  252. 'SAUTER' 1 'LIGNE' ;
  253. * Ecart relatif maximal tolere
  254. Sigref = 1.E-3 ;
  255. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  256.   'MESS' ' ---------------------' ;
  257.   'MESS' '  ECHEC DU CAS-TEST !' ;
  258.   'MESS' ' ---------------------' ;
  259.   'ERREUR' 5 ;
  260. 'SINON' ;
  261.   'MESS' ' ----------------------' ;
  262.   'MESS' '  SUCCES DU CAS-TEST !' ;
  263.   'MESS' ' ----------------------' ;
  264. 'FINSI' ;
  265. 'SAUTER' 1 'LIGNE' ;
  266.  
  267. 'FIN' ;
  268.  
  269.  
  270.  
  271.  
  272.  
  273.  
  274.  
  275.  
  276.  
  277.  
  278.  
  279.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales