Exemples de jeux de données Cast3M

************************************
*******************************************
* Verification du modele GURSON2 (GTN) avec
* des elements 3D a integration reduite
*******************************************
 
OPTI 'DIME' 3 'ELEM' 'CU20';
 
* MAILLAGE
P1 = 0. 0. 0.;
P2 = 1. 0. 0.;
D1 = DROI 4 P1 P2;
S1 = D1 TRAN 4 (0. 1. 0.);
V1 = S1 VOLU 'TRAN' 20 (0. 0. 5.);
* TRAC 'CACH' V1;FIN;
 
* GTN AVEC INTEGRATION COMPLETE
MO = MODE V1 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE_ENDOM' 'GURSON2';
EV1 = EVOL 'MANU' (PROG 0. 0.02) (PROG 5.E8 7.E8);
MA = MATE MO 'YOUN' 2.E11 'NU' 0.3 'ECRO' EV1 'Q' 1.5 'FU' (2./3.) 'FF' 0.25
              'FC' 0.1 'FNS0' 0. 'FNE0' 0. 'SNS' 1.E3 'SNE' 1. 'SIGN' 1.E3
              'EPSN' 1. 'F0' 0.01 'Q2' 1.1;
 
PINF = V1 POIN 'PLAN' (0. 0. 0.) (1. 0. 0.) (0. 1. 0.) 1.E-10;
ZMAX = MAXI (COOR 3 V1);
PSUP = V1 POIN 'PLAN' (0. 0. ZMAX) (1. 0. ZMAX) (0. 1. ZMAX) 1.E-10;
BL1 = BLOQ 'DEPL' PINF;
BL2 = BLOQ 'UZ' PSUP;
 
X_DEP_I = 5.E-2;
DEP_I = DEPI BL2 X_DEP_I;
EV2 = EVOL 'MANU' (PROG 0. 1.)  (PROG 0. 1.);
CHAR1 = CHAR 'DIMP' DEP_I EV2;
 
TAB1 = TABLE;
TAB1.'MODELE' = MO;
TAB1.'CARACTERISTIQUES' = MA;
TAB1.'BLOCAGES_MECANIQUES' = BL1 ET BL2;
TAB1.'CHARGEMENT' = CHAR1;
TAB1.'TEMPS_CALCULES' = PROG 0. PAS 0.05 1.;
TAB1.'VARIABLES_INTERNES' = TABL;
TAB1.'VARIABLES_INTERNES'.(0) = (ZERO MO 'VARINTER') + 
        (MANU 'CHML' MO 'VHWF' 0.01 'TYPE' 'VARINTER' 'STRESSES');
 
PASAPAS TAB1;
* RESULTANTE
NPAS = DIME TAB1.'TEMPS_CALCULES';
EFFORT = PROG;
REPE IPAS NPAS;
    REAC1 = REDU TAB1.'REACTIONS'.(&IPAS-1) PSUP;
    RESU1 = MAXI (RESU REAC1);
    EFFORT = EFFORT ET (PROG RESU1);
FIN IPAS;
EFFORT = EVOL 'MANU' 'DEPL' TAB1.'TEMPS_CALCULES' 'FORCE' EFFORT;
 
* GTN AVEC INTEGRATION REDUITE
MO_R = MODE V1 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE_ENDOM' 'GURSON2' 'C20R';
MA_R = MATE MO_R 'YOUN' 2.E11 'NU' 0.3 'ECRO' EV1 'Q' 1.5 'FU' (2./3.) 'FF' 0.25
              'FC' 0.1 'FNS0' 0. 'FNE0' 0. 'SNS' 1.E3 'SNE' 1. 'SIGN' 1.E3
              'EPSN' 1. 'F0' 0.01 'Q2' 1.1;
 
TAB2 = TABLE;
TAB2.'MODELE' = MO_R;
TAB2.'CARACTERISTIQUES' = MA_R;
TAB2.'BLOCAGES_MECANIQUES' = BL1 ET BL2;
TAB2.'CHARGEMENT' = TAB1.'CHARGEMENT';
TAB2.'TEMPS_CALCULES' = TAB1.'TEMPS_CALCULES';
TAB2.'VARIABLES_INTERNES' = TABL;
TAB2.'VARIABLES_INTERNES'.(0) = (ZERO MO_R 'VARINTER') + 
        (MANU 'CHML' MO_R 'VHWF' 0.1 'TYPE' 'VARINTER' 'STRESSES');
 
PASAPAS TAB2;
EFFORT_R = PROG;
REPE IPAS NPAS;
    REAC1 = REDU TAB1.'REACTIONS'.(&IPAS-1) PSUP;
    RESU1 = MAXI (RESU REAC1);
    EFFORT_R = EFFORT_R ET (PROG RESU1);
FIN IPAS;
EFFORT_R = EVOL 'MANU' 'DEPL' TAB1.'TEMPS_CALCULES' 'FORCE' EFFORT_R;
 
* VERIFICATION DE LA FORCE
ECART = (INTG (EFFORT_R - EFFORT)**2)**0.5;
LIM = ((INTG EFFORT**2)**0.5) * 1.E-3;
MESS ECART LIM;
SI (ECART > LIM);
    MESS 'ERREUR DANS GURSON2 AVEC LES VALEURS PAR DEFAUT DE Q2 ET Q3';
    ERRE 5;
FINSI;
 
* VERIFICATION DU NOMBRE DE POINTS DE GAUSS
NEL = NBEL V1;
CHAM1 = MANU 'CHML' MO 'SCAL' 1. 'STRESSES';
CHPO1 = CHAN 'CHPO' MO CHAM1 'SUPP';
NGAU = (ENTI (MAXI (RESU CHPO1))) / NEL;
CHAM1 = MANU 'CHML' MO_R 'SCAL' 1. 'STRESSES';
CHPO1 = CHAN 'CHPO' MO_R CHAM1 'SUPP';
NGAU_R = (ENTI (MAXI (RESU CHPO1))) / NEL;
SI (NGAU NEG 27);
    MESS 'ERREUR : LES CU20 DEVRAIENT AVOIR 27 POINTS DE GAUSS...';
    ERRE 5;
FINSI;
SI (NGAU_R NEG 8);
    MESS 'ERREUR : LES C20R DEVRAIENT AVOIR 8 POINTS DE GAUSS...';
    ERRE 5;
FINSI;
 
FIN;