Télécharger cg2.eso

Retour à la liste

Numérotation des lignes :

  1. C CG2 SOURCE PV 16/11/17 21:58:21 9180
  2. SUBROUTINE CG2(KMORS,KISA,B,X,
  3. $ KPREC,INVDIA,ILUM,ILUI,
  4. $ LRES,LNMV,
  5. $ R,P,Q,Z,
  6. $ ITER,INMV,RESID,BRTOL,ICALRS,IDDOT,IMVEC,IMPR,IRET)
  7. IMPLICIT INTEGER(I-N)
  8. IMPLICIT REAL*8 (A-H,O-Z)
  9. C***********************************************************************
  10. C NOM : CG2
  11. C DESCRIPTION :
  12. C Résolution d'un système linéaire Ax=b
  13. C par la méthode du gradient conjugué préconditionné.
  14. C
  15. C LANGAGE : FORTRAN 77 + chouhia ESOPE (pour les E/S)
  16. C AUTEUR : Stéphane GOUNAND (CEA/DRN/DMT/SEMT/TTMF)
  17. C mél : gounand@semt2.smts.cea.fr
  18. C REFERENCE (bibtex-like) :
  19. C @BOOK{templates,
  20. C AUTHOR={R.Barrett, M.Berry, T.F.Chan, J.Demmel, J.Donato,
  21. C J.Dongarra, V.Eijkhout, R.Pozo, C.Romine,
  22. C H. Van der Vorst},
  23. C TITLE={Templates for the Solution of Linear Systems :
  24. C Building Blocks for Iterative Methods},
  25. C PUBLISHER={SIAM}, YEAR={1994}, ADDRESS={Philadelphia,PA} }
  26. C -> URL : http://www.netlib.org/templates/Templates.html
  27. C***********************************************************************
  28. C APPELES (BLAS 1) : GCOPY, GAXPY (subroutines)
  29. C GNRM2, GDOT (functions)
  30. C APPELES (Calcul) : GMOMV : produit Matrice Morse - Vecteur
  31. C PSOLVE : Preconditionner solve
  32. C***********************************************************************
  33. C ENTREES :
  34. C ENTREES/SORTIES :
  35. C SORTIES :
  36. C CODE RETOUR (IRET) : 0 si ok
  37. C <0 si problème (non utilisé !)
  38. C >0 si l'algorithme n'a pas convergé
  39. C***********************************************************************
  40. C VERSION : v1, 09/02/06
  41. C HISTORIQUE : v1, 09/02/06, création
  42. C HISTORIQUE :
  43. C HISTORIQUE :
  44. C***********************************************************************
  45. C Prière de PRENDRE LE TEMPS de compléter les commentaires
  46. C en cas de modification de ce sous-programme afin de faciliter
  47. C la maintenance !
  48. C***********************************************************************
  49. *
  50. * .. Includes .. a commenter si mise au point ok
  51.  
  52. -INC PPARAM
  53. -INC CCOPTIO
  54. -INC CCREEL
  55. -INC SMLREEL
  56. POINTEUR LRES.MLREEL
  57. -INC SMLENTI
  58. POINTEUR LNMV.MLENTI
  59. POINTEUR KMORS.PMORS
  60. POINTEUR KISA.IZA
  61. POINTEUR INVDIA.IZA
  62. POINTEUR ILUM.PMORS
  63. POINTEUR ILUI.IZA
  64. POINTEUR B.IZA
  65. POINTEUR X.IZA
  66. * .. Work Vectors for CG
  67. POINTEUR R.IZA,P.IZA,Q.IZA,Z.IZA
  68. * .. Scalar Arguments ..
  69. INTEGER ITER, KPREC, IMPR, IRET
  70. REAL*8 RESID
  71. *
  72. *
  73. * .. Variables locales
  74. * .. Parameters
  75. REAL*8 ZERO , ONE
  76. PARAMETER (ZERO=0.0D0, ONE=1.0D0)
  77. * ..
  78. INTEGER MAXIT
  79. REAL*8 ALPHA,BETA,RHO,RHO1,TOL,GNRM2,OMEGA
  80. REAL*8 GDOT,BNRM2
  81. * ..
  82. * .. External subroutines and functions..
  83. EXTERNAL GAXPY,GCOPY,GDOT,GNRM2
  84. * ..
  85. * .. Executable Statements ..
  86. *
  87.  
  88. IRET = 0
  89. INMV = 0
  90. IWARN = 0
  91. IGRAN = 0
  92. MGRAN = 5
  93. MAXIT = ITER
  94. TOL = RESID
  95. IF(IMPR.GT.5) WRITE(IOIMP,*) 'Entrée dans cg2.eso'
  96. *
  97. * Set parameter tolerances.
  98. *
  99. RHOTOL = BRTOL
  100. OMETOL = BRTOL
  101. * RRMAX = 10.D0
  102. RRMAX = 1.D0/(XZPREC**0.25D0)
  103. *
  104. * Calcul du résidu initial
  105. *
  106. C r(0)=b
  107. CALL GCOPY(B,R)
  108.  
  109. C r(0)=b-Ax
  110. CALL GMOMV(IMVEC,'N',-ONE,KMORS,KISA,X,ONE,R)
  111. INMV=INMV+1
  112. *
  113. ITER = 0
  114. BNRM2 = GNRM2(B)
  115. IF(IMPR.GT.5) THEN
  116. WRITE(IOIMP,*) '||B||=',BNRM2
  117. ENDIF
  118. RNRM2 = GNRM2(R)
  119. IF (ICALRS.EQ.1) BNRM2=RNRM2
  120. IF (BNRM2.LT.XPETIT) BNRM2 = ONE
  121. RESID = RNRM2 / BNRM2
  122. IF(IMPR.GT.5) THEN
  123. WRITE(IOIMP,*) 'Initial residual=',RESID
  124. ENDIF
  125. RESMAX = RESID * RRMAX
  126. LRES.PROG(ITER+1)=RESID
  127. LNMV.LECT(ITER+1)=INMV
  128. *
  129. IF (RESID.LE.TOL) THEN
  130. IRET = 0
  131. GOTO 30
  132. ENDIF
  133.  
  134. *
  135. 10 CONTINUE
  136. *
  137. * Perform (Preconditioned) Conjugate Gradient Iteration.
  138. *
  139. ITER = ITER +1
  140. IF(IMPR.GT.7) THEN
  141. WRITE(IOIMP,*) 'ITER=',ITER
  142. ENDIF
  143. *
  144. * Preconditioner Solve
  145. C Mz(i-1)=r(i-1)
  146. CALL PSOLVE('N',KPREC,KMORS,KISA,INVDIA,ILUM,ILUI
  147. $ ,Z,R)
  148. C rho(i-1)=r(i-1)'z(i-1)
  149. RHO = GDOT(R,Z,IDDOT)
  150. * WRITE(IOIMP,*) ' RHO=',RHO
  151. IF (ABS(RHO).LT.RHOTOL) THEN
  152. RHO=SIGN(XZPREC,RHO)
  153. IWARN=IWARN+1
  154. ENDIF
  155. *
  156. * Compute direction vector P
  157. *
  158. IF (ITER.GT.1) THEN
  159. C beta(i-1)=rho(i-1)/rho(i-2)
  160. BETA = RHO / RHO1
  161. C p(i)=z(i-1)+beta(i-1)p(i-1)
  162. CALL GAXPY(BETA,P,Z)
  163. CALL GCOPY(Z,P)
  164. ELSE
  165. C p(1)=z(0)
  166. CALL GCOPY(Z,P)
  167. ENDIF
  168. *
  169. * Compute scalar ALPHA (save A*p to q)
  170. *
  171. C q(i)=Ap(i)
  172. CALL GMOMV(IMVEC,'N',ONE,KMORS,KISA,P,ZERO,Q)
  173. INMV=INMV+1
  174. C alpha(i)=rho(i-1)/(p(i)'q(i))
  175. OMEGA = GDOT(P,Q,IDDOT)
  176. * WRITE(IOIMP,*) ' OMEGA=',OMEGA
  177. IF (ABS(OMEGA).LT.OMETOL) THEN
  178. OMEGA=SIGN(XZPREC,OMEGA)
  179. IWARN=IWARN+1
  180. ENDIF
  181. ALPHA = RHO / OMEGA
  182. *
  183. * Compute current solution vector x
  184. *
  185. C x(i)=x(i-1)+alpha(i)p(i)
  186. CALL GAXPY(ALPHA,P,X)
  187. *
  188. * Compute residual vector R, find norm,
  189. * then check for tolerance
  190. *
  191. C r(i)=r(i-1)-alpha(i)r(i)
  192. CALL GAXPY(-ALPHA,Q,R)
  193. *
  194. RESID = GNRM2(R) / BNRM2
  195. IF(IMPR.GT.7) THEN
  196. WRITE(IOIMP,*) 'Résidu=',RESID
  197. ENDIF
  198. LRES.PROG(ITER+1)=RESID
  199. LNMV.LECT(ITER+1)=INMV
  200. IF (RESID.GT.RESMAX) THEN
  201. IGRAN=IGRAN+1
  202. ELSE
  203. IGRAN=0
  204. ENDIF
  205. *
  206. * Iteration successful
  207. *
  208. IF (RESID.LE.TOL) THEN
  209. IRET = 0
  210. *
  211. * Iteration fails
  212. *
  213. * ELSE IF (ITER.EQ.MAXIT.OR.IGRAN.GT.MGRAN) THEN
  214. ELSE IF (INMV.GE.MAXIT.OR.IGRAN.GT.MGRAN) THEN
  215. IRET = 1
  216. *
  217. * Do some more
  218. *
  219. ELSE
  220. RHO1 = RHO
  221. GOTO 10
  222. ENDIF
  223. *
  224. * Normal termination
  225. *
  226. 30 CONTINUE
  227. IF (IWARN.GT.0.AND.IMPR.GT.0) THEN
  228. WRITE(IOIMP,*) 'CG nearly failed ',IWARN
  229. $ ,' times.'
  230. ENDIF
  231. RETURN
  232. *
  233. * End of CG2
  234. *
  235. END
  236.  
  237.  
  238.  
  239.  
  240.  
  241.  
  242.  
  243.  
  244.  
  245.  
  246.  
  247.  
  248.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales