Télécharger la plaquette Cast3M


fr en

Télécharger bide2tract.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : bide2tract.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. *         MODELE HYPERELASTIQUE BIDERMAN INCOMPRESSIBLE                *
  6. *           EN GRANDES TRANSFORMATIONS - CONTRAINTES PLANES            *
  7. *                                                                      *
  8. *   TEST DE VALIDATION DU MODELE : TRACTION BIAXIALE DANS LE PLAN X,Y  *
  9. *   COMPARAISON AVEC LA SOLUTION ANALYTIQUE                            *
  10. *                                                                      *
  11. *                                                                      *
  12. *   Contribution de Laurent Gornet - Ecole Centrale de Nantes (2010)   *
  13. *======================================================================*
  14. *  Pour plus d'informations, voir la presentation de L. Gornet lors    *
  15. *  du Club Cast3m 2009, disponible sur le site Web de Cast3m.          *
  16. *======================================================================*
  17. *  Exemple d'utilisation d'un modele UMAT en grandes transformations   *
  18. *                                                                      *
  19. *  Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  20. *         ne peut contenir que des modeles de type UMAT. On ne peut    *
  21. *         pas melanger les derivees objectives et les modeles de C3m.  *
  22. *======================================================================*
  23. *======================================================================*
  24.  
  25. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ECHO' 0 ;
  26. *
  27. * Mettre VRAI si l'on souhaite divers traces.
  28. GRAPH = FAUX ;
  29. *GRAPH = VRAI ;
  30.  
  31.  
  32. title = 'CHAINE' 'BIDERMAN - ' 'TRACTION BIAXIALE XY' ;
  33.  
  34.  
  35. *======================================================================*
  36. *             Geometrie - Maillage                                     *
  37. *======================================================================*
  38. * Longueur (direction x) de la plaque/membrane :
  39. Lg_x = 1. ;
  40. * Largeur (direction y) de la plaque/membrane :
  41. Lg_y = 0.5 ;
  42. * Nombre d'elements selon les directions x et y :
  43. Nel_x = 5 ;
  44. Nel_y = 3 ;
  45. *
  46. *Nel_x = 30 ;
  47. *Nel_y = 10 ;
  48. *
  49. 'OPTION' 'ELEM' 'QUA8' ;
  50. *
  51. P1 =  0.    0. ;
  52. P2 = Lg_x   0. ;
  53. P3 = Lg_x Lg_y ;
  54. P4 =  0.  Lg_y ;
  55. *
  56. L1 = 'DROITE' Nel_x P1 P2 ;
  57. L2 = 'DROITE' Nel_y P2 P3 ;
  58. L3 = 'DROITE' Nel_x P3 P4 ;
  59. L4 = 'DROITE' Nel_y P4 P1 ;
  60. *
  61. SU = 'DALLER' L1 L2 L3 L4 ;
  62. 'SI' GRAPH ;
  63.   'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  64. 'FINSI' ;
  65.  
  66. *======================================================================*
  67. *             Modele - Materiau - Caracteristiques (en MPa)            *
  68. *======================================================================*
  69. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'OU'
  70.       ('NEG' ('VALEUR' 'MODE') 'PLANCONT')) ;
  71.   'MESS' 'Ce modele ne fonctionne qu en 2D CONTRAINTES PLANES' ;
  72.   'ERREUR' 5 ;
  73. 'FINSI' ;
  74. *
  75. * Ne pas oublier de definir les parametres lies a l'elasticite.
  76. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  77. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  78. *
  79. LCMAT =MOTS 'YOUN' 'NU  ' 'C01' 'C10' 'C20' 'C30'  ;
  80. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'  
  81.                     'NON_LINEAIRE' 'UTILISATEUR'
  82.                     'NUME_LOI' 35  'C_MATERIAU' LCMAT ;
  83. * Calcul du Module d'Young
  84. * Coefficients du modele de BIDERMAN (en MPa) :
  85. C1 = 0.183  ;     C2 = 0.0034   ;
  86. *
  87. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  88. * du fait de l'incompressibilite inherente au modele.
  89. * Le module de Young YOU est alors connu, car, pour ce modele, le
  90. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  91. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  92. * de la traction. En fonction du niveau de deformation atteinte en 
  93. * traction, il faut augmenter cette valeur afin de pouvoir faire 
  94. * converger les calculs. Prendre des valeurs superieures n'entraine pas
  95. * de modification des resultats, cela modifie seulement le nombre 
  96. * d'iterations mecaniques.
  97. * Par ex. : pour 1000 %, il faut multiplier par 30 la valeur initiale.
  98. * Si l'on se contente de 10., les calculs s'arretent vers 900 %.
  99. *
  100. XNU = 0.499 ;
  101. YOUini = 3.*(2.*(C1+C2)) ;   YOU = 1000. * YOUini ;
  102. *
  103. *Parametres du modèle Bidermann : essais Treloar/Kawabata MPa
  104. C01 = 0.0233;
  105. C10 = 0.208 ;
  106. C20 = -0.0024 ;
  107. C30 = 0.0005 ;
  108. * 
  109. MA = MATE MO 'YOUN' YOU 'NU  ' XNU 'C01' C01 'C10' C10 
  110.        'C20' C20 'C30' C30 ;
  111.  
  112. *======================================================================*
  113. *             Conditions aux limites - Chargement bi-axe               *
  114. *======================================================================*
  115. BL1 = 'BLOQUER' 'UY  ' L1 ;
  116. BL2 = 'BLOQUER' 'UY  ' L3 ;
  117. BL4 = 'BLOQUER' 'UX  ' L4 ;
  118. BL3 = 'BLOQUER' 'UX  ' L2 ;
  119. BLTOT = BL1 'ET' BL2 'ET' BL3 'ET' BL4 ;
  120. *
  121. * Definition des instants du chargement :
  122. t_deb = 0. ;   t_fin = 10. ;
  123. L_tps = 'PROG' t_deb t_fin ;
  124. * Deplacement suivant X :
  125. FF_x = 'DEPIMP' BL3 1. ;
  126. L_UX = 'PROG' 0. (5. * Lg_x) ;
  127. EV_x = 'EVOL' 'MANU' 'TEMPS' L_tps  'LAMX' L_UX ;
  128. CHAR_x = 'CHARGEMENT' 'DIMP' FF_x EV_x ;
  129. * Deplacement suivant Y :
  130. L_UY = 'PROG' 0. ( 2. * Lg_y) ;
  131. FF_y = 'DEPIMP' BL2 1. ;
  132. EV_y = 'EVOL' 'MANU' 'TEMPS' L_tps  'LAMY' L_UY ;
  133. CHAR_y = 'CHARGEMENT' 'DIMP' FF_y EV_y ;
  134. *
  135. CHARTOT = CHAR_x 'ET' CHAR_y ;
  136.  
  137. *======================================================================*
  138. *             Initialisation de la table pour appel a PASAPAS          *
  139. *======================================================================*
  140. TAB1 = 'TABLE' ;
  141. TAB1.'MODELE' = MO ;
  142. TAB1.'CARACTERISTIQUES' = MA ;
  143. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  144. TAB1.'CHARGEMENT' = CHARTOT ;
  145. **** LG
  146. *TAB1.'PRECISION' = 1.E-6 ;
  147. *TAB1.'FTOL' = 1.E-5 ;
  148. *TAB1.'MTOL' = 1.E-5 ;
  149. *
  150. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  151. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  152. TAB1.'HYPOTHESE_DEFORMATIONS' = MOT 'UTILISATEUR' ;
  153. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  154. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  155. *
  156. L_abs = TAB1.'TEMPS_SAUVES' ;
  157. n_abs = 'DIMENSION' L_abs ;
  158. *
  159. PASAPAS TAB1 ;
  160. *
  161. * Quelques traces de controle apres calculs
  162. 'SI' GRAPH ;
  163.   Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  164.   Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  165.   'TRACER' (Defo_0 'ET' Defo_1)
  166.            'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  167.   'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  168.            'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  169. 'FINSI' ;
  170. *
  171. *======================================================================*
  172. *             Construction de la solution analytique                   *
  173. *======================================================================*
  174. * Definitions :
  175. * - Allongement selon direction x : Lamx = 1 + (UX/Lg_x)
  176. * - Allongement selon direction y : Lamy = 1 + (UY/Lg_y)
  177. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  178. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  179. * Dans le cas du modele de BIDERMAN :
  180. *   dW/dI1 = C10+2*C20*(i1-3)+3*C30*(i1-3)**2 
  181. *   dW/dI2 = C01
  182. * Les contraintes de Cauchy sont calculables analytiquement :
  183. * - SCxx = 2.(Lamx**2 - (Lamx*Lamy)**-2).(dW/dI1 + Lamy**2.dW/dI2)
  184. * - SCyy = 2.(Lamy**2 - (Lamx*Lamy)**-2).(dW/dI1 + Lamx**2.dW/dI2)
  185. * - SCxy = 0  (pas de cisaillement)
  186. * - SCzz = 0  (hypothese des contraintes planes)
  187. *
  188. L_Un  = 'PROG' n_abs '*' 1. ;
  189. Lamx  = L_Un + (('IPOL' L_abs L_tps L_UX) / Lg_X) ;
  190. Lamy  = L_Un + (('IPOL' L_abs L_tps L_UY) / Lg_Y) ;
  191. *
  192. L_z1 = Lamx * Lamx ;  L_z2 = Lamy * Lamy ;
  193. L_z3 = L_z1 - ((L_z1*L_z2)**-1) ;
  194. L_z4 = L_z2 - ((L_z1*L_z2)**-1) ;
  195. *LG
  196. L_tr = L_Un * 3.;
  197. I1 = L_z1 + L_z2 + ((L_z1*L_z2)**-1);
  198. I2 =(L_z1 * L_z2) + (L_z1**-1) + (L_z2**-1);
  199. *dWI1 = C1;
  200. *dWI2 = C2;
  201. *
  202. dWI1=(C10 * L_Un)+(2.*C20*(I1 - L_tr))+(3.*C30*((I1 - L_tr)**2.));
  203. dWI2=C01 ;
  204. *
  205. SCxx_th = L_z3 * ((2.*dWI1*L_Un) + (2.*dWI2*L_z2)) ;
  206. SCyy_th = L_z4 * ((2.*dWI1*L_Un) + (2.*dWI2*L_z1)) ;
  207. SCxy_th = 0. * L_Un ;
  208.  
  209. *======================================================================*
  210. *             Comparaison des resultats avec la solution analytique    *
  211. *======================================================================*
  212. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  213. * calculees et les solutions analytiques correspondantes.
  214. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  215. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  216. *
  217. TabD = TAB1.'DEPLACEMENTS' ;
  218. TabS = TAB1.'CONTRAINTES' ;
  219. Confini = 'FORM' ;
  220. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  221. *
  222. SCxx = 'PROG' 0. ;
  223. SCyy = 'PROG' 0. ;
  224. SCxy = 'PROG' 0. ;
  225. 'REPETER' Boucle (n_abs - 1) ;
  226.   'FORM' (TabD.&Boucle) ;
  227.   VolSU = 'INTG' MO ChmUn ;
  228.   SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  229.   SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  230.   SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  231.   'FORM' Confini ;
  232. 'FIN' Boucle ;
  233. *
  234. *  LG lamb
  235. L_abs = Lamy;
  236. *
  237. 'SI' GRAPH ;
  238.   tlege = 'TABLE' ;
  239.   tlege. 1 = 'MARQ CROI' ;
  240.   tlege.'TITRE' = 'TABLE' ;
  241.   tlege.'TITRE'. 1 = 'Numerique' ;
  242.   tlege.'TITRE'. 2 = 'Analytique' ;
  243.   Evxx    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  244.   Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  245.   'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  246.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (MPa)') ;
  247.   Evyy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  248.   Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  249.   'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  250.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (MPa)') ;
  251.   Evxy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  252.   Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  253.   'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  254.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (MPa)');
  255. 'FINSI' ;
  256. *
  257. * Tests de bon fonctionnement :
  258. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) ;
  259. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) ;
  260. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) ;
  261. *
  262. MESS ' RESULTATS : ' title ;
  263. MESS ' ------------------------------------------------ ';
  264. 'SAUTER' 1 'LIGNE' ;
  265. 'MESS' '  Tests de bon fonctionnement :' ;
  266. 'MESS' ' -------------------------------' ;
  267. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  268. 'MESS' ' Ecart maximal en valeur absolue entre la valeur moyenne '
  269.        'calculee' ;
  270. 'MESS' '                                    et la '
  271.        'solution analytique associee' ;
  272. 'MESS' ' Composante XX : ' r_xx ' MPa' ;
  273. 'MESS' ' Composante YY : ' r_yy ' MPa' ;
  274. 'MESS' ' Composante XY : ' r_xy ' MPa' ;
  275. 'SAUTER' 1 'LIGNE' ;
  276. * Ecart maximal tolere sur la contrainte (en MPa)
  277. Sigref = 1.E-3 ;
  278. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  279.   'MESS' ' ---------------------' ;
  280.   'MESS' '  ECHEC DU CAS-TEST !' ;
  281.   'MESS' ' ---------------------' ;
  282.   'ERREUR' 5 ;
  283. 'SINON' ;
  284.   'MESS' ' ----------------------' ;
  285.   'MESS' '  SUCCES DU CAS-TEST !' ;
  286.   'MESS' ' ----------------------' ;
  287. 'FINSI' ;
  288. 'SAUTER' 1 'LIGNE' ;
  289.  
  290. 'FIN' ;
  291.  
  292.  
  293.  
  294.  
  295.  
  296.  
  297.  
  298.  
  299.  
  300.  
  301.  
  302.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales