Télécharger fvlhtf.eso

Retour à la liste

Numérotation des lignes :

  1. C FVLHTF SOURCE BECC 10/06/11 21:15:08 6690
  2. SUBROUTINE FVLHTF(NESP,NSCA,
  3. & GAMG,ROG,PG,UNG,UTG,UT1G,ETHERG,EFORMG,
  4. & GAMD,ROD,PD,UND,UTD,UT1D,ETHERD,EFORMD,
  5. & YG,YD,SCAG,SCAD,FLU1,FLU2,
  6. & CELLT)
  7. C************************************************************************
  8. C
  9. C NOM : FVLHTT
  10. C
  11. C DESCRIPTION : Formulation Volumes Finis pour les Equations
  12. C d'Euler Multi-Especes relatives à un melange
  13. C de gaz ideals.
  14. C
  15. C Calcul du flux aux interfaces avec la methode
  16. C "Flux Vector Splitting" de van Leer - Hanel.
  17. C
  18. C (voir:
  19. C 1) BECCANTINI, PAILLERE,
  20. C "Upwind Flux Splitting Schemes..."
  21. C RAPPORT DMT 97//268
  22. C 2) B. VAN LEER
  23. C "Flux Vector Splittings for the 1990's"
  24. C 1990. Invited Lecture, NASA Lewis Research
  25. C Center
  26. C 3) B. VAN LEER
  27. C "Flux Vector Splitting for the Euler
  28. C Equations"
  29. C Report ICASE No. 82-30, 1982 )
  30. C
  31. C LANGUAGE : FORTRAN 77
  32. C
  33. C AUTEUR : A. BECCANTINI DRN/DMT/SEMT/TTMF
  34. C
  35. C************************************************************************
  36. C
  37. C APPELES
  38. C
  39. C FVLHTF ------ FSPVLH
  40. C |
  41. C --------- FSMVLH
  42. C
  43. C
  44. C************************************************************************
  45. C
  46. C**** Entrées:
  47. C
  48. C NESP = nombre d'especes considérées dans les Equations
  49. C d'Euler
  50. C
  51. C NSCA = nombre de scalaires passifs a transporter
  52. C
  53. C GAMG, GAMD = les "gamma" du gaz (gauche et droite)
  54. C
  55. C ROG, ROD = les densités
  56. C
  57. C PG, PD = les pressions
  58. C
  59. C UNG, UND = vitesses normales
  60. C
  61. C UTG, UTD = vitesses tangentielles
  62. C
  63. C UT1G, UT1D = vitesses tangentielles
  64. C
  65. C ETHERG, ETHERD = les energies sensibles
  66. C
  67. C EFORMG, EFORMD = les energies de formation
  68. C
  69. C YG, YD = tables des fractiones massiques
  70. C
  71. C SCAG, SCAD = tables des scalaires passifs
  72. C
  73. C**** Sorties:
  74. C
  75. C FLU1 = table du flux a l'interface dans le repaire
  76. C (n,t), i.e.
  77. C (rho*un, rho*un*un + p, rho*un*ut, rho*un*ht,
  78. C rho*un*y1, ...)
  79. C
  80. C FLU2 = table de travail, utilisé ici mais definie
  81. C avant
  82. C
  83. C CELLT = condition de stabilité, i.e.
  84. C
  85. C dT < diamax/cellt
  86. C cellt a la dimension d'une vitesse
  87. C
  88. C************************************************************************
  89. C
  90. C HISTORIQUE (Anomalies et modifications éventuelles)
  91. C
  92. C HISTORIQUE : Créé le 6.1.98
  93. C
  94. C 21.02.00 transport de scalaires passifs
  95. C
  96. C 2010: les energies des formations sont prises en compte
  97. C
  98. C************************************************************************
  99. C
  100. C N.B.: Toutes les variables sont DECLAREES
  101. C
  102. C
  103. C IMPLICIT NONE
  104. IMPLICIT INTEGER(I-N)
  105. INTEGER NESP, I1, NSCA
  106. REAL*8 GAMG,ROG,PG
  107. & ,GAMD,ROD,PD
  108. & ,AG2,AG,UNG,UTG,UT1G,MG,ETHERG,HTG,EFORMG
  109. & ,AD2,AD,UND,UTD,UT1D,MD,ETHERD,HTD,EFORMD
  110. & ,CELL,CELLT,CELLT0,AMG,AMD,PSRO,ECIN
  111. & ,YG(*),YD(*),FLU1(*),FLU2(*),SCAG(*),SCAD(*)
  112. C
  113. C
  114. C**** YG, YD, FLU1, FLU2 déjà definis avant
  115. C
  116. C Dans le cas Euler monoespece, on doit
  117. C avoir :
  118. C YG(1) = YD(1) = 0.0D0
  119. C
  120. C
  121. C**** Onde de "gauche" a "droite"
  122. C
  123. C AG = vitesse du son
  124. C MG = nombre de Mach normal
  125. C HTG = enthalpie totale
  126. C
  127. PSRO = PG / ROG
  128. ECIN = 0.5D0 * ((UNG * UNG) + (UTG * UTG) + (UT1G * UT1G))
  129. HTG = ETHERG + PSRO + ECIN + EFORMG
  130. AG2 = GAMG * PSRO
  131. AG = SQRT(AG2)
  132. MG = UNG / AG
  133. AMG = ABS(MG)
  134. CELL = (2.0D0*GAMG + (AMG*(3.0D0-GAMG)))/(GAMG+3.0D0)
  135. CELLT=(UNG+AG)/CELL
  136. C
  137. CALL FSPVLH(NESP,NSCA,GAMG,ROG,MG,AG,UTG,HTG,YG,SCAG,FLU1)
  138. C
  139. C**** Onde de "droite" a "gauche".
  140. C
  141. C AD = vitesse du son
  142. C MD = nombre de Mach normal
  143. C HTD = enthalpie totale
  144. C
  145. PSRO = PD / ROD
  146. ECIN = 0.5D0 * ((UND * UND) + (UTD * UTD) + (UT1D * UT1D))
  147. HTD = ETHERD + PSRO + ECIN + EFORMD
  148. AD2 = GAMD * PSRO
  149. AD = SQRT(AD2)
  150. MD = UND / AD
  151. AMD = ABS(MD)
  152. CELL = (2.0D0*GAMD + (AMD*(3.0D0-GAMD)))/(GAMD+3.0D0)
  153. CELLT0=(UND+AD)/CELL
  154. CELLT = MIN(CELLT,CELLT0)
  155. C
  156. CALL FSMVLH(NESP,NSCA,GAMD,ROD,MD,AD,UTD,HTD,YD,SCAD,FLU2)
  157. C
  158. C
  159. DO I1 = 1, (NSCA+NESP+4)
  160. FLU1(I1) = FLU1(I1) + FLU2(I1)
  161. ENDDO
  162. C
  163. C
  164. RETURN
  165. END
  166.  
  167.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales