Accueil | Cast3M

* fichier :  Effet_Joule_01.dgibi
************************************************************************
************************************************************************
 
*--------------------------------------------------------------------*
*                                                                    *
*  TEST Effet_Joule_01                                               *
*  -------------------                                               *
*                                                                    *
* Cas-test de Verification uniquement (Pas de valeurs testees)       *
*                                                                    *
* Dimension du probleme   : 2D                                       *
* Elements finis utilises :'QUA4'                                    *
* Modeles utilises        :'THERMIQUE' 'CONDUCTION'                  *
*                         :'THERMIQUE' 'CONVECTION'                  *
*                         :'DIFFUSION' 'FICK'                        *
*                                                                    *
* Barreau 2D soumis a une difference de potentiel. Le courant        *
* electrique y circulant genere une source de chaleur par effet      *
* Joule. Le terme source est mis a jour au cours des iterations      *
* dans la procedure CHARTHER prevue a cet effet. La chaleur est      *
* evacuee par convection sur le contour du barreau.                  *
*                                                                    *
* Les caracteristiques materiaux ont ete choisies variables en       *
* fonction de la temperature. Elles ne correspondent pas a un        *
* materiau reel, mais se rapporche des valeurs pour le Cuivre.       *
*                                                                    *
**********************************************************************
 
'DEBP' CHARTHER PRECED*'TABLE' tt*'FLOTTANT' ;
************************************************************************
* PROCEDURE CHARTHER
* - Definition de la source de chaleur due a l'effet Joule
* - Q = Integrale sur les elements du produit scalaire J . E
* - J = SIG . E
* - E =-GRAD(Ve)
************************************************************************
 
   CHP_Ve   ='EXCO' TH_COUR 'Ve' 'Ve';
   MCH_E    ='GRAD' CHP_Ve MOD1 * -1.;
   MCH_SIG  ='REDU' CHMAT MOD1       ; 'Conductivite Electrique Instanciee';
   MCH_J    = MCH_SIG * MCH_E ('MOTS' 'KD' 'KD') ('MOTS' 'Ve,X' 'Ve,Y') ('MOTS' 'JX' 'JY');
 
*  Sauvegarde du Courant electrique
   PRECED.'ESTIMATION'.'COURANTS_ELECTRIQUES'= MCH_J;
 
*  Puissance Joule par unite de volume
   MCH_Pel  ='PSCA' MCH_J MCH_E ('MOTS' 'JX' 'JY') ('MOTS' 'Ve,X' 'Ve,Y');
 
*  Terme Source
   SRC1     =('SOUR' MCH_Pel MOD1) 'NOMC' 'Q';
 
*  Sortie du terme source dans ADDI_SECOND
   TAA      ='TABL';
   TAA.'ADDI_SECOND' = SRC1 ;
'FINP' TAA;
 
*OPTIONS GENERALES *
'OPTI' 'DIME' 2      ;
'OPTI' 'ELEM' 'QUA4' ;
'OPTI' 'TRAC' 'PSC'  ;
 
*PARAMETRES *
 V_Max = 0.5 ;         'COMM' 'Tension appliquee au bout de la piece en Volts';
 T_ini = 273.15 + 25. ;'COMM' 'Temperature en Kelvins';
 
*MAILLAGE *
 DX = 1.  ;
 DY = 0.1 ;
 
 
 P1 = 0. 0. ;
 P2 = DX 0. ;
 
 L1 ='DROI' 100 P1 P2;
 L2 ='PLUS' L1 (0. DY);
 
 S1 ='REGL' 10 L1 L2;
 C1 ='CONT' S1;
 
 MPot1 ='ELEM' C1 'APPU' 'LARG' P1 ;
 MPot2 ='ELEM' C1 'APPU' 'LARG' ('POIN' C1 'PROC' (DX DY)) ;
 
 
*MODELE *
 MOD1  ='MODE' S1 'DIFFUSION' 'INCO' 'Ve' 'Qe' ;
 MOD2  ='MODE' S1 'THERMIQUE' ;
 MOD3  ='MODE' C1 'THERMIQUE' 'CONVECTION';
 MODTOT= MOD1 'ET' MOD2 'ET' MOD3;
 
 
*Conductivite Electrique dependant de 'T'
 EvSIG='EVOL' 'MANU' 'T' ('PROG' 273.15 500.) 'KD'  ('PROG' 59.6D6 50D6 );
 
*Proprietes Thermique dependant de 'T'
 EvK  ='EVOL' 'MANU' 'T' ('PROG' 273.15 500.) 'K'   ('PROG' 401.   490. );
 EvRHO='EVOL' 'MANU' 'T' ('PROG' 273.15 500.) 'RHO' ('PROG' 8960.  8700.);
 EvC  ='EVOL' 'MANU' 'T' ('PROG' 273.15 500.) 'C'   ('PROG' 380.   390. );
 EvH  ='EVOL' 'MANU' 'T' ('PROG' 273.15 500.) 'H'   ('PROG' 10.    20. );
 
 MAT1 ='MATE' MOD1 'KD' EvSIG ;
 MAT2 ='MATE' MOD2 'K'  EvK 'RHO' EvRHO 'C' EvC ;
 MAT3 ='MATE' MOD3 'H'  EvH ;
 MATTOT= MAT1 'ET' MAT2 'ET' MAT3;
 
*Blocages
 RIG1  ='BLOQ' 'Ve' MPot1;
 RIG2  ='BLOQ' 'Ve' MPot2;
 BLODIF= RIG1 'ET' RIG2 ;
 
*Chargement : Potentiels Electrique et Temperature exterieure
 CHP_Ve1   ='DEPI' RIG1 0. ;
 EVO_Ve1   ='EVOL' 'MANU' 'TEMP' ('PROG' 0. 1.D10) 'Ve' ('PROG' 1. 1.) ;
 CHAR_Ve1  ='CHAR' 'CIMP'  CHP_Ve1 EVO_Ve1 ;
 
 CHP_Ve2   ='DEPI' RIG2 V_Max ;
 EVO_Ve2   ='EVOL' 'MANU' 'TEMP' ('PROG' 0. 10. 1.D10) 'Ve' ('PROG' 0. 1. 1.) ;
 CHAR_Ve2  ='CHAR' 'CIMP'  CHP_Ve2 EVO_Ve2 ;
 
 CHP_TECO  ='MANU' 'CHPO'  C1 1 'T' 300. ;
 EVO_TECO  ='EVOL' 'MANU' 'TEMP' ('PROG' 0. 1.D10) 'TECO' ('PROG' 1. 1.) ;
 CHAR_TECO ='CHAR' 'TECO'  CHP_TECO EVO_TECO ;
 
 CHATOT    =CHAR_Ve1 'ET' CHAR_Ve2 'ET' CHAR_TECO;
 
*Conditions Initiales
 CHP_T_INI='MANU' 'CHPO' S1 1 'T'  T_ini 'NATU' 'DIFFUS';
 
 CHP_J_INI='MANU' 'CHML' MOD1 'JX' 0. 'JY' 0. 'STRESSES';
 
*Temps calcules
 LTPS1 ='PROG' 0. 'PAS' 1. 20. ;
 
*PASAPAS *
 TAB1                           ='TABL'  ;
 TAB1.'MODELE'                  = MODTOT ;
 TAB1.'CARACTERISTIQUES'        = MATTOT ;
 TAB1.'BLOCAGES_DIFFUSIONS'     = BLODIF ;
 TAB1.'CHARGEMENT'              = CHATOT ;
 
 TAB1.'TEMPERATURES'            ='TABL'  ;
 TAB1.'TEMPERATURES' . 0        = CHP_T_INI ;
 
 TAB1.'COURANTS_ELECTRIQUES'    ='TABL'  ;
 TAB1.'COURANTS_ELECTRIQUES' . 0= CHP_J_INI ;
 
 TAB1.'TEMPS_CALCULES'          = LTPS1  ;
 
 TAB1.'PROCEDURE_CHARTHER'      = VRAI   ;
 
 PASAPAS TAB1;
 
* POST-TRAITEMENT *
 
 DIM1 ='DIME' TAB1.'TEMPS';
 
 II   = DIM1;
 tpsi = TAB1.'TEMPS'               . (II - 1) ;
 Ti   = TAB1.'TEMPERATURES'        . (II - 1) ;
 Vei  = TAB1.'CONCENTRATIONS'      . (II - 1) ;
 Ji   = TAB1.'COURANTS_ELECTRIQUES'. (II - 1) ;
 
 TIT1 ='CHAI' 'Temperature[K] a l''instant :' tpsi '[s]';
'TRAC' Ti  S1 'TITR' TIT1;
 
 TIT2 ='CHAI' 'Potentiel electrique [V] a l''instant :' tpsi '[s]';
'TRAC' Vei S1 'TITR' TIT2 ('PROG' 0. 'PAS' (V_Max / 20.) V_Max);
 
 GTi     ='GRAD' Ti MOD2;
 Amp_GTi =('PSCA' GTi GTi ('EXTR' GTi 'COMP') ('EXTR' GTi 'COMP')) ** 0.5;
 Amp_GTi = 1.D0 / ('MAXI' Amp_GTi) * 0.02;
 VectJGTi='VECT' GTi MOD2 Amp_GTi ('EXTR' GTi 'COMP')  ;
 TIT3    ='CHAI' 'Gradient de temperature [K.m-1] a l''instant :' tpsi '[s]';
'TRAC' VectJGTi S1  'TITR' TIT3;
 
 Amp_Ji=('PSCA' Ji Ji ('EXTR' Ji 'COMP') ('EXTR' Ji 'COMP')) ** 0.5;
 Amp_Ji=1.D0 / ('MAXI' Amp_Ji) * 0.02;
 VectJi ='VECT' Ji MOD1 Amp_Ji ('EXTR' Ji 'COMP')  ;
 TIT4 ='CHAI' 'Densite de courant electrique [A.m-2] a l''instant :' tpsi '[s]';
'TRAC' VectJi S1  'TITR' TIT4;
 
'FIN';