Télécharger la plaquette Cast3M


fr en

Télécharger Mooney_LRGTreloar_Cisaillementsimple.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : Mooney_LRGTreloar_Cisaillementsimple.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. *         MODELE HYPERELASTIQUE MOONEY-RIVLIN INCOMPRESSIBLE           *
  6. *           EN GRANDES TRANSFORMATIONS - CONTRAINTES PLANES            *
  7. *                                                                      *
  8. *   TEST DE VALIDATION DU MODELE : CISAILLEMENT DANS LA DIRECTION X    *
  9. *   COMPARAISON AVEC LA SOLUTION ANALYTIQUE                            *
  10. *                                                                      *
  11. *   Contribution de Laurent Gornet - Ecole Centrale de Nantes (2006)   *
  12. *======================================================================*
  13. *  Pour plus d'informations, voir la presentation de L. Gornet lors    *
  14. *  du Club Cast3m 2006, disponible sur le site Web de Cast3m.          *
  15. *======================================================================*
  16. *  Exemple d'utilisation d'un modele UMAT en grandes transformations   *
  17. *                                                                      *
  18. *  Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. *         ne peut contenir que des modeles de type UMAT. On ne peut    *
  20. *         pas melanger les derivees objectives et les modeles de C3m.  *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ECHO' 0 ;
  24. *
  25. * Mettre VRAI si l'on souhaite divers traces.
  26. GRAPH = FAUX ; monop=faux;
  27.  
  28. title = 'CHAINE' 'MOONEY-RIVLIN - ' 'CISAILLEMENT SIMPLE XY' ;
  29.  
  30. *======================================================================*
  31. *             Geometrie - Maillage                                     *
  32. *======================================================================*
  33. * Longueur (direction x) de la plaque/membrane :
  34. Lg_x = 1.8 ;
  35. * Largeur (direction y) de la plaque/membrane :
  36. Lg_y = 1. ;
  37. * Nombre d'elements selon les directions x et y :
  38. Nel_x = 5 ;
  39. Nel_y = 2 ;
  40. *
  41. 'OPTION' 'ELEM' 'QUA4' ;
  42.  
  43. *
  44. P1 =  0.    0. ;
  45. P2 = Lg_x   0. ;
  46. P3 = Lg_x Lg_y ;
  47. P4 =  0.  Lg_y ;
  48. *
  49. L1 = 'DROITE' Nel_x P1 P2 ;
  50. L2 = 'DROITE' Nel_y P2 P3 ;
  51. L3 = 'DROITE' Nel_x P3 P4 ;
  52. L4 = 'DROITE' Nel_y P4 P1 ;
  53. *
  54. SU = 'DALLER' L1 L2 L3 L4 ;
  55. 'SI' GRAPH ;
  56.   'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  57. 'FINSI' ;
  58.  
  59. *======================================================================*
  60. *             Modele - Materiau - Caracteristiques (en Pa)             *
  61. *======================================================================*
  62. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'ET'
  63.       ('NEG' ('VALEUR' 'MODE') 'PLANCONT')) ;
  64.   'MESS' 'Ce modele ne fonctionne qu en 2D CONTRAINTES PLANES' ;
  65.   'ERREUR' 5 ;
  66. 'FINSI' ;
  67. *
  68. * Ne pas oublier de definir les parametres lies a l'elasticite.
  69. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  70. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  71. *
  72. LCMAT = 'MOTS' 'YOUN' 'NU  '  'C1  ' 'C2  ' ;
  73. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  74.                          'NON_LINEAIRE' 'UTILISATEUR'
  75.                          'NUME_LOI' 31  'C_MATERIAU' LCMAT ;
  76. *
  77. * Coefficients du modele de Mooney-Rivlin (en Pa) :
  78. C1 = 0.183E+6 ;     C2 = 0.0034E+6  ;
  79. *
  80. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  81. * du fait de l'incompressibilite inherente au modele.
  82. * Le module de Young YOU est alors connu, car, pour ce modele, le
  83. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  84. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  85. * de la traction. En fonction du niveau de deformation atteinte en 
  86. * traction, il faut augmenter cette valeur afin de pouvoir faire 
  87. * converger les calculs (module tangent en fin de calculs).
  88. * Prendre des valeurs superieures n'entraine pas de modification des
  89. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  90. *
  91. XNU = 0.499 ;
  92. YOUini = 3.*(2.*(C1+C2)) ;   YOU = 1. * YOUini ;
  93. *
  94. MA = 'MATERIAU' MO 'YOUN' YOU  'NU  ' XNU
  95.                    'C1  ' C1   'C2  ' C2 ;
  96.  
  97. *======================================================================*
  98. *             Conditions aux limites - Traction suivant UY             *
  99. *======================================================================*
  100. CTOT = 'CONTOUR' SU ;
  101. BL1 = 'BLOQUER' 'UX  ' CTOT ;
  102. BL2 = 'BLOQUER' 'UY  ' CTOT ;
  103. BLTOT = BL1 'ET' BL2 ;
  104. *
  105. * Definition des instants du chargement :
  106. t_deb = 0. ;   t_fin = 10. ;
  107. L_tps = 'PROG' t_deb t_fin ;
  108. * Cisaillement suivant X :
  109. UX_deb = 0. ;  UX_fin = 3. * Lg_y ;
  110. L_UX = 'PROG' UX_deb UX_fin ;
  111. EV_xy = 'EVOL' 'MANU' 'TEMPS' L_tps  'LAMX' L_UX ;
  112. chp_y = 'NOMC' 'UX  ' ('COORD' 2 CTOT) ;
  113. FF_xy = 'DEPIMP' BL1 chp_y ;
  114. CHARTOT = 'CHARGEMENT' 'DIMP' FF_xy EV_xy ;
  115.  
  116. *======================================================================*
  117. *             Initialisation de la table pour appel a PASAPAS          *
  118. *======================================================================*
  119. TAB1 = 'TABLE' ;
  120. TAB1.'MODELE' = MO ;
  121. TAB1.'CARACTERISTIQUES' = MA ;
  122. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  123. TAB1.'CHARGEMENT' = CHARTOT ;
  124. *TAB1.'PRECISION' = 1.E-6 ;
  125. *TAB1.'FTOL' = 1.E-5 ;
  126. *TAB1.'MTOL' = 1.E-5 ;
  127. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  128. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  129. TAB1.'HYPOTHESE_DEFORMATIONS' = MOT 'UTILISATEUR' ;
  130. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  131. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  132. TAB1.'REAC_GRANDS'=0.4;
  133. *
  134. L_abs = TAB1.'TEMPS_SAUVES' ;
  135. n_abs = 'DIMENSION' L_abs ;
  136. *
  137. tab1.'PROCESSEURS'='MOT' 'MONO_PROCESSEUR';
  138. PASAPAS TAB1 ;
  139. *
  140. * Quelques traces de controle apres calculs
  141. 'SI' GRAPH ;
  142.   Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  143.   Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  144.   'TRACER' (Defo_0 'ET' Defo_1)
  145.            'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  146.   'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  147.            'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  148. 'FINSI' ;
  149. *
  150. *======================================================================*
  151. *             Construction de la solution analytique                   *
  152. *======================================================================*
  153. * Definitions :
  154. * - Cisaillement selon xy : Cisx = UX/Lg_y
  155. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  156. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  157. * Dans le cas du modele de Mooney-Rivlin :
  158. *   W = C1*(I1-3.)+C2*(I2-3.) , soit dW/dI1 = C1 et dW/dI2 = C2
  159. *
  160. * Les contraintes de Cauchy sont calculables analytiquement :
  161. * - SCxx =  2.(Cisx**2).dW/dI1
  162. * - SCyy = -2.(Cisx**2).dW/dI2
  163. * - SCxy =  2.Cisx.(dW/dI1 + dW/dI2)
  164. * - SCzz = 0  (hypothese des contraintes planes)
  165. *
  166. Cisx  = ('IPOL' L_abs L_tps L_UX) / Lg_y ;
  167. L_z1 = Cisx * Cisx ;
  168. *
  169. SCxx_th =  2.*C1*L_z1 ;
  170. SCyy_th = -2.*C2*L_z1 ;
  171. SCxy_th =  2.*(C1+C2)*Cisx ;
  172.  
  173. *======================================================================*
  174. *             Comparaison des resultats avec la solution analytique    *
  175. *======================================================================*
  176. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  177. * calculees et les solutions analytiques correspondantes.
  178. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  179. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  180. *
  181. TabD = TAB1.'DEPLACEMENTS' ;
  182. TabS = TAB1.'CONTRAINTES' ;
  183. Confini = 'FORM' ;
  184. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  185. *
  186. SCxx = 'PROG' 0. ;
  187. SCyy = 'PROG' 0. ;
  188. SCxy = 'PROG' 0. ;
  189. 'REPETER' Boucle (n_abs - 1) ;
  190.   'FORM' (TabD.&Boucle) ;
  191.   VolSU = 'INTG' MO ChmUn ;
  192.   SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  193.   SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  194.   SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  195.   'FORM' Confini ;
  196. 'FIN' Boucle ;
  197. *
  198. 'SI' GRAPH ;
  199.   tlege = 'TABLE' ;
  200.   tlege. 1 = 'MARQ CROI' ;
  201.   tlege.'TITRE' = 'TABLE' ;
  202.   tlege.'TITRE'. 1 = 'Numerique' ;
  203.   tlege.'TITRE'. 2 = 'Analytique' ;
  204.   Evxx    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  205.   Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  206.   'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  207.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (Pa)') ;
  208.   Evyy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  209.   Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  210.   'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  211.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (Pa)') ;
  212.   Evxy    = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  213.   Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  214.   'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  215.            'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  216. 'FINSI' ;
  217. *
  218. * Tests de bon fonctionnement :
  219. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) ;
  220. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) ;
  221. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) ;
  222. *
  223. MESS ' RESULTATS : ' title ;
  224. MESS ' ------------------------------------------------- ';
  225. 'SAUTER' 1 'LIGNE' ;
  226. 'MESS' '  Tests de bon fonctionnement :' ;
  227. 'MESS' ' -------------------------------' ;
  228. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  229. 'MESS' ' Ecart maximal absolu entre la valeur moyenne calculee' ;
  230. 'MESS' '                         et la '
  231.        'solution analytique associee' ;
  232. 'MESS' ' Composante XX : ' r_xx ' Pa' ;
  233. 'MESS' ' Composante YY : ' r_yy ' Pa' ;
  234. 'MESS' ' Composante XY : ' r_xy ' Pa' ;
  235. 'SAUTER' 1 'LIGNE' ;
  236. * Ecart relatif maximal tolere
  237. Sigref = 1.E-3 ;
  238. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  239.   'MESS' ' ---------------------' ;
  240.   'MESS' '  ECHEC DU CAS-TEST !' ;
  241.   'MESS' ' ---------------------' ;
  242.   'ERREUR' 5 ;
  243. 'SINON' ;
  244.   'MESS' ' ----------------------' ;
  245.   'MESS' '  SUCCES DU CAS-TEST !' ;
  246.   'MESS' ' ----------------------' ;
  247. 'FINSI' ;
  248. 'SAUTER' 1 'LIGNE' ;
  249.  
  250. 'FIN' ;
  251.  
  252.  
  253.  
  254.  
  255.  
  256.  
  257.  
  258.  
  259.  
  260.  
  261.  
  262.  
  263.  
  264.  
  265.  
  266.  
  267.  
  268.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales