Télécharger capa4.eso

Retour à la liste

Numérotation des lignes :

  1. C CAPA4 SOURCE FANDEUR 11/07/19 21:15:20 7042
  2.  
  3. C=======================================================================
  4. C= C A P A 4 =
  5. C= --------- =
  6. C= =
  7. C= Fonction : =
  8. C= ---------- =
  9. C= Calcul, au point de Gauss (iGau) considere, du jacobien (DJAC), =
  10. C= des fonctions de forme (FORME) et de leurs derivees (SHP) =
  11. C= =
  12. C= Parametres : (E)=Entree (S)=Sortie =
  13. C= ------------ =
  14. C= iGau (E) Numero du point de Gauss considere =
  15. C= NBNN (E) Nombre de NOEUDS de l'element =
  16. C= XE (E) COORDONNEES des noeuds de l'element (repere GLOBAL) =
  17. C= SHPTOT (E) Fonctions de FORME et leurs DERIVEES par rapport aux =
  18. C= coordonnees de REFERENCE (Qsi,Eta,Dzeta) =
  19. C= SHP (S) Fonctions de FORME et leurs DERIVEES par rapport aux =
  20. C= coordonnees REELLES (X,Y,Z) =
  21. C= FORME (S) Fonctions de FORME dans la geometrie REELLE =
  22. C= DJAC (S) JACOBIEN au point de Gauss considere =
  23. C= =
  24. C= Denis ROBERT, le 17 fevrier 1988. =
  25. C=======================================================================
  26.  
  27. SUBROUTINE CAPA4 (NEF,iGau,NBNN,XE,SHPTOT,SHP,FORME,DJAC)
  28.  
  29. IMPLICIT INTEGER(I-N)
  30. IMPLICIT REAL*8 (A-H,O-Z)
  31.  
  32. -INC CCOPTIO
  33. -INC CCREEL
  34.  
  35. C= Quelques constantes (2.Pi et 4.Pi)
  36. PARAMETER (X2Pi= 6.283185307179586476925286766559D0)
  37. PARAMETER (X4Pi=12.566370614359172953850573533118D0)
  38.  
  39. DIMENSION XE(3,*),FORME(*),SHPTOT(6,NBNN,*),SHP(6,*)
  40.  
  41. C ====================
  42. C 1 - Initialisation
  43. C ====================
  44. C*OF CALL ZERO(FORME,1,NBNN)
  45.  
  46. C ============================================
  47. C 2 - Cas des elements MASSIFS 2D PLAN ou 3D
  48. C ============================================
  49. IF (IFOMOD.EQ.-1.OR.IFOMOD.EQ.2) THEN
  50. iFin=IDIM+1
  51. DO j=1,NBNN
  52. FORME(j)=SHPTOT(1,j,iGau)
  53. SHP(1,j)=FORME(j)
  54. DO i=2,iFin
  55. SHP(i,j)=SHPTOT(i,j,iGau)
  56. ENDDO
  57. ENDDO
  58. CALL JACOBI(XE,SHP,IDIM,NBNN,DJAC)
  59.  
  60. C ================================================
  61. C 3 - Cas des elements MASSIFS 2D AXISYMETRIQUES
  62. C ================================================
  63. ELSE IF (IFOMOD.EQ.0) THEN
  64. DO i=1,NBNN
  65. FORME(i)=SHPTOT(1,i,iGau)
  66. SHP(1,i)=FORME(i)
  67. SHP(2,i)=SHPTOT(2,i,iGau)
  68. SHP(3,i)=SHPTOT(3,i,iGau)
  69. ENDDO
  70. CALL JACOBI(XE,SHP,IDIM,NBNN,DJAC)
  71. CALL DISTRR(XE,SHP,NBNN,RR)
  72. DJAC=X2Pi*DJAC*RR
  73.  
  74. C =================================
  75. C 4 - Cas des elements MASSIFS 1D
  76. C =================================
  77. ELSE IF (IFOMOD.EQ.3.OR.IFOMOD.EQ.4.OR.IFOMOD.EQ.5) THEN
  78. C =====
  79. C 4.1 - Cas generique
  80. C =====
  81. DO i=1,NBNN
  82. FORME(i)=SHPTOT(1,i,iGau)
  83. SHP(1,i)=FORME(i)
  84. SHP(2,i)=SHPTOT(2,i,iGau)
  85. ENDDO
  86. CALL JACOBI(XE,SHP,IDIM,NBNN,DJAC)
  87. C =====
  88. C 4.2 - Cas particulier des modes axisymetriques et spherique 1D
  89. C =====
  90. IF (IFOMOD.EQ.4 .OR. IFOMOD.EQ.5) THEN
  91. CALL DISTRR(XE,SHP,NBNN,RR)
  92. IF (IFOMOD.EQ.5) THEN
  93. DJAC=X4Pi*DJAC*RR*RR
  94. ELSE
  95. DJAC=X2Pi*DJAC*RR
  96. ENDIF
  97. ENDIF
  98.  
  99. C ==============================================
  100. C 5 - Cas des elements MASSIFS en mode FOURIER -> ERREUR
  101. C ==============================================
  102. ELSE IF (IFOMOD.EQ.1) THEN
  103. CALL ERREUR(251)
  104. ENDIF
  105.  
  106. RETURN
  107. END
  108.  
  109.  
  110.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales